data/qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   8 {
   9         entity head;
  10         vector deathmin;
  11         vector deathmax;
  12         float deathradius;
  13         deathmin = player.absmin;
  14         deathmax = player.absmax;
  15         if(telefragmin != telefragmax)
  16         {
  17                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  18                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  19                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  20                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  21                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  22                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  23         }
  24         deathradius = max(vlen(deathmin), vlen(deathmax));
  25         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  26                 if(head != player)
  27                         if(head.takedamage)
  28                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  29                                 {
  30                                         if ((player.classname == "player") && (player.health >= 1))
  31                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  32                                         else if (telefragger.health < 1) // corpses gib
  33                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  34                                         else // dead bodies and monsters gib themselves instead of telefragging
  35                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  36                                 }
  37 }
  38
  39 void spawn_tdeath(vector v0, entity e, vector v)
  40 {
  41         tdeath(e, e, e, '0 0 0', '0 0 0');
  42 }
  43
  44 .entity pusher;
  45 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  46 {
  47         entity oldself;
  48         entity telefragger;
  49         vector from;
  50
  51         if(teleporter.owner)
  52                 telefragger = teleporter.owner;
  53         else
  54                 telefragger = player;
  55
  56         makevectors (to_angles);
  57
  58         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  59         {
  60                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  61                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  62                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  63                 self.pushltime = time + 0.2;
  64         }
  65
  66         // Relocate the player
  67         // assuming to allows PL_MIN to PL_MAX box and some more
  68         from = player.origin;
  69         setorigin (player, to);
  70         player.angles = to_angles;
  71         player.fixangle = TRUE;
  72         player.velocity = to_velocity;
  73         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  74
  75         UpdateCSQCProjectile(player);
  76
  77         if(player.classname == "player")
  78         {
  79                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  80                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  81
  82                 // player no longer is on ground
  83                 player.flags &~= FL_ONGROUND;
  84
  85                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  86                 player.oldvelocity = player.velocity;
  87
  88                 // reset tracking of who pushed you into a hazard (for kill credit)
  89                 if(teleporter.owner)
  90                 {
  91                         player.pusher = teleporter.owner;
  92                         player.pushltime = time + cvar("g_maxpushtime");
  93                 }
  94                 else
  95                 {
  96                         player.pushltime = 0;
  97                 }
  98
  99                 // stop player name display
 100                 {
 101                         oldself = self;
 102                         self = player;
 103                         ClearSelectedPlayer();
 104                         self = oldself;
 105                 }
 106         }
 107 }
 108
 109 void Teleport_Touch (void)
 110 {
 111         entity oldself, e;
 112
 113         if (other.health < 1)
 114                 return;
 115         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 116                 return;
 117
 118         if(self.team)
 119                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 120                         return;
 121
 122         EXACTTRIGGER_TOUCH;
 123
 124         makevectors(self.enemy.mangle);
 125
 126         if(other.classname == "player")
 127                 RemoveGrapplingHook(other);
 128
 129         if(self.enemy)
 130         {
 131                 e = self.enemy;
 132         }
 133         else
 134         {
 135                 RandomSelection_Init();
 136                 for(e = world; (e = find(e, targetname, self.target)); )
 137                 {
 138                         if(e.cnt)
 139                                 RandomSelection_Add(e, 0, e.cnt, 0);
 140                         else
 141                                 RandomSelection_Add(e, 0, 1, 0);
 142                 }
 143                 e = RandomSelection_chosen_ent;
 144         }
 145
 146         if(!e)
 147         {
 148                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 149         }
 150
 151         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 152
 153         if(e.target)
 154         {
 155                 oldself = self;
 156                 activator = other;
 157                 self = e;
 158                 SUB_UseTargets();
 159                 self = oldself;
 160         }
 161 }
 162
 163 void spawnfunc_info_teleport_destination (void)
 164 {
 165         self.classname = "info_teleport_destination";
 166
 167         self.mangle = self.angles;
 168         self.angles = '0 0 0';
 169
 170         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 171         setorigin (self, self.origin);
 172
 173         IFTARGETED
 174         {
 175         }
 176         else
 177                 objerror ("^3Teleport destination without a targetname");
 178 }
 179
 180 void spawnfunc_misc_teleporter_dest (void)
 181 {
 182         spawnfunc_info_teleport_destination();
 183 }
 184
 185 void spawnfunc_target_teleporter (void)
 186 {
 187         spawnfunc_info_teleport_destination();
 188 }
 189
 190 void teleport_findtarget (void)
 191 {
 192         entity e;
 193         float n;
 194
 195         n = 0;
 196         for(e = world; (e = find(e, targetname, self.target)); )
 197         {
 198                 ++n;
 199                 if(e.movetype == MOVETYPE_NONE)
 200                         waypoint_spawnforteleporter(self, e.origin, 0);
 201                 if(e.classname != "info_teleport_destination")
 202                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 203         }
 204
 205         if(n == 0)
 206         {
 207                 // no dest!
 208                 objerror ("Teleporter with nonexistant target");
 209                 return;
 210         }
 211         else if(n == 1)
 212         {
 213                 // exactly one dest - bots love that
 214                 self.enemy = find(e, targetname, self.target);
 215                 self.dest = self.enemy.origin;
 216         }
 217         else
 218         {
 219                 // have to use random selection every single time
 220                 self.enemy = world;
 221         }
 222
 223         // now enable touch
 224         self.touch = Teleport_Touch;
 225 }
 226
 227 void spawnfunc_trigger_teleport (void)
 228 {
 229         self.angles = '0 0 0';
 230
 231         EXACTTRIGGER_INIT;
 232
 233         self.use = trigger_teleport_use;
 234
 235         // this must be called to spawn the teleport waypoints for bots
 236         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 237
 238         if (!self.target)
 239         {
 240                 objerror ("Teleporter with no target");
 241                 return;
 242         }
 243 }