data/qcsrc/server/vote.qc

   1 float VoteCheckNasty(string cmd)
   2 {
   3         if(strstrofs(cmd, ";", 0) >= 0)
   4                 return TRUE;
   5         if(strstrofs(cmd, "\n", 0) >= 0)
   6                 return TRUE;
   7         if(strstrofs(cmd, "\r", 0) >= 0)
   8                 return TRUE;
   9         if(strstrofs(cmd, "$", 0) >= 0)
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 entity GetKickVoteVictim(string vote, string cmd, entity caller)
  15 {
  16         float tokens;
  17         float i, n, t;
  18         string ns;
  19         entity e;
  20
  21         tokens = tokenize(vote);
  22         ns = "";
  23
  24         if(tokens >= 2)
  25                 if(substring(argv(1), 0, 1) == "#")
  26                 {
  27                         ns = substring(argv(1), 1, 999);
  28                         t = 2;
  29                 }
  30
  31         if(tokens >= 3)
  32                 if(argv(1) == "#")
  33                 {
  34                         ns = argv(2);
  35                         t = 3;
  36                 }
  37
  38         if(ns != "")
  39         {
  40                 GetKickVoteVictim_reason = "";
  41                 for(i = t; i < tokens; ++i)
  42                         GetKickVoteVictim_reason = strcat(GetKickVoteVictim_reason, argv(i), " ");
  43                 GetKickVoteVictim_reason = substring(GetKickVoteVictim_reason, 0, strlen(GetKickVoteVictim_reason) - 1);
  44
  45                 n = stof(ns);
  46                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
  47                 {
  48                         e = edict_num(n);
  49                         if(clienttype(e) == CLIENTTYPE_REAL)
  50                         {
  51                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
  52                                 return e;
  53                         }
  54                 }
  55         }
  56
  57         print_to(caller, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
  58         return world;
  59 }
  60
  61 float GameCommand_Vote(string s, entity e) {
  62         local entity victim;
  63         if(argv(0) == "help") {
  64                 print_to(e, "  vote COMMANDS ARGUMENTS. See 'vote help' for more info.");
  65                 return TRUE;
  66         } else if(argv(0) == "vote") {
  67                 if(argv(1) == "") {
  68                         print_to(e, "^1You have to supply a vote command. See help for more info.");
  69                 } else if(argv(1) == "help") {
  70                         VoteHelp(e);
  71                 } else if(argv(1) == "status") {
  72                         if(votecalled) {
  73                                 print_to(e, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", VoteNetname(votecaller), "^7."));
  74                         } else {
  75                                 print_to(e, "^1No vote called.");
  76                         }
  77                 } else if(argv(1) == "call") {
  78                         if(!e || cvar("sv_vote_call")) {
  79                                 if(tourneyInMatchStage
  80                                    && cvar("g_tourney_disable_spec_vote")
  81                                    && e.classname != "player") {
  82                                         print_to(e, "^1Error: Only players can call a vote during the match-stage.");
  83                                 }
  84                                 else if(timeoutStatus) { //don't allow a vote call during a timeout
  85                                         print_to(e, "^1Error: You can not call a vote while a timeout is active.");
  86                                 }
  87                                 else if(votecalled) {
  88                                         print_to(e, "^1There is already a vote called.");
  89                                 } else {
  90                                         local string vote;
  91                                         vote = VoteParse();
  92                                         if(vote == "") {
  93                                                 print_to(e, "^1Your vote is empty. See help for more info.");
  94                                         } else if(e
  95                                                 && time < e.vote_next) {
  96                                                         print_to(e, strcat("^1You have to wait ^2", ftos(e.vote_next - time), "^1 seconds before you can again call a vote."));
  97                                         } else if(VoteCheckNasty(vote)) {
  98                                                 print_to(e, "Syntax error in command. See help for more info.");
  99                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 100                                                 // remap chmap to gotomap (forces intermission)
 101                                                 if(vote == "chmap" || vote == "gotomap") // won't work without arguments
 102                                                         return TRUE;
 103                                                 if(substring(vote, 0, 6) == "chmap ")
 104                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 105                                                 if(substring(vote, 0, 8) == "gotomap ")
 106                                                 {
 107                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8), e)))
 108                                                                 return TRUE;
 109                                                         vote = strcat("gotomap ", vote);
 110                                                 }
 111
 112                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 113                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
 114                                                 {
 115                                                         if(!(victim = GetKickVoteVictim(vote, "vcall", e)))
 116                                                                 return TRUE;
 117                                                         vote = GetKickVoteVictim_newcommand;
 118                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason));
 119                                                 }
 120                                                 else if(vote == "kick" || vote == "kickban")
 121                                                 {
 122                                                         print_to(e, strcat("Usage: ", vote, " #playernumber (as in \"status\")\n"));
 123                                                         return TRUE;
 124                                                 }
 125                                                 else
 126                                                 {
 127                                                         votecalledvote_display = strzone(strcat("^1", vote));
 128                                                 }
 129                                                 votecalledvote = strzone(vote);
 130                                                 votecalled = TRUE;
 131                                                 votecalledmaster = FALSE;
 132                                                 votefinished = time + cvar("sv_vote_timeout");
 133                                                 votecaller = e; // remember who called the vote
 134                                                 if(e) {
 135                                                         e.vote_vote = 1; // of course you vote yes
 136                                                         e.vote_next = time + cvar("sv_vote_wait");
 137                                                 }
 138                                                 bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote for ", votecalledvote_display, "\n");
 139                                                 if(cvar("sv_eventlog"))
 140                                                         GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display), TRUE);
 141                                                 VoteCount(); // needed if you are the only one
 142                                         } else {
 143                                                 print_to(e, "^1This vote is not ok. See help for more info.");
 144                                         }
 145                                 }
 146                         } else {
 147                                 print_to(e, "^1Vote calling is NOT allowed.");
 148                         }
 149                 } else if(argv(1) == "stop") {
 150                         if(!votecalled) {
 151                                 print_to(e, "^1No vote called.");
 152                         } else if(e == votecaller) { // the votecaller can stop a vote
 153                                 VoteStop(e);
 154                         } else if(!e) { // server admin / console can too
 155                                 VoteStop(e);
 156                         } else if(e.vote_master) { // masters can too
 157                                 VoteStop(e);
 158                         } else {
 159                                 print_to(e, "^1You are not allowed to stop that Vote.");
 160                         }
 161                 } else if(argv(1) == "master") {
 162                         if(cvar("sv_vote_master")) {
 163                                 if(votecalled) {
 164                                         print_to(e, "^1There is already a vote called.");
 165                                 } else {
 166                                         votecalled = TRUE;
 167                                         votecalledmaster = TRUE;
 168                                         votecalledvote = strzone("XXX");
 169                                         votecalledvote_display = strzone("^3master");
 170                                         votefinished = time + cvar("sv_vote_timeout");
 171                                         votecaller = e; // remember who called the vote
 172                                         if(e) {
 173                                                 e.vote_vote = 1; // of course you vote yes
 174                                                 e.vote_next = time + cvar("sv_vote_wait");
 175                                         }
 176                                         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote to become ^3master^2.\n");
 177                                         if(cvar("sv_eventlog"))
 178                                                 GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display), FALSE);
 179                                         VoteCount(); // needed if you are the only one
 180                                 }
 181                         } else {
 182                                 print_to(e, "^1Vote to become master is NOT allowed.");
 183                         }
 184                 } else if(argv(1) == "do") {
 185                         if(!e || e.vote_master) {
 186                                 local string dovote, dovote_display;
 187                                 dovote = VoteParse();
 188                                 if(dovote == "") {
 189                                         print_to(e, "^1Your command was empty. See help for more info.");
 190                                 } else if(VoteCheckNasty(dovote)) {
 191                                         print_to(e, "Syntax error in command. See help for more info.");
 192                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
 193                                         if(dovote == "chmap" || dovote == "gotomap") // won't work without arguments
 194                                                 return TRUE;
 195                                         if(substring(dovote, 0, 6) == "chmap ")
 196                                                 dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
 197                                         if(substring(dovote, 0, 8) == "gotomap ")
 198                                         {
 199                                                 if(!(dovote = ValidateMap(substring(dovote, 8, strlen(dovote) - 8), e)))
 200                                                         return TRUE;
 201                                                 dovote = strcat("gotomap ", dovote);
 202                                         }
 203
 204                                         dovote_display = dovote;
 205                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
 206                                         {
 207                                                 if(!(victim = GetKickVoteVictim(dovote, "vdo", e)))
 208                                                         return TRUE;
 209                                                 dovote = GetKickVoteVictim_newcommand;
 210                                                 dovote_display = strcat("^1", dovote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason);
 211                                         }
 212                                         else if(dovote == "kick" || dovote == "kickban")
 213                                         {
 214                                                 print_to(e, strcat("Usage: ", dovote, " #playernumber (as in \"status\")\n"));
 215                                                 return TRUE;
 216                                         }
 217                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
 218                                         if(cvar("sv_eventlog"))
 219                                                 GameLogEcho(strcat(":vote:vdo:", ftos(e.playerid), ":", dovote_display), FALSE);
 220                                         localcmd(strcat(dovote, "\n"));
 221                                 } else {
 222                                         print_to(e, "^1This command is not ok. See help for more info.");
 223                                 }
 224                         } else {
 225                                 print_to(e, "^1You are NOT a master.  You might need to login or vote to become master first. See help for more info.");
 226                         }
 227                 } else if(argv(1) == "login") {
 228                         local string masterpwd;
 229                         masterpwd = cvar_string("sv_vote_master_password");
 230                         if(masterpwd != "") {
 231                                 local float granted;
 232                                 granted = (masterpwd == argv(2));
 233                                 if (e)
 234                                         e.vote_master = granted;
 235                                 if(granted) {
 236                                         ServerConsoleEcho(strcat("Accepted master login from ", VoteNetname(e)), TRUE);
 237                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 logged in as ^3master^2\n");
 238                                         if(cvar("sv_eventlog"))
 239                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(e.playerid)), FALSE);
 240                                 }
 241                                 else
 242                                         ServerConsoleEcho(strcat("REJECTED master login from ", VoteNetname(e)), TRUE);
 243                         }
 244                         else
 245                                 print_to(e, "^1Login to become master is NOT allowed.");
 246                 } else if(argv(1) == "yes") {
 247                         if(!votecalled) {
 248                                 print_to(e, "^1No vote called.");
 249                         } else if (!e) {
 250                                 print_to(e, "^1You can't vote from the server console.");
 251                         } else if(e.vote_vote == 0
 252                                   || cvar("sv_vote_change")) {
 253                                 print_to(e, "^1You accepted the vote.");
 254                                 e.vote_vote = 1;
 255                                 centerprint_expire(e, CENTERPRIO_VOTE);
 256                                 if(!cvar("sv_vote_singlecount")) {
 257                                         VoteCount();
 258                                 }
 259                         } else {
 260                                 print_to(e, "^1You have already voted.");
 261                         }
 262                 } else if(argv(1) == "no") {
 263                         if(!votecalled) {
 264                                 print_to(e, "^1No vote called.");
 265                         } else if (!e) {
 266                                 print_to(e, "^1You can't vote from the server console.");
 267                         } else if(e.vote_vote == 0
 268                                   || cvar("sv_vote_change")) {
 269                                 print_to(e, "^1You rejected the vote.");
 270                                 e.vote_vote = -1;
 271                                 centerprint_expire(e, CENTERPRIO_VOTE);
 272                                 if(!cvar("sv_vote_singlecount")) {
 273                                         VoteCount();
 274                                 }
 275                         } else {
 276                                 print_to(e, "^1You have already voted.");
 277                         }
 278                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
 279                         if(!votecalled) {
 280                                 print_to(e, "^1No vote called.");
 281                         } else if (!e) {
 282                                 print_to(e, "^1You can't vote from the server console.");
 283                         } else if(e.vote_vote == 0
 284                                   || cvar("sv_vote_change")) {
 285                                 print_to(e, "^1You abstained from your vote.");
 286                                 e.vote_vote = -2;
 287                                 centerprint_expire(e, CENTERPRIO_VOTE);
 288                                 if(!cvar("sv_vote_singlecount")) {
 289                                         VoteCount();
 290                                 }
 291                         } else {
 292                                 print_to(e, "^1You have already voted.");
 293                         }
 294                 } else {
 295                         // ignore this?
 296                         print_to(e, "^1Unknown vote command.");
 297                 }
 298                 return TRUE;
 299         }
 300         return FALSE;
 301 }
 302
 303 void VoteHelp(entity e) {
 304         local string vmasterdis;
 305         if(!cvar("sv_vote_master")) {
 306                 vmasterdis = " ^1(disabled)";
 307         }
 308
 309         local string vlogindis;
 310         if("" == cvar_string("sv_vote_master_password")) {
 311                 vlogindis = " ^1(disabled)";
 312         }
 313
 314         local string vcalldis;
 315         if(!cvar("sv_vote_call")) {
 316                 vcalldis = " ^1(disabled)";
 317         }
 318
 319         print_to(e, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote login^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote abstain^7\" \"^2cmd vote dontcare^7\".");
 320         print_to(e, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vlogin^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2abstain^7\" \"^2vdontcare^7\".");
 321         print_to(e, "^7\"^2help^7\" shows this info.");
 322         print_to(e, "^7\"^2status^7\" shows if there is a vote called and who called it.");
 323         print_to(e, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7"));
 324         print_to(e, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.");
 325         print_to(e, strcat("^7\"^2master^7\" call a vote to become master who can execute commands without a vote", vmasterdis, "^7"));
 326         print_to(e, strcat("^7\"^2login^7\" login to become master who can execute commands without a vote.", vlogindis, "^7"));
 327         print_to(e, "^7\"^2do^7\" executes a command if you are a master. See the list of allowed commands.");
 328         print_to(e, "^7\"^2yes^7\", \"^2no^7\", \"^2abstain^7\" and \"^2dontcare^7\" to make your vote.");
 329         print_to(e, "^7If enough of the players vote yes the vote is accepted.");
 330         print_to(e, "^7If enough of the players vote no the vote is rejected.");
 331         print_to(e, strcat("^7If neither the vote will timeout after ", cvar_string("sv_vote_timeout"), "^7 seconds."));
 332         print_to(e, "^7You can call a vote for or execute these commands:");
 333         print_to(e, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7"));
 334 }
 335
 336 string VoteNetname(entity e)
 337 {
 338         if(e) {
 339                 return e.netname;
 340         } else {
 341                 if(cvar_string("sv_adminnick") != "") {
 342                         return cvar_string("sv_adminnick");
 343                 } else {
 344                         return cvar_string("hostname");
 345                 }
 346         }
 347 }
 348
 349 string ValidateMap(string m, entity e)
 350 {
 351 #ifdef MAPINFO
 352         m = MapInfo_FixName(m);
 353         if(!m)
 354         {
 355                 print_to(e, "This map is not available on this server.");
 356                 return string_null;
 357         }
 358 #else
 359         if(!cvar("sv_vote_change_gametype"))
 360                 if(!IsSameGametype(m))
 361                 {
 362                         print_to(e, "This server does not allow changing the game type by map votes.");
 363                         return string_null;
 364                 }
 365 #endif
 366         if(!cvar("sv_vote_override_mostrecent"))
 367                 if(Map_IsRecent(m))
 368                 {
 369                         print_to(e, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 370                         return string_null;
 371                 }
 372 #ifdef MAPINFO
 373         if(!MapInfo_CheckMap(m))
 374         {
 375                 print_to(e, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode."));
 376                 return string_null;
 377         }
 378 #else
 379         if(!TryFile(strcat("maps/", m, ".mapcfg")))
 380         {
 381                 print_to(e, strcat("^1Invalid mapname, \"^3", m, "^1\" does not exist on this server."));
 382                 return string_null;
 383         }
 384 #endif
 385
 386         return m;
 387 }
 388
 389
 390 void VoteThink() {
 391         if(votefinished > 0) // a vote was called
 392         if(time > votefinished) // time is up
 393         {
 394                 VoteCount();
 395         }
 396 }
 397
 398 string VoteParse() {
 399         local float index;
 400         index = 3;
 401         local string vote;
 402         vote = argv(2);
 403         while(argv(index) != "") {
 404                 vote = strcat(vote, " ", argv(index));
 405                 index++;
 406         }
 407
 408         // necessary for some of the string operations
 409         vote = strzone(vote);
 410
 411         return vote;
 412 }
 413
 414 float VoteAllowed(string votecommand) {
 415         tokenize(cvar_string("sv_vote_commands"));
 416         local float index;
 417         index = 0;
 418         while(argv(index) != "") {
 419                 if(votecommand == argv(index)) {
 420                         return TRUE;
 421                 }
 422                 index++;
 423         }
 424         return FALSE;
 425 }
 426
 427 void VoteReset() {
 428         local entity player;
 429
 430         FOR_EACH_CLIENT(player)
 431         {
 432                 player.vote_vote = 0;
 433                 centerprint_expire(player, CENTERPRIO_VOTE);
 434         }
 435
 436         if(votecalled)
 437         {
 438                 strunzone(votecalledvote);
 439                 strunzone(votecalledvote_display);
 440         }
 441
 442         votecalled = FALSE;
 443         votecalledmaster = FALSE;
 444         votefinished = 0;
 445 }
 446
 447 void VoteAccept() {
 448         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 449         if(votecalledmaster)
 450         {
 451                 if(votecaller) {
 452                         votecaller.vote_master = 1;
 453                 }
 454         } else {
 455                 //in g_tourney mode and if the vote is a timelimit-change, don't change it immediately but after restart
 456                 if(cvar("g_tourney")
 457                    && substring(votecalledvote, 0, 10) == "timelimit ") {
 458                         if( stof(substring(votecalledvote, 10, strlen(votecalledvote) - 10)) > 0 ) {
 459                                 timelimit_orig = stof(substring(votecalledvote, 10, strlen(votecalledvote) - 10));
 460                                 bprint(strcat("The timelimit will be set to ", ftos(timelimit_orig), " minutes after the next restart!\n"));
 461                         }
 462                         else //calls like "timelimit -1" can pass immediately
 463                                 localcmd(strcat(votecalledvote, "\n"));
 464                 }
 465                 else
 466                         localcmd(strcat(votecalledvote, "\n"));
 467         }
 468         if(votecaller) {
 469                 votecaller.vote_next = 0; // people like your votes,
 470                                           // no wait for next vote
 471         }
 472         VoteReset();
 473 }
 474
 475 void VoteReject() {
 476         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 477         VoteReset();
 478 }
 479
 480 void VoteTimeout() {
 481         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 482         VoteReset();
 483 }
 484
 485 void VoteStop(entity stopper) {
 486         bprint("\{1}^2* ^3", VoteNetname(stopper), "^2 stopped ^3", VoteNetname(votecaller), "^2's vote\n");
 487         if(cvar("sv_eventlog"))
 488                 GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)), FALSE);
 489         if(stopper == votecaller) {
 490                 // no wait for next vote so you can correct your vote
 491                 if(votecaller) {
 492                         votecaller.vote_next = 0;
 493                 }
 494         }
 495         VoteReset();
 496 }
 497
 498 void VoteNag() {
 499         if(votecalled)
 500         if(self.vote_vote == 0)
 501                 centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", VoteNetname(votecaller), "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
 502 }
 503
 504 void VoteSpam(float yescount, float nocount, float abstaincount, float notvoters, float mincount, string result)
 505 {
 506         string s;
 507         if(mincount >= 0)
 508         {
 509                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 510                 s = strcat(s, ftos(nocount), "^2 (^1");
 511                 s = strcat(s, ftos(mincount), "^2 needed), ^1");
 512                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 513                 s = strcat(s, ftos(notvoters), "^2 didn't vote\n");
 514         }
 515         else
 516         {
 517                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 518                 s = strcat(s, ftos(nocount), "^2, ^1");
 519                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 520                 s = strcat(s, ftos(notvoters), "^2 didn't have to vote\n");
 521         }
 522         bprint(s);
 523         if(cvar("sv_eventlog"))
 524         {
 525                 s = strcat(":vote:v", result, ":", ftos(yescount));
 526                 s = strcat(s, ":", ftos(nocount));
 527                 s = strcat(s, ":", ftos(abstaincount));
 528                 s = strcat(s, ":", ftos(notvoters));
 529                 s = strcat(s, ":", ftos(mincount));
 530                 GameLogEcho(s, FALSE);
 531         }
 532 }
 533
 534 void VoteCount() {
 535         local float playercount;
 536         playercount = 0;
 537         local float yescount;
 538         yescount = 0;
 539         local float nocount;
 540         nocount = 0;
 541         local float abstaincount;
 542         abstaincount = 0;
 543         local entity player;
 544         //same for real players
 545         local float realplayercount;
 546         local float realplayeryescount;
 547         local float realplayernocount;
 548         local float realplayerabstaincount;
 549         realplayercount = realplayernocount = realplayerabstaincount = realplayeryescount = 0;
 550
 551         FOR_EACH_REALCLIENT(player)
 552         {
 553                 if(player.vote_vote == -1) {
 554                         nocount++;
 555                 } else if(player.vote_vote == 1) {
 556                         yescount++;
 557                 } else if(player.vote_vote == -2) {
 558                         abstaincount++;
 559                 }
 560                 playercount++;
 561                 //do the same for real players
 562                 if(player.classname == "player") {
 563                         if(player.vote_vote == -1) {
 564                                 realplayernocount++;
 565                         } else if(player.vote_vote == 1) {
 566                                 realplayeryescount++;
 567                         } else if(player.vote_vote == -2) {
 568                                 realplayerabstaincount++;
 569                         }
 570                         realplayercount++;
 571                 }
 572         }
 573
 574         //in tournament mode, if we have at least one player then don't make the vote dependent on spectators (so specs don't have to press F1)
 575         if(cvar("g_tourney"))
 576         if(realplayercount > 0) {
 577                 yescount = realplayeryescount;
 578                 nocount = realplayernocount;
 579                 abstaincount = realplayerabstaincount;
 580                 playercount = realplayercount;
 581         }
 582
 583
 584         if(votecalledmaster
 585            && playercount == 1) {
 586                 // if only one player is on the server becoming vote
 587                 // master is not allowed.  This could be used for
 588                 // trolling or worse. 'self' is the user who has
 589                 // called the vote because this function is called
 590                 // by SV_ParseClientCommand. Maybe all voting should
 591                 // be disabled for a single player?
 592                 print_to(votecaller, "^1You are the only player on this server so you can not become vote master.");
 593                 if(votecaller) {
 594                         votecaller.vote_next = 0;
 595                 }
 596                 VoteReset();
 597         } else {
 598                 float votefactor;
 599                 votefactor = bound(0.5, cvar("sv_vote_majority_factor"), 0.999);
 600                 if(yescount > (playercount - abstaincount) * votefactor)
 601                 {
 602                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "yes");
 603                         VoteAccept();
 604                 }
 605                 else if(nocount >= (playercount - abstaincount) * (1 - votefactor)) // that means, yescount cannot reach minyes any more
 606                 {
 607                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "no");
 608                         VoteReject();
 609                 }
 610                 else if(time > votefinished)
 611                 {
 612                         if(cvar("sv_vote_simple_majority"))
 613                         {
 614                                 string result;
 615                                 if(yescount > (yescount + nocount) * votefactor)
 616                                         result = "yes";
 617                                 else if(yescount + nocount > 0)
 618                                         result = "no";
 619                                 else
 620                                         result = "timeout";
 621                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((yescount + nocount) * votefactor) + 1, result);
 622                                 if(result == "yes")
 623                                         VoteAccept();
 624                                 else if(result == "no")
 625                                         VoteReject();
 626                                 else
 627                                         VoteTimeout();
 628                         }
 629                         else
 630                         {
 631                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((playercount - abstaincount) * votefactor) + 1, "timeout");
 632                                 VoteTimeout();
 633                         }
 634                 }
 635         }
 636 }