data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
   3 {
   4         entity head;
   5         entity oldself;
   6
   7         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
   8         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
   9
  10         makevectors (to_angles);
  11         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  12
  13         // Relocate the player
  14         // assuming to allows PL_MIN to PL_MAX box and some more
  15         setorigin (player, to + '0 0 1' * (1 - player.mins_z - 24));
  16         player.angles = to_angles;
  17         player.fixangle = TRUE;
  18         player.velocity = to_velocity;
  19
  20         if(player.classname == "player")
  21         {
  22                 RemoveGrapplingHook(player);
  23
  24                 // Kill anyone else in the teleporter box (NO MORE TDEATH)
  25                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  26                 {
  27                         vector deathmin;
  28                         vector deathmax;
  29                         float deathradius;
  30                         deathmin = player.absmin;
  31                         deathmax = player.absmax;
  32                         deathradius = max(vlen(deathmin), vlen(deathmax));
  33                         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  34                                 if(head != player)
  35                                         if(head.takedamage)
  36                                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  37                                                 {
  38                                                         if ((player.classname == "player") && (player.health >= 1))
  39                                                                 Damage (head, teleporter, player, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  40                                                         else if (player.health < 1) // corpses gib
  41                                                                 Damage (head, teleporter, player, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  42                                                         else // dead bodies and monsters gib themselves instead of telefragging
  43                                                                 Damage (player, teleporter, player, 10000, DEATH_TELEFRAG, player.origin, '0 0 0');
  44                                                 }
  45                 }
  46
  47                 // hide myself a tic
  48                 player.effects = player.effects | EF_NODRAW;
  49                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  50                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  51                 player.teleport_time = time + cvar("sys_ticrate");
  52
  53                 // player no longer is on ground
  54                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  55
  56                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  57                 player.oldvelocity = player.velocity;
  58
  59                 // reset tracking of who pushed you into a hazard (for kill credit)
  60                 if(teleporter.owner)
  61                 {
  62                         player.pusher = teleporter.owner;
  63                         player.pushltime = time + cvar("g_maxpushtime");
  64                 }
  65                 else
  66                 {
  67                         player.pushltime = 0;
  68                 }
  69
  70                 // stop player name display
  71                 {
  72                         oldself = self;
  73                         self = player;
  74                         ClearSelectedPlayer();
  75                         self = oldself;
  76                 }
  77         }
  78 }
  79
  80 void Teleport_Touch (void)
  81 {
  82         entity oldself;
  83
  84         if (other.health < 1)
  85                 return;
  86         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
  87                 return;
  88
  89         EXACTTRIGGER_TOUCH;
  90
  91         makevectors(self.enemy.mangle);
  92         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity));
  93
  94         if(self.enemy.target)
  95         {
  96                 oldself = self;
  97                 activator = other;
  98                 self = self.enemy;
  99                 SUB_UseTargets();
 100                 self = oldself;
 101         }
 102 }
 103
 104 void spawnfunc_info_teleport_destination (void)
 105 {
 106         self.mangle = self.angles;
 107         self.angles = '0 0 0';
 108
 109         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 110         setorigin (self, self.origin);
 111
 112         IFTARGETED
 113         {
 114         }
 115         else
 116                 objerror ("Teleport destination without a targetname");
 117 }
 118
 119 void spawnfunc_misc_teleporter_dest (void)
 120 {
 121         spawnfunc_info_teleport_destination();
 122 }
 123
 124 void spawnfunc_target_teleporter (void)
 125 {
 126         spawnfunc_info_teleport_destination();
 127 }
 128
 129 void teleport_findtarget (void)
 130 {
 131         // now enable touch
 132         self.touch = Teleport_Touch;
 133
 134         self.enemy = find (world, targetname, self.target);
 135         if (!self.enemy)
 136         {
 137                 objerror ("Teleporter with nonexistant target");
 138                 remove(self);
 139                 return;
 140         }
 141
 142         self.dest = self.enemy.origin;
 143         waypoint_spawnforteleporter(self, self.dest, 0);
 144 }
 145
 146 void spawnfunc_trigger_teleport (void)
 147 {
 148         self.angles = '0 0 0';
 149
 150         EXACTTRIGGER_INIT;
 151
 152         // this must be called to spawn the teleport waypoints for bots
 153         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 154
 155         if (!self.target)
 156                 objerror ("Teleporter with no target");
 157 }