data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Respawn (void)
  45 {
  46         self.model = self.mdl;          // restore original model
  47         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  48         if(!g_minstagib && self.items == IT_STRENGTH)
  49                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  50         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  51                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  52         else
  53                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  54         setorigin (self, self.origin);
  55
  56         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  57         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  58 }
  59
  60 void Item_RespawnCountdown (void)
  61 {
  62         if(self.count >= ITEM_RESPAWN_TICKS)
  63         {
  64                 if(self.waypointsprite_attached)
  65                         WaypointSprite_Kill(self.waypointsprite_attached);
  66                 Item_Respawn();
  67         }
  68         else
  69         {
  70                 self.nextthink = time + 1;
  71                 self.count += 1;
  72                 if(self.count == 1)
  73                 {
  74                         string name;
  75                         vector rgb;
  76                         name = string_null;
  77                         if(g_minstagib)
  78                         {
  79                                 switch(self.items)
  80                                 {
  81                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  82                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  83                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  84                                 }
  85                         }
  86                         else
  87                         {
  88                                 switch(self.items)
  89                                 {
  90                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  91                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  92                                 }
  93                         }
  94                         switch(self.items)
  95                         {
  96                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  97                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  98                         }
  99                         if(name)
 100                         {
 101                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, FALSE);
 102                                 if(self.waypointsprite_attached)
 103                                 {
 104                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 105                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 106                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 107                                 }
 108                         }
 109                 }
 110                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 111                 if(self.waypointsprite_attached)
 112                 {
 113                         WaypointSprite_Ping(self.waypointsprite_attached);
 114                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 115                 }
 116         }
 117 }
 118
 119 void Item_ScheduleRespawnIn(entity e, float t)
 120 {
 121         if(e.flags & FL_POWERUP)
 122         {
 123                 e.think = Item_RespawnCountdown;
 124                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 125                 e.count = 0;
 126         }
 127         else
 128         {
 129                 e.think = Item_Respawn;
 130                 e.nextthink = time + t;
 131         }
 132 }
 133
 134 void Item_ScheduleRespawn(entity e)
 135 {
 136         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 137 }
 138
 139 void Item_ScheduleInitialRespawn(entity e)
 140 {
 141         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 142 }
 143
 144 float Item_GiveTo(entity item, entity player)
 145 {
 146         float _switchweapon;
 147         float pickedup;
 148         float it;
 149         float i;
 150         entity e;
 151
 152         // if nothing happens to player, just return without taking the item
 153         pickedup = FALSE;
 154         _switchweapon = FALSE;
 155
 156         if (g_minstagib)
 157         {
 158                 if (item.ammo_fuel)
 159                 if (player.ammo_fuel < g_pickup_fuel_max)
 160                 {
 161                         pickedup = TRUE;
 162                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 163                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 164                 }
 165                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 166                 {
 167                         pickedup = TRUE;
 168                         player.items |= it;
 169                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 170                 }
 171
 172                 _switchweapon = TRUE;
 173                 if (item.ammo_cells)
 174                 {
 175                         pickedup = TRUE;
 176                         // play some cool sounds ;)
 177                         centerprint(player, "\n");
 178                         if(player.health <= 5)
 179                                 announce(player, "announcer/robotic/lastsecond.wav");
 180                         else if(player.health < 50)
 181                                 announce(player, "announcer/robotic/narrowly.wav");
 182                         // sound not available
 183                         // else if(item.items == IT_CELLS)
 184                         //      play2(player, "announce/robotic/ammo.wav");
 185
 186                         if (item.weapons & WEPBIT_MINSTANEX)
 187                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 188                         if (item.ammo_cells)
 189                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 190                         player.health = 100;
 191                 }
 192
 193                 // extralife powerup
 194                 if (item.max_health)
 195                 {
 196                         pickedup = TRUE;
 197                         // sound not available
 198                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 199                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 200                         sprint(player, "^3You picked up some extra lives\n");
 201                 }
 202
 203                 // invis powerup
 204                 if (item.strength_finished)
 205                 {
 206                         pickedup = TRUE;
 207                         // sound not available
 208                         // play2(player, "announce/robotic/invisible.wav");
 209                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 210                 }
 211
 212                 // speed powerup
 213                 if (item.invincible_finished)
 214                 {
 215                         pickedup = TRUE;
 216                         // sound not available
 217                         // play2(player, "announce/robotic/speed.wav");
 218                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 219                 }
 220
 221                 if (item.ammo_fuel)
 222                 if (player.ammo_fuel < g_pickup_fuel_max)
 223                 {
 224                         pickedup = TRUE;
 225                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 226                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 227                 }
 228
 229         }
 230         else
 231         {
 232                 if (g_weapon_stay == 1)
 233                 if not(item.flags & FL_NO_WEAPON_STAY)
 234                 if (item.flags & FL_WEAPON)
 235                 {
 236                         if(item.classname == "droppedweapon")
 237                         {
 238                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 239                                         goto skip;
 240                         }
 241                         else
 242                         {
 243                                 if (player.weapons & item.weapons)
 244                                         goto skip;
 245                         }
 246                 }
 247
 248                 // in case the player has autoswitch enabled do the following:
 249                 // if the player is using their best weapon before items are given, they
 250                 // probably want to switch to an even better weapon after items are given
 251                 if (player.autoswitch)
 252                 if (player.switchweapon == w_getbestweapon(player))
 253                         _switchweapon = TRUE;
 254
 255                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 256                         _switchweapon = TRUE;
 257
 258                 if (item.ammo_shells)
 259                 if (player.ammo_shells < g_pickup_shells_max)
 260                 {
 261                         pickedup = TRUE;
 262                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 263                 }
 264                 if (item.ammo_nails)
 265                 if (player.ammo_nails < g_pickup_nails_max)
 266                 {
 267                         pickedup = TRUE;
 268                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 269                 }
 270                 if (item.ammo_rockets)
 271                 if (player.ammo_rockets < g_pickup_rockets_max)
 272                 {
 273                         pickedup = TRUE;
 274                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 275                 }
 276                 if (item.ammo_cells)
 277                 if (player.ammo_cells < g_pickup_cells_max)
 278                 {
 279                         pickedup = TRUE;
 280                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 281                 }
 282                 if (item.ammo_fuel)
 283                 if (player.ammo_fuel < g_pickup_fuel_max)
 284                 {
 285                         pickedup = TRUE;
 286                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 287                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 288                 }
 289
 290                 if (item.flags & FL_WEAPON)
 291                 if ((it = item.weapons - (item.weapons & player.weapons)))
 292                 {
 293                         pickedup = TRUE;
 294                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 295                         {
 296                                 e = get_weaponinfo(i);
 297                                 if(it & e.weapons)
 298                                         W_GiveWeapon (player, e.weapon, item.netname);
 299                         }
 300                 }
 301
 302                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 303                 {
 304                         pickedup = TRUE;
 305                         player.items |= it;
 306                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 307                 }
 308
 309                 if (item.strength_finished)
 310                 {
 311                         pickedup = TRUE;
 312                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 313                 }
 314                 if (item.invincible_finished)
 315                 {
 316                         pickedup = TRUE;
 317                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 318                 }
 319                 //if (item.speed_finished)
 320                 //{
 321                 //      pickedup = TRUE;
 322                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 323                 //}
 324                 //if (item.slowmo_finished)
 325                 //{
 326                 //      pickedup = TRUE;
 327                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 328                 //}
 329
 330                 if (item.health)
 331                 if (player.health < item.max_health)
 332                 {
 333                         pickedup = TRUE;
 334                         player.health = min(player.health + item.health, item.max_health);
 335                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 336                 }
 337                 if (item.armorvalue)
 338                 if (player.armorvalue < item.max_armorvalue)
 339                 {
 340                         pickedup = TRUE;
 341                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 342                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 343                 }
 344         }
 345
 346 :skip
 347         // always eat teamed entities
 348         if(item.team)
 349                 pickedup = TRUE;
 350
 351         if (!pickedup)
 352                 return 0;
 353
 354         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 355         if (_switchweapon)
 356                 if (player.switchweapon != w_getbestweapon(player))
 357                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 358
 359         return 1;
 360 }
 361
 362 void Item_Touch (void)
 363 {
 364         entity e, head;
 365
 366         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 367         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 368         {
 369                 remove(self);
 370                 return;
 371         }
 372         if (other.classname != "player")
 373                 return;
 374         if (other.deadflag)
 375                 return;
 376         if (self.solid != SOLID_TRIGGER)
 377                 return;
 378         if (self.owner == other)
 379                 return;
 380
 381         if(!Item_GiveTo(self, other))
 382                 return;
 383
 384         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 385
 386         if (self.classname == "droppedweapon")
 387                 remove (self);
 388         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 389                 return;
 390         else
 391         {
 392                 self.solid = SOLID_NOT;
 393                 self.model = string_null;
 394                 if(self.team)
 395                 {
 396                         RandomSelection_Init();
 397                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 398                                 RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 399                         e = RandomSelection_chosen_ent;
 400                 }
 401                 else
 402                         e = self;
 403                 Item_ScheduleRespawn(e);
 404         }
 405 }
 406
 407 void Item_FindTeam()
 408 {
 409         entity head, e;
 410
 411         if(self.effects & EF_NODRAW)
 412         {
 413                 // marker for item team search
 414                 dprint("Initializing item team ", ftos(self.team), "\n");
 415                 RandomSelection_Init();
 416                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 417                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 418                 e = RandomSelection_chosen_ent;
 419                 e.state = 0;
 420
 421                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 422                 {
 423                         if(head != e)
 424                         {
 425                                 // make it a non-spawned item
 426                                 head.solid = SOLID_NOT;
 427                                 head.model = string_null;
 428                                 head.state = 1; // state 1 = initially hidden item
 429                         }
 430                         head.effects &~= EF_NODRAW;
 431                 }
 432
 433                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 434                 {
 435                         e.solid = SOLID_NOT;
 436                         e.model = string_null;
 437                         Item_ScheduleInitialRespawn(e);
 438                 }
 439         }
 440 }
 441
 442 void Item_Reset()
 443 {
 444         if(self.state == 1)
 445         {
 446                 self.model = string_null;
 447                 self.solid = SOLID_NOT;
 448         }
 449         else
 450         {
 451                 self.model = self.mdl;
 452                 self.solid = SOLID_TRIGGER;
 453         }
 454         setorigin (self, self.origin);
 455         self.think = SUB_Null;
 456         self.nextthink = 0;
 457
 458         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 459         {
 460                 self.solid = SOLID_NOT;
 461                 self.model = string_null;
 462                 Item_ScheduleInitialRespawn(self);
 463         }
 464 }
 465
 466 // Savage: used for item garbage-collection
 467 // TODO: perhaps nice special effect?
 468 void RemoveItem(void)
 469 {
 470         remove(self);
 471 }
 472
 473 // pickup evaluation functions
 474 // these functions decide how desirable an item is to the bots
 475
 476 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 477
 478 float weapon_pickupevalfunc(entity player, entity item)
 479 {
 480         float c, i, j, position;
 481
 482         // See if I have it already
 483         if(player.weapons & item.weapons == item.weapons)
 484         {
 485                 // If I can pick it up
 486                 if(g_weapon_stay)
 487                         c = 0;
 488                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 489                 {
 490                         // Skilled bots will grab more
 491                         c = bound(0, skill / 10, 1) * 0.5;
 492                 }
 493                 else
 494                         c = 0;
 495         }
 496         else
 497                 c = 1;
 498
 499         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 500         if( bot_custom_weapon && c )
 501         {
 502                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 503                 {
 504                         // Find weapon
 505                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 506                                 continue;
 507
 508                         // Find the highest position on any range
 509                         position = -1;
 510                         for(j = 0; j < WEP_LAST ; ++j){
 511                                 if(
 512                                                 bot_weapons_far[j] == i ||
 513                                                 bot_weapons_mid[j] == i ||
 514                                                 bot_weapons_close[j] == i
 515                                   )
 516                                 {
 517                                         position = j;
 518                                         break;
 519                                 }
 520                         }
 521
 522                         // Rate it
 523                         if (position >= 0 )
 524                         {
 525                                 position = WEP_LAST - position;
 526                                 // item.bot_pickupbasevalue is overwritten here
 527                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 528                         }
 529                 }
 530         }
 531
 532         return item.bot_pickupbasevalue * c;
 533 };
 534
 535 float commodity_pickupevalfunc(entity player, entity item)
 536 {
 537         float c, i, need_shells, need_nails, need_rockets, need_cells;
 538         entity wi;
 539         c = 0;
 540
 541         // Detect needed ammo
 542         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 543         {
 544                 wi = get_weaponinfo(i);
 545
 546                 if not(wi.weapons & player.weapons)
 547                         continue;
 548
 549                 if(wi.items & IT_SHELLS)
 550                         need_shells = TRUE;
 551                 else if(wi.items & IT_NAILS)
 552                         need_nails = TRUE;
 553                 else if(wi.items & IT_ROCKETS)
 554                         need_rockets = TRUE;
 555                 else if(wi.items & IT_CELLS)
 556                         need_cells = TRUE;
 557         }
 558
 559         // TODO: figure out if the player even has the weapon this ammo is for?
 560         // may not affect strategy much though...
 561         // find out how much more ammo/armor/health the player can hold
 562         if (need_shells)
 563         if (item.ammo_shells)
 564         if (player.ammo_shells < g_pickup_shells_max)
 565                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 566         if (need_nails)
 567         if (item.ammo_nails)
 568         if (player.ammo_nails < g_pickup_nails_max)
 569                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 570         if (need_rockets)
 571         if (item.ammo_rockets)
 572         if (player.ammo_rockets < g_pickup_rockets_max)
 573                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 574         if (need_cells)
 575         if (item.ammo_cells)
 576         if (player.ammo_cells < g_pickup_cells_max)
 577                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 578         if (item.armorvalue)
 579         if (player.armorvalue < item.max_armorvalue*0.5)
 580                 c = c + max(0, 1 - player.armorvalue / (item.max_armorvalue*0.5));
 581         if (item.health)
 582         if (player.health < item.max_health*0.5)
 583                 c = c + max(0, 1 - player.health / (item.max_health*0.5));
 584
 585         return item.bot_pickupbasevalue * c;
 586 };
 587
 588
 589 .float is_item;
 590 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 591 {
 592         startitem_failed = FALSE;
 593
 594         // is it a dropped weapon?
 595         if (self.classname == "droppedweapon")
 596         {
 597                 self.reset = SUB_Remove;
 598                 // it's a dropped weapon
 599                 self.movetype = MOVETYPE_TOSS;
 600                 self.solid = SOLID_TRIGGER;
 601                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 602                 self.think = RemoveItem;
 603                 self.nextthink = time + 60;
 604                 // don't drop if in a NODROP zone (such as lava)
 605                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 606                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 607                 {
 608                         startitem_failed = TRUE;
 609                         remove(self);
 610                         return;
 611                 }
 612         }
 613         else
 614         {
 615                 self.reset = Item_Reset;
 616                 // it's a level item
 617                 if(self.spawnflags & 1)
 618                         self.noalign = 1;
 619                 if (self.noalign)
 620                         self.movetype = MOVETYPE_NONE;
 621                 else
 622                         self.movetype = MOVETYPE_TOSS;
 623                 self.solid = SOLID_TRIGGER;
 624                 // do item filtering according to game mode and other things
 625                 if (!self.noalign)
 626                 {
 627                         // first nudge it off the floor a little bit to avoid math errors
 628                         setorigin(self, self.origin + '0 0 1');
 629                         // set item size before we spawn a spawnfunc_waypoint
 630                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 631                                 setsize (self, '-16 -16 0', '16 16 48');
 632                         else
 633                                 setsize (self, '-16 -16 0', '16 16 32');
 634                         // note droptofloor returns FALSE if stuck/or would fall too far
 635                         droptofloor();
 636                         waypoint_spawnforitem(self);
 637                 }
 638
 639                 if(teams_matter)
 640                 {
 641                         if(self.notteam)
 642                         {
 643                                 print("removed non-teamplay ", self.classname, "\n");
 644                                 startitem_failed = TRUE;
 645                                 remove (self);
 646                                 return;
 647                         }
 648                 }
 649                 else
 650                 {
 651                         if(self.notfree)
 652                         {
 653                                 print("removed non-FFA ", self.classname, "\n");
 654                                 startitem_failed = TRUE;
 655                                 remove (self);
 656                                 return;
 657                         }
 658                 }
 659
 660                 if(self.notq3a)
 661                 {
 662                         // We aren't TA or something like that, so we keep the Q3A entities
 663                         print("removed non-Q3A ", self.classname, "\n");
 664                         startitem_failed = TRUE;
 665                         remove (self);
 666                         return;
 667                 }
 668
 669                 /*
 670                  * can't do it that way, as it would break maps
 671                  * TODO make a target_give like entity another way, that perhaps has
 672                  * the weapon name in a key
 673                 if(self.targetname)
 674                 {
 675                         // target_give not yet supported; maybe later
 676                         print("removed targeted ", self.classname, "\n");
 677                         startitem_failed = TRUE;
 678                         remove (self);
 679                         return;
 680                 }
 681                 */
 682
 683                 if(cvar("spawn_debug") >= 2)
 684                 {
 685                         entity otheritem;
 686                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 687                         {
 688                                 if(otheritem.is_item)
 689                                 {
 690                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 691                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 692                                         error("Mapper sucks.");
 693                                 }
 694                         }
 695                         self.is_item = TRUE;
 696                 }
 697
 698                 weaponsInMap |= weaponid;
 699
 700                 if(g_lms)
 701                 {
 702                         startitem_failed = TRUE;
 703                         remove(self);
 704                         return;
 705                 }
 706                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 707                 {
 708                         startitem_failed = TRUE;
 709                         remove(self);
 710                         return;
 711                 }
 712                 else if (g_minstagib)
 713                 {
 714                         // don't remove dropped items and powerups
 715                         if (self.classname != "minstagib")
 716                         {
 717                                 startitem_failed = TRUE;
 718                                 remove (self);
 719                                 return;
 720                         }
 721                 }
 722                 else if (g_nixnex)
 723                 {
 724                         local float rm;
 725
 726                         rm = 1;
 727                         switch (itemid)
 728                         {
 729                                 case IT_HEALTH:
 730                                 case IT_5HP:
 731                                 case IT_25HP:
 732                                 case IT_ARMOR:
 733                                 case IT_ARMOR_SHARD:
 734                                         if (cvar("g_nixnex_with_healtharmor"))
 735                                                 rm = 0;
 736                                         break;
 737                                 case IT_STRENGTH:
 738                                 case IT_INVINCIBLE:
 739                                         if (cvar("g_nixnex_with_powerups"))
 740                                                 rm = 0;
 741                                         break;
 742                         }
 743
 744                         if(rm)
 745                         {
 746                                 startitem_failed = TRUE;
 747                                 remove (self);
 748                                 return;
 749                         }
 750                 }
 751                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 752                 {
 753                         startitem_failed = TRUE;
 754                         remove (self);
 755                         return;
 756                 }
 757
 758                 precache_model (itemmodel);
 759                 precache_sound (pickupsound);
 760                 precache_sound ("misc/itemrespawn.wav");
 761                 precache_sound ("misc/itemrespawncountdown.wav");
 762
 763                 if(itemid == IT_STRENGTH)
 764                         precache_sound ("misc/strength_respawn.wav");
 765                 if(itemid == IT_INVINCIBLE)
 766                         precache_sound ("misc/shield_respawn.wav");
 767
 768                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 769                         self.target = "###item###"; // for finding the nearest item using find()
 770         }
 771
 772         self.bot_pickup = TRUE;
 773         self.bot_pickupevalfunc = pickupevalfunc;
 774         self.bot_pickupbasevalue = pickupbasevalue;
 775         self.mdl = itemmodel;
 776         self.item_pickupsound = pickupsound;
 777         // let mappers override respawntime
 778         if(!self.respawntime) // both set
 779         {
 780                 self.respawntime = defaultrespawntime;
 781                 self.respawntimejitter = defaultrespawntimejitter;
 782         }
 783         self.netname = itemname;
 784         self.items = itemid;
 785         self.weapons = weaponid;
 786         self.flags = FL_ITEM | itemflags;
 787         self.touch = Item_Touch;
 788         setmodel (self, self.mdl); // precision set below
 789         self.effects |= EF_LOWPRECISION;
 790         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 791                 setsize (self, '-16 -16 0', '16 16 48');
 792         else
 793                 setsize (self, '-16 -16 0', '16 16 32');
 794         if(itemflags & FL_WEAPON)
 795                 self.modelflags |= MF_ROTATE;
 796
 797         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 798         if (itemflags & FL_WEAPON)
 799         {
 800                 // neutral team color for pickup weapons
 801                 self.colormap = 1024; // color shirt=0 pants=0 grey
 802         }
 803
 804         if (cvar("g_fullbrightitems"))
 805                 self.effects = self.effects | EF_FULLBRIGHT;
 806
 807         self.state = 0;
 808         if(self.team)
 809         {
 810                 if(!self.cnt)
 811                         self.cnt = 1; // item probability weight
 812                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 813                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 814         }
 815         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 816         {
 817                 self.solid = SOLID_NOT;
 818                 self.model = string_null;
 819                 Item_ScheduleInitialRespawn(self);
 820         }
 821 }
 822
 823 /* replace items in minstagib
 824  * IT_STRENGTH   = invisibility
 825  * IT_NAILS      = extra lives
 826  * IT_INVINCIBLE = speed
 827  */
 828 void minstagib_items (float itemid)
 829 {
 830         // we don't want to replace dropped weapons ;)
 831         if (self.classname == "droppedweapon")
 832         {
 833                 self.ammo_cells = 25;
 834                 StartItem ("models/weapons/g_nex.md3",
 835                         "weapons/weaponpickup.wav", 15, 0,
 836                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 837                 return;
 838         }
 839
 840         local float rnd;
 841         self.classname = "minstagib";
 842
 843         // replace rocket launchers and nex guns with ammo cells
 844         if (itemid == IT_CELLS)
 845         {
 846                 self.ammo_cells = 1;
 847                 StartItem ("models/items/a_cells.md3",
 848                         "misc/itempickup.wav", 45, 0,
 849                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 850                 return;
 851         }
 852
 853         // randomize
 854         rnd = random() * 3;
 855         if (rnd <= 1)
 856                 itemid = IT_STRENGTH;
 857         else if (rnd <= 2)
 858                 itemid = IT_NAILS;
 859         else
 860                 itemid = IT_INVINCIBLE;
 861
 862         // replace with invis
 863         if (itemid == IT_STRENGTH)
 864         {
 865                 self.effects = EF_ADDITIVE;
 866                 self.strength_finished = 30;
 867                 StartItem ("models/items/g_strength.md3",
 868                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 869                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 870         }
 871         // replace with extra lives
 872         if (itemid == IT_NAILS)
 873         {
 874                 self.max_health = 1;
 875                 StartItem ("models/items/g_h100.md3",
 876                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 877                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 878
 879         }
 880         // replace with speed
 881         if (itemid == IT_INVINCIBLE)
 882         {
 883                 self.effects = EF_ADDITIVE;
 884                 self.invincible_finished = 30;
 885                 StartItem ("models/items/g_invincible.md3",
 886                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 887                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 888         }
 889
 890 }
 891
 892 float minst_no_auto_cells;
 893 void minst_remove_item (void) {
 894         if(minst_no_auto_cells)
 895                 remove(self);
 896 }
 897
 898 float weaponswapping;
 899 float internalteam;
 900
 901 void weapon_defaultspawnfunc(float wpn)
 902 {
 903         entity e;
 904         float t;
 905         var .float ammofield;
 906         string s;
 907         entity oldself;
 908         float i, j;
 909
 910         // set the respawntime in advance (so replaced weapons can copy it)
 911
 912         if(!self.respawntime)
 913         {
 914                 e = get_weaponinfo(wpn);
 915                 if(e.items == IT_SUPERWEAPON)
 916                 {
 917                         self.respawntime = g_pickup_respawntime_powerup;
 918                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 919                 }
 920                 else
 921                 {
 922                         self.respawntime = g_pickup_respawntime_weapon;
 923                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 924                 }
 925         }
 926
 927         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 928         {
 929                 e = get_weaponinfo(wpn);
 930                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 931                 if(s == "0")
 932                 {
 933                         remove(self);
 934                         startitem_failed = TRUE;
 935                         return;
 936                 }
 937                 t = tokenize_console(s);
 938                 if(t >= 2)
 939                 {
 940                         self.team = --internalteam;
 941                         oldself = self;
 942                         for(i = 1; i < t; ++i)
 943                         {
 944                                 s = argv(i);
 945                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 946                                 {
 947                                         e = get_weaponinfo(j);
 948                                         if(e.netname == s)
 949                                         {
 950                                                 self = spawn();
 951                                                 copyentity(oldself, self);
 952                                                 self.classname = "replacedweapon";
 953                                                 weapon_defaultspawnfunc(j);
 954                                                 break;
 955                                         }
 956                                 }
 957                                 if(j > WEP_LAST)
 958                                 {
 959                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 960                                 }
 961                         }
 962                         self = oldself;
 963                 }
 964                 if(t >= 1)
 965                 {
 966                         s = argv(0);
 967                         wpn = 0;
 968                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 969                         {
 970                                 e = get_weaponinfo(j);
 971                                 if(e.netname == s)
 972                                 {
 973                                         wpn = j;
 974                                         break;
 975                                 }
 976                         }
 977                         if(j > WEP_LAST)
 978                         {
 979                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 980                         }
 981                 }
 982                 if(wpn == 0)
 983                 {
 984                         remove(self);
 985                         startitem_failed = TRUE;
 986                         return;
 987                 }
 988         }
 989
 990         e = get_weaponinfo(wpn);
 991
 992         if(e.items && e.items != IT_SUPERWEAPON)
 993         {
 994                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 995                 {
 996                         if(e.items & j)
 997                         {
 998                                 ammofield = Item_CounterField(j);
 999                                 if(!self.ammofield)
1000                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1001                         }
1002                 }
1003         }
1004         else
1005         {
1006                 self.flags |= FL_NO_WEAPON_STAY;
1007         }
1008
1009         // weapon stay isn't supported for teamed weapons
1010         if(self.team)
1011                 self.flags |= FL_NO_WEAPON_STAY;
1012
1013         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1014         {
1015                 self.ammo_shells = 0;
1016                 self.ammo_nails = 0;
1017                 self.ammo_cells = 0;
1018                 self.ammo_rockets = 0;
1019                 // weapon stay 2: don't use ammo on weapon pickups; instead
1020                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1021         }
1022
1023         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1024         if (self.modelindex) // don't precache if self was removed
1025                 weapon_action(e.weapon, WR_PRECACHE);
1026 }
1027
1028 void spawnfunc_weapon_shotgun (void);
1029 void spawnfunc_weapon_uzi (void) {
1030         if(q3acompat_machineshotgunswap)
1031         if(self.classname != "droppedweapon")
1032         {
1033                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1034                 return;
1035         }
1036         weapon_defaultspawnfunc(WEP_UZI);
1037 }
1038
1039 void spawnfunc_weapon_shotgun (void) {
1040         if(q3acompat_machineshotgunswap)
1041         if(self.classname != "droppedweapon")
1042         {
1043                 weapon_defaultspawnfunc(WEP_UZI);
1044                 return;
1045         }
1046         weapon_defaultspawnfunc(WEP_SHOTGUN);
1047 }
1048
1049 void spawnfunc_weapon_nex (void)
1050 {
1051         if (g_minstagib)
1052         {
1053                 minstagib_items(IT_CELLS);
1054                 self.think = minst_remove_item;
1055                 self.nextthink = time;
1056                 return;
1057         }
1058         weapon_defaultspawnfunc(WEP_NEX);
1059 }
1060
1061 void spawnfunc_weapon_minstanex (void)
1062 {
1063         if (g_minstagib)
1064         {
1065                 minstagib_items(IT_CELLS);
1066                 self.think = minst_remove_item;
1067                 self.nextthink = time;
1068                 return;
1069         }
1070         weapon_defaultspawnfunc(WEP_MINSTANEX);
1071 }
1072
1073 void spawnfunc_weapon_rocketlauncher (void)
1074 {
1075         if (g_minstagib)
1076         {
1077                 minstagib_items(IT_CELLS);
1078                 self.think = minst_remove_item;
1079                 self.nextthink = time;
1080                 return;
1081         }
1082         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1083 }
1084
1085 void spawnfunc_item_rockets (void) {
1086         if(!self.ammo_rockets)
1087                 self.ammo_rockets = g_pickup_rockets;
1088         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1089 }
1090
1091 void spawnfunc_item_shells (void);
1092 void spawnfunc_item_bullets (void) {
1093         if(!weaponswapping)
1094         if(q3acompat_machineshotgunswap)
1095         if(self.classname != "droppedweapon")
1096         {
1097                 weaponswapping = TRUE;
1098                 spawnfunc_item_shells();
1099                 weaponswapping = FALSE;
1100                 return;
1101         }
1102
1103         if(!self.ammo_nails)
1104                 self.ammo_nails = g_pickup_nails;
1105         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1106 }
1107
1108 void spawnfunc_item_cells (void) {
1109         if(!self.ammo_cells)
1110                 self.ammo_cells = g_pickup_cells;
1111         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1112 }
1113
1114 void spawnfunc_item_shells (void) {
1115         if(!weaponswapping)
1116         if(q3acompat_machineshotgunswap)
1117         if(self.classname != "droppedweapon")
1118         {
1119                 weaponswapping = TRUE;
1120                 spawnfunc_item_bullets();
1121                 weaponswapping = FALSE;
1122                 return;
1123         }
1124
1125         if(!self.ammo_shells)
1126                 self.ammo_shells = g_pickup_shells;
1127         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1128 }
1129
1130 void spawnfunc_item_armor_small (void) {
1131         if(!self.armorvalue)
1132                 self.armorvalue = g_pickup_armorsmall;
1133         if(!self.max_armorvalue)
1134                 self.max_armorvalue = g_pickup_armorsmall_max;
1135         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1136 }
1137
1138 void spawnfunc_item_armor_medium (void) {
1139         if(!self.armorvalue)
1140                 self.armorvalue = g_pickup_armormedium;
1141         if(!self.max_armorvalue)
1142                 self.max_armorvalue = g_pickup_armormedium_max;
1143         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1144 }
1145
1146 void spawnfunc_item_armor_big (void) {
1147         if(!self.armorvalue)
1148                 self.armorvalue = g_pickup_armorbig;
1149         if(!self.max_armorvalue)
1150                 self.max_armorvalue = g_pickup_armorbig_max;
1151         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1152 }
1153
1154 void spawnfunc_item_armor_large (void) {
1155         if(!self.armorvalue)
1156                 self.armorvalue = g_pickup_armorlarge;
1157         if(!self.max_armorvalue)
1158                 self.max_armorvalue = g_pickup_armorlarge_max;
1159         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1160 }
1161
1162 void spawnfunc_item_health_small (void) {
1163         if(!self.max_health)
1164                 self.max_health = g_pickup_healthsmall_max;
1165         if(!self.health)
1166                 self.health = g_pickup_healthsmall;
1167         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1168 }
1169
1170 void spawnfunc_item_health_medium (void) {
1171         if(!self.max_health)
1172                 self.max_health = g_pickup_healthmedium_max;
1173         if(!self.health)
1174                 self.health = g_pickup_healthmedium;
1175         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1176 }
1177
1178 void spawnfunc_item_health_large (void) {
1179         if(!self.max_health)
1180                 self.max_health = g_pickup_healthlarge_max;
1181         if(!self.health)
1182                 self.health = g_pickup_healthlarge;
1183         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1184 }
1185
1186 void spawnfunc_item_health_mega (void) {
1187         if(!cvar("g_powerup_superhealth"))
1188                 return;
1189
1190         if(g_arena && !cvar("g_arena_powerups"))
1191                 return;
1192
1193         if(g_minstagib) {
1194                 minstagib_items(IT_NAILS);
1195         } else {
1196                 if(!self.max_health)
1197                         self.max_health = g_pickup_healthmega_max;
1198                 if(!self.health)
1199                         self.health = g_pickup_healthmega;
1200                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1201         }
1202 }
1203
1204 // support old misnamed entities
1205 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1206 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1207 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1208 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1209 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1210
1211 void spawnfunc_item_strength (void) {
1212         if(!cvar("g_powerup_strength"))
1213                 return;
1214
1215         if(g_arena && !cvar("g_arena_powerups"))
1216                 return;
1217
1218         if(g_minstagib) {
1219                 minstagib_items(IT_STRENGTH);
1220         } else {
1221                 precache_sound("weapons/strength_fire.wav");
1222                 self.strength_finished = 30;
1223                 self.effects = EF_ADDITIVE;
1224                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1225         }
1226 }
1227
1228 void spawnfunc_item_invincible (void) {
1229         if(!cvar("g_powerup_shield"))
1230                 return;
1231
1232         if(g_arena && !cvar("g_arena_powerups"))
1233                 return;
1234
1235         if(g_minstagib) {
1236                 minstagib_items(IT_INVINCIBLE);
1237         } else {
1238                 self.invincible_finished = 30;
1239                 self.effects = EF_ADDITIVE;
1240                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1241         }
1242 }
1243
1244 void spawnfunc_item_minst_cells (void) {
1245         if (g_minstagib)
1246         {
1247                 minst_no_auto_cells = 1;
1248                 minstagib_items(IT_CELLS);
1249         }
1250         else
1251                 remove(self);
1252 }
1253
1254 // compatibility:
1255 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1256
1257 float target_item_func_set(float a, float b)
1258 {
1259         if(b == 0)
1260                 return a;
1261         else if(b < 0)
1262                 return 0;
1263         else
1264                 return b;
1265 }
1266
1267 float target_item_func_min(float a, float b)
1268 {
1269         if(b == 0)
1270                 return a;
1271         else if(b < 0)
1272                 return 0;
1273         else
1274                 return min(a, b);
1275 }
1276
1277 float target_item_func_max(float a, float b)
1278 {
1279         return max(a, b);
1280 }
1281
1282 float target_item_func_bitset(float a, float b)
1283 {
1284         return b;
1285 }
1286
1287 float target_item_func_and(float a, float b)
1288 {
1289         return a & b;
1290 }
1291
1292 float target_item_func_itembitset(float a, float b)
1293 {
1294         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1295 }
1296
1297 float target_item_func_itemand(float a, float b)
1298 {
1299         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1300 }
1301
1302 float target_item_func_or(float a, float b)
1303 {
1304         return a | b;
1305 }
1306
1307 float target_item_func_andnot(float a, float b)
1308 {
1309         return a - (a & b);
1310 }
1311
1312 float target_item_changed;
1313 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1314 {
1315         float n, d;
1316         n = func(activator.field, self.field);
1317
1318         if(binary)
1319         {
1320                 d = n & activator.field;
1321                 if(d != n) // bits added?
1322                         d = +1;
1323                 else if(d != activator.field) // bits removed?
1324                         d = -1;
1325                 else
1326                         d = 0;
1327         }
1328         else
1329                 d = n - activator.field;
1330
1331         if(d < 0)
1332         {
1333                 if(sound_decrease != "")
1334                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1335                 target_item_changed = 1;
1336         }
1337         else if(d > 0)
1338         {
1339                 if(sound_increase != "")
1340                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1341                 target_item_changed = 1;
1342         }
1343         activator.field = n;
1344 }
1345
1346 void target_items_use (void)
1347 {
1348         float h0, a0, f0;
1349
1350         if(activator.classname == "droppedweapon")
1351         {
1352                 EXACTTRIGGER_TOUCH;
1353                 remove(activator);
1354                 return;
1355         }
1356
1357         if(activator.classname != "player")
1358                 return;
1359         if(activator.deadflag != DEAD_NO)
1360                 return;
1361         EXACTTRIGGER_TOUCH;
1362
1363         entity e;
1364         for(e = world; (e = find(e, classname, "droppedweapon")); )
1365                 if(e.enemy == activator)
1366                         remove(e);
1367
1368         float _switchweapon;
1369         _switchweapon = FALSE;
1370         if (activator.autoswitch)
1371                 if (activator.switchweapon == w_getbestweapon(activator))
1372                         _switchweapon = TRUE;
1373
1374         a0 = activator.armorvalue;
1375         h0 = activator.health;
1376         f0 = activator.ammo_fuel;
1377         target_item_changed = 0;
1378
1379         if(self.spawnflags == 0) // SET
1380         {
1381                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1382                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1383                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1384                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1385                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1386                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1387                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1388                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1389                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1390
1391                 if((self.items & activator.items) & IT_STRENGTH)
1392                         activator.strength_finished = time + self.strength_finished;
1393                 if((self.items & activator.items) & IT_INVINCIBLE)
1394                         activator.invincible_finished = time + self.invincible_finished;
1395         }
1396         else if(self.spawnflags == 1) // AND/MIN
1397         {
1398                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1399                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1400                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1401                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1402                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1403                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1404                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1405                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1406                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1407
1408                 if((self.items & activator.items) & IT_STRENGTH)
1409                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1410                 if((self.items & activator.items) & IT_INVINCIBLE)
1411                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1412         }
1413         else if(self.spawnflags == 2) // OR/MAX
1414         {
1415                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1416                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1417                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1418                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1419                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1420                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1421                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1422                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1423                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1424
1425                 if((self.items & activator.items) & IT_STRENGTH)
1426                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1427                 if((self.items & activator.items) & IT_INVINCIBLE)
1428                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1429         }
1430         else if(self.spawnflags == 4) // ANDNOT/MIN
1431         {
1432                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1433                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1434                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1435                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1436                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1437                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1438                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1439                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1440                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1441
1442                 if((self.items & activator.items) & IT_STRENGTH)
1443                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1444                 if((self.items & activator.items) & IT_INVINCIBLE)
1445                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1446         }
1447
1448         if not(activator.items & IT_STRENGTH)
1449                 activator.strength_finished = 0;
1450         if not(activator.items & IT_INVINCIBLE)
1451                 activator.invincible_finished = 0;
1452
1453         if(activator.health > h0)
1454                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1455         else if(activator.health < h0)
1456                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1457
1458         if(activator.ammo_fuel > f0)
1459                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1460         else if(activator.ammo_fuel < f0)
1461                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1462
1463         if(activator.armorvalue > a0)
1464                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1465
1466         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1467                 _switchweapon = TRUE;
1468         if(_switchweapon)
1469                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1470
1471         if(target_item_changed)
1472                 centerprint(activator, self.message);
1473 }
1474
1475 void spawnfunc_target_items (void)
1476 {
1477         float n, i, j;
1478         entity e;
1479
1480         if(g_nixnex)
1481         {
1482                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1483                 remove(self);
1484                 return;
1485         }
1486
1487         self.use = target_items_use;
1488         if(!self.strength_finished)
1489                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1490         if(!self.invincible_finished)
1491                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1492
1493         precache_sound("misc/itempickup.wav");
1494         precache_sound("misc/itempickup.wav");
1495         precache_sound("misc/itempickup.wav");
1496         precache_sound("misc/itempickup.wav");
1497         precache_sound("misc/megahealth.wav");
1498         precache_sound("misc/armor25.wav");
1499         precache_sound("misc/powerup.wav");
1500         precache_sound("misc/poweroff.wav");
1501         precache_sound("weapons/weaponpickup.wav");
1502
1503         n = tokenize_console(self.netname);
1504         for(i = 0; i < n; ++i)
1505         {
1506                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1507                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1508                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1509                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1510                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1511                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1512                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1513                 else
1514                 {
1515                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1516                         {
1517                                 e = get_weaponinfo(j);
1518                                 if(argv(i) == e.netname)
1519                                 {
1520                                         self.weapons |= e.weapons;
1521                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1522                                                 weapon_action(e.weapon, WR_PRECACHE);
1523                                         break;
1524                                 }
1525                         }
1526                         if(j > WEP_LAST)
1527                                 print("target_items: invalid item ", argv(i), "\n");
1528                 }
1529         }
1530 }
1531
1532 void spawnfunc_item_fuel(void)
1533 {
1534         if(!self.ammo_fuel)
1535                 self.ammo_fuel = g_pickup_fuel;
1536         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1537 }
1538
1539 void spawnfunc_item_fuel_regen(void)
1540 {
1541         if(start_items & IT_FUEL_REGEN)
1542         {
1543                 spawnfunc_item_fuel();
1544                 return;
1545         }
1546         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1547 }
1548
1549 void spawnfunc_item_jetpack(void)
1550 {
1551         if(g_grappling_hook)
1552                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1553         if(!self.ammo_fuel)
1554                 self.ammo_fuel = g_pickup_fuel_jetpack;
1555         if(start_items & IT_JETPACK)
1556         {
1557                 spawnfunc_item_fuel();
1558                 return;
1559         }
1560         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1561 }
1562
1563 // we no longer have the seeker
1564 void spawnfunc_weapon_seeker()
1565 {
1566         spawnfunc_weapon_rocketlauncher();
1567 }