data/qcsrc/server/w_crylink.qc

   1 .float gravity;
   2
   3 .entity realowner;
   4
   5 // NO bounce protection, as bounces are limited!
   6 void W_Crylink_Touch (void)
   7 {
   8         float finalhit;
   9         float f;
  10         PROJECTILE_TOUCH;
  11         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  12         if(finalhit)
  13                 f = 1;
  14         else
  15                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
  16         if(self.alpha)
  17                 f *= self.alpha;
  18         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other);
  19         if (finalhit)
  20         {
  21                 remove (self);
  22                 return;
  23         }
  24         self.cnt = self.cnt - 1;
  25         self.angles = vectoangles(self.velocity);
  26         self.owner = world;
  27         self.projectiledeathtype |= HITTYPE_BOUNCE;
  28         // commented out as it causes a little hitch...
  29         //if(proj.cnt == 0)
  30         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
  31 }
  32
  33 void W_Crylink_Touch2 (void)
  34 {
  35         float finalhit;
  36         float f;
  37         PROJECTILE_TOUCH;
  38         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  39         if(finalhit)
  40                 f = 1;
  41         else
  42                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
  43         if(self.alpha)
  44                 f *= self.alpha;
  45         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other);
  46         if (finalhit)
  47         {
  48                 remove (self);
  49                 return;
  50         }
  51         self.cnt = self.cnt - 1;
  52         self.angles = vectoangles(self.velocity);
  53         self.owner = world;
  54         self.projectiledeathtype |= HITTYPE_BOUNCE;
  55         // commented out as it causes a little hitch...
  56         //if(proj.cnt == 0)
  57         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
  58 }
  59
  60 void W_Crylink_Attack (void)
  61 {
  62         local float counter, shots;
  63         local entity proj;
  64         local vector s;
  65         vector forward, right, up;
  66
  67         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  68                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
  69
  70         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire.wav", (cvar("g_balance_crylink_primary_damage")*cvar("g_balance_crylink_primary_shots")));
  71         forward = v_forward;
  72         right = v_right;
  73         up = v_up;
  74
  75         shots = cvar("g_balance_crylink_primary_shots");
  76         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
  77         while (counter < shots)
  78         {
  79                 proj = spawn ();
  80                 proj.realowner = proj.owner = self;
  81                 proj.classname = "spike";
  82                 proj.bot_dodge = TRUE;
  83                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
  84
  85                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
  86                 PROJECTILE_MAKETRIGGER(proj);
  87                 proj.projectiledeathtype = WEP_CRYLINK;
  88                 //proj.gravity = 0.001;
  89
  90                 setorigin (proj, w_shotorg);
  91                 setsize(proj, '0 0 0', '0 0 0');
  92
  93
  94                 s = '0 0 0';
  95                 if (counter == 0)
  96                         s = '0 0 0';
  97                 else
  98                 {
  99                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 100                         s_y = v_forward_x;
 101                         s_z = v_forward_y;
 102                 }
 103                 s = s * cvar("g_balance_crylink_primary_spread");
 104                 proj.velocity = (w_shotdir + right * s_y + up * s_z) * cvar("g_balance_crylink_primary_speed");
 105 //              proj.velocity = (w_shotdir + randomvec() * cvar("g_balance_crylink_primary_spread")) * cvar("g_balance_crylink_primary_speed");
 106                 W_SetupProjectileVelocity(proj);
 107                 proj.touch = W_Crylink_Touch;
 108                 if(counter == 0)
 109                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_middle_lifetime"), cvar("g_balance_crylink_primary_middle_fadetime"));
 110                 else if(counter <= 3)
 111                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_star_lifetime"), cvar("g_balance_crylink_primary_star_fadetime"));
 112                 else
 113                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_other_lifetime"), cvar("g_balance_crylink_primary_other_fadetime"));
 114                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
 115                 //proj.scale = 1 + 1 * proj.cnt;
 116
 117                 proj.angles = vectoangles (proj.velocity);
 118
 119                 //proj.glow_size = 20;
 120
 121                 proj.flags = FL_PROJECTILE;
 122
 123                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 124
 125                 counter = counter + 1;
 126         }
 127 }
 128
 129 void W_Crylink_Attack2 (void)
 130 {
 131         local float counter, shots;
 132         local entity proj;
 133
 134         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 135                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
 136
 137         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire2.wav", (cvar("g_balance_crylink_secondary_damage")*cvar("g_balance_crylink_secondary_shots")));
 138
 139         shots = cvar("g_balance_crylink_secondary_shots");
 140         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 141         while (counter < shots)
 142         {
 143                 proj = spawn ();
 144                 proj.realowner = proj.owner = self;
 145                 proj.classname = "spike";
 146                 proj.bot_dodge = TRUE;
 147                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
 148
 149                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 150                 PROJECTILE_MAKETRIGGER(proj);
 151                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 152                 //proj.gravity = 0.001;
 153
 154                 setorigin (proj, w_shotorg);
 155                 setsize(proj, '0 0 0', '0 0 0');
 156
 157                 proj.velocity = (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread")) * cvar("g_balance_crylink_secondary_speed");
 158                 W_SetupProjectileVelocity(proj);
 159                 proj.touch = W_Crylink_Touch2;
 160                 if(counter == (shots - 1) / 2)
 161                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_middle_lifetime"), cvar("g_balance_crylink_secondary_middle_fadetime"));
 162                 else
 163                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_line_lifetime"), cvar("g_balance_crylink_secondary_line_fadetime"));
 164                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
 165                 //proj.scale = 1 + 1 * proj.cnt;
 166
 167                 proj.angles = vectoangles (proj.velocity);
 168
 169                 //proj.glow_size = 20;
 170
 171                 proj.flags = FL_PROJECTILE;
 172
 173                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 174
 175                 counter = counter + 1;
 176         }
 177 }
 178
 179
 180 /*
 181 // experimental lightning gun
 182 void W_Crylink_Attack3 (void)
 183 {
 184         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 185                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
 186         W_SetupShot (self, TRUE, 0, "weapons/crylink_fire.wav");
 187
 188         traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * 1000, FALSE, self, self.ping * 0.001);
 189
 190         pointparticles(particleeffectnum("lightning_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 191         pointparticles(particleeffectnum("lightning_impact", trace_endpos, trace_plane_normal * 1000, 1);
 192         trailparticles(world, particleeffectnum("lightning_beam", w_shotorg, trace_endpos);
 193
 194         if (trace_fraction < 1)
 195                 Damage(trace_ent, self, self, cvar("g_balance_crylink_primary_damage"), WEP_CRYLINK | HITTYPE_SECONDARY, trace_endpos, '0 0 0');
 196 }
 197 */
 198
 199 void spawnfunc_weapon_crylink (void)
 200 {
 201         weapon_defaultspawnfunc(WEP_CRYLINK);
 202 }
 203
 204 float w_crylink(float req)
 205 {
 206         if (req == WR_AIM)
 207         {
 208                 if (random() > 0.15)
 209                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
 210                 else
 211                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
 212         }
 213         else if (req == WR_THINK)
 214         {
 215                 if (self.BUTTON_ATCK)
 216                 if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
 217                 {
 218                         W_Crylink_Attack();
 219                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
 220                 }
 221                 if (self.BUTTON_ATCK2)
 222                 if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
 223                 {
 224                         W_Crylink_Attack2();
 225                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
 226                 }
 227         }
 228         else if (req == WR_PRECACHE)
 229         {
 230                 precache_model ("models/weapons/g_crylink.md3");
 231                 precache_model ("models/weapons/v_crylink.md3");
 232                 precache_model ("models/weapons/h_crylink.dpm");
 233                 precache_sound ("weapons/crylink_fire.wav");
 234                 precache_sound ("weapons/crylink_fire2.wav");
 235         }
 236         else if (req == WR_SETUP)
 237                 weapon_setup(WEP_CRYLINK);
 238         else if (req == WR_CHECKAMMO1)
 239                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
 240         else if (req == WR_CHECKAMMO2)
 241                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
 242         else if (req == WR_SUICIDEMESSAGE)
 243         {
 244                 w_deathtypestring = "succeeded at self-destructing themself with the Crylink";
 245         }
 246         else if (req == WR_KILLMESSAGE)
 247         {
 248                 if(w_deathtype & HITTYPE_BOUNCE)
 249                         w_deathtypestring = "could not hide from #'s Crylink"; // unchecked: SPLASH (SECONDARY can't be)
 250                 else if(w_deathtype & HITTYPE_SPLASH)
 251                         w_deathtypestring = "was too close to #'s Crylink"; // unchecked: SECONDARY
 252                 else
 253                         w_deathtypestring = "took a close look at #'s Crylink"; // unchecked: SECONDARY
 254         }
 255         return TRUE;
 256 };