crylink: honor g_weaponspreadfactor
[divverent/nexuiz.git] / data / qcsrc / server / w_crylink.qc
1 .float gravity;
2
3 .entity realowner;
4
5 // NO bounce protection, as bounces are limited!
6 void W_Crylink_Touch (void)
7 {
8         float finalhit;
9         float f;
10         PROJECTILE_TOUCH;
11         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
12         if(finalhit)
13                 f = 1;
14         else
15                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
16         if(self.alpha)
17                 f *= self.alpha;
18         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other);
19         if (finalhit)
20         {
21                 remove (self);
22                 return;
23         }
24         self.cnt = self.cnt - 1;
25         self.angles = vectoangles(self.velocity);
26         self.owner = world;
27         self.projectiledeathtype |= HITTYPE_BOUNCE;
28         // commented out as it causes a little hitch...
29         //if(proj.cnt == 0)
30         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
31 }
32
33 void W_Crylink_Touch2 (void)
34 {
35         float finalhit;
36         float f;
37         PROJECTILE_TOUCH;
38         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
39         if(finalhit)
40                 f = 1;
41         else
42                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
43         if(self.alpha)
44                 f *= self.alpha;
45         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other);
46         if (finalhit)
47         {
48                 remove (self);
49                 return;
50         }
51         self.cnt = self.cnt - 1;
52         self.angles = vectoangles(self.velocity);
53         self.owner = world;
54         self.projectiledeathtype |= HITTYPE_BOUNCE;
55         // commented out as it causes a little hitch...
56         //if(proj.cnt == 0)
57         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
58 }
59
60 void W_Crylink_Attack (void)
61 {
62         local float counter, shots;
63         local entity proj;
64         local vector s;
65         vector forward, right, up;
66
67         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
68                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
69
70         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire.wav", (cvar("g_balance_crylink_primary_damage")*cvar("g_balance_crylink_primary_shots")));
71         forward = v_forward;
72         right = v_right;
73         up = v_up;
74
75         shots = cvar("g_balance_crylink_primary_shots");
76         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
77         while (counter < shots)
78         {
79                 proj = spawn ();
80                 proj.realowner = proj.owner = self;
81                 proj.classname = "spike";
82                 proj.bot_dodge = TRUE;
83                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
84
85                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
86                 PROJECTILE_MAKETRIGGER(proj);
87                 proj.projectiledeathtype = WEP_CRYLINK;
88                 //proj.gravity = 0.001;
89
90                 setorigin (proj, w_shotorg);
91                 setsize(proj, '0 0 0', '0 0 0');
92
93
94                 s = '0 0 0';
95                 if (counter == 0)
96                         s = '0 0 0';
97                 else
98                 {
99                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
100                         s_y = v_forward_x;
101                         s_z = v_forward_y;
102                 }
103                 s = s * cvar("g_balance_crylink_primary_spread") * g_weaponspreadfactor;
104                 W_SetupProjectileVelocityEx(proj, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_crylink_primary_speed"), 0, 0);
105                 proj.touch = W_Crylink_Touch;
106                 if(counter == 0)
107                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_middle_lifetime"), cvar("g_balance_crylink_primary_middle_fadetime"));
108                 else if(counter <= 3)
109                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_star_lifetime"), cvar("g_balance_crylink_primary_star_fadetime"));
110                 else
111                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_other_lifetime"), cvar("g_balance_crylink_primary_other_fadetime"));
112                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
113                 //proj.scale = 1 + 1 * proj.cnt;
114
115                 proj.angles = vectoangles (proj.velocity);
116
117                 //proj.glow_size = 20;
118
119                 proj.flags = FL_PROJECTILE;
120
121                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
122
123                 counter = counter + 1;
124         }
125 }
126
127 void W_Crylink_Attack2 (void)
128 {
129         local float counter, shots;
130         local entity proj;
131
132         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
133                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
134
135         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire2.wav", (cvar("g_balance_crylink_secondary_damage")*cvar("g_balance_crylink_secondary_shots")));
136
137         shots = cvar("g_balance_crylink_secondary_shots");
138         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
139         while (counter < shots)
140         {
141                 proj = spawn ();
142                 proj.realowner = proj.owner = self;
143                 proj.classname = "spike";
144                 proj.bot_dodge = TRUE;
145                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
146
147                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
148                 PROJECTILE_MAKETRIGGER(proj);
149                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
150                 //proj.gravity = 0.001;
151
152                 setorigin (proj, w_shotorg);
153                 setsize(proj, '0 0 0', '0 0 0');
154
155                 W_SetupProjectileVelocityEx(proj, (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread") * g_weaponspreadfactor), v_up, cvar("g_balance_crylink_secondary_speed"), 0, 0);
156                 proj.touch = W_Crylink_Touch2;
157                 if(counter == (shots - 1) / 2)
158                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_middle_lifetime"), cvar("g_balance_crylink_secondary_middle_fadetime"));
159                 else
160                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_line_lifetime"), cvar("g_balance_crylink_secondary_line_fadetime"));
161                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
162                 //proj.scale = 1 + 1 * proj.cnt;
163
164                 proj.angles = vectoangles (proj.velocity);
165
166                 //proj.glow_size = 20;
167
168                 proj.flags = FL_PROJECTILE;
169
170                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
171
172                 counter = counter + 1;
173         }
174 }
175
176 // experimental lightning gun
177 void W_Crylink_Attack3 (void)
178 {
179         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
180                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
181         W_SetupShot (self, TRUE, 0, "weapons/crylink_fire2.wav", cvar("g_balance_crylink_secondary_damage"));
182
183         traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_crylink_secondary_radius"), FALSE, self, ANTILAG_LATENCY(self));
184
185         te_lightning1(self, w_shotorg, trace_endpos);
186
187         if (trace_fraction < 1)
188                 Damage(trace_ent, self, self, cvar("g_balance_crylink_secondary_damage"), WEP_CRYLINK | HITTYPE_SECONDARY, trace_endpos, cvar("g_balance_crylink_secondary_force") * w_shotdir);
189 }
190
191 void spawnfunc_weapon_crylink (void)
192 {
193         weapon_defaultspawnfunc(WEP_CRYLINK);
194 }
195
196 float w_crylink(float req)
197 {
198         if (req == WR_AIM)
199         {
200                 if (random() > 0.15)
201                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
202                 else
203                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
204         }
205         else if (req == WR_THINK)
206         {
207                 if (self.BUTTON_ATCK)
208                 if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
209                 {
210                         W_Crylink_Attack();
211                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
212                 }
213                 if (self.BUTTON_ATCK2)
214                 if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
215                 {
216                         if(cvar("g_balance_crylink_secondary_lightning"))
217                                 W_Crylink_Attack3();
218                         else
219                                 W_Crylink_Attack2();
220                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
221                 }
222         }
223         else if (req == WR_PRECACHE)
224         {
225                 precache_model ("models/weapons/g_crylink.md3");
226                 precache_model ("models/weapons/v_crylink.md3");
227                 precache_model ("models/weapons/h_crylink.dpm");
228                 precache_sound ("weapons/crylink_fire.wav");
229                 precache_sound ("weapons/crylink_fire2.wav");
230         }
231         else if (req == WR_SETUP)
232                 weapon_setup(WEP_CRYLINK);
233         else if (req == WR_CHECKAMMO1)
234                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
235         else if (req == WR_CHECKAMMO2)
236                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
237         else if (req == WR_SUICIDEMESSAGE)
238         {
239                 w_deathtypestring = "succeeded at self-destructing themself with the Crylink";
240         }
241         else if (req == WR_KILLMESSAGE)
242         {
243                 if(w_deathtype & HITTYPE_BOUNCE)
244                         w_deathtypestring = "could not hide from #'s Crylink"; // unchecked: SPLASH (SECONDARY can't be)
245                 else if(w_deathtype & HITTYPE_SPLASH)
246                         w_deathtypestring = "was too close to #'s Crylink"; // unchecked: SECONDARY
247                 else
248                         w_deathtypestring = "took a close look at #'s Crylink"; // unchecked: SECONDARY
249         }
250         return TRUE;
251 };