data/qcsrc/server/w_electro.qc

   1
   2 void W_Plasma_Explode (void)
   3 {
   4         vector org2;
   5         org2 = findbetterlocation (self.origin, 8);
   6
   7         self.event_damage = SUB_Null;
   8         if (self.movetype == MOVETYPE_BOUNCE)
   9         {
  10                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
  11                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), WEP_ELECTRO);
  12         }
  13         else
  14         {
  15                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
  16                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), WEP_ELECTRO);
  17         }
  18         sound (self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
  19
  20         remove (self);
  21 }
  22
  23 void W_Plasma_Explode_Combo (void) {
  24         vector org2;
  25
  26         org2 = findbetterlocation (self.origin, 8);
  27         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
  28
  29         sound (self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
  30
  31         self.event_damage = SUB_Null;
  32         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO);
  33         remove (self);
  34 }
  35
  36 void W_Plasma_Touch (void)
  37 {
  38         entity o;
  39         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  40         {
  41                 sound (self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
  42                 remove(self);
  43                 return;
  44         }
  45         if (other.takedamage == DAMAGE_AIM) {
  46                 o = self.owner;
  47                 W_Plasma_Explode ();
  48                 if(other.classname == "player")
  49                         if(IsDifferentTeam(o, other))
  50                                 if(IsFlying(other))
  51                                         announce(o, "announcer/male/electrobitch.ogg");
  52         } else {
  53                 sound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  54         }
  55 }
  56
  57 void W_Plasma_TouchExplode (void)
  58 {
  59         entity o;
  60         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  61         {
  62                 sound (self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
  63                 remove(self);
  64                 return;
  65         }
  66         o = self.owner;
  67         W_Plasma_Explode ();
  68         if(other.takedamage == DAMAGE_AIM)
  69                 if(other.classname == "player")
  70                         if(IsDifferentTeam(o, other))
  71                                 if(IsFlying(other))
  72                                         announce(o, "announcer/male/electrobitch.ogg");
  73 }
  74
  75 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  76 {
  77         self.health = self.health - damage;
  78         if (self.health <= 0)
  79         {
  80                 self.takedamage = DAMAGE_NO;
  81                 self.nextthink = time;
  82                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  83                 {
  84                         // change owner to whoever caused the combo explosion
  85                         self.owner = inflictor.owner;
  86                         self.classname = "plasma_chain";
  87                         self.think = W_Plasma_Explode_Combo;
  88                 }
  89                 else
  90                         self.think = W_Plasma_Explode;
  91         }
  92 }
  93
  94 void W_Electro_Attack()
  95 {
  96         local entity proj;
  97
  98         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/electro_fire.wav");
  99
 100         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 101
 102         proj = spawn ();
 103         proj.classname = "plasma_prim";
 104         proj.owner = self;
 105         proj.bot_dodge = TRUE;
 106         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 107         proj.think = W_Plasma_Explode;
 108         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 109         proj.solid = SOLID_BBOX;
 110         setorigin(proj, w_shotorg);
 111
 112         if not(self.items & IT_UNLIMITED_AMMO)
 113                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 114         proj.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 115         proj.movetype = MOVETYPE_FLY;
 116         proj.velocity = w_shotdir * cvar("g_balance_electro_primary_speed");
 117         W_SetupProjectileVelocity(proj);
 118         proj.angles = vectoangles(proj.velocity);
 119         proj.touch = W_Plasma_TouchExplode;
 120         proj.flags = FL_PROJECTILE;
 121         setmodel(proj, "models/elaser.mdl"); // precision set above
 122         setsize(proj, '0 0 0', '0 0 0');
 123
 124         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 125         //sound (proj, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 126 }
 127
 128 void W_Electro_Attack2()
 129 {
 130         local entity proj;
 131
 132         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/electro_fire2.wav");
 133
 134         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 135
 136         proj = spawn ();
 137         proj.classname = "plasma";
 138         proj.owner = self;
 139         proj.think = W_Plasma_Explode;
 140         proj.bot_dodge = TRUE;
 141         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 142         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 143         proj.solid = SOLID_BBOX;
 144         setorigin(proj, w_shotorg);
 145
 146         if not(self.items & IT_UNLIMITED_AMMO)
 147                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 148         proj.effects = EF_LOWPRECISION;
 149         //proj.glow_size = 50;
 150         //proj.glow_color = 45;
 151         proj.movetype = MOVETYPE_BOUNCE;
 152         proj.velocity = (w_shotdir + randomvec() * cvar("g_balance_electro_secondary_spread")) * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 153         W_SetupProjectileVelocity(proj);
 154         proj.touch = W_Plasma_Touch;
 155         setmodel(proj, "models/ebomb.mdl"); // precision set above
 156         setsize(proj, '0 0 -3', '0 0 -3');
 157         proj.takedamage = DAMAGE_YES;
 158         proj.damageforcescale = 4;
 159         proj.health = cvar("g_balance_electro_secondary_health");
 160         proj.event_damage = W_Plasma_Damage;
 161         proj.flags = FL_PROJECTILE;
 162
 163         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 164         //sound (proj, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 165 }
 166
 167 void spawnfunc_weapon_electro (void)
 168 {
 169         weapon_defaultspawnfunc(WEP_ELECTRO);
 170 }
 171
 172 .float bot_secondary_electromooth;
 173 float w_electro(float req)
 174 {
 175         if (req == WR_AIM)
 176         {
 177                 self.BUTTON_ATCK=FALSE;
 178                 self.BUTTON_ATCK2=FALSE;
 179                 if(vlen(self.origin-self.enemy.origin) > 1000)
 180                         self.bot_secondary_electromooth = 0;
 181                 if(self.bot_secondary_electromooth == 0)
 182                 {
 183                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 184                         {
 185                                 self.BUTTON_ATCK = TRUE;
 186                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 187                         }
 188                 }
 189                 else
 190                 {
 191                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 192                         {
 193                                 self.BUTTON_ATCK2 = TRUE;
 194                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 195                         }
 196                 }
 197         }
 198         else if (req == WR_THINK)
 199         {
 200                 if (self.BUTTON_ATCK)
 201                 if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 202                 {
 203                         W_Electro_Attack();
 204                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 205                 }
 206                 if (self.BUTTON_ATCK2)
 207                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 208                 {
 209                         W_Electro_Attack2();
 210                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), w_ready);
 211                 }
 212         }
 213         else if (req == WR_PRECACHE)
 214         {
 215                 precache_model ("models/ebomb.mdl");
 216                 precache_model ("models/elaser.mdl");
 217                 precache_model ("models/weapons/g_electro.md3");
 218                 precache_model ("models/weapons/v_electro.md3");
 219                 precache_model ("models/weapons/w_electro.zym");
 220                 precache_sound ("weapons/electro_bounce.wav");
 221                 precache_sound ("weapons/electro_fire.wav");
 222                 precache_sound ("weapons/electro_fire2.wav");
 223                 precache_sound ("weapons/electro_fly.wav");
 224                 precache_sound ("weapons/electro_impact.wav");
 225                 precache_sound ("weapons/electro_impact_combo.wav");
 226         }
 227         else if (req == WR_SETUP)
 228                 weapon_setup(WEP_ELECTRO);
 229         else if (req == WR_CHECKAMMO1)
 230                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 231         else if (req == WR_CHECKAMMO2)
 232                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 233         else if (req == WR_SUICIDEMESSAGE)
 234                 w_deathtypestring = "played with plasma";
 235         // else if (req == WR_KILLMESSAGE) // TODO
 236         return TRUE;
 237 };