data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 float Item_Customize()
  45 {
  46         if(self.spawnshieldtime)
  47                 return TRUE;
  48         if(self.weapons != (self.weapons & other.weapons))
  49         {
  50                 self.colormod = '0 0 0';
  51                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
  52                         self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(cvar_string("g_ghost_items_color"));
  61                         if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
  62                                 self.glowmod = self.colormod;
  63                         self.alpha = g_ghost_items;
  64                         return TRUE;
  65                 }
  66                 else
  67                         return FALSE;
  68         }
  69 }
  70
  71 void Item_Show (entity e, float mode)
  72 {
  73         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  74         if (mode > 0)
  75         {
  76                 // make the item look normal, and be touchable
  77                 e.model = e.mdl;
  78                 e.solid = SOLID_TRIGGER;
  79                 e.colormod = '0 0 0';
  80                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
  81                         self.glowmod = self.colormod;
  82                 e.alpha = 0;
  83                 e.customizeentityforclient = func_null;
  84
  85                 e.spawnshieldtime = 1;
  86         }
  87         else if (mode < 0)
  88         {
  89                 // hide the item completely
  90                 e.model = string_null;
  91                 e.solid = SOLID_NOT;
  92                 e.colormod = '0 0 0';
  93                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
  94                         self.glowmod = self.colormod;
  95                 e.alpha = 0;
  96                 e.customizeentityforclient = func_null;
  97
  98                 e.spawnshieldtime = 1;
  99         }
 100         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
 101         {
 102                 // make the item translucent green and not touchable
 103                 e.model = e.mdl;
 104                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 105                 e.colormod = '0 0 0';
 106                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
 107                         self.glowmod = self.colormod;
 108                 e.effects |= EF_STARDUST;
 109                 e.customizeentityforclient = Item_Customize;
 110
 111                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 112         }
 113         else if(g_ghost_items)
 114         {
 115                 // make the item translucent green and not touchable
 116                 e.model = e.mdl;
 117                 e.solid = SOLID_NOT;
 118                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 119                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
 120                         self.glowmod = self.colormod;
 121                 e.alpha = g_ghost_items;
 122                 e.customizeentityforclient = func_null;
 123
 124                 e.spawnshieldtime = 1;
 125         }
 126         else
 127         {
 128                 // hide the item completely
 129                 e.model = string_null;
 130                 e.solid = SOLID_NOT;
 131                 e.colormod = stov(cvar_string("g_ghost_items_color"));
 132                 if(cvar("gameversion") >= 20600) // only do this for 2.6 and above FIXME remove this check when making 2.6
 133                         self.glowmod = self.colormod;
 134                 e.alpha = 0;
 135                 e.customizeentityforclient = func_null;
 136
 137                 e.spawnshieldtime = 1;
 138         }
 139
 140         if (e.strength_finished || e.invincible_finished)
 141                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 142         if (cvar("g_nodepthtestitems"))
 143                 e.effects |= EF_NODEPTHTEST;
 144         if (cvar("g_fullbrightitems"))
 145                 e.effects |= EF_FULLBRIGHT;
 146
 147         // relink entity (because solid may have changed)
 148         setorigin(e, e.origin);
 149 }
 150
 151 void Item_Respawn (void)
 152 {
 153         Item_Show(self, 1);
 154         if(!g_minstagib && self.items == IT_STRENGTH)
 155                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 156         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 157                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 158         else
 159                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 160         setorigin (self, self.origin);
 161
 162         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 163         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 164 }
 165
 166 void Item_RespawnCountdown (void)
 167 {
 168         if(self.count >= ITEM_RESPAWN_TICKS)
 169         {
 170                 if(self.waypointsprite_attached)
 171                         WaypointSprite_Kill(self.waypointsprite_attached);
 172                 Item_Respawn();
 173         }
 174         else
 175         {
 176                 self.nextthink = time + 1;
 177                 self.count += 1;
 178                 if(self.count == 1)
 179                 {
 180                         string name;
 181                         vector rgb;
 182                         name = string_null;
 183                         if(g_minstagib)
 184                         {
 185                                 switch(self.items)
 186                                 {
 187                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 188                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 189                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 190                                 }
 191                         }
 192                         else
 193                         {
 194                                 switch(self.items)
 195                                 {
 196                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 197                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 198                                 }
 199                         }
 200                         switch(self.items)
 201                         {
 202                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 203                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 204                         }
 205                         if(name)
 206                         {
 207                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 208                                 if(self.waypointsprite_attached)
 209                                 {
 210                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 211                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 212                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 213                                 }
 214                         }
 215                 }
 216                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 217                 if(self.waypointsprite_attached)
 218                 {
 219                         WaypointSprite_Ping(self.waypointsprite_attached);
 220                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 221                 }
 222         }
 223 }
 224
 225 void Item_ScheduleRespawnIn(entity e, float t)
 226 {
 227         if(e.flags & FL_POWERUP)
 228         {
 229                 e.think = Item_RespawnCountdown;
 230                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 231                 e.count = 0;
 232         }
 233         else
 234         {
 235                 e.think = Item_Respawn;
 236                 e.nextthink = time + t;
 237         }
 238 }
 239
 240 void Item_ScheduleRespawn(entity e)
 241 {
 242         Item_Show(e, 0);
 243         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 244 }
 245
 246 void Item_ScheduleInitialRespawn(entity e)
 247 {
 248         Item_Show(e, 0);
 249         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 250 }
 251
 252 float Item_GiveTo(entity item, entity player)
 253 {
 254         float _switchweapon;
 255         float pickedup;
 256         float it;
 257         float i;
 258         entity e;
 259
 260         // if nothing happens to player, just return without taking the item
 261         pickedup = FALSE;
 262         _switchweapon = FALSE;
 263
 264         if (g_minstagib)
 265         {
 266                 if(item.spawnshieldtime)
 267                 {
 268                         if (item.ammo_fuel)
 269                         if (player.ammo_fuel < g_pickup_fuel_max)
 270                         {
 271                                 pickedup = TRUE;
 272                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 273                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 274                         }
 275                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 276                         {
 277                                 pickedup = TRUE;
 278                                 player.items |= it;
 279                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 280                         }
 281
 282                         _switchweapon = TRUE;
 283                         if (item.ammo_cells)
 284                         {
 285                                 pickedup = TRUE;
 286                                 // play some cool sounds ;)
 287                                 centerprint(player, "\n");
 288                                 if (clienttype(player) == CLIENTTYPE_REAL)
 289                                 {
 290                                         if(player.health <= 5)
 291                                                 AnnounceTo(player, "lastsecond");
 292                                         else if(player.health < 50)
 293                                                 AnnounceTo(player, "narrowly");
 294                                 }
 295                                 // sound not available
 296                                 // else if(item.items == IT_CELLS)
 297                                 //      AnnounceTo(player, "ammo");
 298
 299                                 if (item.weapons & WEPBIT_MINSTANEX)
 300                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 301                                 if (item.ammo_cells)
 302                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 303                                 player.health = 100;
 304                         }
 305
 306                         // extralife powerup
 307                         if (item.max_health)
 308                         {
 309                                 pickedup = TRUE;
 310                                 // sound not available
 311                                 // AnnounceTo(player, "_lives");
 312                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 313                                 sprint(player, "^3You picked up some extra lives\n");
 314                         }
 315
 316                         // invis powerup
 317                         if (item.strength_finished)
 318                         {
 319                                 pickedup = TRUE;
 320                                 // sound not available
 321                                 // AnnounceTo(player, "invisible");
 322                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 323                         }
 324
 325                         // speed powerup
 326                         if (item.invincible_finished)
 327                         {
 328                                 pickedup = TRUE;
 329                                 // sound not available
 330                                 // AnnounceTo(player, "speed");
 331                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 332                         }
 333
 334                         if (item.ammo_fuel)
 335                         if (player.ammo_fuel < g_pickup_fuel_max)
 336                         {
 337                                 pickedup = TRUE;
 338                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 339                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 340                         }
 341                 }
 342         }
 343         else
 344         {
 345                 if (g_weapon_stay == 1)
 346                 if not(item.flags & FL_NO_WEAPON_STAY)
 347                 if (item.flags & FL_WEAPON)
 348                 {
 349                         if(item.classname == "droppedweapon")
 350                         {
 351                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 352                                         goto skip;
 353                         }
 354                         else
 355                         {
 356                                 if (player.weapons & item.weapons)
 357                                         goto skip;
 358                         }
 359                 }
 360
 361                 // in case the player has autoswitch enabled do the following:
 362                 // if the player is using their best weapon before items are given, they
 363                 // probably want to switch to an even better weapon after items are given
 364                 if (player.autoswitch)
 365                 if (player.switchweapon == w_getbestweapon(player))
 366                         _switchweapon = TRUE;
 367
 368                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 369                         _switchweapon = TRUE;
 370
 371                 if(item.spawnshieldtime)
 372                 {
 373                         if (item.ammo_shells)
 374                         if (player.ammo_shells < g_pickup_shells_max)
 375                         {
 376                                 pickedup = TRUE;
 377                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 378                         }
 379                         if (item.ammo_nails)
 380                         if (player.ammo_nails < g_pickup_nails_max)
 381                         {
 382                                 pickedup = TRUE;
 383                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 384                         }
 385                         if (item.ammo_rockets)
 386                         if (player.ammo_rockets < g_pickup_rockets_max)
 387                         {
 388                                 pickedup = TRUE;
 389                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 390                         }
 391                         if (item.ammo_cells)
 392                         if (player.ammo_cells < g_pickup_cells_max)
 393                         {
 394                                 pickedup = TRUE;
 395                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 396                         }
 397                         if (item.ammo_fuel)
 398                         if (player.ammo_fuel < g_pickup_fuel_max)
 399                         {
 400                                 pickedup = TRUE;
 401                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 402                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 403                         }
 404                 }
 405
 406                 if (item.flags & FL_WEAPON)
 407                 if ((it = item.weapons - (item.weapons & player.weapons)))
 408                 {
 409                         pickedup = TRUE;
 410                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 411                         {
 412                                 e = get_weaponinfo(i);
 413                                 if(it & e.weapons)
 414                                         W_GiveWeapon (player, e.weapon, item.netname);
 415                         }
 416                 }
 417
 418                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 419                 {
 420                         pickedup = TRUE;
 421                         player.items |= it;
 422                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 423                 }
 424
 425                 if(item.spawnshieldtime)
 426                 {
 427                         if (item.strength_finished)
 428                         {
 429                                 pickedup = TRUE;
 430                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 431                         }
 432                         if (item.invincible_finished)
 433                         {
 434                                 pickedup = TRUE;
 435                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 436                         }
 437
 438                         if (item.health)
 439                         if (player.health < item.max_health)
 440                         {
 441                                 pickedup = TRUE;
 442                                 player.health = min(player.health + item.health, item.max_health);
 443                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 444                         }
 445                         if (item.armorvalue)
 446                         if (player.armorvalue < item.max_armorvalue)
 447                         {
 448                                 pickedup = TRUE;
 449                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 450                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 451                         }
 452                 }
 453         }
 454
 455 :skip
 456         // always eat teamed entities
 457         if(item.team)
 458                 pickedup = TRUE;
 459
 460         if (!pickedup)
 461                 return 0;
 462
 463         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 464         if (_switchweapon)
 465                 if (player.switchweapon != w_getbestweapon(player))
 466                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 467
 468         return 1;
 469 }
 470
 471 void Item_Touch (void)
 472 {
 473         entity e, head;
 474
 475         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 476         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 477         {
 478                 remove(self);
 479                 return;
 480         }
 481         if (other.classname != "player")
 482                 return;
 483         if (other.deadflag)
 484                 return;
 485         if (self.solid != SOLID_TRIGGER)
 486                 return;
 487         if (self.owner == other)
 488                 return;
 489
 490         if(!Item_GiveTo(self, other))
 491                 return;
 492
 493         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 494
 495         if (self.classname == "droppedweapon")
 496                 remove (self);
 497         else if not(self.spawnshieldtime)
 498                 return;
 499         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 500                 return;
 501         else
 502         {
 503                 if(self.team)
 504                 {
 505                         RandomSelection_Init();
 506                         for(head = world; (head = findfloat(head, team, self.team)); )
 507                         {
 508                                 if(head.flags & FL_ITEM)
 509                                 {
 510                                         Item_Show(head, -1);
 511                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 512                                 }
 513                         }
 514                         e = RandomSelection_chosen_ent;
 515                 }
 516                 else
 517                         e = self;
 518                 Item_ScheduleRespawn(e);
 519         }
 520 }
 521
 522 void Item_FindTeam()
 523 {
 524         entity head, e;
 525
 526         if(self.effects & EF_NODRAW)
 527         {
 528                 // marker for item team search
 529                 dprint("Initializing item team ", ftos(self.team), "\n");
 530                 RandomSelection_Init();
 531                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 532                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 533                 e = RandomSelection_chosen_ent;
 534                 e.state = 0;
 535                 Item_Show(e, 1);
 536
 537                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 538                 {
 539                         if(head != e)
 540                         {
 541                                 // make it a non-spawned item
 542                                 Item_Show(head, -1);
 543                                 head.state = 1; // state 1 = initially hidden item
 544                         }
 545                         head.effects &~= EF_NODRAW;
 546                 }
 547
 548                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 549                         Item_ScheduleInitialRespawn(e);
 550         }
 551 }
 552
 553 void Item_Reset()
 554 {
 555         Item_Show(self, !self.state);
 556         setorigin (self, self.origin);
 557         self.think = SUB_Null;
 558         self.nextthink = 0;
 559
 560         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 561                 Item_ScheduleInitialRespawn(self);
 562 }
 563
 564 // Savage: used for item garbage-collection
 565 // TODO: perhaps nice special effect?
 566 void RemoveItem(void)
 567 {
 568         remove(self);
 569 }
 570
 571 // pickup evaluation functions
 572 // these functions decide how desirable an item is to the bots
 573
 574 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 575
 576 float weapon_pickupevalfunc(entity player, entity item)
 577 {
 578         float c, i, j, position;
 579
 580         // See if I have it already
 581         if(player.weapons & item.weapons == item.weapons)
 582         {
 583                 // If I can pick it up
 584                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 585                         c = 0;
 586                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 587                 {
 588                         // Skilled bots will grab more
 589                         c = bound(0, skill / 10, 1) * 0.5;
 590                 }
 591                 else
 592                         c = 0;
 593         }
 594         else
 595                 c = 1;
 596
 597         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 598         if( bot_custom_weapon && c )
 599         {
 600                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 601                 {
 602                         // Find weapon
 603                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 604                                 continue;
 605
 606                         // Find the highest position on any range
 607                         position = -1;
 608                         for(j = 0; j < WEP_LAST ; ++j){
 609                                 if(
 610                                                 bot_weapons_far[j] == i ||
 611                                                 bot_weapons_mid[j] == i ||
 612                                                 bot_weapons_close[j] == i
 613                                   )
 614                                 {
 615                                         position = j;
 616                                         break;
 617                                 }
 618                         }
 619
 620                         // Rate it
 621                         if (position >= 0 )
 622                         {
 623                                 position = WEP_LAST - position;
 624                                 // item.bot_pickupbasevalue is overwritten here
 625                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 626                         }
 627                 }
 628         }
 629
 630         return item.bot_pickupbasevalue * c;
 631 };
 632
 633 float commodity_pickupevalfunc(entity player, entity item)
 634 {
 635         float c, i, need_shells, need_nails, need_rockets, need_cells;
 636         entity wi;
 637         c = 0;
 638
 639         // Detect needed ammo
 640         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 641         {
 642                 wi = get_weaponinfo(i);
 643
 644                 if not(wi.weapons & player.weapons)
 645                         continue;
 646
 647                 if(wi.items & IT_SHELLS)
 648                         need_shells = TRUE;
 649                 else if(wi.items & IT_NAILS)
 650                         need_nails = TRUE;
 651                 else if(wi.items & IT_ROCKETS)
 652                         need_rockets = TRUE;
 653                 else if(wi.items & IT_CELLS)
 654                         need_cells = TRUE;
 655         }
 656
 657         // TODO: figure out if the player even has the weapon this ammo is for?
 658         // may not affect strategy much though...
 659         // find out how much more ammo/armor/health the player can hold
 660         if (need_shells)
 661         if (item.ammo_shells)
 662         if (player.ammo_shells < g_pickup_shells_max)
 663                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 664         if (need_nails)
 665         if (item.ammo_nails)
 666         if (player.ammo_nails < g_pickup_nails_max)
 667                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 668         if (need_rockets)
 669         if (item.ammo_rockets)
 670         if (player.ammo_rockets < g_pickup_rockets_max)
 671                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 672         if (need_cells)
 673         if (item.ammo_cells)
 674         if (player.ammo_cells < g_pickup_cells_max)
 675                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 676         if (item.armorvalue)
 677         if (player.armorvalue < item.max_armorvalue)
 678                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 679         if (item.health)
 680         if (player.health < item.max_health)
 681                 c = c + max(0, 1 - player.health / item.max_health);
 682
 683         return item.bot_pickupbasevalue * c;
 684 };
 685
 686
 687 .float is_item;
 688 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 689 {
 690         startitem_failed = FALSE;
 691
 692         // is it a dropped weapon?
 693         if (self.classname == "droppedweapon")
 694         {
 695                 self.reset = SUB_Remove;
 696                 // it's a dropped weapon
 697                 self.movetype = MOVETYPE_TOSS;
 698                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 699                 self.think = RemoveItem;
 700                 self.nextthink = time + 60;
 701                 // don't drop if in a NODROP zone (such as lava)
 702                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 703                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 704                 {
 705                         startitem_failed = TRUE;
 706                         remove(self);
 707                         return;
 708                 }
 709         }
 710         else
 711         {
 712                 self.reset = Item_Reset;
 713                 // it's a level item
 714                 if(self.spawnflags & 1)
 715                         self.noalign = 1;
 716                 if (self.noalign)
 717                         self.movetype = MOVETYPE_NONE;
 718                 else
 719                         self.movetype = MOVETYPE_TOSS;
 720                 // do item filtering according to game mode and other things
 721                 if (!self.noalign)
 722                 {
 723                         // first nudge it off the floor a little bit to avoid math errors
 724                         setorigin(self, self.origin + '0 0 1');
 725                         // set item size before we spawn a spawnfunc_waypoint
 726                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 727                                 setsize (self, '-16 -16 0', '16 16 48');
 728                         else
 729                                 setsize (self, '-16 -16 0', '16 16 32');
 730                         // note droptofloor returns FALSE if stuck/or would fall too far
 731                         droptofloor();
 732                         waypoint_spawnforitem(self);
 733                 }
 734
 735                 if(teams_matter)
 736                 {
 737                         if(self.notteam)
 738                         {
 739                                 print("removed non-teamplay ", self.classname, "\n");
 740                                 startitem_failed = TRUE;
 741                                 remove (self);
 742                                 return;
 743                         }
 744                 }
 745                 else
 746                 {
 747                         if(self.notfree)
 748                         {
 749                                 print("removed non-FFA ", self.classname, "\n");
 750                                 startitem_failed = TRUE;
 751                                 remove (self);
 752                                 return;
 753                         }
 754                 }
 755
 756                 if(self.notq3a)
 757                 {
 758                         // We aren't TA or something like that, so we keep the Q3A entities
 759                         print("removed non-Q3A ", self.classname, "\n");
 760                         startitem_failed = TRUE;
 761                         remove (self);
 762                         return;
 763                 }
 764
 765                 /*
 766                  * can't do it that way, as it would break maps
 767                  * TODO make a target_give like entity another way, that perhaps has
 768                  * the weapon name in a key
 769                 if(self.targetname)
 770                 {
 771                         // target_give not yet supported; maybe later
 772                         print("removed targeted ", self.classname, "\n");
 773                         startitem_failed = TRUE;
 774                         remove (self);
 775                         return;
 776                 }
 777                 */
 778
 779                 if(cvar("spawn_debug") >= 2)
 780                 {
 781                         entity otheritem;
 782                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 783                         {
 784                                 if(otheritem.is_item)
 785                                 {
 786                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 787                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 788                                         error("Mapper sucks.");
 789                                 }
 790                         }
 791                         self.is_item = TRUE;
 792                 }
 793
 794                 weaponsInMap |= weaponid;
 795
 796                 if(g_lms || g_ca)
 797                 {
 798                         startitem_failed = TRUE;
 799                         remove(self);
 800                         return;
 801                 }
 802                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 803                 {
 804                         startitem_failed = TRUE;
 805                         remove(self);
 806                         return;
 807                 }
 808                 else if (g_minstagib)
 809                 {
 810                         // don't remove dropped items and powerups
 811                         if (self.classname != "minstagib")
 812                         {
 813                                 startitem_failed = TRUE;
 814                                 remove (self);
 815                                 return;
 816                         }
 817                 }
 818                 else if (g_nixnex)
 819                 {
 820                         local float rm;
 821
 822                         rm = 1;
 823                         switch (itemid)
 824                         {
 825                                 case IT_HEALTH:
 826                                 case IT_5HP:
 827                                 case IT_25HP:
 828                                 case IT_ARMOR:
 829                                 case IT_ARMOR_SHARD:
 830                                         if (cvar("g_nixnex_with_healtharmor"))
 831                                                 rm = 0;
 832                                         break;
 833                                 case IT_STRENGTH:
 834                                 case IT_INVINCIBLE:
 835                                         if (cvar("g_nixnex_with_powerups"))
 836                                                 rm = 0;
 837                                         break;
 838                         }
 839
 840                         if(rm)
 841                         {
 842                                 startitem_failed = TRUE;
 843                                 remove (self);
 844                                 return;
 845                         }
 846                 }
 847                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 848                 {
 849                         startitem_failed = TRUE;
 850                         remove (self);
 851                         return;
 852                 }
 853
 854                 precache_model (itemmodel);
 855                 precache_sound (pickupsound);
 856                 precache_sound ("misc/itemrespawn.wav");
 857                 precache_sound ("misc/itemrespawncountdown.wav");
 858
 859                 if(itemid == IT_STRENGTH)
 860                         precache_sound ("misc/strength_respawn.wav");
 861                 if(itemid == IT_INVINCIBLE)
 862                         precache_sound ("misc/shield_respawn.wav");
 863
 864                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 865                         self.target = "###item###"; // for finding the nearest item using find()
 866         }
 867
 868         self.bot_pickup = TRUE;
 869         self.bot_pickupevalfunc = pickupevalfunc;
 870         self.bot_pickupbasevalue = pickupbasevalue;
 871         self.mdl = itemmodel;
 872         self.item_pickupsound = pickupsound;
 873         // let mappers override respawntime
 874         if(!self.respawntime) // both set
 875         {
 876                 self.respawntime = defaultrespawntime;
 877                 self.respawntimejitter = defaultrespawntimejitter;
 878         }
 879         self.netname = itemname;
 880         self.items = itemid;
 881         self.weapons = weaponid;
 882         self.flags = FL_ITEM | itemflags;
 883         self.touch = Item_Touch;
 884         setmodel (self, self.mdl); // precision set below
 885         self.effects |= EF_LOWPRECISION;
 886         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 887                 setsize (self, '-16 -16 0', '16 16 48');
 888         else
 889                 setsize (self, '-16 -16 0', '16 16 32');
 890         if(itemflags & FL_WEAPON)
 891                 self.modelflags |= MF_ROTATE;
 892
 893         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 894         if (itemflags & FL_WEAPON)
 895         {
 896                 // neutral team color for pickup weapons
 897                 self.colormap = 1024; // color shirt=0 pants=0 grey
 898         }
 899
 900         Item_Show(self, 1);
 901         self.state = 0;
 902         if(self.team)
 903         {
 904                 if(!self.cnt)
 905                         self.cnt = 1; // item probability weight
 906                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 907                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 908         }
 909         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 910                 Item_ScheduleInitialRespawn(self);
 911 }
 912
 913 /* replace items in minstagib
 914  * IT_STRENGTH   = invisibility
 915  * IT_NAILS      = extra lives
 916  * IT_INVINCIBLE = speed
 917  */
 918 void minstagib_items (float itemid)
 919 {
 920         // we don't want to replace dropped weapons ;)
 921         if (self.classname == "droppedweapon")
 922         {
 923                 self.ammo_cells = 25;
 924                 StartItem ("models/weapons/g_nex.md3",
 925                         "weapons/weaponpickup.wav", 15, 0,
 926                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 927                 return;
 928         }
 929
 930         local float rnd;
 931         self.classname = "minstagib";
 932
 933         // replace rocket launchers and nex guns with ammo cells
 934         if (itemid == IT_CELLS)
 935         {
 936                 self.ammo_cells = 1;
 937                 StartItem ("models/items/a_cells.md3",
 938                         "misc/itempickup.wav", 45, 0,
 939                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 940                 return;
 941         }
 942
 943         // randomize
 944         rnd = random() * 3;
 945         if (rnd <= 1)
 946                 itemid = IT_STRENGTH;
 947         else if (rnd <= 2)
 948                 itemid = IT_NAILS;
 949         else
 950                 itemid = IT_INVINCIBLE;
 951
 952         // replace with invis
 953         if (itemid == IT_STRENGTH)
 954         {
 955                 self.strength_finished = 30;
 956                 StartItem ("models/items/g_strength.md3",
 957                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 958                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 959         }
 960         // replace with extra lives
 961         if (itemid == IT_NAILS)
 962         {
 963                 self.max_health = 1;
 964                 StartItem ("models/items/g_h100.md3",
 965                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 966                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 967
 968         }
 969         // replace with speed
 970         if (itemid == IT_INVINCIBLE)
 971         {
 972                 self.invincible_finished = 30;
 973                 StartItem ("models/items/g_invincible.md3",
 974                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 975                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 976         }
 977
 978 }
 979
 980 float minst_no_auto_cells;
 981 void minst_remove_item (void) {
 982         if(minst_no_auto_cells)
 983                 remove(self);
 984 }
 985
 986 float weaponswapping;
 987 float internalteam;
 988
 989 void weapon_defaultspawnfunc(float wpn)
 990 {
 991         entity e;
 992         float t;
 993         var .float ammofield;
 994         string s;
 995         entity oldself;
 996         float i, j;
 997
 998         // set the respawntime in advance (so replaced weapons can copy it)
 999
1000         if(!self.respawntime)
1001         {
1002                 e = get_weaponinfo(wpn);
1003                 if(e.items == IT_SUPERWEAPON)
1004                 {
1005                         self.respawntime = g_pickup_respawntime_powerup;
1006                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
1007                 }
1008                 else
1009                 {
1010                         self.respawntime = g_pickup_respawntime_weapon;
1011                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1012                 }
1013         }
1014
1015         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1016         {
1017                 e = get_weaponinfo(wpn);
1018                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1019                 if(s == "0")
1020                 {
1021                         remove(self);
1022                         startitem_failed = TRUE;
1023                         return;
1024                 }
1025                 t = tokenize_console(s);
1026                 if(t >= 2)
1027                 {
1028                         self.team = --internalteam;
1029                         oldself = self;
1030                         for(i = 1; i < t; ++i)
1031                         {
1032                                 s = argv(i);
1033                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1034                                 {
1035                                         e = get_weaponinfo(j);
1036                                         if(e.netname == s)
1037                                         {
1038                                                 self = spawn();
1039                                                 copyentity(oldself, self);
1040                                                 self.classname = "replacedweapon";
1041                                                 weapon_defaultspawnfunc(j);
1042                                                 break;
1043                                         }
1044                                 }
1045                                 if(j > WEP_LAST)
1046                                 {
1047                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1048                                 }
1049                         }
1050                         self = oldself;
1051                 }
1052                 if(t >= 1)
1053                 {
1054                         s = argv(0);
1055                         wpn = 0;
1056                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1057                         {
1058                                 e = get_weaponinfo(j);
1059                                 if(e.netname == s)
1060                                 {
1061                                         wpn = j;
1062                                         break;
1063                                 }
1064                         }
1065                         if(j > WEP_LAST)
1066                         {
1067                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1068                         }
1069                 }
1070                 if(wpn == 0)
1071                 {
1072                         remove(self);
1073                         startitem_failed = TRUE;
1074                         return;
1075                 }
1076         }
1077
1078         e = get_weaponinfo(wpn);
1079
1080         if(e.items && e.items != IT_SUPERWEAPON)
1081         {
1082                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1083                 {
1084                         if(e.items & j)
1085                         {
1086                                 ammofield = Item_CounterField(j);
1087                                 if(!self.ammofield)
1088                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1089                         }
1090                 }
1091         }
1092         else
1093         {
1094                 self.flags |= FL_NO_WEAPON_STAY;
1095         }
1096
1097         // weapon stay isn't supported for teamed weapons
1098         if(self.team)
1099                 self.flags |= FL_NO_WEAPON_STAY;
1100
1101         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1102         {
1103                 self.ammo_shells = 0;
1104                 self.ammo_nails = 0;
1105                 self.ammo_cells = 0;
1106                 self.ammo_rockets = 0;
1107                 // weapon stay 2: don't use ammo on weapon pickups; instead
1108                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1109         }
1110
1111         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1112         if (self.modelindex) // don't precache if self was removed
1113                 weapon_action(e.weapon, WR_PRECACHE);
1114 }
1115
1116 void spawnfunc_weapon_shotgun (void);
1117 void spawnfunc_weapon_uzi (void) {
1118         if(q3acompat_machineshotgunswap)
1119         if(self.classname != "droppedweapon")
1120         {
1121                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1122                 return;
1123         }
1124         weapon_defaultspawnfunc(WEP_UZI);
1125 }
1126
1127 void spawnfunc_weapon_shotgun (void) {
1128         if(q3acompat_machineshotgunswap)
1129         if(self.classname != "droppedweapon")
1130         {
1131                 weapon_defaultspawnfunc(WEP_UZI);
1132                 return;
1133         }
1134         weapon_defaultspawnfunc(WEP_SHOTGUN);
1135 }
1136
1137 void spawnfunc_weapon_nex (void)
1138 {
1139         if (g_minstagib)
1140         {
1141                 minstagib_items(IT_CELLS);
1142                 self.think = minst_remove_item;
1143                 self.nextthink = time;
1144                 return;
1145         }
1146         weapon_defaultspawnfunc(WEP_NEX);
1147 }
1148
1149 void spawnfunc_weapon_minstanex (void)
1150 {
1151         if (g_minstagib)
1152         {
1153                 minstagib_items(IT_CELLS);
1154                 self.think = minst_remove_item;
1155                 self.nextthink = time;
1156                 return;
1157         }
1158         weapon_defaultspawnfunc(WEP_MINSTANEX);
1159 }
1160
1161 void spawnfunc_weapon_rocketlauncher (void)
1162 {
1163         if (g_minstagib)
1164         {
1165                 minstagib_items(IT_CELLS);
1166                 self.think = minst_remove_item;
1167                 self.nextthink = time;
1168                 return;
1169         }
1170         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1171 }
1172
1173 void spawnfunc_item_rockets (void) {
1174         if(!self.ammo_rockets)
1175                 self.ammo_rockets = g_pickup_rockets;
1176         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1177 }
1178
1179 void spawnfunc_item_shells (void);
1180 void spawnfunc_item_bullets (void) {
1181         if(!weaponswapping)
1182         if(q3acompat_machineshotgunswap)
1183         if(self.classname != "droppedweapon")
1184         {
1185                 weaponswapping = TRUE;
1186                 spawnfunc_item_shells();
1187                 weaponswapping = FALSE;
1188                 return;
1189         }
1190
1191         if(!self.ammo_nails)
1192                 self.ammo_nails = g_pickup_nails;
1193         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1194 }
1195
1196 void spawnfunc_item_cells (void) {
1197         if(!self.ammo_cells)
1198                 self.ammo_cells = g_pickup_cells;
1199         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1200 }
1201
1202 void spawnfunc_item_shells (void) {
1203         if(!weaponswapping)
1204         if(q3acompat_machineshotgunswap)
1205         if(self.classname != "droppedweapon")
1206         {
1207                 weaponswapping = TRUE;
1208                 spawnfunc_item_bullets();
1209                 weaponswapping = FALSE;
1210                 return;
1211         }
1212
1213         if(!self.ammo_shells)
1214                 self.ammo_shells = g_pickup_shells;
1215         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1216 }
1217
1218 void spawnfunc_item_armor_small (void) {
1219         if(!self.armorvalue)
1220                 self.armorvalue = g_pickup_armorsmall;
1221         if(!self.max_armorvalue)
1222                 self.max_armorvalue = g_pickup_armorsmall_max;
1223         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1224 }
1225
1226 void spawnfunc_item_armor_medium (void) {
1227         if(!self.armorvalue)
1228                 self.armorvalue = g_pickup_armormedium;
1229         if(!self.max_armorvalue)
1230                 self.max_armorvalue = g_pickup_armormedium_max;
1231         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1232 }
1233
1234 void spawnfunc_item_armor_big (void) {
1235         if(!self.armorvalue)
1236                 self.armorvalue = g_pickup_armorbig;
1237         if(!self.max_armorvalue)
1238                 self.max_armorvalue = g_pickup_armorbig_max;
1239         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1240 }
1241
1242 void spawnfunc_item_armor_large (void) {
1243         if(!self.armorvalue)
1244                 self.armorvalue = g_pickup_armorlarge;
1245         if(!self.max_armorvalue)
1246                 self.max_armorvalue = g_pickup_armorlarge_max;
1247         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1248 }
1249
1250 void spawnfunc_item_health_small (void) {
1251         if(!self.max_health)
1252                 self.max_health = g_pickup_healthsmall_max;
1253         if(!self.health)
1254                 self.health = g_pickup_healthsmall;
1255         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1256 }
1257
1258 void spawnfunc_item_health_medium (void) {
1259         if(!self.max_health)
1260                 self.max_health = g_pickup_healthmedium_max;
1261         if(!self.health)
1262                 self.health = g_pickup_healthmedium;
1263         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1264 }
1265
1266 void spawnfunc_item_health_large (void) {
1267         if(!self.max_health)
1268                 self.max_health = g_pickup_healthlarge_max;
1269         if(!self.health)
1270                 self.health = g_pickup_healthlarge;
1271         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1272 }
1273
1274 void spawnfunc_item_health_mega (void) {
1275         if(!cvar("g_powerup_superhealth"))
1276                 return;
1277
1278         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1279                 return;
1280
1281         if(g_minstagib) {
1282                 minstagib_items(IT_NAILS);
1283         } else {
1284                 if(!self.max_health)
1285                         self.max_health = g_pickup_healthmega_max;
1286                 if(!self.health)
1287                         self.health = g_pickup_healthmega;
1288                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1289         }
1290 }
1291
1292 // support old misnamed entities
1293 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1294 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1295 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1296 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1297 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1298
1299 void spawnfunc_item_strength (void) {
1300         if(!cvar("g_powerup_strength"))
1301                 return;
1302
1303         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1304                 return;
1305
1306         if(g_minstagib) {
1307                 minstagib_items(IT_STRENGTH);
1308         } else {
1309                 precache_sound("weapons/strength_fire.wav");
1310                 self.strength_finished = 30;
1311                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1312         }
1313 }
1314
1315 void spawnfunc_item_invincible (void) {
1316         if(!cvar("g_powerup_shield"))
1317                 return;
1318
1319         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1320                 return;
1321
1322         if(g_minstagib) {
1323                 minstagib_items(IT_INVINCIBLE);
1324         } else {
1325                 self.invincible_finished = 30;
1326                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1327         }
1328 }
1329
1330 void spawnfunc_item_minst_cells (void) {
1331         if (g_minstagib)
1332         {
1333                 minst_no_auto_cells = 1;
1334                 minstagib_items(IT_CELLS);
1335         }
1336         else
1337                 remove(self);
1338 }
1339
1340 // compatibility:
1341 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1342
1343 float GiveItems(entity e, float beginarg, float endarg);
1344 void target_items_use (void)
1345 {
1346         if(activator.classname == "droppedweapon")
1347         {
1348                 EXACTTRIGGER_TOUCH;
1349                 remove(activator);
1350                 return;
1351         }
1352
1353         if(activator.classname != "player")
1354                 return;
1355         if(activator.deadflag != DEAD_NO)
1356                 return;
1357         EXACTTRIGGER_TOUCH;
1358
1359         entity e;
1360         for(e = world; (e = find(e, classname, "droppedweapon")); )
1361                 if(e.enemy == activator)
1362                         remove(e);
1363
1364         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1365                 centerprint(activator, self.message);
1366 }
1367
1368 void spawnfunc_target_items (void)
1369 {
1370         float n, i, j;
1371         entity e;
1372
1373         if(g_nixnex)
1374         {
1375                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1376                 remove(self);
1377                 return;
1378         }
1379
1380         self.use = target_items_use;
1381         if(!self.strength_finished)
1382                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1383         if(!self.invincible_finished)
1384                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1385
1386         precache_sound("misc/itempickup.wav");
1387         precache_sound("misc/itempickup.wav");
1388         precache_sound("misc/itempickup.wav");
1389         precache_sound("misc/itempickup.wav");
1390         precache_sound("misc/megahealth.wav");
1391         precache_sound("misc/armor25.wav");
1392         precache_sound("misc/powerup.wav");
1393         precache_sound("misc/poweroff.wav");
1394         precache_sound("weapons/weaponpickup.wav");
1395
1396         n = tokenize_console(self.netname);
1397         if(argv(0) == "give")
1398         {
1399                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1400         }
1401         else
1402         {
1403                 for(i = 0; i < n; ++i)
1404                 {
1405                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1406                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1407                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1408                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1409                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1410                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1411                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1412                         else
1413                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1414                         {
1415                                 e = get_weaponinfo(j);
1416                                 if(argv(i) == e.netname)
1417                                 {
1418                                         self.weapons |= e.weapons;
1419                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1420                                                 weapon_action(e.weapon, WR_PRECACHE);
1421                                         break;
1422                                 }
1423                         }
1424                         if(j > WEP_LAST)
1425                                 print("target_items: invalid item ", argv(i), "\n");
1426                 }
1427
1428                 string itemprefix, valueprefix;
1429                 if(self.spawnflags == 0)
1430                 {
1431                         itemprefix = "";
1432                         valueprefix = "";
1433                 }
1434                 else if(self.spawnflags == 1)
1435                 {
1436                         itemprefix = "max ";
1437                         valueprefix = "max ";
1438                 }
1439                 else if(self.spawnflags == 2)
1440                 {
1441                         itemprefix = "min ";
1442                         valueprefix = "min ";
1443                 }
1444                 else if(self.spawnflags == 4)
1445                 {
1446                         itemprefix = "minus ";
1447                         valueprefix = "max ";
1448                 }
1449                 else
1450                         error("invalid spawnflags");
1451
1452                 self.netname = "";
1453                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1454                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1455                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1456                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1457                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1458                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1459                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1460                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1461                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1462                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1463                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1464                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1465                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1466                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1467                 {
1468                         e = get_weaponinfo(j);
1469                         if(e.weapons)
1470                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1471                 }
1472         }
1473         self.netname = strzone(self.netname);
1474         //print(self.netname, "\n");
1475
1476         n = tokenize_console(self.netname);
1477         for(i = 0; i < n; ++i)
1478         {
1479                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1480                 {
1481                         e = get_weaponinfo(j);
1482                         if(argv(i) == e.netname)
1483                         {
1484                                 weapon_action(e.weapon, WR_PRECACHE);
1485                                 break;
1486                         }
1487                 }
1488         }
1489 }
1490
1491 void spawnfunc_item_fuel(void)
1492 {
1493         if(!self.ammo_fuel)
1494                 self.ammo_fuel = g_pickup_fuel;
1495         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1496 }
1497
1498 void spawnfunc_item_fuel_regen(void)
1499 {
1500         if(start_items & IT_FUEL_REGEN)
1501         {
1502                 spawnfunc_item_fuel();
1503                 return;
1504         }
1505         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1506 }
1507
1508 void spawnfunc_item_jetpack(void)
1509 {
1510         if(g_grappling_hook)
1511                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1512         if(!self.ammo_fuel)
1513                 self.ammo_fuel = g_pickup_fuel_jetpack;
1514         if(start_items & IT_JETPACK)
1515         {
1516                 spawnfunc_item_fuel();
1517                 return;
1518         }
1519         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1520 }
1521
1522
1523 #define OP_SET 0
1524 #define OP_MIN 1
1525 #define OP_MAX 2
1526 #define OP_PLUS 3
1527 #define OP_MINUS 4
1528
1529 float GiveBit(entity e, .float fld, float bit, float op, float val)
1530 {
1531         float v0, v1;
1532         v0 = (e.fld & bit);
1533         switch(op)
1534         {
1535                 case OP_SET:
1536                         if(val > 0)
1537                                 e.fld |= bit;
1538                         else
1539                                 e.fld &~= bit;
1540                         break;
1541                 case OP_MIN:
1542                 case OP_PLUS:
1543                         if(val > 0)
1544                                 e.fld |= bit;
1545                         break;
1546                 case OP_MAX:
1547                         if(val <= 0)
1548                                 e.fld &~= bit;
1549                         break;
1550                 case OP_MINUS:
1551                         if(val > 0)
1552                                 e.fld &~= bit;
1553                         break;
1554         }
1555         v1 = (e.fld & bit);
1556         return (v0 != v1);
1557 }
1558
1559 float GiveValue(entity e, .float fld, float op, float val)
1560 {
1561         float v0, v1;
1562         v0 = e.fld;
1563         switch(op)
1564         {
1565                 case OP_SET:
1566                         e.fld = val;
1567                         break;
1568                 case OP_MIN:
1569                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1570                         break;
1571                 case OP_MAX:
1572                         e.fld = min(e.fld, val);
1573                         break;
1574                 case OP_PLUS:
1575                         e.fld += val;
1576                         break;
1577                 case OP_MINUS:
1578                         e.fld -= val;
1579                         break;
1580         }
1581         v1 = e.fld;
1582         return (v0 != v1);
1583 }
1584
1585 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1586 {
1587         if(v1 == v0)
1588                 return;
1589         if(v1 <= v0 - t)
1590         {
1591                 if(snd_decr != "")
1592                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1593         }
1594         else if(v0 >= v0 + t)
1595         {
1596                 if(snd_incr != "")
1597                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1598         }
1599 }
1600
1601 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1602 {
1603         if(v0 < v1)
1604                 e.rotfield = max(e.rotfield, time + rottime);
1605         else if(v0 > v1)
1606                 e.regenfield = max(e.regenfield, time + regentime);
1607 }
1608
1609 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1610 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1611 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1612 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1613
1614 float GiveItems(entity e, float beginarg, float endarg)
1615 {
1616         float got, i, j, val, op;
1617         float _switchweapon;
1618         entity wi;
1619         string cmd;
1620
1621         val = 999;
1622         op = OP_SET;
1623
1624         got = 0;
1625
1626         _switchweapon = FALSE;
1627         if (e.autoswitch)
1628                 if (e.switchweapon == w_getbestweapon(e))
1629                         _switchweapon = TRUE;
1630
1631         e.strength_finished = max(0, e.strength_finished - time);
1632         e.invincible_finished = max(0, e.invincible_finished - time);
1633
1634         PREGIVE(e, items);
1635         PREGIVE(e, weapons);
1636         PREGIVE(e, strength_finished);
1637         PREGIVE(e, invincible_finished);
1638         PREGIVE(e, ammo_nails);
1639         PREGIVE(e, ammo_cells);
1640         PREGIVE(e, ammo_shells);
1641         PREGIVE(e, ammo_rockets);
1642         PREGIVE(e, ammo_fuel);
1643         PREGIVE(e, armorvalue);
1644         PREGIVE(e, health);
1645
1646         for(i = beginarg; i < endarg; ++i)
1647         {
1648                 cmd = argv(i);
1649
1650                 if(cmd == "0" || stof(cmd))
1651                 {
1652                         val = stof(cmd);
1653                         continue;
1654                 }
1655                 switch(cmd)
1656                 {
1657                         case "no":
1658                                 op = OP_MAX;
1659                                 val = 0;
1660                                 continue;
1661                         case "max":
1662                                 op = OP_MAX;
1663                                 continue;
1664                         case "min":
1665                                 op = OP_MIN;
1666                                 continue;
1667                         case "plus":
1668                                 op = OP_PLUS;
1669                                 continue;
1670                         case "minus":
1671                                 op = OP_MINUS;
1672                                 continue;
1673                         case "ALL":
1674                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1675                                 got += GiveValue(e, strength_finished, op, time + val);
1676                                 got += GiveValue(e, invincible_finished, op, time + val);
1677                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1678                         case "all":
1679                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1680                                 got += GiveValue(e, health, op, val);
1681                                 got += GiveValue(e, armorvalue, op, val);
1682                         case "allweapons":
1683                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1684                                 {
1685                                         wi = get_weaponinfo(j);
1686                                         if(wi.weapons)
1687                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1688                                 }
1689                         case "allammo":
1690                                 got += GiveValue(e, ammo_cells, op, val);
1691                                 got += GiveValue(e, ammo_shells, op, val);
1692                                 got += GiveValue(e, ammo_nails, op, val);
1693                                 got += GiveValue(e, ammo_rockets, op, val);
1694                                 got += GiveValue(e, ammo_fuel, op, val);
1695                                 break;
1696                         case "unlimited_ammo":
1697                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1698                                 break;
1699                         case "unlimited_weapon_ammo":
1700                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1701                                 break;
1702                         case "unlimited_superweapons":
1703                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1704                                 break;
1705                         case "jetpack":
1706                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1707                                 break;
1708                         case "fuel_regen":
1709                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1710                                 break;
1711                         case "strength":
1712                                 got += GiveValue(e, strength_finished, op, val);
1713                                 break;
1714                         case "invincible":
1715                                 got += GiveValue(e, invincible_finished, op, val);
1716                                 break;
1717                         case "cells":
1718                                 got += GiveValue(e, ammo_cells, op, val);
1719                                 break;
1720                         case "shells":
1721                                 got += GiveValue(e, ammo_shells, op, val);
1722                                 break;
1723                         case "nails":
1724                         case "bullets":
1725                                 got += GiveValue(e, ammo_nails, op, val);
1726                                 break;
1727                         case "rockets":
1728                                 got += GiveValue(e, ammo_rockets, op, val);
1729                                 break;
1730                         case "health":
1731                                 got += GiveValue(e, health, op, val);
1732                                 break;
1733                         case "armor":
1734                                 got += GiveValue(e, armorvalue, op, val);
1735                                 break;
1736                         case "fuel":
1737                                 got += GiveValue(e, ammo_fuel, op, val);
1738                                 break;
1739                         default:
1740                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1741                                 {
1742                                         wi = get_weaponinfo(j);
1743                                         if(cmd == wi.netname)
1744                                         {
1745                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1746                                                 break;
1747                                         }
1748                                 }
1749                                 if(j > WEP_LAST)
1750                                         print("give: invalid item ", cmd, "\n");
1751                                 break;
1752                 }
1753                 val = 999;
1754                 op = OP_SET;
1755         }
1756
1757         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1758         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1759         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1760         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1761         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1762         {
1763                 wi = get_weaponinfo(j);
1764                 if(wi.weapons)
1765                 {
1766                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1767                         if not(save_weapons & wi.weapons)
1768                                 if(e.weapons & wi.weapons)
1769                                         weapon_action(wi.weapon, WR_PRECACHE);
1770                 }
1771         }
1772         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1773         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1774         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1775         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1776         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1777         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1778         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1779         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1780         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1781
1782         if(e.strength_finished <= 0)
1783                 e.strength_finished = 0;
1784         else
1785                 e.strength_finished += time;
1786         if(e.invincible_finished <= 0)
1787                 e.invincible_finished = 0;
1788         else
1789                 e.invincible_finished += time;
1790
1791         if not(e.weapons & W_WeaponBit(e.switchweapon))
1792                 _switchweapon = TRUE;
1793         if(_switchweapon)
1794                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1795
1796         return got;
1797 }