data/qcsrc/server/tturrets/units/turret_unit_phaser.qc

   1 void spawnfunc_turret_phaser();\r
   2 void turret_phaser_dinit();\r
   3 void turret_phaser_attack();\r
   4 \r
   5 .float fireflag;\r
   6 \r
   7 float turret_phaser_firecheck()\r
   8 {\r
   9     if (self.fireflag != 0) return 0;\r
  10     return turret_stdproc_firecheck();\r
  11 }\r
  12 \r
  13 void turret_phaser_postthink()\r
  14 {\r
  15     if (self.tur_head.frame == 0)\r
  16         return;\r
  17 \r
  18     if (self.fireflag == 1)\r
  19     {\r
  20         if (self.tur_head.frame == 10)\r
  21             self.tur_head.frame = 1;\r
  22         else\r
  23             self.tur_head.frame = self.tur_head.frame +1;\r
  24     }\r
  25     else if (self.fireflag == 2 )\r
  26     {\r
  27         self.tur_head.frame = self.tur_head.frame +1;\r
  28         if (self.tur_head.frame == 15)\r
  29         {\r
  30             self.tur_head.frame = 0;\r
  31             self.fireflag = 0;\r
  32         }\r
  33     }\r
  34 }\r
  35 \r
  36 void beam_think()\r
  37 {\r
  38     if ((time > self.cnt)||(self.owner.deadflag != DEAD_NO))\r
  39     {\r
  40         self.owner.attack_finished_single = time + self.owner.shot_refire;\r
  41         self.owner.fireflag = 2;\r
  42         self.owner.tur_head.frame = 10;\r
  43         sound (self, CHAN_PROJECTILE, "", 1, ATTN_NORM);\r
  44         remove(self);\r
  45         return;\r
  46     }\r
  47 \r
  48     turret_do_updates(self.owner);\r
  49 \r
  50     if (time - self.shot_spread > 0)\r
  51     {\r
  52         self.shot_spread = time + 2;\r
  53         sound (self, CHAN_VOICE, "turrets/phaser.ogg", 1, ATTN_NORM);\r
  54     }\r
  55 \r
  56 \r
  57     self.nextthink = time + self.ticrate;\r
  58 \r
  59     self.owner.attack_finished_single = time + frametime;\r
  60     entity oldself;\r
  61     oldself = self;\r
  62     self = self.owner;\r
  63     FireImoBeam (   self.tur_shotorg_updated,\r
  64                     self.tur_shotorg_updated + self.tur_shotdir_updated * self.target_range_fire,\r
  65                     '-1 -1 -1' * self.shot_radius,\r
  66                     '1 1 1' * self.shot_radius,\r
  67                     self.shot_force,\r
  68                     oldself.shot_dmg,\r
  69                     0.75,\r
  70                     DEATH_TURRET);\r
  71     self = oldself;\r
  72     self.scale = vlen(self.owner.tur_shotorg_updated - trace_endpos) / 256;\r
  73 \r
  74 }\r
  75 \r
  76 void turret_phaser_attack()\r
  77 {\r
  78     entity beam;\r
  79 \r
  80     beam = spawn();\r
  81     beam.ticrate = 0.1; //cvar("sys_ticrate");\r
  82     setmodel(beam,"models/turrets/phaser_beam.md3");\r
  83     beam.effects = EF_LOWPRECISION;\r
  84     beam.solid = SOLID_NOT;\r
  85     beam.think = beam_think;\r
  86     beam.cnt = time + self.shot_speed;\r
  87     beam.shot_spread = time + 2;\r
  88     beam.nextthink = time;\r
  89     beam.owner = self;\r
  90     beam.shot_dmg = self.shot_dmg / (self.shot_speed / beam.ticrate);\r
  91     beam.scale = self.target_range_fire / 256;\r
  92     beam.movetype = MOVETYPE_NONE;\r
  93     beam.enemy = self.enemy;\r
  94     beam.bot_dodge = TRUE;\r
  95     beam.bot_dodgerating = beam.shot_dmg;\r
  96     sound (beam, CHAN_PROJECTILE, "turrets/phaser.ogg", 1, ATTN_NORM);\r
  97     self.fireflag = 1;\r
  98 \r
  99     beam.attack_finished_single = self.attack_finished_single;\r
 100     self.attack_finished_single = time; // + cvar("sys_ticrate");\r
 101 \r
 102     setattachment(beam,self.tur_head,"tag_fire");\r
 103 \r
 104     soundat (self, trace_endpos, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);\r
 105 \r
 106     if (self.tur_head.frame == 0)\r
 107         self.tur_head.frame = 1;\r
 108 }\r
 109 \r
 110 void turret_phaser_dinit()\r
 111 {\r
 112     if (self.netname == "")      self.netname  = "Phaser Cannon";\r
 113 \r
 114     self.turrcaps_flags = TFL_TURRCAPS_SNIPER|TFL_TURRCAPS_HITSCAN|TFL_TURRCAPS_PLAYERKILL;\r
 115     self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE | TFL_AMMO_RECIVE;\r
 116     self.aim_flags = TFL_AIM_ZEASE | TFL_AIM_LEAD;\r
 117 \r
 118     if (turret_stdproc_init("phaser_std") == 0)\r
 119     {\r
 120         remove(self);\r
 121         return;\r
 122     }\r
 123 \r
 124     setmodel(self,"models/turrets/base.md3");\r
 125     setmodel(self.tur_head,"models/turrets/phaser.md3");\r
 126 \r
 127     if (!turret_tag_setup(0))\r
 128         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");\r
 129 \r
 130     self.turret_firecheckfunc = turret_phaser_firecheck;\r
 131     self.turret_firefunc  = turret_phaser_attack;\r
 132     self.turret_postthink = turret_phaser_postthink;\r
 133 \r
 134 }\r
 135 \r
 136 /*QUAKED turret_phaser(0 .5 .8) ?\r
 137 */\r
 138 void spawnfunc_turret_phaser()\r
 139 {\r
 140     //precache_sound ("turrets/phaser.ogg");\r
 141     //precache_model ("models/turrets/phaser.md3");\r
 142     //precache_model ("models/turrets/phaser_beam.md3");\r
 143     //precache_model ("models/turrets/base.md3");\r
 144 \r
 145     self.think = turret_phaser_dinit;\r
 146     self.nextthink = time + 0.5;\r
 147 }\r
 148 \r