data/qcsrc/server/mode_onslaught.qc

   1 void onslaught_generator_updatesprite(entity e);
   2 void onslaught_controlpoint_updatesprite(entity e);
   3 void onslaught_link_checkupdate();
   4
   5 .entity sprite;
   6 .string target2;
   7 .float iscaptured;
   8 .float islinked;
   9 .float isgenneighbor_red;
  10 .float isgenneighbor_blue;
  11 .float iscpneighbor_red;
  12 .float iscpneighbor_blue;
  13 .float isshielded;
  14 .float lasthealth;
  15 .float lastteam;
  16 .float lastshielded;
  17
  18 .string model1, model2, model3;
  19
  20 void onslaught_updatelinks()
  21 {
  22         local entity l, links;
  23         local float stop, t1, t2, t3, t4;
  24         // first check if the game has ended
  25         dprint("--- updatelinks ---\n");
  26         links = findchain(classname, "onslaught_link");
  27         // mark generators as being shielded and networked
  28         l = findchain(classname, "onslaught_generator");
  29         while (l)
  30         {
  31                 if (l.iscaptured)
  32                         dprint(etos(l), " (generator) belongs to team ", ftos(l.team), "\n");
  33                 else
  34                         dprint(etos(l), " (generator) is destroyed\n");
  35                 l.islinked = l.iscaptured;
  36                 l.isshielded = l.iscaptured;
  37                 l = l.chain;
  38         }
  39         // mark points as shielded and not networked
  40         l = findchain(classname, "onslaught_controlpoint");
  41         while (l)
  42         {
  43                 l.islinked = FALSE;
  44                 l.isshielded = TRUE;
  45                 l.isgenneighbor_red = FALSE;
  46                 l.isgenneighbor_blue = FALSE;
  47                 l.iscpneighbor_red = FALSE;
  48                 l.iscpneighbor_blue = FALSE;
  49                 dprint(etos(l), " (point) belongs to team ", ftos(l.team), "\n");
  50                 l = l.chain;
  51         }
  52         // flow power outward from the generators through the network
  53         l = links;
  54         while (l)
  55         {
  56                 dprint(etos(l), " (link) connects ", etos(l.goalentity), " with ", etos(l.enemy), "\n");
  57                 l = l.chain;
  58         }
  59         stop = FALSE;
  60         while (!stop)
  61         {
  62                 stop = TRUE;
  63                 l = links;
  64                 while (l)
  65                 {
  66                         // if both points are captured by the same team, and only one of
  67                         // them is powered, mark the other one as powered as well
  68                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
  69                         if (l.enemy.islinked != l.goalentity.islinked)
  70                         if (l.enemy.team == l.goalentity.team)
  71                         {
  72                                 if (!l.goalentity.islinked)
  73                                 {
  74                                         stop = FALSE;
  75                                         l.goalentity.islinked = TRUE;
  76                                         dprint(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)\n");
  77                                 }
  78                                 else if (!l.enemy.islinked)
  79                                 {
  80                                         stop = FALSE;
  81                                         l.enemy.islinked = TRUE;
  82                                         dprint(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)\n");
  83                                 }
  84                         }
  85                         l = l.chain;
  86                 }
  87         }
  88         // now that we know which points are powered we can mark their neighbors
  89         // as unshielded if team differs
  90         l = links;
  91         while (l)
  92         {
  93                 if (l.goalentity.team != l.enemy.team)
  94                 {
  95                         if (l.goalentity.islinked)
  96                         {
  97                                 dprint(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)\n");
  98                                 l.enemy.isshielded = FALSE;
  99                                 if(l.goalentity.classname == "onslaught_generator")
 100                                 {
 101                                         if(l.goalentity.team == COLOR_TEAM1)
 102                                                 l.enemy.isgenneighbor_red = TRUE;
 103                                         else if(l.goalentity.team == COLOR_TEAM2)
 104                                                 l.enemy.isgenneighbor_blue = TRUE;
 105                                 }
 106                                 else
 107                                 {
 108                                         if(l.goalentity.team == COLOR_TEAM1)
 109                                                 l.enemy.iscpneighbor_red = TRUE;
 110                                         else if(l.goalentity.team == COLOR_TEAM2)
 111                                                 l.enemy.iscpneighbor_blue = TRUE;
 112                                 }
 113                         }
 114                         if (l.enemy.islinked)
 115                         {
 116                                 dprint(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)\n");
 117                                 l.goalentity.isshielded = FALSE;
 118                                 if(l.enemy.classname == "onslaught_generator")
 119                                 {
 120                                         if(l.enemy.team == COLOR_TEAM1)
 121                                                 l.goalentity.isgenneighbor_red = TRUE;
 122                                         else if(l.enemy.team == COLOR_TEAM2)
 123                                                 l.goalentity.isgenneighbor_blue = TRUE;
 124                                 }
 125                                 else
 126                                 {
 127                                         if(l.enemy.team == COLOR_TEAM1)
 128                                                 l.goalentity.iscpneighbor_red = TRUE;
 129                                         else if(l.enemy.team == COLOR_TEAM2)
 130                                                 l.goalentity.iscpneighbor_blue = TRUE;
 131                                 }
 132                         }
 133                 }
 134                 l = l.chain;
 135         }
 136         // now update the takedamage and alpha variables on generator shields
 137         l = findchain(classname, "onslaught_generator");
 138         while (l)
 139         {
 140                 if (l.isshielded)
 141                 {
 142                         dprint(etos(l), " (generator) is shielded\n");
 143                         l.enemy.alpha = 1;
 144                         l.takedamage = DAMAGE_NO;
 145                         l.bot_attack = FALSE;
 146                 }
 147                 else
 148                 {
 149                         dprint(etos(l), " (generator) is not shielded\n");
 150                         l.enemy.alpha = -1;
 151                         l.takedamage = DAMAGE_AIM;
 152                         l.bot_attack = TRUE;
 153                 }
 154                 l = l.chain;
 155         }
 156         // now update the takedamage and alpha variables on control point icons
 157         l = findchain(classname, "onslaught_controlpoint");
 158         while (l)
 159         {
 160                 if (l.isshielded)
 161                 {
 162                         dprint(etos(l), " (point) is shielded\n");
 163                         l.enemy.alpha = 1;
 164                         if (l.goalentity)
 165                         {
 166                                 l.goalentity.takedamage = DAMAGE_NO;
 167                                 l.goalentity.bot_attack = FALSE;
 168                         }
 169                 }
 170                 else
 171                 {
 172                         dprint(etos(l), " (point) is not shielded\n");
 173                         l.enemy.alpha = -1;
 174                         if (l.goalentity)
 175                         {
 176                                 l.goalentity.takedamage = DAMAGE_AIM;
 177                                 l.goalentity.bot_attack = TRUE;
 178                         }
 179                 }
 180                 onslaught_controlpoint_updatesprite(l);
 181                 l = l.chain;
 182         }
 183         // count generators owned by each team
 184         t1 = t2 = t3 = t4 = 0;
 185         l = findchain(classname, "onslaught_generator");
 186         while (l)
 187         {
 188                 if (l.iscaptured)
 189                 {
 190                         if (l.team == COLOR_TEAM1) t1 = 1;
 191                         if (l.team == COLOR_TEAM2) t2 = 1;
 192                         if (l.team == COLOR_TEAM3) t3 = 1;
 193                         if (l.team == COLOR_TEAM4) t4 = 1;
 194                 }
 195                 onslaught_generator_updatesprite(l);
 196                 l = l.chain;
 197         }
 198         // see if multiple teams remain (if not, it's game over)
 199         if (t1 + t2 + t3 + t4 < 2)
 200                 dprint("--- game over ---\n");
 201         else
 202                 dprint("--- done updating links ---\n");
 203 };
 204
 205 float onslaught_controlpoint_can_be_linked(entity cp, float t)
 206 {
 207         if(t == COLOR_TEAM1)
 208         {
 209                 if(cp.isgenneighbor_red)
 210                         return 2;
 211                 if(cp.iscpneighbor_red)
 212                         return 1;
 213         }
 214         else if(t == COLOR_TEAM2)
 215         {
 216                 if(cp.isgenneighbor_blue)
 217                         return 2;
 218                 if(cp.iscpneighbor_blue)
 219                         return 1;
 220         }
 221         return 0;
 222 /*
 223         entity e;
 224         // check to see if this player has a legitimate claim to capture this
 225         // control point - more specifically that there is a captured path of
 226         // points leading back to the team generator
 227         e = findchain(classname, "onslaught_link");
 228         while (e)
 229         {
 230                 if (e.goalentity == cp)
 231                 {
 232                         dprint(etos(e), " (link) connects to ", etos(e.enemy), " (point)");
 233                         if (e.enemy.islinked)
 234                         {
 235                                 dprint(" which is linked");
 236                                 if (e.enemy.team == t)
 237                                 {
 238                                         dprint(" and has the correct team!\n");
 239                                         return 1;
 240                                 }
 241                                 else
 242                                         dprint(" but has the wrong team\n");
 243                         }
 244                         else
 245                                 dprint("\n");
 246                 }
 247                 else if (e.enemy == cp)
 248                 {
 249                         dprint(etos(e), " (link) connects to ", etos(e.goalentity), " (point)");
 250                         if (e.goalentity.islinked)
 251                         {
 252                                 dprint(" which is linked");
 253                                 if (e.goalentity.team == t)
 254                                 {
 255                                         dprint(" and has a team!\n");
 256                                         return 1;
 257                                 }
 258                                 else
 259                                         dprint(" but has the wrong team\n");
 260                         }
 261                         else
 262                                 dprint("\n");
 263                 }
 264                 e = e.chain;
 265         }
 266         return 0;
 267 */
 268 }
 269
 270 float onslaught_controlpoint_attackable(entity cp, float t)
 271 // -2: SAME TEAM, attackable by enemy!
 272 // -1: SAME TEAM!
 273 // 0:  off limits
 274 // 1:  attack it
 275 // 2:  touch it
 276 // 3:  attack it (HIGH PRIO)
 277 // 4:  touch it (HIGH PRIO)
 278 {
 279         float a;
 280
 281         if(cp.isshielded)
 282         {
 283                 return 0;
 284         }
 285         else if(cp.goalentity)
 286         {
 287                 // if there's already an icon built, nothing happens
 288                 if(cp.team == t)
 289                 {
 290                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 291                         if(a) // attackable by enemy?
 292                                 return -2; // EMERGENCY!
 293                         return -1;
 294                 }
 295                 // we know it can be linked, so no need to check
 296                 // but...
 297                 a = onslaught_controlpoint_can_be_linked(cp, t);
 298                 if(a == 2) // near our generator?
 299                         return 3; // EMERGENCY!
 300                 return 1;
 301         }
 302         else
 303         {
 304                 // free point
 305                 if(onslaught_controlpoint_can_be_linked(cp, t))
 306                 {
 307                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 308                         if(a == 2)
 309                                 return 4; // GET THIS ONE NOW!
 310                         else
 311                                 return 2; // TOUCH ME
 312                 }
 313         }
 314         return 0;
 315 }
 316
 317 void onslaught_generator_think()
 318 {
 319         local float d;
 320         local entity e;
 321         self.nextthink = ceil(time + 1);
 322         if (cvar("timelimit"))
 323         if (time > cvar("timelimit") * 60 - 60)
 324         {
 325                 // self.max_health / 300 gives 5 minutes of overtime.
 326                 // control points reduce the overtime duration.
 327                 sound(self, CHAN_TRIGGER, "sound/onslaught/generator_decay.wav", VOL_BASE, ATTN_NORM);
 328                 d = 1;
 329                 e = findchain(classname, "onslaught_controlpoint");
 330                 while (e)
 331                 {
 332                         if (e.team != self.team)
 333                         if (e.islinked)
 334                                 d = d + 1;
 335                         e = e.chain;
 336                 }
 337                 d = d * self.max_health / 300;
 338                 Damage(self, self, self, d, DEATH_HURTTRIGGER, self.origin, '0 0 0');
 339         }
 340 };
 341
 342 void onslaught_generator_deaththink()
 343 {
 344         local vector org;
 345         if (self.count > 0)
 346         {
 347                 self.nextthink = time + 0.1;
 348                 self.count = self.count - 1;
 349                 org = randompos(self.origin + self.mins + '8 8 8', self.origin + self.maxs + '-8 -8 -8');
 350                 pointparticles(particleeffectnum("onslaught_generator_smallexplosion"), org, '0 0 0', 1);
 351                 sound(self, CHAN_TRIGGER, "sound/weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 352         }
 353         else
 354         {
 355                 org = self.origin;
 356                 pointparticles(particleeffectnum("onslaught_generator_finalexplosion"), org, '0 0 0', 1);
 357                 sound(self, CHAN_TRIGGER, "sound/weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 358         }
 359 };
 360
 361 void onslaught_generator_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 362 {
 363         if (damage <= 0)
 364                 return;
 365         if (attacker != self)
 366         {
 367                 if (self.isshielded)
 368                 {
 369                         // this is protected by a shield, so ignore the damage
 370                         if (time > self.pain_finished)
 371                         if (attacker.classname == "player")
 372                         {
 373                                 play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
 374                                 self.pain_finished = time + 1;
 375                         }
 376                         return;
 377                 }
 378                 if (time > self.pain_finished)
 379                 {
 380                         self.pain_finished = time + 5;
 381                         bprint(ColoredTeamName(self.team), " generator under attack!\n");
 382                         play2team(self.team, "sound/onslaught/generator_underattack.wav");
 383                 }
 384         }
 385         self.health = self.health - damage;
 386         // choose an animation frame based on health
 387         self.frame = 10 * bound(0, (1 - self.health / self.max_health), 1);
 388         // see if the generator is still functional, or dying
 389         if (self.health > 0)
 390         {
 391                 float h, lh;
 392                 lh = ceil(self.lasthealth / 100) * 100;
 393                 h = ceil(self.health / 100) * 100;
 394                 if(lh != h)
 395                         bprint(ColoredTeamName(self.team), " generator has less than ", ftos(h), " health remaining\n");
 396                 self.lasthealth = self.health;
 397         }
 398         else
 399         {
 400                 if (attacker == self)
 401                         bprint(ColoredTeamName(self.team), " generator spontaneously exploded due to overtime!\n");
 402                 else
 403                 {
 404                         string t;
 405                         t = ColoredTeamName(attacker.team);
 406                         bprint(ColoredTeamName(self.team), " generator destroyed by ", t, "!\n");
 407                 }
 408                 self.iscaptured = FALSE;
 409                 self.islinked = FALSE;
 410                 self.isshielded = FALSE;
 411                 self.takedamage = DAMAGE_NO; // can't be hurt anymore
 412                 self.event_damage = SUB_Null; // won't do anything if hurt
 413                 self.count = 30; // 30 explosions
 414                 self.think = onslaught_generator_deaththink; // explosion sequence
 415                 self.nextthink = time; // start exploding immediately
 416                 self.think(); // do the first explosion now
 417                 onslaught_updatelinks();
 418         }
 419 };
 420
 421 // update links after a delay
 422 void onslaught_generator_delayed()
 423 {
 424         onslaught_updatelinks();
 425         // now begin normal thinking
 426         self.think = onslaught_generator_think;
 427         self.nextthink = time;
 428 };
 429
 430 string onslaught_generator_waypointsprite_for_team(entity e, float t)
 431 {
 432         if(t == e.team)
 433         {
 434                 if(e.team == COLOR_TEAM1)
 435                         return "ons-gen-red";
 436                 else if(e.team == COLOR_TEAM2)
 437                         return "ons-gen-blue";
 438         }
 439         if(e.isshielded)
 440                 return "ons-gen-shielded";
 441         if(e.team == COLOR_TEAM1)
 442                 return "ons-gen-red";
 443         else if(e.team == COLOR_TEAM2)
 444                 return "ons-gen-blue";
 445         return "";
 446 }
 447
 448 void onslaught_generator_updatesprite(entity e)
 449 {
 450         string s1, s2, s3;
 451         s1 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM1);
 452         s2 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM2);
 453         s3 = onslaught_generator_waypointsprite_for_team(e, -1);
 454         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 455
 456         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 457         {
 458                 e.lastteam = e.team + 2;
 459                 e.lastshielded = e.isshielded;
 460                 if(e.lastshielded)
 461                 {
 462                         if(e.team == COLOR_TEAM1)
 463                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0 0');
 464                         else if(e.team == COLOR_TEAM2)
 465                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0 0 0.5');
 466                         else
 467                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 468                 }
 469                 else
 470                 {
 471                         if(e.team == COLOR_TEAM1)
 472                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '1 0 0');
 473                         else if(e.team == COLOR_TEAM2)
 474                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0 0 1');
 475                         else
 476                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 477                 }
 478                 WaypointSprite_Ping(e.sprite);
 479         }
 480 }
 481
 482 string onslaught_controlpoint_waypointsprite_for_team(entity e, float t)
 483 {
 484         float a;
 485         if(t != -1)
 486         {
 487                 a = onslaught_controlpoint_attackable(e, t);
 488                 if(a == 3 || a == 4) // ATTACK/TOUCH THIS ONE NOW
 489                 {
 490                         if(e.team == COLOR_TEAM1)
 491                                 return "ons-cp-atck-red";
 492                         else if(e.team == COLOR_TEAM2)
 493                                 return "ons-cp-atck-blue";
 494                         else
 495                                 return "ons-cp-atck-neut";
 496                 }
 497                 else if(a == -2) // DEFEND THIS ONE NOW
 498                 {
 499                         if(e.team == COLOR_TEAM1)
 500                                 return "ons-cp-dfnd-red";
 501                         else if(e.team == COLOR_TEAM2)
 502                                 return "ons-cp-dfnd-blue";
 503                 }
 504                 else if(e.team == t || a == -1 || a == 1) // own point, or fire at it
 505                 {
 506                         if(e.team == COLOR_TEAM1)
 507                                 return "ons-cp-red";
 508                         else if(e.team == COLOR_TEAM2)
 509                                 return "ons-cp-blue";
 510                 }
 511                 else if(a == 2) // touch it
 512                         return "ons-cp-neut";
 513         }
 514         else
 515         {
 516                 if(e.team == COLOR_TEAM1)
 517                         return "ons-cp-red";
 518                 else if(e.team == COLOR_TEAM2)
 519                         return "ons-cp-blue";
 520                 else
 521                         return "ons-cp-neut";
 522         }
 523         return "";
 524 }
 525
 526 void onslaught_controlpoint_updatesprite(entity e)
 527 {
 528         string s1, s2, s3;
 529         s1 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM1);
 530         s2 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM2);
 531         s3 = onslaught_controlpoint_waypointsprite_for_team(e, -1);
 532         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 533
 534         float sh;
 535         sh = !(onslaught_controlpoint_can_be_linked(e, COLOR_TEAM1) || onslaught_controlpoint_can_be_linked(e, COLOR_TEAM2));
 536
 537         if(e.lastteam != e.team + 2 || e.lastshielded != sh)
 538         {
 539                 e.lastteam = e.team + 2;
 540                 e.lastshielded = sh;
 541                 if(e.lastshielded)
 542                 {
 543                         if(e.team == COLOR_TEAM1)
 544                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0 0');
 545                         else if(e.team == COLOR_TEAM2)
 546                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0 0 0.5');
 547                         else
 548                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 549                 }
 550                 else
 551                 {
 552                         if(e.team == COLOR_TEAM1)
 553                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '1 0 0');
 554                         else if(e.team == COLOR_TEAM2)
 555                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0 0 1');
 556                         else
 557                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 558                 }
 559                 WaypointSprite_Ping(e.sprite);
 560         }
 561 }
 562
 563 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
 564 Base generator.
 565
 566 spawnfunc_onslaught_link entities can target this.
 567
 568 keys:
 569 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
 570 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
 571 */
 572 void spawnfunc_onslaught_generator()
 573 {
 574         if (!g_onslaught)
 575         {
 576                 remove(self);
 577                 return;
 578         }
 579
 580         local entity e;
 581         precache_model("models/onslaught/generator.md3");
 582         precache_model("models/onslaught/generator_shield.md3");
 583         precache_sound("sound/onslaught/generator_decay.wav");
 584         precache_sound("sound/weapons/grenade_impact.wav");
 585         precache_sound("sound/weapons/rocket_impact.wav");
 586         precache_sound("sound/onslaught/generator_underattack.wav");
 587         if (!self.team)
 588                 objerror("team must be set");
 589         self.team_saved = self.team;
 590         self.colormap = 1024 + (self.team - 1) * 17;
 591         self.solid = SOLID_BSP;
 592         self.movetype = MOVETYPE_NONE;
 593         self.lasthealth = self.max_health = self.health = cvar("g_onslaught_gen_health");
 594         setmodel(self, "models/onslaught/generator.md3");
 595         //setsize(self, '-32 -32 -24', '32 32 64');
 596         setorigin(self, self.origin);
 597         self.takedamage = DAMAGE_AIM;
 598         self.bot_attack = TRUE;
 599         self.event_damage = onslaught_generator_damage;
 600         self.iscaptured = TRUE;
 601         self.islinked = TRUE;
 602         self.isshielded = TRUE;
 603         // spawn shield model which indicates whether this can be damaged
 604         self.enemy = e = spawn();
 605         e.classname = "onslaught_generator_shield";
 606         e.solid = SOLID_NOT;
 607         e.movetype = MOVETYPE_NONE;
 608         e.effects = EF_ADDITIVE;
 609         setmodel(e, "models/onslaught/generator_shield.md3");
 610         //setsize(e, '-32 -32 0', '32 32 128');
 611         setorigin(e, self.origin);
 612         e.colormap = self.colormap;
 613         e.team = self.team;
 614         self.think = onslaught_generator_delayed;
 615         self.nextthink = time + 0.2;
 616
 617         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite);
 618         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
 619
 620         onslaught_updatelinks();
 621 };
 622
 623 void onslaught_generator_reset()
 624 {
 625         self.team = self.team_saved;
 626         self.lasthealth = self.max_health = self.health = cvar("g_onslaught_gen_health");
 627         self.takedamage = DAMAGE_AIM;
 628         self.bot_attack = TRUE;
 629         self.iscaptured = TRUE;
 630         self.islinked = TRUE;
 631         self.isshielded = TRUE;
 632         self.enemy.solid = SOLID_NOT;
 633         self.think = onslaught_generator_delayed;
 634         self.nextthink = time + 0.2;
 635 }
 636
 637 void onslaught_controlpoint_icon_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 638 {
 639         entity oself;
 640         if (damage <= 0)
 641                 return;
 642         if (self.owner.isshielded)
 643         {
 644                 // this is protected by a shield, so ignore the damage
 645                 if (time > self.pain_finished)
 646                 if (attacker.classname == "player")
 647                 {
 648                         play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
 649                         self.pain_finished = time + 1;
 650                 }
 651                 return;
 652         }
 653         if (time > self.pain_finished)
 654         if (attacker.classname == "player")
 655         {
 656                 play2team(self.team, "sound/onslaught/controlpoint_underattack.wav");
 657                 self.pain_finished = time + 5;
 658         }
 659         self.health = self.health - damage;
 660         self.alpha = self.health / self.max_health;
 661         self.pain_finished = time + 1;
 662         // colormod flash when shot
 663         self.colormod = '2 2 2';
 664         if (self.health < 0)
 665         {
 666                 sound(self, CHAN_TRIGGER, "sound/weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 667                 pointparticles(particleeffectnum("onslaught_controlpoint_explosion"), self.origin, '0 0 0', 1);
 668                 {
 669                         string t;
 670                         t = ColoredTeamName(attacker.team);
 671                         bprint(ColoredTeamName(self.team), " ", self.message, " control point destroyed by ", t, "\n");
 672                 }
 673                 self.owner.goalentity = world;
 674                 self.owner.islinked = FALSE;
 675                 self.owner.iscaptured = FALSE;
 676                 self.owner.team = 0;
 677                 self.owner.colormap = 1024;
 678                 onslaught_updatelinks();
 679
 680                 // Use targets now (somebody make sure this is in the right place..)
 681                 oself = self;
 682                 self = self.owner;
 683                 activator = self.owner;
 684                 SUB_UseTargets ();
 685                 self = oself;
 686
 687                 remove(self);
 688         }
 689 };
 690
 691 void onslaught_controlpoint_icon_think()
 692 {
 693         self.nextthink = time + 0.1;
 694         if (time > self.pain_finished + 1)
 695         {
 696                 self.health = self.health + self.count;
 697                 if (self.health >= self.max_health)
 698                         self.health = self.max_health;
 699         }
 700         self.alpha = self.health / self.max_health;
 701         // colormod flash when shot
 702         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
 703 };
 704
 705 void onslaught_controlpoint_icon_buildthink()
 706 {
 707         local entity oself;
 708
 709         self.nextthink = time + 0.1;
 710         self.health = self.health + self.count;
 711         if (self.health >= self.max_health)
 712         {
 713                 self.health = self.max_health;
 714                 self.count = self.count * 0.2; // slow repair rate from now on
 715                 self.think = onslaught_controlpoint_icon_think;
 716                 sound(self, CHAN_TRIGGER, "sound/onslaught/controlpoint_built.wav", VOL_BASE, ATTN_NORM);
 717                 bprint(ColoredTeamName(self.team), " captured ", self.owner.message, " control point\n");
 718                 self.owner.iscaptured = TRUE;
 719                 onslaught_updatelinks();
 720
 721                 // Use targets now (somebody make sure this is in the right place..)
 722                 oself = self;
 723                 self = self.owner;
 724                 activator = self;
 725                 SUB_UseTargets ();
 726                 self = oself;
 727         }
 728         self.alpha = self.health / self.max_health;
 729         // colormod flash when shot
 730         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
 731 };
 732
 733 void onslaught_controlpoint_touch()
 734 {
 735         local entity e;
 736         float a;
 737         if (other.classname != "player")
 738                 return;
 739         a = onslaught_controlpoint_attackable(self, other.team);
 740         if(a != 2 && a != 4)
 741                 return;
 742         // we've verified that this player has a legitimate claim to this point,
 743         // so start building the captured point icon (which only captures this
 744         // point if it successfully builds without being destroyed first)
 745         self.goalentity = e = spawn();
 746         e.classname = "onslaught_controlpoint_icon";
 747         e.owner = self;
 748         e.max_health = cvar("g_onslaught_cp_health");
 749         e.health = e.max_health * 0.1;
 750         e.alpha = e.health / e.max_health;
 751         e.solid = SOLID_BBOX;
 752         e.movetype = MOVETYPE_NONE;
 753         setmodel(e, "models/onslaught/controlpoint_icon.md3");
 754         setsize(e, '-32 -32 -32', '32 32 32');
 755         setorigin(e, self.origin + '0 0 96');
 756         e.takedamage = DAMAGE_AIM;
 757         e.bot_attack = TRUE;
 758         e.event_damage = onslaught_controlpoint_icon_damage;
 759         e.team = other.team;
 760         e.colormap = 1024 + (e.team - 1) * 17;
 761         e.think = onslaught_controlpoint_icon_buildthink;
 762         e.nextthink = time + 0.1;
 763         e.count = e.max_health / 50; // how long it takes to build
 764         sound(e, CHAN_TRIGGER, "sound/onslaught/controlpoint_build.wav", VOL_BASE, ATTN_NORM);
 765         self.team = e.team;
 766         self.colormap = e.colormap;
 767 };
 768
 769 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
 770 Control point.  Be sure to give this enough clearance so that the shootable part has room to exist
 771
 772 This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
 773
 774 keys:
 775 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
 776 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
 777 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
 778 */
 779 void spawnfunc_onslaught_controlpoint()
 780 {
 781         local entity e;
 782         if (!g_onslaught)
 783         {
 784                 remove(self);
 785                 return;
 786         }
 787         precache_model("models/onslaught/controlpoint_pad.md3");
 788         precache_model("models/onslaught/controlpoint_shield.md3");
 789         precache_model("models/onslaught/controlpoint_icon.md3");
 790         precache_sound("sound/onslaught/controlpoint_build.wav");
 791         precache_sound("sound/onslaught/controlpoint_built.wav");
 792         precache_sound("sound/weapons/grenade_impact.wav");
 793         precache_sound("sound/onslaught/damageblockedbyshield.wav");
 794         precache_sound("sound/onslaught/controlpoint_underattack.wav");
 795         self.solid = SOLID_BSP;
 796         self.movetype = MOVETYPE_NONE;
 797         setmodel(self, "models/onslaught/controlpoint_pad.md3");
 798         //setsize(self, '-32 -32 0', '32 32 8');
 799         setorigin(self, self.origin);
 800         self.touch = onslaught_controlpoint_touch;
 801         self.team = 0;
 802         self.colormap = 1024;
 803         self.iscaptured = FALSE;
 804         self.islinked = FALSE;
 805         self.isshielded = TRUE;
 806         // spawn shield model which indicates whether this can be damaged
 807         self.enemy = e = spawn();
 808         e.classname = "onslaught_controlpoint_shield";
 809         e.solid = SOLID_NOT;
 810         e.movetype = MOVETYPE_NONE;
 811         e.effects = EF_ADDITIVE;
 812         setmodel(e, "models/onslaught/controlpoint_shield.md3");
 813         //setsize(e, '-32 -32 0', '32 32 128');
 814         setorigin(e, self.origin);
 815         e.colormap = self.colormap;
 816
 817         waypoint_spawnforitem(self);
 818
 819         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite);
 820         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
 821
 822         onslaught_updatelinks();
 823 };
 824
 825 void onslaught_controlpoint_reset()
 826 {
 827         if(self.goalentity && self.goalentity != world)
 828                 remove(self.goalentity);
 829         self.goalentity = world;
 830         self.team = 0;
 831         self.colormap = 1024;
 832         self.iscaptured = FALSE;
 833         self.islinked = FALSE;
 834         self.isshielded = TRUE;
 835         self.enemy.solid = SOLID_NOT;
 836         self.enemy.colormap = self.colormap;
 837         self.think = self.enemy.think = SUB_Null;
 838         self.nextthink = 0; // don't like SUB_Null :P
 839
 840         onslaught_updatelinks();
 841
 842         activator = self;
 843         SUB_UseTargets(); // to reset the structures, playerspawns etc.
 844 }
 845
 846 float onslaught_link_send(entity to, float sendflags)
 847 {
 848         WriteByte(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 849         WriteByte(MSG_ENTITY, sendflags);
 850         if(sendflags & 1)
 851         {
 852                 WriteCoord(MSG_ENTITY, self.goalentity.origin_x);
 853                 WriteCoord(MSG_ENTITY, self.goalentity.origin_y);
 854                 WriteCoord(MSG_ENTITY, self.goalentity.origin_z);
 855         }
 856         if(sendflags & 2)
 857         {
 858                 WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 859                 WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 860                 WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 861         }
 862         if(sendflags & 4)
 863         {
 864                 WriteByte(MSG_ENTITY, self.clientcolors); // which is goalentity's color + enemy's color * 16
 865         }
 866         return TRUE;
 867 }
 868
 869 void onslaught_link_checkupdate()
 870 {
 871         // TODO check if the two sides have moved (currently they won't move anyway)
 872         float redpower, bluepower;
 873
 874         redpower = bluepower = 0;
 875         if(self.goalentity.islinked)
 876         {
 877                 if(self.goalentity.team == COLOR_TEAM1)
 878                         redpower = 1;
 879                 else if(self.goalentity.team == COLOR_TEAM2)
 880                         bluepower = 1;
 881         }
 882         if(self.enemy.islinked)
 883         {
 884                 if(self.enemy.team == COLOR_TEAM1)
 885                         redpower = 2;
 886                 else if(self.enemy.team == COLOR_TEAM2)
 887                         bluepower = 2;
 888         }
 889
 890         float cc;
 891         if(redpower == 1 && bluepower == 2)
 892                 cc = (COLOR_TEAM1 - 1) * 0x01 + (COLOR_TEAM2 - 1) * 0x10;
 893         else if(redpower == 2 && bluepower == 1)
 894                 cc = (COLOR_TEAM1 - 1) * 0x10 + (COLOR_TEAM2 - 1) * 0x01;
 895         else if(redpower)
 896                 cc = (COLOR_TEAM1 - 1) * 0x11;
 897         else if(bluepower)
 898                 cc = (COLOR_TEAM2 - 1) * 0x11;
 899         else
 900                 cc = 0;
 901
 902         if(cc != self.clientcolors)
 903         {
 904                 self.clientcolors = cc;
 905                 self.SendFlags |= 4;
 906         }
 907
 908         self.nextthink = time;
 909 }
 910
 911 void onslaught_link_delayed()
 912 {
 913         self.goalentity = find(world, targetname, self.target);
 914         self.enemy = find(world, targetname, self.target2);
 915         if (!self.goalentity)
 916                 objerror("can not find target\n");
 917         if (!self.enemy)
 918                 objerror("can not find target2\n");
 919         dprint(etos(self.goalentity), " linked with ", etos(self.enemy), "\n");
 920
 921         self.SendFlags |= 3;
 922         self.think = onslaught_link_checkupdate;
 923         self.nextthink = time;
 924 }
 925
 926 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
 927 Link between control points.
 928
 929 This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
 930
 931 keys:
 932 "target" - first control point.
 933 "target2" - second control point.
 934 */
 935 void spawnfunc_onslaught_link()
 936 {
 937         if (!g_onslaught)
 938         {
 939                 remove(self);
 940                 return;
 941         }
 942         if (self.target == "" || self.target2 == "")
 943                 objerror("target and target2 must be set\n");
 944         self.think = onslaught_link_delayed;
 945         self.nextthink = time + 0.1;
 946         self.SendEntity = onslaught_link_send;
 947         Net_LinkEntity(self);
 948 };