data/qcsrc/server/tturrets/units/unit_flac.qc

   1 void spawnfunc_turret_flac();\r
   2 void turret_flac_dinit();\r
   3 void turret_flac_attack();\r
   4 void turret_flac_projectile_explode();\r
   5 \r
   6 void turret_flac_attack()\r
   7 {\r
   8     local entity proj;\r
   9 \r
  10     turret_tag_fire_update();\r
  11 \r
  12     sound (self, CHAN_WEAPON, "weapons/hagar_fire.wav", VOL_BASE, ATTN_NORM);\r
  13     proj = spawn ();\r
  14     setorigin(proj, self.tur_shotorg_updated);\r
  15     setmodel(proj, "models/turrets/pd_proj.md3");\r
  16     setsize(proj, '0 0 0', '0 0 0');\r
  17     proj.classname          = "turret_fire";\r
  18     proj.owner              = self;\r
  19     proj.bot_dodge          = TRUE;\r
  20     proj.bot_dodgerating    = self.shot_dmg;\r
  21     proj.solid              = SOLID_NOT;\r
  22     proj.movetype           = MOVETYPE_FLYMISSILE;\r
  23     proj.flags              = FL_PROJECTILE;\r
  24     proj.effects            = EF_LOWPRECISION;\r
  25     proj.takedamage         = DAMAGE_YES;\r
  26     proj.health             = 10;\r
  27     proj.velocity           = (self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;\r
  28     proj.angles             = vectoangles(proj.velocity);\r
  29     proj.touch              = turret_flac_projectile_explode;\r
  30     proj.think              = turret_flac_projectile_explode;\r
  31     proj.nextthink          = time + (vlen(self.tur_aimpos - self.tur_shotorg_updated) / self.shot_speed) + (random() * self.shot_spread);\r
  32 \r
  33     self.tur_head.frame = self.tur_head.frame + 1;\r
  34     if (self.tur_head.frame >= 4) self.tur_head.frame = 0;\r
  35 \r
  36 }\r
  37 \r
  38 void turret_flac_projectile_explode()\r
  39 {\r
  40     float ftmp;\r
  41 \r
  42     te_explosion (self.origin);\r
  43 \r
  44     ftmp = crandom();\r
  45     if (ftmp<-0.7)\r
  46         sound (self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);\r
  47     else if (ftmp<0.4)\r
  48         sound (self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);\r
  49     else if (ftmp<1)\r
  50         sound (self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);\r
  51 \r
  52 \r
  53     self.event_damage = SUB_Null;\r
  54 \r
  55 \r
  56 #ifdef TURRET_DEBUG\r
  57 \r
  58     ftmp = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);\r
  59     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + ftmp; //self.owner.shot_dmg;\r
  60     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;\r
  61 #else\r
  62     RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);\r
  63 #endif\r
  64 \r
  65     remove (self);\r
  66 }\r
  67 \r
  68 \r
  69 void turret_flac_dinit()\r
  70 {\r
  71     if (self.netname == "")      self.netname  = "FLAC Cannon";\r
  72 \r
  73 \r
  74     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_FASTPROJ | TFL_TURRCAPS_MISSILEKILL;\r
  75     self.ammo_flags     = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;\r
  76     self.aim_flags      = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;\r
  77 \r
  78     if (turret_stdproc_init("flac_std") == 0)\r
  79     {\r
  80         remove(self);\r
  81         return;\r
  82     }\r
  83 \r
  84     setmodel(self,"models/turrets/base.md3");\r
  85     setmodel(self.tur_head,"models/turrets/flac.md3");\r
  86 \r
  87     if (!turret_tag_setup(0))\r
  88         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");\r
  89 \r
  90     // Our fire routine\r
  91     self.turret_firefunc  = turret_flac_attack;\r
  92 \r
  93 }\r
  94 /*QUAKED turret_flac (0 .5 .8) ?\r
  95 */\r
  96 \r
  97 void spawnfunc_turret_flac()\r
  98 {\r
  99     //precache_model ("models/turrets/base.md3");\r
 100     //precache_model ("models/turrets/flac.md3");\r
 101     //precache_model("models/turrets/pd_proj.md3");\r
 102 \r
 103     self.think = turret_flac_dinit;\r
 104     self.nextthink = time + 0.5;\r
 105 }\r
 106 \r