data/qcsrc/server/w_electro.qc

   1
   2 void W_Plasma_Explode (void)
   3 {
   4         vector org2;
   5         org2 = findbetterlocation (self.origin, 8);
   6         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
   7         WriteByte (MSG_BROADCAST, 79);
   8         WriteCoord (MSG_BROADCAST, org2_x);
   9         WriteCoord (MSG_BROADCAST, org2_y);
  10         WriteCoord (MSG_BROADCAST, org2_z);
  11         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  12         WriteCoord (MSG_BROADCAST, 0);
  13         WriteCoord (MSG_BROADCAST, 0);
  14         WriteByte (MSG_BROADCAST, 155);
  15
  16         self.event_damage = SUB_Null;
  17         if (self.movetype == MOVETYPE_BOUNCE)
  18                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), IT_ELECTRO);
  19         else
  20                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), IT_ELECTRO);
  21         sound (self, CHAN_BODY, "weapons/electro_impact.wav", 1, ATTN_NORM);
  22
  23         remove (self);
  24 }
  25
  26 void W_Plasma_Explode_Combo (void) {
  27         vector org2;
  28
  29         org2 = findbetterlocation (self.origin, 8);
  30         te_spikequad(self.origin);
  31
  32         sound (self, CHAN_BODY, "weapons/electro_impact_combo.wav", 1, ATTN_NORM);
  33
  34         self.event_damage = SUB_Null;
  35         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), IT_ELECTRO);
  36         te_explosionrgb(org2, '0.5 0.5 1');
  37         remove (self);
  38 }
  39
  40 void W_Plasma_Touch (void)
  41 {
  42         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  43         {
  44                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  45                 remove(self);
  46                 return;
  47         }
  48         if (other.takedamage == DAMAGE_AIM) {
  49                 W_Plasma_Explode ();
  50         } else {
  51                 sound (self, CHAN_IMPACT, "weapons/electro_bounce.wav", 1, ATTN_NORM);
  52         }
  53 }
  54
  55 void W_Plasma_TouchExplode (void)
  56 {
  57         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  58         {
  59                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  60                 remove(self);
  61                 return;
  62         }
  63         W_Plasma_Explode ();
  64 }
  65
  66 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  67 {
  68         self.health = self.health - damage;
  69         if (self.health <= 0)
  70         {
  71                 self.takedamage = DAMAGE_NO;
  72                 self.nextthink = time;
  73                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  74                 {
  75                         // change owner to whoever caused the combo explosion
  76                         self.owner = inflictor.owner;
  77                         self.classname = "plasma_chain";
  78                         self.think = W_Plasma_Explode_Combo;
  79                 }
  80                 else
  81                         self.think = W_Plasma_Explode;
  82         }
  83 }
  84
  85 void() W_Electro_Attack
  86 {
  87         local entity proj;
  88
  89         W_SetupShot (self, '11 8 -8', FALSE, 2, "weapons/electro_fire.wav");
  90
  91         proj = spawn ();
  92         proj.classname = "plasma_prim";
  93         proj.owner = self;
  94         proj.bot_dodge = TRUE;
  95         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
  96         proj.think = W_Plasma_Explode;
  97         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
  98         proj.solid = SOLID_BBOX;
  99         setorigin(proj, w_shotorg);
 100
 101         if (cvar("g_use_ammunition"))
 102                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 103         proj.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 104         proj.movetype = MOVETYPE_FLY;
 105         proj.velocity = w_shotdir * cvar("g_balance_electro_primary_speed");
 106         W_SetupProjectileVelocity(proj);
 107         proj.angles = vectoangles(proj.velocity);
 108         proj.touch = W_Plasma_TouchExplode;
 109         proj.flags = FL_PROJECTILE;
 110         setmodel(proj, "models/elaser.mdl"); // precision set above
 111         setsize(proj, '0 0 0', '0 0 0');
 112
 113         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 114         //sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 115 }
 116
 117 void() W_Electro_Attack2
 118 {
 119         local entity proj;
 120
 121         W_SetupShot (self, '8 3 -13', FALSE, 2, "weapons/electro_fire2.wav");
 122
 123         proj = spawn ();
 124         proj.classname = "plasma";
 125         proj.owner = self;
 126         proj.think = W_Plasma_Explode;
 127         proj.bot_dodge = TRUE;
 128         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 129         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 130         proj.solid = SOLID_BBOX;
 131         setorigin(proj, w_shotorg);
 132
 133         if (cvar("g_use_ammunition"))
 134                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 135         proj.effects = EF_LOWPRECISION;
 136         //proj.glow_size = 50;
 137         //proj.glow_color = 45;
 138         proj.movetype = MOVETYPE_BOUNCE;
 139         proj.velocity = v_forward * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 140         W_SetupProjectileVelocity(proj);
 141         proj.touch = W_Plasma_Touch;
 142         setmodel(proj, "models/ebomb.mdl"); // precision set above
 143         setsize(proj, '0 0 -3', '0 0 -3');
 144         proj.takedamage = DAMAGE_YES;
 145         proj.damageforcescale = 4;
 146         proj.health = 5;
 147         proj.event_damage = W_Plasma_Damage;
 148         proj.flags = FL_PROJECTILE;
 149
 150         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 151         //sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 152 }
 153
 154 .float bot_secondary_electromooth;
 155 float(float req) w_electro =
 156 {
 157         if (req == WR_AIM)
 158         {
 159                 self.button0=FALSE;
 160                 self.button3=FALSE;
 161                 if(vlen(self.origin-self.enemy.origin) > 1000)
 162                         self.bot_secondary_electromooth = 0;
 163                 if(self.bot_secondary_electromooth == 0)
 164                 {
 165                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 166                         {
 167                                 self.button0 = TRUE;
 168                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 169                         }
 170                 }
 171                 else
 172                 {
 173                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 174                         {
 175                                 self.button3 = TRUE;
 176                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 177                         }
 178                 }
 179         }
 180         else if (req == WR_THINK)
 181         {
 182                 if (self.button0)
 183                 if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 184                 {
 185                         W_Electro_Attack();
 186                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 187                 }
 188                 if (self.button3)
 189                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 190                 {
 191                         W_Electro_Attack2();
 192                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), w_ready);
 193                 }
 194         }
 195         else if (req == WR_PRECACHE)
 196         {
 197                 precache_model ("models/ebomb.mdl");
 198                 precache_model ("models/elaser.mdl");
 199                 precache_model ("models/weapons/g_electro.md3");
 200                 precache_model ("models/weapons/v_electro.md3");
 201                 precache_model ("models/weapons/w_electro.zym");
 202                 precache_sound ("weapons/electro_bounce.wav");
 203                 precache_sound ("weapons/electro_fire.wav");
 204                 precache_sound ("weapons/electro_fire2.wav");
 205                 precache_sound ("weapons/electro_fly.wav");
 206                 precache_sound ("weapons/electro_impact.wav");
 207                 precache_sound ("weapons/electro_impact_combo.wav");
 208         }
 209         else if (req == WR_SETUP)
 210                 weapon_setup(WEP_ELECTRO, "electro", IT_CELLS);
 211         else if (req == WR_CHECKAMMO1)
 212                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 213         else if (req == WR_CHECKAMMO2)
 214                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 215         return TRUE;
 216 };