data/qcsrc/server/w_grenadelauncher.qc

   1 void W_Grenade_Explode (void)
   2 {
   3         vector  org2;
   4         org2 = findbetterlocation (self.origin, 12);
   5         pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
   6         sound (self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
   7
   8         self.event_damage = SUB_Null;
   9         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  10
  11         remove (self);
  12 }
  13
  14 void W_Grenade_Explode2 (void)
  15 {
  16         vector  org2;
  17         org2 = findbetterlocation (self.origin, 12);
  18         pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
  19         sound (self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  20
  21         self.event_damage = SUB_Null;
  22         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  23
  24         remove (self);
  25 }
  26
  27 void W_Grenade_Touch1 (void)
  28 {
  29         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  30         {
  31                 remove(self);
  32                 return;
  33         }
  34         W_Grenade_Explode ();
  35 }
  36
  37 void W_Grenade_Touch2 (void)
  38 {
  39         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  40         {
  41                 remove(self);
  42                 return;
  43         }
  44         if (other.takedamage == DAMAGE_AIM)
  45                 self.use ();
  46         else
  47         {
  48                 float r;
  49                 r = random() * 6;
  50                 if(r < 1)
  51                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  52                 else if(r < 2)
  53                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  54                 else if(r < 3)
  55                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  56                 else if(r < 4)
  57                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  58                 else if(r < 5)
  59                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  60                 else
  61                         sound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  62                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  63         }
  64 }
  65
  66 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  67 {
  68         self.health = self.health - damage;
  69         if (self.health <= 0)
  70         {
  71                 self.owner = attacker;
  72                 self.think ();
  73         }
  74 }
  75
  76 void W_Grenade_Attack (void)
  77 {
  78         local entity gren;
  79
  80         if not(self.items & IT_UNLIMITED_AMMO)
  81                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  82         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/grenade_fire.wav");
  83         //W_SetupShot (self, '25 8 -8', FALSE, 4, "weapons/grenade_fire.wav"); // TODO: move model to the right a little
  84
  85         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  86
  87         gren = spawn ();
  88         gren.owner = self;
  89         gren.classname = "grenade";
  90         gren.bot_dodge = TRUE;
  91         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  92         gren.movetype = MOVETYPE_BOUNCE;
  93         gren.solid = SOLID_BBOX;
  94         gren.effects = EF_LOWPRECISION;
  95         gren.modelflags = MF_TRACER2;
  96         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
  97         setmodel(gren, "models/grenademodel.md3"); // precision set above
  98         setsize(gren, '0 0 0', '0 0 0');
  99         setorigin(gren, w_shotorg);
 100
 101         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 102         gren.think = adaptor_think2use;
 103         gren.use = W_Grenade_Explode;
 104         gren.touch = W_Grenade_Touch1;
 105         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 106         W_SetupProjectileVelocity(gren);
 107         gren.avelocity_x = random () * -500 - 500;
 108
 109         gren.angles = vectoangles (gren.velocity);
 110         gren.flags = FL_PROJECTILE;
 111 }
 112
 113 void W_Grenade_Attack2 (void)
 114 {
 115         local entity gren;
 116
 117         if not(self.items & IT_UNLIMITED_AMMO)
 118                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 119         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/grenade_fire.wav");
 120         //W_SetupShot (self, '25 8 -8', FALSE, 4, "weapons/grenade_fire.wav"); // TODO: move model to the right a little
 121
 122         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 123
 124         gren = spawn ();
 125         gren.owner = self;
 126         gren.classname = "grenade";
 127         gren.bot_dodge = TRUE;
 128         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 129         gren.movetype = MOVETYPE_BOUNCE;
 130         gren.solid = SOLID_BBOX;
 131         gren.effects = EF_LOWPRECISION;
 132         gren.modelflags = MF_TRACER2;
 133         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 134         setmodel(gren, "models/grenademodel.md3"); // precision set above
 135         setsize(gren, '0 0 -3', '0 0 -3');
 136         setorigin(gren, w_shotorg);
 137
 138         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 139         gren.think = adaptor_think2use;
 140         gren.use = W_Grenade_Explode2;
 141         gren.touch = W_Grenade_Touch2;
 142         gren.takedamage = DAMAGE_YES;
 143         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 144         gren.damageforcescale = 4;
 145         gren.event_damage = W_Grenade_Damage;
 146         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 147         W_SetupProjectileVelocity(gren);
 148         gren.avelocity = '100 150 100';
 149
 150         gren.angles = vectoangles (gren.velocity);
 151         gren.flags = FL_PROJECTILE;
 152 }
 153
 154 void spawnfunc_weapon_grenadelauncher (void)
 155 {
 156         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 157 }
 158
 159 .float bot_secondary_grenademooth;
 160 float w_glauncher(float req)
 161 {
 162         if (req == WR_AIM)
 163         {
 164                 self.BUTTON_ATCK = FALSE;
 165                 self.BUTTON_ATCK2 = FALSE;
 166                 if (self.bot_secondary_grenademooth == 0)
 167                 {
 168                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 169                         {
 170                                 self.BUTTON_ATCK = TRUE;
 171                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 172                         }
 173                 }
 174                 else
 175                 {
 176                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 177                         {
 178                                 self.BUTTON_ATCK2 = TRUE;
 179                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 180                         }
 181                 }
 182         }
 183         else if (req == WR_THINK)
 184         {
 185                 if (self.BUTTON_ATCK)
 186                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 187                 {
 188                         W_Grenade_Attack();
 189                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 190                 }
 191                 if (self.BUTTON_ATCK2)
 192                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 193                 {
 194                         W_Grenade_Attack2();
 195                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 196                 }
 197         }
 198         else if (req == WR_PRECACHE)
 199         {
 200                 precache_model ("models/grenademodel.md3");
 201                 precache_model ("models/weapons/g_gl.md3");
 202                 precache_model ("models/weapons/v_gl.md3");
 203                 precache_model ("models/weapons/w_gl.zym");
 204                 precache_sound ("weapons/grenade_bounce1.wav");
 205                 precache_sound ("weapons/grenade_bounce2.wav");
 206                 precache_sound ("weapons/grenade_bounce3.wav");
 207                 precache_sound ("weapons/grenade_bounce4.wav");
 208                 precache_sound ("weapons/grenade_bounce5.wav");
 209                 precache_sound ("weapons/grenade_bounce6.wav");
 210                 precache_sound ("weapons/grenade_fire.wav");
 211                 precache_sound ("weapons/grenade_impact.wav");
 212         }
 213         else if (req == WR_SETUP)
 214                 weapon_setup(WEP_GRENADE_LAUNCHER);
 215         else if (req == WR_CHECKAMMO1)
 216                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 217         else if (req == WR_CHECKAMMO2)
 218                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 219         else if (req == WR_SUICIDEMESSAGE)
 220         {
 221                 if(w_deathtype & HITTYPE_SECONDARY)
 222                         w_deathtypestring = "tried out his own grenade";
 223                 else
 224                         w_deathtypestring = "detonated";
 225         }
 226         else if (req == WR_KILLMESSAGE)
 227         {
 228                 if(w_deathtype & HITTYPE_SPLASH)
 229                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 230                                 w_deathtypestring = "didn't see #'s grenade";
 231                         else // unchecked: SECONDARY
 232                                 w_deathtypestring = "almost dodged #'s grenade";
 233                 else // unchecked: SECONDARY, BOUNCE
 234                         w_deathtypestring = "ate #'s grenade";
 235         }
 236         return TRUE;
 237 };