data/qcsrc/server/sv_main.qc

   1
   2 void CreatureFrame (void)
   3 {
   4         local entity oldself;
   5         local float dm;
   6         oldself = self;
   7         self = findfloat(world, iscreature, TRUE);
   8         while (self)
   9         {
  10                 if (self.movetype != MOVETYPE_NOCLIP)
  11                 {
  12                         if (self.waterlevel)
  13                         {
  14                                 if (!(self.flags & FL_INWATER))
  15                                 {
  16                                         self.flags |= FL_INWATER;
  17                                         self.dmgtime = 0;
  18                                 }
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  20                                 {
  21                                         if(self.air_finished < time + 9)
  22                                                 PlayerSound(playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  23                                         self.air_finished = time + 12;
  24                                         self.dmg = 2;
  25                                 }
  26                                 else if (self.air_finished < time)
  27                                 {       // drown!
  28                                         if (!self.deadflag)
  29                                         if (self.pain_finished < time)
  30                                         {
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');
  32                                                 self.pain_finished = time + 0.5;
  33                                         }
  34                                 }
  35                                 if (self.dmgtime < time)
  36                                 {
  37                                         self.dmgtime = time + 0.1;
  38                                         if (self.watertype == CONTENT_LAVA)
  39                                         {
  40                                                 if (self.watersound_finished < time)
  41                                                 {
  42                                                         self.watersound_finished = time + 0.5;
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  44                                                 }
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  46                                         }
  47                                         else if (self.watertype == CONTENT_SLIME)
  48                                         {
  49                                                 if (self.watersound_finished < time)
  50                                                 {
  51                                                         self.watersound_finished = time + 0.5;
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  53                                                 }
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  55                                         }
  56                                 }
  57                         }
  58                         else
  59                         {
  60                                 if (self.flags & FL_INWATER)
  61                                 {
  62                                         // play leave water sound
  63                                         self.flags &~= FL_INWATER;
  64                                         self.dmgtime = 0;
  65                                 }
  66                                 self.air_finished = time + 12;
  67                                 self.dmg = 2;
  68                         }
  69                         // check for falling damage
  70                         if(!self.hook.state)
  71                         {
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
  73                                 if (self.deadflag)
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");
  75                                 else
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));
  77                                 if (dm > 0)
  78                                 {
  79                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
  80                                 }
  81                                 else if(vlen(self.velocity) > 100000 && cvar("developer"))
  82                                 {
  83                                         dprint(strcat(self.netname, " became too fast, please investigate: ", vtos(self.spawnorigin), "\n"));
  84                                         Damage (self, world, world, 50000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
  85                                 }
  86                         }
  87
  88                         // play stupid sounds
  89                         if (g_footsteps)
  90                         if (!gameover)
  91                         if (self.flags & FL_ONGROUND)
  92                         if (vlen(self.velocity) > sv_maxspeed * 0.6)
  93                         if (!self.deadflag)
  94                         if (time < self.lastground + 0.2)
  95                         {
  96                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
  97                                 {
  98                                         self.nextstep = time + 0.3 + random() * 0.1;
  99                                         trace_dphitq3surfaceflags = 0;
 100                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 101                                         /*
 102                                         if(trace_fraction == 1)
 103                                                 dprint("nohit\n");
 104                                         else
 105                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 106                                         */
 107                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 108                                         {
 109                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 110                                                         GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 111                                                 else
 112                                                         GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 113                                         }
 114                                 }
 115                         }
 116                         self.oldvelocity = self.velocity;
 117                 }
 118                 self = findfloat(self, iscreature, TRUE);
 119         }
 120         self = oldself;
 121 }
 122
 123
 124 /*
 125 =============
 126 StartFrame
 127
 128 Called before each frame by the server
 129 =============
 130 */
 131 void RuneMatchGivePoints();
 132 float RedirectionThink();
 133 entity SelectSpawnPoint (float anypoint);
 134 void StartFrame (void)
 135 {
 136         remove = remove_unsafely; // not during spawning!
 137         serverprevtime = servertime;
 138         servertime = time;
 139         serverframetime = frametime;
 140
 141         dprint_load(); // load dprint status from cvar
 142
 143         entity e;
 144         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 145                 CSQCProjectile_Check(e);
 146
 147         if(RedirectionThink())
 148                 return;
 149
 150         UncustomizeEntitiesRun();
 151         InitializeEntitiesRun();
 152
 153         sv_gravity = cvar("sv_gravity");
 154         sv_maxairspeed = cvar("sv_maxairspeed");
 155         sv_maxspeed = cvar ("sv_maxspeed");
 156         sv_friction = cvar ("sv_friction");
 157         sv_accelerate = cvar ("sv_accelerate");
 158         sv_airaccelerate = cvar("sv_airaccelerate");
 159         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");
 160         sv_airaccel_qw = cvar("sv_airaccel_qw");
 161         sv_stopspeed = cvar ("sv_stopspeed");
 162         sv_airstopaccelerate = cvar("sv_airstopaccelerate");
 163         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");
 164         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");
 165         sv_aircontrol = cvar("sv_aircontrol");
 166         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");
 167         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");
 168         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");
 169         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");
 170         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");
 171         teamplay = cvar ("teamplay");
 172
 173         if(teams_matter && !teamplay)
 174                 teamplay = 3;
 175         if(!teams_matter && teamplay)
 176                 teamplay = 0;
 177
 178         skill = cvar("skill");
 179
 180         Spawnqueue_Check();
 181
 182         // if in warmup stage and limit for warmup is hit start match
 183         if (inWarmupStage
 184             && 0 < g_warmup_limit
 185             && time >= g_warmup_limit)
 186         {
 187                 ReadyRestart();
 188                 return;
 189         }
 190
 191         CreatureFrame ();
 192         CheckRules_World ();
 193
 194         AuditTeams();
 195
 196         RuneMatchGivePoints();
 197         bot_serverframe();
 198
 199         if(cvar("spawn_debugview"))
 200         {
 201                 RandomSelection_Init();
 202                 for(self = world; (self = find(self, classname, "player")); )
 203                         RandomSelection_Add(self, 0, string_null, 1, 0);
 204                 self = RandomSelection_chosen_ent;
 205                 SelectSpawnPoint(0);
 206         }
 207
 208         FOR_EACH_PLAYER(self)
 209                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 210 }
 211
 212 .vector originjitter;
 213 .vector anglesjitter;
 214 .float anglejitter;
 215 .string gametypefilter;
 216 void SV_OnEntityPreSpawnFunction()
 217 {
 218         if(self.gametypefilter != "")
 219         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))
 220         {
 221                 remove(self);
 222                 return;
 223         }
 224
 225         // support special -1 and -2 angle from radiant
 226         if (self.angles == '0 -1 0')
 227                 self.angles = '-90 0 0';
 228         else if (self.angles == '0 -2 0')
 229                 self.angles = '+90 0 0';
 230
 231         if(self.originjitter_x != 0)
 232                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 233         if(self.originjitter_y != 0)
 234                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 235         if(self.originjitter_z != 0)
 236                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 237         if(self.anglesjitter_x != 0)
 238                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 239         if(self.anglesjitter_y != 0)
 240                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 241         if(self.anglesjitter_z != 0)
 242                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 243         if(self.anglejitter != 0)
 244                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 245 }