data/qcsrc/server/t_teleporters.qc

   1 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   2 {
   3         entity head;
   4         vector deathmin;
   5         vector deathmax;
   6         float deathradius;
   7         deathmin = player.absmin;
   8         deathmax = player.absmax;
   9         if(telefragmin != telefragmax)
  10         {
  11                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  12                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  13                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  14                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  15                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  16                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  17         }
  18         deathradius = max(vlen(deathmin), vlen(deathmax));
  19         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  20                 if(head != player)
  21                         if(head.takedamage)
  22                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  23                                 {
  24                                         if ((player.classname == "player") && (player.health >= 1))
  25                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  26                                         else if (telefragger.health < 1) // corpses gib
  27                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  28                                         else // dead bodies and monsters gib themselves instead of telefragging
  29                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  30                                 }
  31 }
  32
  33 void spawn_tdeath(vector v0, entity e, vector v)
  34 {
  35         tdeath(e, e, e, '0 0 0', '0 0 0');
  36 }
  37
  38 .entity pusher;
  39 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  40 {
  41         entity oldself;
  42         entity telefragger;
  43         vector from;
  44
  45         if(teleporter.owner)
  46                 telefragger = teleporter.owner;
  47         else
  48                 telefragger = player;
  49
  50         makevectors (to_angles);
  51
  52         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  53         {
  54                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  55                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  56                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  57                 self.pushltime = time + 0.2;
  58         }
  59
  60         // Relocate the player
  61         // assuming to allows PL_MIN to PL_MAX box and some more
  62         from = player.origin;
  63         setorigin (player, to);
  64         player.angles = to_angles;
  65         player.fixangle = TRUE;
  66         player.velocity = to_velocity;
  67         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  68
  69         UpdateCSQCProjectile(player);
  70
  71         if(player.classname == "player")
  72         {
  73                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  74                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  75
  76                 // player no longer is on ground
  77                 player.flags &~= FL_ONGROUND;
  78
  79                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  80                 player.oldvelocity = player.velocity;
  81
  82                 // reset tracking of who pushed you into a hazard (for kill credit)
  83                 if(teleporter.owner)
  84                 {
  85                         player.pusher = teleporter.owner;
  86                         player.pushltime = time + cvar("g_maxpushtime");
  87                 }
  88                 else
  89                 {
  90                         player.pushltime = 0;
  91                 }
  92
  93                 // stop player name display
  94                 {
  95                         oldself = self;
  96                         self = player;
  97                         ClearSelectedPlayer();
  98                         self = oldself;
  99                 }
 100         }
 101 }
 102
 103 void Teleport_Touch (void)
 104 {
 105         entity oldself, e;
 106
 107         if (other.health < 1)
 108                 return;
 109         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 110                 return;
 111
 112         EXACTTRIGGER_TOUCH;
 113
 114         makevectors(self.enemy.mangle);
 115
 116         if(other.classname == "player")
 117                 RemoveGrapplingHook(other);
 118
 119         if(self.enemy)
 120         {
 121                 e = self.enemy;
 122         }
 123         else
 124         {
 125                 RandomSelection_Init();
 126                 for(e = world; (e = find(e, targetname, self.target)); )
 127                 {
 128                         if(e.cnt)
 129                                 RandomSelection_Add(e, 0, e.cnt, 0);
 130                         else
 131                                 RandomSelection_Add(e, 0, 1, 0);
 132                 }
 133                 e = RandomSelection_chosen_ent;
 134         }
 135
 136         if(!e)
 137         {
 138                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 139         }
 140
 141         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 142
 143         if(e.target)
 144         {
 145                 oldself = self;
 146                 activator = other;
 147                 self = e;
 148                 SUB_UseTargets();
 149                 self = oldself;
 150         }
 151 }
 152
 153 void spawnfunc_info_teleport_destination (void)
 154 {
 155         self.classname = "info_teleport_destination";
 156
 157         self.mangle = self.angles;
 158         self.angles = '0 0 0';
 159
 160         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 161         setorigin (self, self.origin);
 162
 163         IFTARGETED
 164         {
 165         }
 166         else
 167                 objerror ("^3Teleport destination without a targetname");
 168 }
 169
 170 void spawnfunc_misc_teleporter_dest (void)
 171 {
 172         spawnfunc_info_teleport_destination();
 173 }
 174
 175 void spawnfunc_target_teleporter (void)
 176 {
 177         spawnfunc_info_teleport_destination();
 178 }
 179
 180 void teleport_findtarget (void)
 181 {
 182         entity e;
 183         float n;
 184
 185         n = 0;
 186         for(e = world; (e = find(e, targetname, self.target)); )
 187         {
 188                 ++n;
 189                 if(e.movetype == MOVETYPE_NONE)
 190                         waypoint_spawnforteleporter(self, e.origin, 0);
 191                 if(e.classname != "info_teleport_destination")
 192                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 193         }
 194
 195         if(n == 0)
 196         {
 197                 // no dest!
 198                 objerror ("Teleporter with nonexistant target");
 199                 return;
 200         }
 201         else if(n == 1)
 202         {
 203                 // exactly one dest - bots love that
 204                 self.enemy = find(e, targetname, self.target);
 205                 self.dest = self.enemy.origin;
 206         }
 207         else
 208         {
 209                 // have to use random selection every single time
 210                 self.enemy = world;
 211         }
 212
 213         // now enable touch
 214         self.touch = Teleport_Touch;
 215 }
 216
 217 void spawnfunc_trigger_teleport (void)
 218 {
 219         self.angles = '0 0 0';
 220
 221         EXACTTRIGGER_INIT;
 222
 223         // this must be called to spawn the teleport waypoints for bots
 224         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 225
 226         if (!self.target)
 227         {
 228                 objerror ("Teleporter with no target");
 229                 return;
 230         }
 231 }