data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Show (entity e, float mode)
  45 {
  46         if (mode > 0)
  47         {
  48                 // make the item look normal, and be touchable
  49                 e.model = e.mdl;
  50                 e.solid = SOLID_TRIGGER;
  51                 e.effects &~= EF_ADDITIVE;
  52                 //e.colormod = '0 0 0';
  53                 e.alpha = 0;
  54
  55                 // special cases
  56                 if (e.strength_finished || e.invincible_finished)
  57                         e.effects = e.effects | EF_ADDITIVE | EF_FULLBRIGHT;
  58                 if (cvar("g_fullbrightitems"))
  59                         e.effects = e.effects | EF_FULLBRIGHT;
  60         }
  61         else if (mode < 0)
  62         {
  63                 // hide the item completely
  64                 e.model = string_null;
  65                 e.solid = SOLID_NOT;
  66                 e.effects &~= EF_ADDITIVE;
  67                 //e.colormod = '0 0 0';
  68                 e.alpha = 0;
  69         }
  70         else
  71         {
  72                 // make the item translucent green and not touchable
  73                 e.model = e.mdl;
  74                 e.solid = SOLID_NOT;
  75                 // e.effects |= EF_ADDITIVE;
  76                         // we need this to prevent weird display because of
  77                         // missing depth sorting - or maybe not
  78                 //e.colormod = '0.2 1 0.2';
  79                 e.alpha = 0.2;
  80
  81                 // special cases
  82                 if (e.strength_finished || e.invincible_finished)
  83                         e.effects = e.effects | EF_ADDITIVE | EF_FULLBRIGHT;
  84                 if (cvar("g_fullbrightitems"))
  85                         e.effects = e.effects | EF_FULLBRIGHT;
  86         }
  87
  88         // relink entity (because solid may have changed)
  89         setorigin(e, e.origin);
  90 }
  91
  92 void Item_Respawn (void)
  93 {
  94         Item_Show(self, 1);
  95         if(!g_minstagib && self.items == IT_STRENGTH)
  96                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  97         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  98                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  99         else
 100                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 101         setorigin (self, self.origin);
 102
 103         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 104         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 105 }
 106
 107 void Item_RespawnCountdown (void)
 108 {
 109         if(self.count >= ITEM_RESPAWN_TICKS)
 110         {
 111                 if(self.waypointsprite_attached)
 112                         WaypointSprite_Kill(self.waypointsprite_attached);
 113                 Item_Respawn();
 114         }
 115         else
 116         {
 117                 self.nextthink = time + 1;
 118                 self.count += 1;
 119                 if(self.count == 1)
 120                 {
 121                         string name;
 122                         vector rgb;
 123                         name = string_null;
 124                         if(g_minstagib)
 125                         {
 126                                 switch(self.items)
 127                                 {
 128                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 129                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 130                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 131                                 }
 132                         }
 133                         else
 134                         {
 135                                 switch(self.items)
 136                                 {
 137                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 138                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 139                                 }
 140                         }
 141                         switch(self.items)
 142                         {
 143                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 144                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 145                         }
 146                         if(name)
 147                         {
 148                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 149                                 if(self.waypointsprite_attached)
 150                                 {
 151                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 152                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 153                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 154                                 }
 155                         }
 156                 }
 157                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 158                 if(self.waypointsprite_attached)
 159                 {
 160                         WaypointSprite_Ping(self.waypointsprite_attached);
 161                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 162                 }
 163         }
 164 }
 165
 166 void Item_ScheduleRespawnIn(entity e, float t)
 167 {
 168         if(e.flags & FL_POWERUP)
 169         {
 170                 e.think = Item_RespawnCountdown;
 171                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 172                 e.count = 0;
 173         }
 174         else
 175         {
 176                 e.think = Item_Respawn;
 177                 e.nextthink = time + t;
 178         }
 179 }
 180
 181 void Item_ScheduleRespawn(entity e)
 182 {
 183         Item_Show(e, 0);
 184         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 185 }
 186
 187 void Item_ScheduleInitialRespawn(entity e)
 188 {
 189         Item_Show(e, 0);
 190         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 191 }
 192
 193 float Item_GiveTo(entity item, entity player)
 194 {
 195         float _switchweapon;
 196         float pickedup;
 197         float it;
 198         float i;
 199         entity e;
 200
 201         // if nothing happens to player, just return without taking the item
 202         pickedup = FALSE;
 203         _switchweapon = FALSE;
 204
 205         if (g_minstagib)
 206         {
 207                 if (item.ammo_fuel)
 208                 if (player.ammo_fuel < g_pickup_fuel_max)
 209                 {
 210                         pickedup = TRUE;
 211                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 212                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 213                 }
 214                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 215                 {
 216                         pickedup = TRUE;
 217                         player.items |= it;
 218                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 219                 }
 220
 221                 _switchweapon = TRUE;
 222                 if (item.ammo_cells)
 223                 {
 224                         pickedup = TRUE;
 225                         // play some cool sounds ;)
 226                         centerprint(player, "\n");
 227                         if (clienttype(player) == CLIENTTYPE_REAL)
 228                         {
 229                                 if(player.health <= 5)
 230                                         play2(player, "announcer/robotic/lastsecond.wav");
 231                                 else if(player.health < 50)
 232                                         play2(player, "announcer/robotic/narrowly.wav");
 233                         }
 234                         // sound not available
 235                         // else if(item.items == IT_CELLS)
 236                         //      play2(player, "announce/robotic/ammo.wav");
 237
 238                         if (item.weapons & WEPBIT_MINSTANEX)
 239                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 240                         if (item.ammo_cells)
 241                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 242                         player.health = 100;
 243                 }
 244
 245                 // extralife powerup
 246                 if (item.max_health)
 247                 {
 248                         pickedup = TRUE;
 249                         // sound not available
 250                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 251                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 252                         sprint(player, "^3You picked up some extra lives\n");
 253                 }
 254
 255                 // invis powerup
 256                 if (item.strength_finished)
 257                 {
 258                         pickedup = TRUE;
 259                         // sound not available
 260                         // play2(player, "announce/robotic/invisible.wav");
 261                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 262                 }
 263
 264                 // speed powerup
 265                 if (item.invincible_finished)
 266                 {
 267                         pickedup = TRUE;
 268                         // sound not available
 269                         // play2(player, "announce/robotic/speed.wav");
 270                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 271                 }
 272
 273                 if (item.ammo_fuel)
 274                 if (player.ammo_fuel < g_pickup_fuel_max)
 275                 {
 276                         pickedup = TRUE;
 277                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 278                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 279                 }
 280
 281         }
 282         else
 283         {
 284                 if (g_weapon_stay == 1)
 285                 if not(item.flags & FL_NO_WEAPON_STAY)
 286                 if (item.flags & FL_WEAPON)
 287                 {
 288                         if(item.classname == "droppedweapon")
 289                         {
 290                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 291                                         goto skip;
 292                         }
 293                         else
 294                         {
 295                                 if (player.weapons & item.weapons)
 296                                         goto skip;
 297                         }
 298                 }
 299
 300                 // in case the player has autoswitch enabled do the following:
 301                 // if the player is using their best weapon before items are given, they
 302                 // probably want to switch to an even better weapon after items are given
 303                 if (player.autoswitch)
 304                 if (player.switchweapon == w_getbestweapon(player))
 305                         _switchweapon = TRUE;
 306
 307                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 308                         _switchweapon = TRUE;
 309
 310                 if (item.ammo_shells)
 311                 if (player.ammo_shells < g_pickup_shells_max)
 312                 {
 313                         pickedup = TRUE;
 314                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 315                 }
 316                 if (item.ammo_nails)
 317                 if (player.ammo_nails < g_pickup_nails_max)
 318                 {
 319                         pickedup = TRUE;
 320                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 321                 }
 322                 if (item.ammo_rockets)
 323                 if (player.ammo_rockets < g_pickup_rockets_max)
 324                 {
 325                         pickedup = TRUE;
 326                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 327                 }
 328                 if (item.ammo_cells)
 329                 if (player.ammo_cells < g_pickup_cells_max)
 330                 {
 331                         pickedup = TRUE;
 332                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 333                 }
 334                 if (item.ammo_fuel)
 335                 if (player.ammo_fuel < g_pickup_fuel_max)
 336                 {
 337                         pickedup = TRUE;
 338                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 339                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 340                 }
 341
 342                 if (item.flags & FL_WEAPON)
 343                 if ((it = item.weapons - (item.weapons & player.weapons)))
 344                 {
 345                         pickedup = TRUE;
 346                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 347                         {
 348                                 e = get_weaponinfo(i);
 349                                 if(it & e.weapons)
 350                                         W_GiveWeapon (player, e.weapon, item.netname);
 351                         }
 352                 }
 353
 354                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 355                 {
 356                         pickedup = TRUE;
 357                         player.items |= it;
 358                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 359                 }
 360
 361                 if (item.strength_finished)
 362                 {
 363                         pickedup = TRUE;
 364                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 365                 }
 366                 if (item.invincible_finished)
 367                 {
 368                         pickedup = TRUE;
 369                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 370                 }
 371                 //if (item.speed_finished)
 372                 //{
 373                 //      pickedup = TRUE;
 374                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 375                 //}
 376                 //if (item.slowmo_finished)
 377                 //{
 378                 //      pickedup = TRUE;
 379                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 380                 //}
 381
 382                 if (item.health)
 383                 if (player.health < item.max_health)
 384                 {
 385                         pickedup = TRUE;
 386                         player.health = min(player.health + item.health, item.max_health);
 387                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 388                 }
 389                 if (item.armorvalue)
 390                 if (player.armorvalue < item.max_armorvalue)
 391                 {
 392                         pickedup = TRUE;
 393                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 394                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 395                 }
 396         }
 397
 398 :skip
 399         // always eat teamed entities
 400         if(item.team)
 401                 pickedup = TRUE;
 402
 403         if (!pickedup)
 404                 return 0;
 405
 406         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 407         if (_switchweapon)
 408                 if (player.switchweapon != w_getbestweapon(player))
 409                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 410
 411         return 1;
 412 }
 413
 414 void Item_Touch (void)
 415 {
 416         entity e, head;
 417
 418         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 419         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 420         {
 421                 remove(self);
 422                 return;
 423         }
 424         if (other.classname != "player")
 425                 return;
 426         if (other.deadflag)
 427                 return;
 428         if (self.solid != SOLID_TRIGGER)
 429                 return;
 430         if (self.owner == other)
 431                 return;
 432
 433         if(!Item_GiveTo(self, other))
 434                 return;
 435
 436         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 437
 438         if (self.classname == "droppedweapon")
 439                 remove (self);
 440         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 441                 return;
 442         else
 443         {
 444                 if(self.team)
 445                 {
 446                         RandomSelection_Init();
 447                         for(head = world; (head = findfloat(head, team, self.team)); )
 448                         {
 449                                 if(head.flags & FL_ITEM)
 450                                 {
 451                                         Item_Show(head, -1);
 452                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 453                                 }
 454                         }
 455                         e = RandomSelection_chosen_ent;
 456                 }
 457                 else
 458                         e = self;
 459                 Item_ScheduleRespawn(e);
 460         }
 461 }
 462
 463 void Item_FindTeam()
 464 {
 465         entity head, e;
 466
 467         if(self.effects & EF_NODRAW)
 468         {
 469                 // marker for item team search
 470                 dprint("Initializing item team ", ftos(self.team), "\n");
 471                 RandomSelection_Init();
 472                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 473                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 474                 e = RandomSelection_chosen_ent;
 475                 e.state = 0;
 476                 Item_Show(e, 1);
 477
 478                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 479                 {
 480                         if(head != e)
 481                         {
 482                                 // make it a non-spawned item
 483                                 Item_Show(head, -1);
 484                                 head.state = 1; // state 1 = initially hidden item
 485                         }
 486                         head.effects &~= EF_NODRAW;
 487                 }
 488
 489                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 490                         Item_ScheduleInitialRespawn(e);
 491         }
 492 }
 493
 494 void Item_Reset()
 495 {
 496         Item_Show(self, !self.state);
 497         setorigin (self, self.origin);
 498         self.think = SUB_Null;
 499         self.nextthink = 0;
 500
 501         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 502                 Item_ScheduleInitialRespawn(self);
 503 }
 504
 505 // Savage: used for item garbage-collection
 506 // TODO: perhaps nice special effect?
 507 void RemoveItem(void)
 508 {
 509         remove(self);
 510 }
 511
 512 // pickup evaluation functions
 513 // these functions decide how desirable an item is to the bots
 514
 515 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 516
 517 float weapon_pickupevalfunc(entity player, entity item)
 518 {
 519         float c, i, j, position;
 520
 521         // See if I have it already
 522         if(player.weapons & item.weapons == item.weapons)
 523         {
 524                 // If I can pick it up
 525                 if(g_weapon_stay)
 526                         c = 0;
 527                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 528                 {
 529                         // Skilled bots will grab more
 530                         c = bound(0, skill / 10, 1) * 0.5;
 531                 }
 532                 else
 533                         c = 0;
 534         }
 535         else
 536                 c = 1;
 537
 538         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 539         if( bot_custom_weapon && c )
 540         {
 541                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 542                 {
 543                         // Find weapon
 544                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 545                                 continue;
 546
 547                         // Find the highest position on any range
 548                         position = -1;
 549                         for(j = 0; j < WEP_LAST ; ++j){
 550                                 if(
 551                                                 bot_weapons_far[j] == i ||
 552                                                 bot_weapons_mid[j] == i ||
 553                                                 bot_weapons_close[j] == i
 554                                   )
 555                                 {
 556                                         position = j;
 557                                         break;
 558                                 }
 559                         }
 560
 561                         // Rate it
 562                         if (position >= 0 )
 563                         {
 564                                 position = WEP_LAST - position;
 565                                 // item.bot_pickupbasevalue is overwritten here
 566                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 567                         }
 568                 }
 569         }
 570
 571         return item.bot_pickupbasevalue * c;
 572 };
 573
 574 float commodity_pickupevalfunc(entity player, entity item)
 575 {
 576         float c, i, need_shells, need_nails, need_rockets, need_cells;
 577         entity wi;
 578         c = 0;
 579
 580         // Detect needed ammo
 581         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 582         {
 583                 wi = get_weaponinfo(i);
 584
 585                 if not(wi.weapons & player.weapons)
 586                         continue;
 587
 588                 if(wi.items & IT_SHELLS)
 589                         need_shells = TRUE;
 590                 else if(wi.items & IT_NAILS)
 591                         need_nails = TRUE;
 592                 else if(wi.items & IT_ROCKETS)
 593                         need_rockets = TRUE;
 594                 else if(wi.items & IT_CELLS)
 595                         need_cells = TRUE;
 596         }
 597
 598         // TODO: figure out if the player even has the weapon this ammo is for?
 599         // may not affect strategy much though...
 600         // find out how much more ammo/armor/health the player can hold
 601         if (need_shells)
 602         if (item.ammo_shells)
 603         if (player.ammo_shells < g_pickup_shells_max)
 604                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 605         if (need_nails)
 606         if (item.ammo_nails)
 607         if (player.ammo_nails < g_pickup_nails_max)
 608                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 609         if (need_rockets)
 610         if (item.ammo_rockets)
 611         if (player.ammo_rockets < g_pickup_rockets_max)
 612                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 613         if (need_cells)
 614         if (item.ammo_cells)
 615         if (player.ammo_cells < g_pickup_cells_max)
 616                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 617         if (item.armorvalue)
 618         if (player.armorvalue < item.max_armorvalue*0.5)
 619                 c = c + max(0, 1 - player.armorvalue / (item.max_armorvalue*0.5));
 620         if (item.health)
 621         if (player.health < item.max_health*0.5)
 622                 c = c + max(0, 1 - player.health / (item.max_health*0.5));
 623
 624         return item.bot_pickupbasevalue * c;
 625 };
 626
 627
 628 .float is_item;
 629 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 630 {
 631         startitem_failed = FALSE;
 632
 633         // is it a dropped weapon?
 634         if (self.classname == "droppedweapon")
 635         {
 636                 self.reset = SUB_Remove;
 637                 // it's a dropped weapon
 638                 self.movetype = MOVETYPE_TOSS;
 639                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 640                 self.think = RemoveItem;
 641                 self.nextthink = time + 60;
 642                 // don't drop if in a NODROP zone (such as lava)
 643                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 644                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 645                 {
 646                         startitem_failed = TRUE;
 647                         remove(self);
 648                         return;
 649                 }
 650         }
 651         else
 652         {
 653                 self.reset = Item_Reset;
 654                 // it's a level item
 655                 if(self.spawnflags & 1)
 656                         self.noalign = 1;
 657                 if (self.noalign)
 658                         self.movetype = MOVETYPE_NONE;
 659                 else
 660                         self.movetype = MOVETYPE_TOSS;
 661                 // do item filtering according to game mode and other things
 662                 if (!self.noalign)
 663                 {
 664                         // first nudge it off the floor a little bit to avoid math errors
 665                         setorigin(self, self.origin + '0 0 1');
 666                         // set item size before we spawn a spawnfunc_waypoint
 667                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 668                                 setsize (self, '-16 -16 0', '16 16 48');
 669                         else
 670                                 setsize (self, '-16 -16 0', '16 16 32');
 671                         // note droptofloor returns FALSE if stuck/or would fall too far
 672                         droptofloor();
 673                         waypoint_spawnforitem(self);
 674                 }
 675
 676                 if(teams_matter)
 677                 {
 678                         if(self.notteam)
 679                         {
 680                                 print("removed non-teamplay ", self.classname, "\n");
 681                                 startitem_failed = TRUE;
 682                                 remove (self);
 683                                 return;
 684                         }
 685                 }
 686                 else
 687                 {
 688                         if(self.notfree)
 689                         {
 690                                 print("removed non-FFA ", self.classname, "\n");
 691                                 startitem_failed = TRUE;
 692                                 remove (self);
 693                                 return;
 694                         }
 695                 }
 696
 697                 if(self.notq3a)
 698                 {
 699                         // We aren't TA or something like that, so we keep the Q3A entities
 700                         print("removed non-Q3A ", self.classname, "\n");
 701                         startitem_failed = TRUE;
 702                         remove (self);
 703                         return;
 704                 }
 705
 706                 /*
 707                  * can't do it that way, as it would break maps
 708                  * TODO make a target_give like entity another way, that perhaps has
 709                  * the weapon name in a key
 710                 if(self.targetname)
 711                 {
 712                         // target_give not yet supported; maybe later
 713                         print("removed targeted ", self.classname, "\n");
 714                         startitem_failed = TRUE;
 715                         remove (self);
 716                         return;
 717                 }
 718                 */
 719
 720                 if(cvar("spawn_debug") >= 2)
 721                 {
 722                         entity otheritem;
 723                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 724                         {
 725                                 if(otheritem.is_item)
 726                                 {
 727                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 728                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 729                                         error("Mapper sucks.");
 730                                 }
 731                         }
 732                         self.is_item = TRUE;
 733                 }
 734
 735                 weaponsInMap |= weaponid;
 736
 737                 if(g_lms)
 738                 {
 739                         startitem_failed = TRUE;
 740                         remove(self);
 741                         return;
 742                 }
 743                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 744                 {
 745                         startitem_failed = TRUE;
 746                         remove(self);
 747                         return;
 748                 }
 749                 else if (g_minstagib)
 750                 {
 751                         // don't remove dropped items and powerups
 752                         if (self.classname != "minstagib")
 753                         {
 754                                 startitem_failed = TRUE;
 755                                 remove (self);
 756                                 return;
 757                         }
 758                 }
 759                 else if (g_nixnex)
 760                 {
 761                         local float rm;
 762
 763                         rm = 1;
 764                         switch (itemid)
 765                         {
 766                                 case IT_HEALTH:
 767                                 case IT_5HP:
 768                                 case IT_25HP:
 769                                 case IT_ARMOR:
 770                                 case IT_ARMOR_SHARD:
 771                                         if (cvar("g_nixnex_with_healtharmor"))
 772                                                 rm = 0;
 773                                         break;
 774                                 case IT_STRENGTH:
 775                                 case IT_INVINCIBLE:
 776                                         if (cvar("g_nixnex_with_powerups"))
 777                                                 rm = 0;
 778                                         break;
 779                         }
 780
 781                         if(rm)
 782                         {
 783                                 startitem_failed = TRUE;
 784                                 remove (self);
 785                                 return;
 786                         }
 787                 }
 788                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 789                 {
 790                         startitem_failed = TRUE;
 791                         remove (self);
 792                         return;
 793                 }
 794
 795                 precache_model (itemmodel);
 796                 precache_sound (pickupsound);
 797                 precache_sound ("misc/itemrespawn.wav");
 798                 precache_sound ("misc/itemrespawncountdown.wav");
 799
 800                 if(itemid == IT_STRENGTH)
 801                         precache_sound ("misc/strength_respawn.wav");
 802                 if(itemid == IT_INVINCIBLE)
 803                         precache_sound ("misc/shield_respawn.wav");
 804
 805                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 806                         self.target = "###item###"; // for finding the nearest item using find()
 807         }
 808
 809         self.bot_pickup = TRUE;
 810         self.bot_pickupevalfunc = pickupevalfunc;
 811         self.bot_pickupbasevalue = pickupbasevalue;
 812         self.mdl = itemmodel;
 813         self.item_pickupsound = pickupsound;
 814         // let mappers override respawntime
 815         if(!self.respawntime) // both set
 816         {
 817                 self.respawntime = defaultrespawntime;
 818                 self.respawntimejitter = defaultrespawntimejitter;
 819         }
 820         self.netname = itemname;
 821         self.items = itemid;
 822         self.weapons = weaponid;
 823         self.flags = FL_ITEM | itemflags;
 824         self.touch = Item_Touch;
 825         setmodel (self, self.mdl); // precision set below
 826         self.effects |= EF_LOWPRECISION;
 827         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 828                 setsize (self, '-16 -16 0', '16 16 48');
 829         else
 830                 setsize (self, '-16 -16 0', '16 16 32');
 831         if(itemflags & FL_WEAPON)
 832                 self.modelflags |= MF_ROTATE;
 833
 834         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 835         if (itemflags & FL_WEAPON)
 836         {
 837                 // neutral team color for pickup weapons
 838                 self.colormap = 1024; // color shirt=0 pants=0 grey
 839         }
 840
 841         Item_Show(self, 1);
 842         self.state = 0;
 843         if(self.team)
 844         {
 845                 if(!self.cnt)
 846                         self.cnt = 1; // item probability weight
 847                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 848                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 849         }
 850         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 851                 Item_ScheduleInitialRespawn(self);
 852 }
 853
 854 /* replace items in minstagib
 855  * IT_STRENGTH   = invisibility
 856  * IT_NAILS      = extra lives
 857  * IT_INVINCIBLE = speed
 858  */
 859 void minstagib_items (float itemid)
 860 {
 861         // we don't want to replace dropped weapons ;)
 862         if (self.classname == "droppedweapon")
 863         {
 864                 self.ammo_cells = 25;
 865                 StartItem ("models/weapons/g_nex.md3",
 866                         "weapons/weaponpickup.wav", 15, 0,
 867                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 868                 return;
 869         }
 870
 871         local float rnd;
 872         self.classname = "minstagib";
 873
 874         // replace rocket launchers and nex guns with ammo cells
 875         if (itemid == IT_CELLS)
 876         {
 877                 self.ammo_cells = 1;
 878                 StartItem ("models/items/a_cells.md3",
 879                         "misc/itempickup.wav", 45, 0,
 880                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 881                 return;
 882         }
 883
 884         // randomize
 885         rnd = random() * 3;
 886         if (rnd <= 1)
 887                 itemid = IT_STRENGTH;
 888         else if (rnd <= 2)
 889                 itemid = IT_NAILS;
 890         else
 891                 itemid = IT_INVINCIBLE;
 892
 893         // replace with invis
 894         if (itemid == IT_STRENGTH)
 895         {
 896                 self.strength_finished = 30;
 897                 StartItem ("models/items/g_strength.md3",
 898                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 899                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 900         }
 901         // replace with extra lives
 902         if (itemid == IT_NAILS)
 903         {
 904                 self.max_health = 1;
 905                 StartItem ("models/items/g_h100.md3",
 906                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 907                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 908
 909         }
 910         // replace with speed
 911         if (itemid == IT_INVINCIBLE)
 912         {
 913                 self.invincible_finished = 30;
 914                 StartItem ("models/items/g_invincible.md3",
 915                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 916                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 917         }
 918
 919 }
 920
 921 float minst_no_auto_cells;
 922 void minst_remove_item (void) {
 923         if(minst_no_auto_cells)
 924                 remove(self);
 925 }
 926
 927 float weaponswapping;
 928 float internalteam;
 929
 930 void weapon_defaultspawnfunc(float wpn)
 931 {
 932         entity e;
 933         float t;
 934         var .float ammofield;
 935         string s;
 936         entity oldself;
 937         float i, j;
 938
 939         // set the respawntime in advance (so replaced weapons can copy it)
 940
 941         if(!self.respawntime)
 942         {
 943                 e = get_weaponinfo(wpn);
 944                 if(e.items == IT_SUPERWEAPON)
 945                 {
 946                         self.respawntime = g_pickup_respawntime_powerup;
 947                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 948                 }
 949                 else
 950                 {
 951                         self.respawntime = g_pickup_respawntime_weapon;
 952                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 953                 }
 954         }
 955
 956         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 957         {
 958                 e = get_weaponinfo(wpn);
 959                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 960                 if(s == "0")
 961                 {
 962                         remove(self);
 963                         startitem_failed = TRUE;
 964                         return;
 965                 }
 966                 t = tokenize_console(s);
 967                 if(t >= 2)
 968                 {
 969                         self.team = --internalteam;
 970                         oldself = self;
 971                         for(i = 1; i < t; ++i)
 972                         {
 973                                 s = argv(i);
 974                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 975                                 {
 976                                         e = get_weaponinfo(j);
 977                                         if(e.netname == s)
 978                                         {
 979                                                 self = spawn();
 980                                                 copyentity(oldself, self);
 981                                                 self.classname = "replacedweapon";
 982                                                 weapon_defaultspawnfunc(j);
 983                                                 break;
 984                                         }
 985                                 }
 986                                 if(j > WEP_LAST)
 987                                 {
 988                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 989                                 }
 990                         }
 991                         self = oldself;
 992                 }
 993                 if(t >= 1)
 994                 {
 995                         s = argv(0);
 996                         wpn = 0;
 997                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 998                         {
 999                                 e = get_weaponinfo(j);
1000                                 if(e.netname == s)
1001                                 {
1002                                         wpn = j;
1003                                         break;
1004                                 }
1005                         }
1006                         if(j > WEP_LAST)
1007                         {
1008                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1009                         }
1010                 }
1011                 if(wpn == 0)
1012                 {
1013                         remove(self);
1014                         startitem_failed = TRUE;
1015                         return;
1016                 }
1017         }
1018
1019         e = get_weaponinfo(wpn);
1020
1021         if(e.items && e.items != IT_SUPERWEAPON)
1022         {
1023                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1024                 {
1025                         if(e.items & j)
1026                         {
1027                                 ammofield = Item_CounterField(j);
1028                                 if(!self.ammofield)
1029                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1030                         }
1031                 }
1032         }
1033         else
1034         {
1035                 self.flags |= FL_NO_WEAPON_STAY;
1036         }
1037
1038         // weapon stay isn't supported for teamed weapons
1039         if(self.team)
1040                 self.flags |= FL_NO_WEAPON_STAY;
1041
1042         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1043         {
1044                 self.ammo_shells = 0;
1045                 self.ammo_nails = 0;
1046                 self.ammo_cells = 0;
1047                 self.ammo_rockets = 0;
1048                 // weapon stay 2: don't use ammo on weapon pickups; instead
1049                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1050         }
1051
1052         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1053         if (self.modelindex) // don't precache if self was removed
1054                 weapon_action(e.weapon, WR_PRECACHE);
1055 }
1056
1057 void spawnfunc_weapon_shotgun (void);
1058 void spawnfunc_weapon_uzi (void) {
1059         if(q3acompat_machineshotgunswap)
1060         if(self.classname != "droppedweapon")
1061         {
1062                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1063                 return;
1064         }
1065         weapon_defaultspawnfunc(WEP_UZI);
1066 }
1067
1068 void spawnfunc_weapon_shotgun (void) {
1069         if(q3acompat_machineshotgunswap)
1070         if(self.classname != "droppedweapon")
1071         {
1072                 weapon_defaultspawnfunc(WEP_UZI);
1073                 return;
1074         }
1075         weapon_defaultspawnfunc(WEP_SHOTGUN);
1076 }
1077
1078 void spawnfunc_weapon_nex (void)
1079 {
1080         if (g_minstagib)
1081         {
1082                 minstagib_items(IT_CELLS);
1083                 self.think = minst_remove_item;
1084                 self.nextthink = time;
1085                 return;
1086         }
1087         weapon_defaultspawnfunc(WEP_NEX);
1088 }
1089
1090 void spawnfunc_weapon_minstanex (void)
1091 {
1092         if (g_minstagib)
1093         {
1094                 minstagib_items(IT_CELLS);
1095                 self.think = minst_remove_item;
1096                 self.nextthink = time;
1097                 return;
1098         }
1099         weapon_defaultspawnfunc(WEP_MINSTANEX);
1100 }
1101
1102 void spawnfunc_weapon_rocketlauncher (void)
1103 {
1104         if (g_minstagib)
1105         {
1106                 minstagib_items(IT_CELLS);
1107                 self.think = minst_remove_item;
1108                 self.nextthink = time;
1109                 return;
1110         }
1111         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1112 }
1113
1114 void spawnfunc_item_rockets (void) {
1115         if(!self.ammo_rockets)
1116                 self.ammo_rockets = g_pickup_rockets;
1117         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1118 }
1119
1120 void spawnfunc_item_shells (void);
1121 void spawnfunc_item_bullets (void) {
1122         if(!weaponswapping)
1123         if(q3acompat_machineshotgunswap)
1124         if(self.classname != "droppedweapon")
1125         {
1126                 weaponswapping = TRUE;
1127                 spawnfunc_item_shells();
1128                 weaponswapping = FALSE;
1129                 return;
1130         }
1131
1132         if(!self.ammo_nails)
1133                 self.ammo_nails = g_pickup_nails;
1134         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1135 }
1136
1137 void spawnfunc_item_cells (void) {
1138         if(!self.ammo_cells)
1139                 self.ammo_cells = g_pickup_cells;
1140         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1141 }
1142
1143 void spawnfunc_item_shells (void) {
1144         if(!weaponswapping)
1145         if(q3acompat_machineshotgunswap)
1146         if(self.classname != "droppedweapon")
1147         {
1148                 weaponswapping = TRUE;
1149                 spawnfunc_item_bullets();
1150                 weaponswapping = FALSE;
1151                 return;
1152         }
1153
1154         if(!self.ammo_shells)
1155                 self.ammo_shells = g_pickup_shells;
1156         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1157 }
1158
1159 void spawnfunc_item_armor_small (void) {
1160         if(!self.armorvalue)
1161                 self.armorvalue = g_pickup_armorsmall;
1162         if(!self.max_armorvalue)
1163                 self.max_armorvalue = g_pickup_armorsmall_max;
1164         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1165 }
1166
1167 void spawnfunc_item_armor_medium (void) {
1168         if(!self.armorvalue)
1169                 self.armorvalue = g_pickup_armormedium;
1170         if(!self.max_armorvalue)
1171                 self.max_armorvalue = g_pickup_armormedium_max;
1172         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1173 }
1174
1175 void spawnfunc_item_armor_big (void) {
1176         if(!self.armorvalue)
1177                 self.armorvalue = g_pickup_armorbig;
1178         if(!self.max_armorvalue)
1179                 self.max_armorvalue = g_pickup_armorbig_max;
1180         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1181 }
1182
1183 void spawnfunc_item_armor_large (void) {
1184         if(!self.armorvalue)
1185                 self.armorvalue = g_pickup_armorlarge;
1186         if(!self.max_armorvalue)
1187                 self.max_armorvalue = g_pickup_armorlarge_max;
1188         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1189 }
1190
1191 void spawnfunc_item_health_small (void) {
1192         if(!self.max_health)
1193                 self.max_health = g_pickup_healthsmall_max;
1194         if(!self.health)
1195                 self.health = g_pickup_healthsmall;
1196         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1197 }
1198
1199 void spawnfunc_item_health_medium (void) {
1200         if(!self.max_health)
1201                 self.max_health = g_pickup_healthmedium_max;
1202         if(!self.health)
1203                 self.health = g_pickup_healthmedium;
1204         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1205 }
1206
1207 void spawnfunc_item_health_large (void) {
1208         if(!self.max_health)
1209                 self.max_health = g_pickup_healthlarge_max;
1210         if(!self.health)
1211                 self.health = g_pickup_healthlarge;
1212         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1213 }
1214
1215 void spawnfunc_item_health_mega (void) {
1216         if(!cvar("g_powerup_superhealth"))
1217                 return;
1218
1219         if(g_arena && !cvar("g_arena_powerups"))
1220                 return;
1221
1222         if(g_minstagib) {
1223                 minstagib_items(IT_NAILS);
1224         } else {
1225                 if(!self.max_health)
1226                         self.max_health = g_pickup_healthmega_max;
1227                 if(!self.health)
1228                         self.health = g_pickup_healthmega;
1229                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1230         }
1231 }
1232
1233 // support old misnamed entities
1234 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1235 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1236 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1237 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1238 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1239
1240 void spawnfunc_item_strength (void) {
1241         if(!cvar("g_powerup_strength"))
1242                 return;
1243
1244         if(g_arena && !cvar("g_arena_powerups"))
1245                 return;
1246
1247         if(g_minstagib) {
1248                 minstagib_items(IT_STRENGTH);
1249         } else {
1250                 precache_sound("weapons/strength_fire.wav");
1251                 self.strength_finished = 30;
1252                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1253         }
1254 }
1255
1256 void spawnfunc_item_invincible (void) {
1257         if(!cvar("g_powerup_shield"))
1258                 return;
1259
1260         if(g_arena && !cvar("g_arena_powerups"))
1261                 return;
1262
1263         if(g_minstagib) {
1264                 minstagib_items(IT_INVINCIBLE);
1265         } else {
1266                 self.invincible_finished = 30;
1267                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1268         }
1269 }
1270
1271 void spawnfunc_item_minst_cells (void) {
1272         if (g_minstagib)
1273         {
1274                 minst_no_auto_cells = 1;
1275                 minstagib_items(IT_CELLS);
1276         }
1277         else
1278                 remove(self);
1279 }
1280
1281 // compatibility:
1282 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1283
1284 float target_item_func_set(float a, float b)
1285 {
1286         if(b == 0)
1287                 return a;
1288         else if(b < 0)
1289                 return 0;
1290         else
1291                 return b;
1292 }
1293
1294 float target_item_func_min(float a, float b)
1295 {
1296         if(b == 0)
1297                 return a;
1298         else if(b < 0)
1299                 return 0;
1300         else
1301                 return min(a, b);
1302 }
1303
1304 float target_item_func_max(float a, float b)
1305 {
1306         return max(a, b);
1307 }
1308
1309 float target_item_func_bitset(float a, float b)
1310 {
1311         return b;
1312 }
1313
1314 float target_item_func_and(float a, float b)
1315 {
1316         return a & b;
1317 }
1318
1319 float target_item_func_itembitset(float a, float b)
1320 {
1321         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1322 }
1323
1324 float target_item_func_itemand(float a, float b)
1325 {
1326         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1327 }
1328
1329 float target_item_func_or(float a, float b)
1330 {
1331         return a | b;
1332 }
1333
1334 float target_item_func_andnot(float a, float b)
1335 {
1336         return a - (a & b);
1337 }
1338
1339 float target_item_changed;
1340 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1341 {
1342         float n, d;
1343         n = func(activator.field, self.field);
1344
1345         if(binary)
1346         {
1347                 d = n & activator.field;
1348                 if(d != n) // bits added?
1349                         d = +1;
1350                 else if(d != activator.field) // bits removed?
1351                         d = -1;
1352                 else
1353                         d = 0;
1354         }
1355         else
1356                 d = n - activator.field;
1357
1358         if(d < 0)
1359         {
1360                 if(sound_decrease != "")
1361                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1362                 target_item_changed = 1;
1363         }
1364         else if(d > 0)
1365         {
1366                 if(sound_increase != "")
1367                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1368                 target_item_changed = 1;
1369         }
1370         activator.field = n;
1371 }
1372
1373 void target_items_use (void)
1374 {
1375         float h0, a0, f0;
1376
1377         if(activator.classname == "droppedweapon")
1378         {
1379                 EXACTTRIGGER_TOUCH;
1380                 remove(activator);
1381                 return;
1382         }
1383
1384         if(activator.classname != "player")
1385                 return;
1386         if(activator.deadflag != DEAD_NO)
1387                 return;
1388         EXACTTRIGGER_TOUCH;
1389
1390         entity e;
1391         for(e = world; (e = find(e, classname, "droppedweapon")); )
1392                 if(e.enemy == activator)
1393                         remove(e);
1394
1395         float _switchweapon;
1396         _switchweapon = FALSE;
1397         if (activator.autoswitch)
1398                 if (activator.switchweapon == w_getbestweapon(activator))
1399                         _switchweapon = TRUE;
1400
1401         a0 = activator.armorvalue;
1402         h0 = activator.health;
1403         f0 = activator.ammo_fuel;
1404         target_item_changed = 0;
1405
1406         if(self.spawnflags == 0) // SET
1407         {
1408                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1409                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1410                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1411                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1412                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1413                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1414                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1415                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1416                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1417
1418                 if((self.items & activator.items) & IT_STRENGTH)
1419                         activator.strength_finished = time + self.strength_finished;
1420                 if((self.items & activator.items) & IT_INVINCIBLE)
1421                         activator.invincible_finished = time + self.invincible_finished;
1422         }
1423         else if(self.spawnflags == 1) // AND/MIN
1424         {
1425                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1426                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1427                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1428                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1429                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1430                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1431                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1432                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1433                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1434
1435                 if((self.items & activator.items) & IT_STRENGTH)
1436                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1437                 if((self.items & activator.items) & IT_INVINCIBLE)
1438                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1439         }
1440         else if(self.spawnflags == 2) // OR/MAX
1441         {
1442                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1443                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1444                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1445                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1446                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1447                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1448                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1449                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1450                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1451
1452                 if((self.items & activator.items) & IT_STRENGTH)
1453                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1454                 if((self.items & activator.items) & IT_INVINCIBLE)
1455                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1456         }
1457         else if(self.spawnflags == 4) // ANDNOT/MIN
1458         {
1459                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1460                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1461                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1462                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1463                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1464                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1465                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1466                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1467                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1468
1469                 if((self.items & activator.items) & IT_STRENGTH)
1470                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1471                 if((self.items & activator.items) & IT_INVINCIBLE)
1472                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1473         }
1474
1475         if not(activator.items & IT_STRENGTH)
1476                 activator.strength_finished = 0;
1477         if not(activator.items & IT_INVINCIBLE)
1478                 activator.invincible_finished = 0;
1479
1480         if(activator.health > h0)
1481                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1482         else if(activator.health < h0)
1483                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1484
1485         if(activator.ammo_fuel > f0)
1486                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1487         else if(activator.ammo_fuel < f0)
1488                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1489
1490         if(activator.armorvalue > a0)
1491                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1492
1493         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1494                 _switchweapon = TRUE;
1495         if(_switchweapon)
1496                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1497
1498         if(target_item_changed)
1499                 centerprint(activator, self.message);
1500 }
1501
1502 void spawnfunc_target_items (void)
1503 {
1504         float n, i, j;
1505         entity e;
1506
1507         if(g_nixnex)
1508         {
1509                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1510                 remove(self);
1511                 return;
1512         }
1513
1514         self.use = target_items_use;
1515         if(!self.strength_finished)
1516                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1517         if(!self.invincible_finished)
1518                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1519
1520         precache_sound("misc/itempickup.wav");
1521         precache_sound("misc/itempickup.wav");
1522         precache_sound("misc/itempickup.wav");
1523         precache_sound("misc/itempickup.wav");
1524         precache_sound("misc/megahealth.wav");
1525         precache_sound("misc/armor25.wav");
1526         precache_sound("misc/powerup.wav");
1527         precache_sound("misc/poweroff.wav");
1528         precache_sound("weapons/weaponpickup.wav");
1529
1530         n = tokenize_console(self.netname);
1531         for(i = 0; i < n; ++i)
1532         {
1533                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1534                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1535                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1536                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1537                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1538                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1539                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1540                 else
1541                 {
1542                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1543                         {
1544                                 e = get_weaponinfo(j);
1545                                 if(argv(i) == e.netname)
1546                                 {
1547                                         self.weapons |= e.weapons;
1548                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1549                                                 weapon_action(e.weapon, WR_PRECACHE);
1550                                         break;
1551                                 }
1552                         }
1553                         if(j > WEP_LAST)
1554                                 print("target_items: invalid item ", argv(i), "\n");
1555                 }
1556         }
1557 }
1558
1559 void spawnfunc_item_fuel(void)
1560 {
1561         if(!self.ammo_fuel)
1562                 self.ammo_fuel = g_pickup_fuel;
1563         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1564 }
1565
1566 void spawnfunc_item_fuel_regen(void)
1567 {
1568         if(start_items & IT_FUEL_REGEN)
1569         {
1570                 spawnfunc_item_fuel();
1571                 return;
1572         }
1573         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1574 }
1575
1576 void spawnfunc_item_jetpack(void)
1577 {
1578         if(g_grappling_hook)
1579                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1580         if(!self.ammo_fuel)
1581                 self.ammo_fuel = g_pickup_fuel_jetpack;
1582         if(start_items & IT_JETPACK)
1583         {
1584                 spawnfunc_item_fuel();
1585                 return;
1586         }
1587         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1588 }
1589
1590 // we no longer have the seeker
1591 void spawnfunc_weapon_seeker()
1592 {
1593         spawnfunc_weapon_fireball();
1594 }