data/qcsrc/server/portals.qc

   1 #define PORTALS_ARE_NOT_SOLID
   2
   3 #define SAFENUDGE '1 1 1'
   4 #define SAFERNUDGE '8 8 8'
   5
   6 .vector portal_transform;
   7 .vector portal_safe_origin;
   8 .float portal_wants_to_vanish;
   9 .float portal_activatetime;
  10
  11 float PlayerEdgeDistance(entity p, vector v)
  12 {
  13         vector vbest;
  14
  15         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  16         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  17         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  18
  19         return vbest * v;
  20 }
  21
  22 .vector right_vector;
  23 float Portal_TeleportPlayer(entity teleporter, entity player)
  24 {
  25         vector from, to, safe, step, transform, ang, newvel;
  26         vector new_forward, new_up;
  27         vector old_forward, old_up;
  28         vector new_yawforward;
  29         vector old_yawforward;
  30         float planeshift, s, t;
  31
  32         if not(teleporter.enemy)
  33         {
  34                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  35                 return 0;
  36         }
  37
  38         from = teleporter.origin;
  39         transform = teleporter.portal_transform;
  40
  41         to = teleporter.enemy.origin;
  42         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
  43         newvel = AnglesTransform_Apply(transform, player.velocity);
  44         // this now is INSIDE the plane... can't use that
  45
  46         // shift it out
  47         fixedmakevectors(teleporter.enemy.angles);
  48
  49         // first shift it ON the plane if needed
  50         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
  51         /*
  52         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
  53                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
  54                 to += newvel * (planeshift / (newvel * v_forward));
  55         else
  56         */
  57                 to += v_forward * planeshift;
  58
  59         s = (to - teleporter.enemy.origin) * v_right;
  60         t = (to - teleporter.enemy.origin) * v_up;
  61         s = bound(-48, s, 48);
  62         t = bound(-48, t, 48);
  63         to = teleporter.enemy.origin
  64            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
  65            +     s                                        * v_right
  66            +     t                                        * v_up;
  67
  68         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
  69         step = to + ((safe - to) * v_forward) * v_forward;
  70         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
  71         if(trace_startsolid)
  72         {
  73                 print("'safe' teleport location is not safe!\n");
  74                 // FAIL TODO why does this happen?
  75                 return 0;
  76         }
  77         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
  78         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
  79         if(trace_startsolid)
  80         {
  81                 print("trace_endpos in solid, this can't be!\n");
  82                 // FAIL TODO why does this happen? (reported by MrBougo)
  83                 return 0;
  84         }
  85         to = trace_endpos + normalize(safe - trace_endpos) * 0;
  86         //print(vtos(to), "\n");
  87
  88         // ang_x stuff works around weird quake angles
  89         if(player.classname == "player")
  90         {
  91                 ang = player.v_angle;
  92                 /*
  93                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  94                 ang = AnglesTransform_Multiply(transform, ang);
  95                 */
  96
  97                 // PLAYERS use different math
  98                 ang_x = -ang_x;
  99
 100                 //print("reference: ", vtos(AnglesTransform_Multiply(transform, ang)), "\n");
 101
 102                 fixedmakevectors(ang);
 103                 old_forward = v_forward;
 104                 old_up = v_up;
 105                 fixedmakevectors(ang_y * '0 1 0');
 106                 old_yawforward = v_forward;
 107
 108                 // their aiming directions are portalled...
 109                 new_forward = AnglesTransform_Apply(transform, old_forward);
 110                 new_up = AnglesTransform_Apply(transform, old_up);
 111                 new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
 112
 113                 // but now find a new sense of direction
 114                 // this is NOT easy!
 115                 // assume new_forward points straight up.
 116                 // What is our yaw?
 117                 //
 118                 // new_up could now point forward OR backward... which direction to choose?
 119
 120                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 121                 {
 122                         // new_yawforward and new_yawup define the new aiming half-circle
 123                         // we "just" need to find out whether new_up or -new_up is in that half circle
 124                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 125                         if(new_up * new_yawforward < 0)
 126                                 new_up = -1 * new_up;
 127                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 128                         //print("UP/DOWN path: ", vtos(ang), "\n");
 129                 }
 130                 else
 131                 {
 132                         // good angles; here, "forward" suffices
 133                         ang = fixedvectoangles(new_forward);
 134                         //print("GOOD path: ", vtos(ang), "\n");
 135                 }
 136
 137                 ang_x = -ang_x;
 138                 ang_z = player.angles_z;
 139         }
 140         else
 141         {
 142                 ang = player.angles;
 143                 ang = AnglesTransform_Multiply(transform, player.angles);
 144         }
 145
 146         // factor -1 allows chaining portals, but may be weird
 147         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 148
 149         if(player.flagcarried)
 150                 DropFlag(player.flagcarried, player, world);
 151
 152         if not(teleporter.enemy)
 153         {
 154                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 155                 return 0;
 156         }
 157
 158         tdeath_hit = 0;
 159         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 160         if(tdeath_hit)
 161         {
 162                 // telefrag within 1 second of portal creation = amazing
 163                 if(time < teleporter.teleport_time + 1)
 164                         announce(player, "announcer/male/amazing.wav");
 165         }
 166
 167         if not(teleporter.enemy)
 168         {
 169                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 170                 return 0;
 171         }
 172
 173         // reset fade counter
 174         teleporter.portal_wants_to_vanish = 0;
 175         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 176         teleporter.health = cvar("g_balance_portal_health");
 177         teleporter.enemy.health = cvar("g_balance_portal_health");
 178
 179         return 1;
 180 }
 181
 182 float Portal_FindSafeOrigin(entity portal)
 183 {
 184         vector o;
 185         o = portal.origin;
 186         portal.mins = PL_MIN - SAFERNUDGE;
 187         portal.maxs = PL_MAX + SAFERNUDGE;
 188         fixedmakevectors(portal.angles);
 189         portal.origin += 16 * v_forward;
 190         if(!move_out_of_solid(portal))
 191         {
 192 #ifdef DEBUG
 193                 print("NO SAFE ORIGIN\n");
 194 #endif
 195                 return 0;
 196         }
 197         portal.portal_safe_origin = portal.origin;
 198         setorigin(portal, o);
 199         return 1;
 200 }
 201
 202 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 203 {
 204         float dist, distpersec, delta;
 205         vector v;
 206
 207         dist = (eorg - porg) * pnorm;
 208         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 209         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 210         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 211         if(dist < -1) // other side?
 212                 return 0;
 213 #ifdef PORTALS_ARE_NOT_SOLID
 214         distpersec = evel * pnorm;
 215         if(distpersec >= 0) // going away from the portal?
 216                 return 0;
 217         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 218         delta = dist / distpersec;
 219         v = eorg - evel * delta - porg;
 220         v = v - pnorm * (pnorm * v);
 221         return vlen(v) < psize;
 222 #else
 223         return 1;
 224 #endif
 225 }
 226
 227 void Portal_Touch()
 228 {
 229         vector g;
 230
 231 #ifdef PORTALS_ARE_NOT_SOLID
 232         // portal is being removed?
 233         if(self.solid != SOLID_TRIGGER)
 234                 return; // possibly engine bug
 235
 236         if(other.classname == "player")
 237                 return; // handled by think
 238 #endif
 239
 240         if(other.classname == "item_flag_team")
 241                 return; // never portal these
 242
 243         if(other.classname == "grapplinghook")
 244                 return; // handled by think
 245
 246         if(!self.enemy)
 247                 error("Portal_Touch called for a broken portal\n");
 248
 249 #ifdef PORTALS_ARE_NOT_SOLID
 250         if(trace_fraction < 1)
 251                 return; // only handle TouchAreaGrid ones (only these can teleport)
 252 #else
 253         if(trace_fraction >= 1)
 254                 return; // only handle impacts
 255 #endif
 256
 257         if(other.classname == "porto")
 258         {
 259                 if(other.portal_id == self.portal_id)
 260                         return;
 261         }
 262         if(time < self.portal_activatetime)
 263                 if(other == self.aiment)
 264                 {
 265                         self.portal_activatetime = time + 0.1;
 266                         return;
 267                 }
 268         if(other != self.aiment)
 269                 if(other.classname == "player")
 270                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 271                                 return; // cannot go through someone else's portal
 272         if(other.aiment != self.aiment)
 273                 if(other.aiment.classname == "player")
 274                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 275                                 return; // cannot go through someone else's portal
 276         fixedmakevectors(self.angles);
 277         g = frametime * '0 0 -1' * cvar("sv_gravity");
 278         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 279                 return;
 280
 281         /*
 282         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 283         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 284         {
 285                 // can't teleport this
 286                 return;
 287         }
 288         */
 289
 290         if(Portal_TeleportPlayer(self, other))
 291                 if(other.classname == "porto")
 292                         if(other.effects & EF_RED)
 293                                 other.effects += EF_BLUE - EF_RED;
 294 }
 295
 296 void Portal_Think();
 297 void Portal_MakeBrokenPortal(entity portal)
 298 {
 299         portal.skin = 2;
 300         portal.solid = SOLID_NOT;
 301         portal.touch = SUB_Null;
 302         portal.think = SUB_Null;
 303         portal.effects = 0;
 304         portal.nextthink = 0;
 305         portal.takedamage = DAMAGE_NO;
 306 }
 307
 308 void Portal_MakeWaitingPortal(entity portal)
 309 {
 310         portal.skin = 2;
 311         portal.solid = SOLID_NOT;
 312         portal.touch = SUB_Null;
 313         portal.think = SUB_Null;
 314         portal.effects = EF_ADDITIVE;
 315         portal.nextthink = 0;
 316         portal.takedamage = DAMAGE_YES;
 317 }
 318
 319 void Portal_MakeInPortal(entity portal)
 320 {
 321         portal.skin = 0;
 322         portal.solid = SOLID_NOT; // this is done when connecting them!
 323         portal.touch = Portal_Touch;
 324         portal.think = Portal_Think;
 325         portal.effects = EF_RED;
 326         portal.nextthink = time;
 327         portal.takedamage = DAMAGE_NO;
 328 }
 329
 330 void Portal_MakeOutPortal(entity portal)
 331 {
 332         portal.skin = 1;
 333         portal.solid = SOLID_NOT;
 334         portal.touch = SUB_Null;
 335         portal.think = SUB_Null;
 336         portal.effects = EF_STARDUST | EF_BLUE;
 337         portal.nextthink = 0;
 338         portal.takedamage = DAMAGE_YES;
 339 }
 340
 341 void Portal_Disconnect(entity teleporter, entity destination)
 342 {
 343         teleporter.enemy = world;
 344         destination.enemy = world;
 345         Portal_MakeBrokenPortal(teleporter);
 346         Portal_MakeBrokenPortal(destination);
 347 }
 348
 349 void Portal_Connect(entity teleporter, entity destination)
 350 {
 351         teleporter.portal_transform = AnglesTransform_Divide(AnglesTransform_TurnDirection(destination.angles), teleporter.angles);
 352
 353         teleporter.enemy = destination;
 354         destination.enemy = teleporter;
 355         Portal_MakeInPortal(teleporter);
 356         Portal_MakeOutPortal(destination);
 357         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 358         destination.fade_time = teleporter.fade_time;
 359         teleporter.portal_wants_to_vanish = 0;
 360         destination.portal_wants_to_vanish = 0;
 361         teleporter.teleport_time = time;
 362 #ifdef PORTALS_ARE_NOT_SOLID
 363         teleporter.solid = SOLID_TRIGGER;
 364 #else
 365         teleporter.solid = SOLID_BSP;
 366 #endif
 367 }
 368
 369 void Portal_Remove(entity portal, float killed)
 370 {
 371         entity e;
 372         e = portal.enemy;
 373
 374         if(e)
 375         {
 376                 Portal_Disconnect(portal, e);
 377                 Portal_Remove(e, killed);
 378         }
 379
 380         if(portal == portal.aiment.portal_in)
 381                 portal.aiment.portal_in = world;
 382         if(portal == portal.aiment.portal_out)
 383                 portal.aiment.portal_out = world;
 384         //portal.aiment = world;
 385
 386         // makes the portal vanish
 387         if(killed)
 388         {
 389                 fixedmakevectors(portal.angles);
 390                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 391                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 392                 remove(portal);
 393         }
 394         else
 395         {
 396                 Portal_MakeBrokenPortal(portal);
 397                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 398                 SUB_SetFade(portal, time, 0.5);
 399         }
 400 }
 401
 402 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 403 {
 404         if(deathtype == DEATH_TELEFRAG)
 405                 return;
 406         if(attacker != self.aiment)
 407                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 408                         return;
 409         self.health -= damage;
 410         if(self.health < 0)
 411                 Portal_Remove(self, 1);
 412 }
 413
 414 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 415 {
 416         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 417                 return;
 418
 419         // if e would hit the portal in a frame...
 420         // already teleport him
 421         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 422         if(trace_ent == self)
 423                 Portal_TeleportPlayer(self, e);
 424 }
 425
 426 void Portal_Think()
 427 {
 428         entity e, o;
 429         vector g;
 430
 431 #ifdef PORTALS_ARE_NOT_SOLID
 432         // portal is being removed?
 433         if(self.solid != SOLID_TRIGGER)
 434                 return; // possibly engine bug
 435
 436         if(!self.enemy)
 437                 error("Portal_Think called for a broken portal\n");
 438
 439         o = self.aiment;
 440         self.solid = SOLID_BBOX;
 441         self.aiment = world;
 442
 443         g = frametime * '0 0 -1' * cvar("sv_gravity");
 444
 445         fixedmakevectors(self.angles);
 446
 447         FOR_EACH_PLAYER(e)
 448         {
 449                 if(e != o)
 450                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 451                                 continue; // cannot go through someone else's portal
 452
 453                 if(e != o || time >= self.portal_activatetime)
 454                         Portal_Think_TryTeleportPlayer(e, g);
 455
 456                 if(e.hook)
 457                         Portal_Think_TryTeleportPlayer(e.hook, g);
 458         }
 459         self.solid = SOLID_TRIGGER;
 460         self.aiment = o;
 461 #endif
 462
 463         self.nextthink = time;
 464
 465         if(time > self.fade_time)
 466                 Portal_Remove(self, 0);
 467 }
 468
 469 float Portal_Customize()
 470 {
 471         if(other.classname == "spectator")
 472                 other = other.enemy;
 473         if(other == self.aiment)
 474         {
 475                 self.modelindex = self.modelindex_lod0;
 476         }
 477         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 478         {
 479                 self.modelindex = 0;
 480         }
 481         else
 482         {
 483                 self.modelindex = self.modelindex_lod0;
 484         }
 485         return TRUE;
 486 }
 487
 488 // cleanup:
 489 //   when creating in-portal:
 490 //     disconnect
 491 //     clear existing in-portal
 492 //     set as in-portal
 493 //     connect
 494 //   when creating out-portal:
 495 //     disconnect
 496 //     clear existing out-portal
 497 //     set as out-portal
 498 //   when player dies:
 499 //     disconnect portals
 500 //     clear both portals
 501 //   after timeout of in-portal:
 502 //     disconnect portals
 503 //     clear both portals
 504 //   TODO: ensure only one portal shot at once
 505 float Portal_SetInPortal(entity own, entity portal)
 506 {
 507         if(own.portal_in)
 508         {
 509                 if(own.portal_out)
 510                         Portal_Disconnect(own.portal_in, own.portal_out);
 511                 Portal_Remove(own.portal_in, 0);
 512         }
 513         own.portal_in = portal;
 514         if(own.portal_out)
 515         {
 516                 own.portal_out.portal_id = portal.portal_id;
 517                 Portal_Connect(own.portal_in, own.portal_out);
 518         }
 519         return 2;
 520 }
 521 float Portal_SetOutPortal(entity own, entity portal)
 522 {
 523         if(own.portal_out)
 524         {
 525                 if(own.portal_in)
 526                         Portal_Disconnect(own.portal_in, own.portal_out);
 527                 Portal_Remove(own.portal_out, 0);
 528         }
 529         own.portal_out = portal;
 530         if(own.portal_in)
 531         {
 532                 own.portal_in.portal_id = portal.portal_id;
 533                 Portal_Connect(own.portal_in, own.portal_out);
 534         }
 535         return 1;
 536 }
 537 void Portal_ClearAll_PortalsOnly(entity own)
 538 {
 539         if(own.portal_in)
 540                 Portal_Remove(own.portal_in, 0);
 541         if(own.portal_out)
 542                 Portal_Remove(own.portal_out, 0);
 543 }
 544 void Portal_ClearAll(entity own)
 545 {
 546         Portal_ClearAll_PortalsOnly(own);
 547         W_Porto_Remove(own);
 548 }
 549 void Portal_RemoveLater_Think()
 550 {
 551         Portal_Remove(self, self.cnt);
 552 }
 553 void Portal_RemoveLater(entity portal, float kill)
 554 {
 555         Portal_MakeBrokenPortal(portal);
 556         portal.cnt = kill;
 557         portal.think = Portal_RemoveLater_Think;
 558         portal.nextthink = time;
 559 }
 560 void Portal_ClearAllLater_PortalsOnly(entity own)
 561 {
 562         if(own.portal_in)
 563                 Portal_RemoveLater(own.portal_in, 0);
 564         if(own.portal_out)
 565                 Portal_RemoveLater(own.portal_out, 0);
 566 }
 567 void Portal_ClearAllLater(entity own)
 568 {
 569         Portal_ClearAllLater_PortalsOnly(own);
 570         W_Porto_Remove(own);
 571 }
 572 void Portal_ClearWithID(entity own, float id)
 573 {
 574         if(own.portal_in)
 575                 if(own.portal_in.portal_id == id)
 576                 {
 577                         if(own.portal_out)
 578                                 Portal_Disconnect(own.portal_in, own.portal_out);
 579                         Portal_Remove(own.portal_in, 0);
 580                 }
 581         if(own.portal_out)
 582                 if(own.portal_out.portal_id == id)
 583                 {
 584                         if(own.portal_in)
 585                                 Portal_Disconnect(own.portal_in, own.portal_out);
 586                         Portal_Remove(own.portal_out, 0);
 587                 }
 588 }
 589
 590 entity Portal_Spawn(entity own, vector org, vector ang)
 591 {
 592         entity portal;
 593
 594         fixedmakevectors(ang);
 595         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 596                 return world;
 597
 598         portal = spawn();
 599         portal.classname = "portal";
 600         portal.aiment = own;
 601         setorigin(portal, org);
 602         portal.angles = ang;
 603         portal.think = Portal_Think;
 604         portal.nextthink = 0;
 605         portal.portal_activatetime = time + 0.1;
 606         portal.takedamage = DAMAGE_AIM;
 607         portal.event_damage = Portal_Damage;
 608         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 609         portal.health = cvar("g_balance_portal_health");
 610         setmodel(portal, "models/portal.md3");
 611         portal.modelindex_lod0 = portal.modelindex;
 612         portal.customizeentityforclient = Portal_Customize;
 613
 614         if(!Portal_FindSafeOrigin(portal))
 615         {
 616                 remove(portal);
 617                 return world;
 618         }
 619
 620         setsize(portal, '-48 -48 -48', '48 48 48');
 621         Portal_MakeWaitingPortal(portal);
 622
 623         return portal;
 624 }
 625
 626 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 627 {
 628         entity portal;
 629         vector ang;
 630         vector org;
 631
 632         org = trace_endpos;
 633         ang = fixedvectoangles2(trace_plane_normal, dir);
 634         fixedmakevectors(ang);
 635
 636         portal = Portal_Spawn(own, org, ang);
 637         if(!portal)
 638         {
 639                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 640                         Portal_ClearAll_PortalsOnly(own);
 641                 return 0;
 642         }
 643
 644         portal.portal_id = portal_id_val;
 645         Portal_SetInPortal(own, portal);
 646
 647         return 1;
 648 }
 649
 650 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 651 {
 652         entity portal;
 653         vector ang;
 654         vector org;
 655
 656         org = trace_endpos;
 657         ang = fixedvectoangles2(trace_plane_normal, dir);
 658         fixedmakevectors(ang);
 659
 660         portal = Portal_Spawn(own, org, ang);
 661         if(!portal)
 662         {
 663                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 664                         Portal_ClearAll_PortalsOnly(own);
 665                 return 0;
 666         }
 667
 668         portal.portal_id = portal_id_val;
 669         Portal_SetOutPortal(own, portal);
 670
 671         return 1;
 672 }