data/qcsrc/server/portals.qc

   1 #define PORTALS_ARE_NOT_SOLID
   2
   3 #define SAFENUDGE '1 1 1'
   4 #define SAFERNUDGE '8 8 8'
   5
   6 .vector portal_transform;
   7 .vector portal_safe_origin;
   8 .float portal_wants_to_vanish;
   9 .float portal_activatetime;
  10
  11 float PlayerEdgeDistance(entity p, vector v)
  12 {
  13         vector vbest;
  14
  15         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  16         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  17         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  18
  19         return vbest * v;
  20 }
  21
  22 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  23 {
  24         vector old_forward, old_up;
  25         vector old_yawforward;
  26         vector new_forward, new_up;
  27         vector new_yawforward;
  28
  29         vector ang;
  30         ang = vangle;
  31         /*
  32            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  33            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  34          */
  35
  36         // PLAYERS use different math
  37         ang_x = -ang_x;
  38
  39         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  40
  41         fixedmakevectors(ang);
  42         old_forward = v_forward;
  43         old_up = v_up;
  44         fixedmakevectors(ang_y * '0 1 0');
  45         old_yawforward = v_forward;
  46
  47         // their aiming directions are portalled...
  48         new_forward = AnglesTransform_Apply(transform, old_forward);
  49         new_up = AnglesTransform_Apply(transform, old_up);
  50         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  51
  52         // but now find a new sense of direction
  53         // this is NOT easy!
  54         // assume new_forward points straight up.
  55         // What is our yaw?
  56         //
  57         // new_up could now point forward OR backward... which direction to choose?
  58
  59         if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
  60         {
  61                 // new_yawforward and new_yawup define the new aiming half-circle
  62                 // we "just" need to find out whether new_up or -new_up is in that half circle
  63                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  64                 if(new_up * new_yawforward < 0)
  65                         new_up = -1 * new_up;
  66                 ang_y = vectoyaw(new_up); // this vector is the yaw we want
  67                 //print("UP/DOWN path: ", vtos(ang), "\n");
  68         }
  69         else
  70         {
  71                 // good angles; here, "forward" suffices
  72                 ang = fixedvectoangles(new_forward);
  73                 //print("GOOD path: ", vtos(ang), "\n");
  74         }
  75
  76         ang_x = -ang_x;
  77         ang_z = vangle_z;
  78         return ang;
  79 }
  80
  81 .vector right_vector;
  82 float Portal_TeleportPlayer(entity teleporter, entity player)
  83 {
  84         vector from, to, safe, step, transform, ang, newvel;
  85         float planeshift, s, t;
  86
  87         if not(teleporter.enemy)
  88         {
  89                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  90                 return 0;
  91         }
  92
  93         from = teleporter.origin;
  94         transform = teleporter.portal_transform;
  95
  96         to = teleporter.enemy.origin;
  97         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
  98         newvel = AnglesTransform_Apply(transform, player.velocity);
  99         // this now is INSIDE the plane... can't use that
 100
 101         // shift it out
 102         fixedmakevectors(teleporter.enemy.angles);
 103
 104         // first shift it ON the plane if needed
 105         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 106         /*
 107         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 108                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 109                 to += newvel * (planeshift / (newvel * v_forward));
 110         else
 111         */
 112                 to += v_forward * planeshift;
 113
 114         s = (to - teleporter.enemy.origin) * v_right;
 115         t = (to - teleporter.enemy.origin) * v_up;
 116         s = bound(-48, s, 48);
 117         t = bound(-48, t, 48);
 118         to = teleporter.enemy.origin
 119            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 120            +     s                                        * v_right
 121            +     t                                        * v_up;
 122
 123         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 124         step = to + ((safe - to) * v_forward) * v_forward;
 125         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 126         if(trace_startsolid)
 127         {
 128                 print("'safe' teleport location is not safe!\n");
 129                 // FAIL TODO why does this happen?
 130                 return 0;
 131         }
 132         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 133         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 134         if(trace_startsolid)
 135         {
 136                 print("trace_endpos in solid, this can't be!\n");
 137                 // FAIL TODO why does this happen? (reported by MrBougo)
 138                 return 0;
 139         }
 140         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 141         //print(vtos(to), "\n");
 142
 143         // ang_x stuff works around weird quake angles
 144         if(player.classname == "player")
 145                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 146         else
 147                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 148
 149         // factor -1 allows chaining portals, but may be weird
 150         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 151
 152         if(player.flagcarried)
 153                 DropFlag(player.flagcarried, player, world);
 154
 155         if not(teleporter.enemy)
 156         {
 157                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 158                 return 0;
 159         }
 160
 161         tdeath_hit = 0;
 162         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 163         if(tdeath_hit)
 164         {
 165                 // telefrag within 1 second of portal creation = amazing
 166                 if(time < teleporter.teleport_time + 1)
 167                         AnnounceTo(player, "amazing");
 168         }
 169
 170         if not(teleporter.enemy)
 171         {
 172                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 173                 return 0;
 174         }
 175
 176         // reset fade counter
 177         teleporter.portal_wants_to_vanish = 0;
 178         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 179         teleporter.health = cvar("g_balance_portal_health");
 180         teleporter.enemy.health = cvar("g_balance_portal_health");
 181
 182         return 1;
 183 }
 184
 185 float Portal_FindSafeOrigin(entity portal)
 186 {
 187         vector o;
 188         o = portal.origin;
 189         portal.mins = PL_MIN - SAFERNUDGE;
 190         portal.maxs = PL_MAX + SAFERNUDGE;
 191         fixedmakevectors(portal.angles);
 192         portal.origin += 16 * v_forward;
 193         if(!move_out_of_solid(portal))
 194         {
 195 #ifdef DEBUG
 196                 print("NO SAFE ORIGIN\n");
 197 #endif
 198                 return 0;
 199         }
 200         portal.portal_safe_origin = portal.origin;
 201         setorigin(portal, o);
 202         return 1;
 203 }
 204
 205 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 206 {
 207         float dist, distpersec, delta;
 208         vector v;
 209
 210         dist = (eorg - porg) * pnorm;
 211         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 212         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 213         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 214         if(dist < -1) // other side?
 215                 return 0;
 216 #ifdef PORTALS_ARE_NOT_SOLID
 217         distpersec = evel * pnorm;
 218         if(distpersec >= 0) // going away from the portal?
 219                 return 0;
 220         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 221         delta = dist / distpersec;
 222         v = eorg - evel * delta - porg;
 223         v = v - pnorm * (pnorm * v);
 224         return vlen(v) < psize;
 225 #else
 226         return 1;
 227 #endif
 228 }
 229
 230 void Portal_Touch()
 231 {
 232         vector g;
 233
 234 #ifdef PORTALS_ARE_NOT_SOLID
 235         // portal is being removed?
 236         if(self.solid != SOLID_TRIGGER)
 237                 return; // possibly engine bug
 238
 239         if(other.classname == "player")
 240                 return; // handled by think
 241 #endif
 242
 243         if(other.classname == "item_flag_team")
 244                 return; // never portal these
 245
 246         if(other.classname == "grapplinghook")
 247                 return; // handled by think
 248
 249         if(!self.enemy)
 250                 error("Portal_Touch called for a broken portal\n");
 251
 252 #ifdef PORTALS_ARE_NOT_SOLID
 253         if(trace_fraction < 1)
 254                 return; // only handle TouchAreaGrid ones (only these can teleport)
 255 #else
 256         if(trace_fraction >= 1)
 257                 return; // only handle impacts
 258 #endif
 259
 260         if(other.classname == "porto")
 261         {
 262                 if(other.portal_id == self.portal_id)
 263                         return;
 264         }
 265         if(time < self.portal_activatetime)
 266                 if(other == self.aiment)
 267                 {
 268                         self.portal_activatetime = time + 0.1;
 269                         return;
 270                 }
 271         if(other != self.aiment)
 272                 if(other.classname == "player")
 273                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 274                                 return; // cannot go through someone else's portal
 275         if(other.aiment != self.aiment)
 276                 if(other.aiment.classname == "player")
 277                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 278                                 return; // cannot go through someone else's portal
 279         fixedmakevectors(self.angles);
 280         g = frametime * '0 0 -1' * cvar("sv_gravity");
 281         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 282                 return;
 283
 284         /*
 285         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 286         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 287         {
 288                 // can't teleport this
 289                 return;
 290         }
 291         */
 292
 293         if(Portal_TeleportPlayer(self, other))
 294                 if(other.classname == "porto")
 295                         if(other.effects & EF_RED)
 296                                 other.effects += EF_BLUE - EF_RED;
 297 }
 298
 299 void Portal_Think();
 300 void Portal_MakeBrokenPortal(entity portal)
 301 {
 302         portal.skin = 2;
 303         portal.solid = SOLID_NOT;
 304         portal.touch = SUB_Null;
 305         portal.think = SUB_Null;
 306         portal.effects = 0;
 307         portal.nextthink = 0;
 308         portal.takedamage = DAMAGE_NO;
 309 }
 310
 311 void Portal_MakeWaitingPortal(entity portal)
 312 {
 313         portal.skin = 2;
 314         portal.solid = SOLID_NOT;
 315         portal.touch = SUB_Null;
 316         portal.think = SUB_Null;
 317         portal.effects = EF_ADDITIVE;
 318         portal.nextthink = 0;
 319         portal.takedamage = DAMAGE_YES;
 320 }
 321
 322 void Portal_MakeInPortal(entity portal)
 323 {
 324         portal.skin = 0;
 325         portal.solid = SOLID_NOT; // this is done when connecting them!
 326         portal.touch = Portal_Touch;
 327         portal.think = Portal_Think;
 328         portal.effects = EF_RED;
 329         portal.nextthink = time;
 330         portal.takedamage = DAMAGE_NO;
 331 }
 332
 333 void Portal_MakeOutPortal(entity portal)
 334 {
 335         portal.skin = 1;
 336         portal.solid = SOLID_NOT;
 337         portal.touch = SUB_Null;
 338         portal.think = SUB_Null;
 339         portal.effects = EF_STARDUST | EF_BLUE;
 340         portal.nextthink = 0;
 341         portal.takedamage = DAMAGE_YES;
 342 }
 343
 344 void Portal_Disconnect(entity teleporter, entity destination)
 345 {
 346         teleporter.enemy = world;
 347         destination.enemy = world;
 348         Portal_MakeBrokenPortal(teleporter);
 349         Portal_MakeBrokenPortal(destination);
 350 }
 351
 352 void Portal_Connect(entity teleporter, entity destination)
 353 {
 354         teleporter.portal_transform = AnglesTransform_Divide(AnglesTransform_TurnDirectionFR(destination.angles), teleporter.angles);
 355
 356         teleporter.enemy = destination;
 357         destination.enemy = teleporter;
 358         Portal_MakeInPortal(teleporter);
 359         Portal_MakeOutPortal(destination);
 360         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 361         destination.fade_time = teleporter.fade_time;
 362         teleporter.portal_wants_to_vanish = 0;
 363         destination.portal_wants_to_vanish = 0;
 364         teleporter.teleport_time = time;
 365 #ifdef PORTALS_ARE_NOT_SOLID
 366         teleporter.solid = SOLID_TRIGGER;
 367 #else
 368         teleporter.solid = SOLID_BSP;
 369 #endif
 370 }
 371
 372 void Portal_Remove(entity portal, float killed)
 373 {
 374         entity e;
 375         e = portal.enemy;
 376
 377         if(e)
 378         {
 379                 Portal_Disconnect(portal, e);
 380                 Portal_Remove(e, killed);
 381         }
 382
 383         if(portal == portal.aiment.portal_in)
 384                 portal.aiment.portal_in = world;
 385         if(portal == portal.aiment.portal_out)
 386                 portal.aiment.portal_out = world;
 387         //portal.aiment = world;
 388
 389         // makes the portal vanish
 390         if(killed)
 391         {
 392                 fixedmakevectors(portal.angles);
 393                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 394                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 395                 remove(portal);
 396         }
 397         else
 398         {
 399                 Portal_MakeBrokenPortal(portal);
 400                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 401                 SUB_SetFade(portal, time, 0.5);
 402         }
 403 }
 404
 405 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 406 {
 407         if(deathtype == DEATH_TELEFRAG)
 408                 return;
 409         if(attacker != self.aiment)
 410                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 411                         return;
 412         self.health -= damage;
 413         if(self.health < 0)
 414                 Portal_Remove(self, 1);
 415 }
 416
 417 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 418 {
 419         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 420                 return;
 421
 422         // if e would hit the portal in a frame...
 423         // already teleport him
 424         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 425         if(trace_ent == self)
 426                 Portal_TeleportPlayer(self, e);
 427 }
 428
 429 void Portal_Think()
 430 {
 431         entity e, o;
 432         vector g;
 433
 434 #ifdef PORTALS_ARE_NOT_SOLID
 435         // portal is being removed?
 436         if(self.solid != SOLID_TRIGGER)
 437                 return; // possibly engine bug
 438
 439         if(!self.enemy)
 440                 error("Portal_Think called for a broken portal\n");
 441
 442         o = self.aiment;
 443         self.solid = SOLID_BBOX;
 444         self.aiment = world;
 445
 446         g = frametime * '0 0 -1' * cvar("sv_gravity");
 447
 448         fixedmakevectors(self.angles);
 449
 450         FOR_EACH_PLAYER(e)
 451         {
 452                 if(e != o)
 453                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 454                                 continue; // cannot go through someone else's portal
 455
 456                 if(e != o || time >= self.portal_activatetime)
 457                         Portal_Think_TryTeleportPlayer(e, g);
 458
 459                 if(e.hook)
 460                         Portal_Think_TryTeleportPlayer(e.hook, g);
 461         }
 462         self.solid = SOLID_TRIGGER;
 463         self.aiment = o;
 464 #endif
 465
 466         self.nextthink = time;
 467
 468         if(time > self.fade_time)
 469                 Portal_Remove(self, 0);
 470 }
 471
 472 float Portal_Customize()
 473 {
 474         if(other.classname == "spectator")
 475                 other = other.enemy;
 476         if(other == self.aiment)
 477         {
 478                 self.modelindex = self.modelindex_lod0;
 479         }
 480         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 481         {
 482                 self.modelindex = 0;
 483         }
 484         else
 485         {
 486                 self.modelindex = self.modelindex_lod0;
 487         }
 488         return TRUE;
 489 }
 490
 491 // cleanup:
 492 //   when creating in-portal:
 493 //     disconnect
 494 //     clear existing in-portal
 495 //     set as in-portal
 496 //     connect
 497 //   when creating out-portal:
 498 //     disconnect
 499 //     clear existing out-portal
 500 //     set as out-portal
 501 //   when player dies:
 502 //     disconnect portals
 503 //     clear both portals
 504 //   after timeout of in-portal:
 505 //     disconnect portals
 506 //     clear both portals
 507 //   TODO: ensure only one portal shot at once
 508 float Portal_SetInPortal(entity own, entity portal)
 509 {
 510         if(own.portal_in)
 511         {
 512                 if(own.portal_out)
 513                         Portal_Disconnect(own.portal_in, own.portal_out);
 514                 Portal_Remove(own.portal_in, 0);
 515         }
 516         own.portal_in = portal;
 517         if(own.portal_out)
 518         {
 519                 own.portal_out.portal_id = portal.portal_id;
 520                 Portal_Connect(own.portal_in, own.portal_out);
 521         }
 522         return 2;
 523 }
 524 float Portal_SetOutPortal(entity own, entity portal)
 525 {
 526         if(own.portal_out)
 527         {
 528                 if(own.portal_in)
 529                         Portal_Disconnect(own.portal_in, own.portal_out);
 530                 Portal_Remove(own.portal_out, 0);
 531         }
 532         own.portal_out = portal;
 533         if(own.portal_in)
 534         {
 535                 own.portal_in.portal_id = portal.portal_id;
 536                 Portal_Connect(own.portal_in, own.portal_out);
 537         }
 538         return 1;
 539 }
 540 void Portal_ClearAll_PortalsOnly(entity own)
 541 {
 542         if(own.portal_in)
 543                 Portal_Remove(own.portal_in, 0);
 544         if(own.portal_out)
 545                 Portal_Remove(own.portal_out, 0);
 546 }
 547 void Portal_ClearAll(entity own)
 548 {
 549         Portal_ClearAll_PortalsOnly(own);
 550         W_Porto_Remove(own);
 551 }
 552 void Portal_RemoveLater_Think()
 553 {
 554         Portal_Remove(self, self.cnt);
 555 }
 556 void Portal_RemoveLater(entity portal, float kill)
 557 {
 558         Portal_MakeBrokenPortal(portal);
 559         portal.cnt = kill;
 560         portal.think = Portal_RemoveLater_Think;
 561         portal.nextthink = time;
 562 }
 563 void Portal_ClearAllLater_PortalsOnly(entity own)
 564 {
 565         if(own.portal_in)
 566                 Portal_RemoveLater(own.portal_in, 0);
 567         if(own.portal_out)
 568                 Portal_RemoveLater(own.portal_out, 0);
 569 }
 570 void Portal_ClearAllLater(entity own)
 571 {
 572         Portal_ClearAllLater_PortalsOnly(own);
 573         W_Porto_Remove(own);
 574 }
 575 void Portal_ClearWithID(entity own, float id)
 576 {
 577         if(own.portal_in)
 578                 if(own.portal_in.portal_id == id)
 579                 {
 580                         if(own.portal_out)
 581                                 Portal_Disconnect(own.portal_in, own.portal_out);
 582                         Portal_Remove(own.portal_in, 0);
 583                 }
 584         if(own.portal_out)
 585                 if(own.portal_out.portal_id == id)
 586                 {
 587                         if(own.portal_in)
 588                                 Portal_Disconnect(own.portal_in, own.portal_out);
 589                         Portal_Remove(own.portal_out, 0);
 590                 }
 591 }
 592
 593 entity Portal_Spawn(entity own, vector org, vector ang)
 594 {
 595         entity portal;
 596
 597         fixedmakevectors(ang);
 598         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 599                 return world;
 600
 601         portal = spawn();
 602         portal.classname = "portal";
 603         portal.aiment = own;
 604         setorigin(portal, org);
 605         portal.angles = ang;
 606         portal.think = Portal_Think;
 607         portal.nextthink = 0;
 608         portal.portal_activatetime = time + 0.1;
 609         portal.takedamage = DAMAGE_AIM;
 610         portal.event_damage = Portal_Damage;
 611         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 612         portal.health = cvar("g_balance_portal_health");
 613         setmodel(portal, "models/portal.md3");
 614         portal.modelindex_lod0 = portal.modelindex;
 615         portal.customizeentityforclient = Portal_Customize;
 616
 617         if(!Portal_FindSafeOrigin(portal))
 618         {
 619                 remove(portal);
 620                 return world;
 621         }
 622
 623         setsize(portal, '-48 -48 -48', '48 48 48');
 624         Portal_MakeWaitingPortal(portal);
 625
 626         return portal;
 627 }
 628
 629 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 630 {
 631         entity portal;
 632         vector ang;
 633         vector org;
 634
 635         org = trace_endpos;
 636         ang = fixedvectoangles2(trace_plane_normal, dir);
 637         fixedmakevectors(ang);
 638
 639         portal = Portal_Spawn(own, org, ang);
 640         if(!portal)
 641         {
 642                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 643                         Portal_ClearAll_PortalsOnly(own);
 644                 return 0;
 645         }
 646
 647         portal.portal_id = portal_id_val;
 648         Portal_SetInPortal(own, portal);
 649
 650         return 1;
 651 }
 652
 653 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 654 {
 655         entity portal;
 656         vector ang;
 657         vector org;
 658
 659         org = trace_endpos;
 660         ang = fixedvectoangles2(trace_plane_normal, dir);
 661         fixedmakevectors(ang);
 662
 663         portal = Portal_Spawn(own, org, ang);
 664         if(!portal)
 665         {
 666                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 667                         Portal_ClearAll_PortalsOnly(own);
 668                 return 0;
 669         }
 670
 671         portal.portal_id = portal_id_val;
 672         Portal_SetOutPortal(own, portal);
 673
 674         return 1;
 675 }