data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p;
 399         float n;
 400         string msg_save;
 401         string escape;
 402         string replacement;
 403         msg_save = strzone(msg);
 404         p = 0;
 405         n = 7;
 406         while(1)
 407         {
 408                 if(n < 1)
 409                         break; // too many replacements
 410                 n = n - 1;
 411                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 if(p < 0)
 413                         break;
 414                 replacement = substring(msg_save, p, 2);
 415                 escape = substring(msg_save, p + 1, 1);
 416                 if(escape == "%")
 417                         replacement = "%";
 418                 else if(escape == "a")
 419                         replacement = ftos(floor(self.armorvalue));
 420                 else if(escape == "h")
 421                         replacement = ftos(floor(self.health));
 422                 else if(escape == "l")
 423                         replacement = NearestLocation(self.origin);
 424                 else if(escape == "y")
 425                         replacement = NearestLocation(self.cursor_trace_endpos);
 426                 else if(escape == "d")
 427                         replacement = NearestLocation(self.death_origin);
 428                 else if(escape == "w")
 429                 {
 430                         float wep;
 431                         wep = self.weapon;
 432                         if(!wep)
 433                                 wep = self.switchweapon;
 434                         if(!wep)
 435                                 wep = self.cnt;
 436                         replacement = W_Name(wep);
 437                 }
 438                 else if(escape == "W")
 439                 {
 440                         if(self.items & IT_SHELLS) replacement = "shells";
 441                         else if(self.items & IT_NAILS) replacement = "bullets";
 442                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 443                         else if(self.items & IT_CELLS) replacement = "cells";
 444                         else replacement = "batteries"; // ;)
 445                 }
 446                 else if(escape == "x")
 447                 {
 448                         replacement = self.cursor_trace_ent.netname;
 449                         if(!replacement || !self.cursor_trace_ent)
 450                                 replacement = "nothing";
 451                 }
 452                 else if(escape == "p")
 453                 {
 454                         if(self.last_selected_player)
 455                                 replacement = self.last_selected_player.netname;
 456                         else
 457                                 replacement = "(nobody)";
 458                 }
 459                 msg = strcat(substring(msg_save, 0, p), replacement);
 460                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 461                 strunzone(msg_save);
 462                 msg_save = strzone(msg);
 463                 p = p + 2;
 464         }
 465         msg = strcat(msg_save, "");
 466         strunzone(msg_save);
 467         return msg;
 468 }
 469
 470 /*
 471 =============
 472 GetCvars
 473 =============
 474 Called with:
 475   0:  sends the request
 476   >0: receives a cvar from name=argv(f) value=argv(f+1)
 477 */
 478 void GetCvars_handleString(string thisname, float f, .string field, string name)
 479 {
 480         if(f < 0)
 481         {
 482                 if(self.field)
 483                         strunzone(self.field);
 484                 self.field = string_null;
 485         }
 486         else if(f > 0)
 487         {
 488                 if(thisname == name)
 489                 {
 490                         if(self.field)
 491                                 strunzone(self.field);
 492                         self.field = strzone(argv(f + 1));
 493                 }
 494         }
 495         else
 496                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 497 }
 498 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 499 {
 500         GetCvars_handleString(thisname, f, field, name);
 501         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 502         if(thisname == name)
 503         {
 504                 string s;
 505                 s = func(strcat1(self.field));
 506                 if(s != self.field)
 507                 {
 508                         strunzone(self.field);
 509                         self.field = strzone(s);
 510                 }
 511         }
 512 }
 513 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 514 {
 515         if(f < 0)
 516         {
 517         }
 518         else if(f > 0)
 519         {
 520                 if(thisname == name)
 521                         self.field = stof(argv(f + 1));
 522         }
 523         else
 524                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 525 }
 526 string W_FixWeaponOrder_ForceComplete(string s);
 527 string W_FixWeaponOrder_AllowIncomplete(string s);
 528 float w_getbestweapon(entity e);
 529 void GetCvars(float f)
 530 {
 531         string s;
 532         if(f > 0)
 533                 s = strcat1(argv(f));
 534         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 535         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 536         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 537         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 538         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 539         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 540         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 541         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 552         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 553         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 554         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 555
 556         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 557         if(f > 0)
 558         {
 559                 if(s == "cl_weaponpriority")
 560                         self.switchweapon = w_getbestweapon(self);
 561         }
 562 }
 563
 564 float fexists(string f)
 565 {
 566         float fh;
 567         fh = fopen(f, FILE_READ);
 568         if(fh < 0)
 569                 return FALSE;
 570         fclose(fh);
 571         return TRUE;
 572 }
 573
 574 void backtrace(string msg)
 575 {
 576         float dev;
 577         dev = cvar("developer");
 578         cvar_set("developer", "1");
 579         dprint("\n");
 580         dprint("--- CUT HERE ---\nWARNING: ");
 581         dprint(msg);
 582         dprint("\n");
 583         remove(world); // isn't there any better way to cause a backtrace?
 584         dprint("\n--- CUT UNTIL HERE ---\n");
 585         cvar_set("developer", ftos(dev));
 586 }
 587
 588 string Team_ColorCode(float teamid)
 589 {
 590         if(teamid == COLOR_TEAM1)
 591                 return "^1";
 592         else if(teamid == COLOR_TEAM2)
 593                 return "^4";
 594         else if(teamid == COLOR_TEAM3)
 595                 return "^3";
 596         else if(teamid == COLOR_TEAM4)
 597                 return "^6";
 598         else
 599                 return "^7";
 600 }
 601 string Team_ColorName(float t)
 602 {
 603         // fixme: Search for team entities and get their .netname's!
 604         if(t == COLOR_TEAM1)
 605                 return "Red";
 606         if(t == COLOR_TEAM2)
 607                 return "Blue";
 608         if(t == COLOR_TEAM3)
 609                 return "Yellow";
 610         if(t == COLOR_TEAM4)
 611                 return "Pink";
 612         return "Neutral";
 613 }
 614 string Team_ColorNameLowerCase(float t)
 615 {
 616         // fixme: Search for team entities and get their .netname's!
 617         if(t == COLOR_TEAM1)
 618                 return "red";
 619         if(t == COLOR_TEAM2)
 620                 return "blue";
 621         if(t == COLOR_TEAM3)
 622                 return "yellow";
 623         if(t == COLOR_TEAM4)
 624                 return "pink";
 625         return "neutral";
 626 }
 627
 628 #define CENTERPRIO_POINT 1
 629 #define CENTERPRIO_SPAM 2
 630 #define CENTERPRIO_VOTE 4
 631 #define CENTERPRIO_NORMAL 5
 632 #define CENTERPRIO_SHIELDING 7
 633 #define CENTERPRIO_MAPVOTE 9
 634 #define CENTERPRIO_IDLEKICK 50
 635 #define CENTERPRIO_ADMIN 99
 636 .float centerprint_priority;
 637 .float centerprint_expires;
 638 void centerprint_atprio(entity e, float prio, string s)
 639 {
 640         if(intermission_running)
 641                 if(prio < CENTERPRIO_MAPVOTE)
 642                         return;
 643         if(time > e.centerprint_expires)
 644                 e.centerprint_priority = 0;
 645         if(prio >= e.centerprint_priority)
 646         {
 647                 e.centerprint_priority = prio;
 648                 if(timeoutStatus == 2)
 649                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 650                 else
 651                         e.centerprint_expires = time + e.cvar_scr_centertime;
 652                 centerprint_builtin(e, s);
 653         }
 654 }
 655 void centerprint_expire(entity e, float prio)
 656 {
 657         if(prio == e.centerprint_priority)
 658         {
 659                 e.centerprint_priority = 0;
 660                 centerprint_builtin(e, "");
 661         }
 662 }
 663 void centerprint(entity e, string s)
 664 {
 665         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 666 }
 667
 668 // decolorizes and team colors the player name when needed
 669 string playername(entity p)
 670 {
 671         string t;
 672         if(teams_matter && !intermission_running && p.classname == "player")
 673         {
 674                 t = Team_ColorCode(p.team);
 675                 return strcat(t, strdecolorize(p.netname));
 676         }
 677         else
 678                 return p.netname;
 679 }
 680
 681 vector randompos(vector m1, vector m2)
 682 {
 683         local vector v;
 684         m2 = m2 - m1;
 685         v_x = m2_x * random() + m1_x;
 686         v_y = m2_y * random() + m1_y;
 687         v_z = m2_z * random() + m1_z;
 688         return  v;
 689 };
 690
 691 float g_pickup_shells;
 692 float g_pickup_shells_max;
 693 float g_pickup_nails;
 694 float g_pickup_nails_max;
 695 float g_pickup_rockets;
 696 float g_pickup_rockets_max;
 697 float g_pickup_cells;
 698 float g_pickup_cells_max;
 699 float g_pickup_armorsmall;
 700 float g_pickup_armorsmall_max;
 701 float g_pickup_armormedium;
 702 float g_pickup_armormedium_max;
 703 float g_pickup_armorlarge;
 704 float g_pickup_armorlarge_max;
 705 float g_pickup_healthsmall;
 706 float g_pickup_healthsmall_max;
 707 float g_pickup_healthmedium;
 708 float g_pickup_healthmedium_max;
 709 float g_pickup_healthlarge;
 710 float g_pickup_healthlarge_max;
 711 float g_pickup_healthmega;
 712 float g_pickup_healthmega_max;
 713 float g_weaponarena;
 714 string g_weaponarena_list;
 715
 716 float start_weapons;
 717 float start_items;
 718 float start_ammo_shells;
 719 float start_ammo_nails;
 720 float start_ammo_rockets;
 721 float start_ammo_cells;
 722 float start_health;
 723 float start_armorvalue;
 724 float warmup_start_weapons;
 725 float warmup_start_ammo_shells;
 726 float warmup_start_ammo_nails;
 727 float warmup_start_ammo_rockets;
 728 float warmup_start_ammo_cells;
 729 float warmup_start_health;
 730 float warmup_start_armorvalue;
 731 float g_weapon_stay;
 732
 733 entity get_weaponinfo(float w);
 734
 735 void readplayerstartcvars()
 736 {
 737         entity e;
 738         float i, j, t;
 739         string s;
 740
 741         // initialize starting values for players
 742         start_weapons = 0;
 743         start_items = 0;
 744         start_ammo_shells = 0;
 745         start_ammo_nails = 0;
 746         start_ammo_rockets = 0;
 747         start_ammo_cells = 0;
 748         start_health = cvar("g_balance_health_start");
 749         start_armorvalue = cvar("g_balance_armor_start");
 750
 751         g_weaponarena = 0;
 752         s = cvar_string("g_weaponarena");
 753         if(s == "0")
 754         {
 755         }
 756         else if(s == "all")
 757         {
 758                 g_weaponarena_list = "All Weapons";
 759                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 760                 {
 761                         e = get_weaponinfo(j);
 762                         g_weaponarena |= e.weapons;
 763                         weapon_action(e.weapon, WR_PRECACHE);
 764                 }
 765         }
 766         else if(s == "most")
 767         {
 768                 g_weaponarena_list = "Most Weapons";
 769                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 773                         {
 774                                 g_weaponarena |= e.weapons;
 775                                 weapon_action(e.weapon, WR_PRECACHE);
 776                         }
 777                 }
 778         }
 779         else
 780         {
 781                 t = tokenize_sane(s);
 782                 g_weaponarena_list = "";
 783                 for(i = 0; i < t; ++i)
 784                 {
 785                         s = argv(i);
 786                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 787                         {
 788                                 e = get_weaponinfo(j);
 789                                 if(e.netname == s)
 790                                 {
 791                                         g_weaponarena |= e.weapons;
 792                                         weapon_action(e.weapon, WR_PRECACHE);
 793                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 794                                         break;
 795                                 }
 796                         }
 797                         if(j > WEP_LAST)
 798                         {
 799                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 800                         }
 801                 }
 802                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 803         }
 804
 805         if(g_weaponarena)
 806         {
 807                 start_weapons = g_weaponarena;
 808                 start_ammo_rockets = 999;
 809                 start_ammo_shells = 999;
 810                 start_ammo_cells = 999;
 811                 start_ammo_nails = 999;
 812                 start_items |= IT_UNLIMITED_AMMO;
 813         }
 814         else if(g_nixnex)
 815         {
 816                 start_weapons = 0;
 817                 // will be done later
 818                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 819                 {
 820                         e = get_weaponinfo(i);
 821                         if(!(e.weapon))
 822                                 continue;
 823                         weapon_action(e.weapon, WR_PRECACHE);
 824                 }
 825         }
 826         else if(g_minstagib)
 827         {
 828                 start_health = 100;
 829                 start_armorvalue = 0;
 830                 start_weapons = WEPBIT_MINSTANEX;
 831                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 832                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 833                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 834         }
 835         else
 836         {
 837                 if(g_lms)
 838                 {
 839                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 840                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 841                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 842                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 843                         start_health = cvar("g_lms_start_health");
 844                         start_armorvalue = cvar("g_lms_start_armor");
 845                 } else if (cvar("g_use_ammunition")) {
 846                         start_ammo_shells = cvar("g_start_ammo_shells");
 847                         start_ammo_nails = cvar("g_start_ammo_nails");
 848                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 849                         start_ammo_cells = cvar("g_start_ammo_cells");
 850                 } else {
 851                         start_ammo_shells = cvar("g_pickup_shells_max");
 852                         start_ammo_nails = cvar("g_pickup_nails_max");
 853                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 854                         start_ammo_cells = cvar("g_pickup_cells_max");
 855                         start_items |= IT_UNLIMITED_AMMO;
 856                 }
 857
 858                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 859                 {
 860                         e = get_weaponinfo(i);
 861                         if(!(e.weapon))
 862                                 continue;
 863                         if(((e.spawnflags & WEPSPAWNFLAG_NORMAL) && g_lms) || cvar(strcat("g_start_weapon_", e.netname)))
 864                         {
 865                                 start_weapons |= e.weapons;
 866                                 weapon_action(e.weapon, WR_PRECACHE);
 867                         }
 868                 }
 869         }
 870
 871         if(inWarmupStage)
 872         {
 873                 warmup_start_ammo_shells = start_ammo_shells;
 874                 warmup_start_ammo_nails = start_ammo_nails;
 875                 warmup_start_ammo_rockets = start_ammo_rockets;
 876                 warmup_start_ammo_cells = start_ammo_cells;
 877                 warmup_start_health = start_health;
 878                 warmup_start_armorvalue = start_armorvalue;
 879                 warmup_start_weapons = start_weapons;
 880
 881                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 882                 {
 883                         if(cvar("g_use_ammunition"))
 884                         {
 885                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 886                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 887                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 888                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 889                         }
 890                         warmup_start_health = cvar("g_warmup_start_health");
 891                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 892                         if(cvar("g_warmup_allguns"))
 893                         {
 894                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 895                                 {
 896                                         e = get_weaponinfo(i);
 897                                         if(!(e.weapon))
 898                                                 continue;
 899                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 900                                         {
 901                                                 warmup_start_weapons |= e.weapons;
 902                                                 weapon_action(e.weapon, WR_PRECACHE);
 903                                         }
 904                                 }
 905                         }
 906                 }
 907         }
 908
 909         if(g_grappling_hook) // offhand hook
 910         {
 911                 start_weapons &~= WEPBIT_HOOK;
 912                 warmup_start_weapons &~= WEPBIT_HOOK;
 913         }
 914
 915         if(g_weapon_stay == 2)
 916         {
 917                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 918                 if(!start_ammo_nails) start_ammo_shells = g_pickup_nails;
 919                 if(!start_ammo_cells) start_ammo_shells = g_pickup_cells;
 920                 if(!start_ammo_rockets) start_ammo_shells = g_pickup_rockets;
 921                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 922                 if(!warmup_start_ammo_nails) warmup_start_ammo_shells = g_pickup_nails;
 923                 if(!warmup_start_ammo_cells) warmup_start_ammo_shells = g_pickup_cells;
 924                 if(!warmup_start_ammo_rockets) warmup_start_ammo_shells = g_pickup_rockets;
 925         }
 926
 927         start_ammo_shells = max(0, start_ammo_shells);
 928         start_ammo_nails = max(0, start_ammo_nails);
 929         start_ammo_cells = max(0, start_ammo_cells);
 930         start_ammo_rockets = max(0, start_ammo_rockets);
 931
 932         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 933         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 934         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 935         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 936 }
 937
 938 float g_bugrigs;
 939 float g_bugrigs_planar_movement;
 940 float g_bugrigs_planar_movement_car_jumping;
 941 float g_bugrigs_reverse_spinning;
 942 float g_bugrigs_reverse_speeding;
 943 float g_bugrigs_reverse_stopping;
 944 float g_bugrigs_air_steering;
 945 float g_bugrigs_angle_smoothing;
 946 float g_bugrigs_friction_floor;
 947 float g_bugrigs_friction_brake;
 948 float g_bugrigs_friction_air;
 949 float g_bugrigs_accel;
 950 float g_bugrigs_speed_ref;
 951 float g_bugrigs_speed_pow;
 952 float g_bugrigs_steer;
 953
 954 float g_touchexplode;
 955 float g_touchexplode_radius;
 956 float g_touchexplode_damage;
 957 float g_touchexplode_edgedamage;
 958 float g_touchexplode_force;
 959
 960 void readlevelcvars(void)
 961 {
 962         g_bugrigs = cvar("g_bugrigs");
 963         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 964         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 965         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 966         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 967         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 968         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 969         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 970         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 971         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 972         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 973         g_bugrigs_accel = cvar("g_bugrigs_accel");
 974         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 975         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 976         g_bugrigs_steer = cvar("g_bugrigs_steer");
 977
 978         g_touchexplode = cvar("g_touchexplode");
 979         g_touchexplode_radius = cvar("g_touchexplode_radius");
 980         g_touchexplode_damage = cvar("g_touchexplode_damage");
 981         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
 982         g_touchexplode_force = cvar("g_touchexplode_force");
 983
 984         sv_clones = cvar("sv_clones");
 985         sv_cheats = cvar("sv_cheats");
 986         sv_gentle = cvar("sv_gentle");
 987         sv_foginterval = cvar("sv_foginterval");
 988         g_cloaked = cvar("g_cloaked");
 989         g_jump_grunt = cvar("g_jump_grunt");
 990         g_footsteps = cvar("g_footsteps");
 991         g_grappling_hook = cvar("g_grappling_hook");
 992         g_laserguided_missile = cvar("g_laserguided_missile");
 993         g_midair = cvar("g_midair");
 994         g_minstagib = cvar("g_minstagib");
 995         g_nixnex = cvar("g_nixnex");
 996         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 997         g_norecoil = cvar("g_norecoil");
 998         g_vampire = cvar("g_vampire");
 999         sv_maxidle = cvar("sv_maxidle");
1000         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1001         sv_pogostick = cvar("sv_pogostick");
1002         sv_doublejump = cvar("sv_doublejump");
1003         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1004         g_ctf_reverse = cvar("g_ctf_reverse");
1005
1006         inWarmupStage = cvar("g_warmup");
1007         g_warmup_limit = cvar("g_warmup_limit");
1008         g_warmup_allguns = cvar("g_warmup_allguns");
1009         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1010
1011         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1012                 inWarmupStage = 0; // these modes cannot work together, sorry
1013
1014         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1015         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1016         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1017         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1018         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1019         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1020
1021         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1022         if(g_nixnex) g_weaponarena = 0;
1023         g_weaponarena = 0;
1024
1025         g_pickup_shells                    = cvar("g_pickup_shells");
1026         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1027         g_pickup_nails                     = cvar("g_pickup_nails");
1028         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1029         g_pickup_rockets                   = cvar("g_pickup_rockets");
1030         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1031         g_pickup_cells                     = cvar("g_pickup_cells");
1032         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1033         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1034         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1035         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1036         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1037         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1038         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1039         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1040         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1041         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1042         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1043         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1044         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1045         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1046         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1047
1048         g_weapon_stay = cvar("g_weapon_stay");
1049         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1050                 g_weapon_stay = 1;
1051
1052         if not(inWarmupStage)
1053         {
1054                 game_starttime                 = cvar("g_start_delay");
1055                 if(game_starttime)
1056                 {
1057                         restartAnnouncer = spawn();
1058                         restartAnnouncer.think = restartAnnouncer_Think;
1059                         restartAnnouncer.nextthink = time + 0.1;
1060                         restartAnnouncer.spawnflags = 0;
1061                 }
1062         }
1063
1064         readplayerstartcvars();
1065 }
1066
1067 /*
1068 // TODO sound pack system
1069 string soundpack;
1070
1071 string precache_sound_builtin (string s) = #19;
1072 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1073 string precache_sound(string s)
1074 {
1075         return precache_sound_builtin(strcat(soundpack, s));
1076 }
1077 void play2(entity e, string filename)
1078 {
1079         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1080 }
1081 void sound(entity e, float chan, string samp, float vol, float atten)
1082 {
1083         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1084 }
1085 */
1086
1087 // Sound functions
1088 string precache_sound (string s) = #19;
1089 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1090 float precache_sound_index (string s) = #19;
1091
1092 #define SND_VOLUME      1
1093 #define SND_ATTENUATION 2
1094 #define SND_LARGEENTITY 8
1095 #define SND_LARGESOUND  16
1096
1097 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1098 {
1099         float entno, idx;
1100         entno = num_for_edict(e);
1101         idx = precache_sound_index(samp);
1102
1103         float sflags;
1104         sflags = 0;
1105
1106         atten = floor(atten * 64);
1107         vol = floor(vol * 255);
1108
1109         if(vol != 255)
1110                 sflags |= SND_VOLUME;
1111         if(atten != 64)
1112                 sflags |= SND_ATTENUATION;
1113         if(entno >= 8192)
1114                 sflags |= SND_LARGEENTITY;
1115         if(idx >= 256)
1116                 sflags |= SND_LARGESOUND;
1117
1118         WriteByte(dest, SVC_SOUND);
1119         WriteByte(dest, sflags);
1120         if(sflags & SND_VOLUME)
1121                 WriteByte(dest, vol * 255);
1122         if(sflags & SND_ATTENUATION)
1123                 WriteByte(dest, atten);
1124         if(sflags & SND_LARGEENTITY)
1125         {
1126                 WriteShort(dest, entno);
1127                 WriteByte(dest, chan);
1128         }
1129         else
1130         {
1131                 WriteShort(dest, entno * 8 + chan);
1132         }
1133         if(sflags & SND_LARGESOUND)
1134                 WriteShort(dest, idx);
1135         else
1136                 WriteByte(dest, idx);
1137
1138         WriteCoord(dest, o_x);
1139         WriteCoord(dest, o_y);
1140         WriteCoord(dest, o_z);
1141 }
1142 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1143 {
1144         vector o;
1145         o = e.origin + 0.5 * (e.mins + e.maxs);
1146         soundtoat(dest, e, o, chan, samp, vol, atten);
1147 }
1148 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1149 {
1150         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1151 }
1152 void stopsoundto(float dest, entity e, float chan)
1153 {
1154         float entno;
1155         entno = num_for_edict(e);
1156
1157         if(entno >= 8192)
1158         {
1159                 float idx, sflags;
1160                 idx = precache_sound_index("misc/null.wav");
1161                 sflags = SND_LARGEENTITY;
1162                 if(idx >= 256)
1163                         sflags |= SND_LARGESOUND;
1164                 WriteByte(dest, SVC_SOUND);
1165                 WriteByte(dest, sflags);
1166                 WriteShort(dest, entno);
1167                 WriteByte(dest, chan);
1168                 if(sflags & SND_LARGESOUND)
1169                         WriteShort(dest, idx);
1170                 else
1171                         WriteByte(dest, idx);
1172                 WriteCoord(dest, e.origin_x);
1173                 WriteCoord(dest, e.origin_y);
1174                 WriteCoord(dest, e.origin_z);
1175         }
1176         else
1177         {
1178                 WriteByte(dest, SVC_STOPSOUND);
1179                 WriteShort(dest, entno * 8 + chan);
1180         }
1181 }
1182 void stopsound(entity e, float chan)
1183 {
1184         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1185         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1186 }
1187
1188 void play2(entity e, string filename)
1189 {
1190         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1191         msg_entity = e;
1192         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1193 }
1194
1195 .float announcetime;
1196 float announce(entity player, string msg)
1197 {
1198         if(time > player.announcetime)
1199         if(clienttype(player) == CLIENTTYPE_REAL)
1200         {
1201                 player.announcetime = time + 0.8;
1202                 play2(player, msg);
1203                 return TRUE;
1204         }
1205         return FALSE;
1206 }
1207
1208 void play2team(float t, string filename)
1209 {
1210         local entity head;
1211         FOR_EACH_REALPLAYER(head)
1212         {
1213                 if (head.team == t)
1214                         play2(head, filename);
1215         }
1216 }
1217
1218 void play2all(string samp)
1219 {
1220         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1221 }
1222
1223 void PrecachePlayerSounds(string f);
1224 void precache_all_models(string pattern)
1225 {
1226         float globhandle, i, n;
1227         string f;
1228
1229         globhandle = search_begin(pattern, TRUE, FALSE);
1230         if(globhandle < 0)
1231                 return;
1232         n = search_getsize(globhandle);
1233         for(i = 0; i < n; ++i)
1234         {
1235                 //print(search_getfilename(globhandle, i), "\n");
1236                 f = search_getfilename(globhandle, i);
1237                 precache_model(f);
1238                 PrecachePlayerSounds(strcat(f, ".sounds"));
1239         }
1240         search_end(globhandle);
1241 }
1242
1243 void precache()
1244 {
1245         // gamemode related things
1246         precache_model ("null");
1247         precache_model ("models/misc/chatbubble.spr");
1248         precache_model ("models/misc/teambubble.spr");
1249         if (g_runematch)
1250         {
1251                 precache_model ("models/runematch/curse.mdl");
1252                 precache_model ("models/runematch/rune.mdl");
1253         }
1254
1255 #ifdef TTURRETS_ENABLED
1256     if(cvar("g_turrets"))
1257         turrets_precash();
1258 #endif
1259
1260         // Precache all player models if desired
1261         if (cvar("sv_precacheplayermodels"))
1262         {
1263                 PrecachePlayerSounds("sound/player/default.sounds");
1264                 precache_all_models("models/player/*.zym");
1265                 precache_all_models("models/player/*.dpm");
1266                 precache_all_models("models/player/*.md3");
1267                 precache_all_models("models/player/*.psk");
1268                 //precache_model("models/player/carni.zym");
1269                 //precache_model("models/player/crash.zym");
1270                 //precache_model("models/player/grunt.zym");
1271                 //precache_model("models/player/headhunter.zym");
1272                 //precache_model("models/player/insurrectionist.zym");
1273                 //precache_model("models/player/jeandarc.zym");
1274                 //precache_model("models/player/lurk.zym");
1275                 //precache_model("models/player/lycanthrope.zym");
1276                 //precache_model("models/player/marine.zym");
1277                 //precache_model("models/player/nexus.zym");
1278                 //precache_model("models/player/pyria.zym");
1279                 //precache_model("models/player/shock.zym");
1280                 //precache_model("models/player/skadi.zym");
1281                 //precache_model("models/player/specop.zym");
1282                 //precache_model("models/player/visitant.zym");
1283         }
1284
1285         if(cvar("sv_defaultcharacter"))
1286         {
1287                 string s;
1288                 s = cvar_string("sv_defaultplayermodel_red");
1289                 if(s != "")
1290                 {
1291                         precache_model(s);
1292                         PrecachePlayerSounds(strcat(s, ".sounds"));
1293                 }
1294                 s = cvar_string("sv_defaultplayermodel_blue");
1295                 if(s != "")
1296                 {
1297                         precache_model(s);
1298                         PrecachePlayerSounds(strcat(s, ".sounds"));
1299                 }
1300                 s = cvar_string("sv_defaultplayermodel_yellow");
1301                 if(s != "")
1302                 {
1303                         precache_model(s);
1304                         PrecachePlayerSounds(strcat(s, ".sounds"));
1305                 }
1306                 s = cvar_string("sv_defaultplayermodel_pink");
1307                 if(s != "")
1308                 {
1309                         precache_model(s);
1310                         PrecachePlayerSounds(strcat(s, ".sounds"));
1311                 }
1312                 s = cvar_string("sv_defaultplayermodel");
1313                 if(s != "")
1314                 {
1315                         precache_model(s);
1316                         PrecachePlayerSounds(strcat(s, ".sounds"));
1317                 }
1318         }
1319
1320         if (g_footsteps)
1321         {
1322                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1323                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1324         }
1325
1326         // gore and miscellaneous sounds
1327         //precache_sound ("misc/h2ohit.wav");
1328         precache_model ("models/gibs/bloodyskull.md3");
1329         precache_model ("models/gibs/chunk.mdl");
1330         precache_model ("models/gibs/eye.md3");
1331         precache_model ("models/gibs/gib1.md3");
1332         precache_model ("models/gibs/gib2.md3");
1333         precache_model ("models/gibs/gib3.md3");
1334         precache_model ("models/gibs/gib4.md3");
1335         precache_model ("models/gibs/gib5.md3");
1336         precache_model ("models/gibs/gib6.md3");
1337         precache_model ("models/gibs/smallchest.md3");
1338         precache_model ("models/gibs/chest.md3");
1339         precache_model ("models/gibs/arm.md3");
1340         precache_model ("models/gibs/leg1.md3");
1341         precache_model ("models/gibs/leg2.md3");
1342         precache_model ("models/hook.md3");
1343         precache_sound ("misc/armorimpact.wav");
1344         precache_sound ("misc/bodyimpact1.wav");
1345         precache_sound ("misc/bodyimpact2.wav");
1346         precache_sound ("misc/gib.wav");
1347         precache_sound ("misc/gib_splat01.wav");
1348         precache_sound ("misc/gib_splat02.wav");
1349         precache_sound ("misc/gib_splat03.wav");
1350         precache_sound ("misc/gib_splat04.wav");
1351         precache_sound ("misc/hit.wav");
1352         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1353         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1354         precache_sound ("misc/null.wav");
1355         precache_sound ("misc/spawn.wav");
1356         precache_sound ("misc/talk.wav");
1357         precache_sound ("misc/teleport.wav");
1358         precache_sound ("player/lava.wav");
1359         precache_sound ("player/slime.wav");
1360
1361         // announcer sounds - male
1362         precache_sound ("announcer/male/electrobitch.wav");
1363         precache_sound ("announcer/male/airshot.wav");
1364         precache_sound ("announcer/male/03kills.wav");
1365         precache_sound ("announcer/male/05kills.wav");
1366         precache_sound ("announcer/male/10kills.wav");
1367         precache_sound ("announcer/male/15kills.wav");
1368         precache_sound ("announcer/male/20kills.wav");
1369         precache_sound ("announcer/male/25kills.wav");
1370         precache_sound ("announcer/male/30kills.wav");
1371         precache_sound ("announcer/male/botlike.wav");
1372         precache_sound ("announcer/male/yoda.wav");
1373         precache_sound ("announcer/male/headshot.wav");
1374         precache_sound ("announcer/male/impressive.wav");
1375
1376         // announcer sounds - robotic
1377         precache_sound ("announcer/robotic/prepareforbattle.wav");
1378         precache_sound ("announcer/robotic/begin.wav");
1379         precache_sound ("announcer/robotic/timeoutcalled.wav");
1380         precache_sound ("announcer/robotic/1fragleft.wav");
1381         precache_sound ("announcer/robotic/1minuteremains.wav");
1382         precache_sound ("announcer/robotic/2fragsleft.wav");
1383         precache_sound ("announcer/robotic/3fragsleft.wav");
1384         if (g_minstagib)
1385         {
1386                 precache_sound ("announcer/robotic/lastsecond.wav");
1387                 precache_sound ("announcer/robotic/narrowly.wav");
1388         }
1389
1390         precache_model ("models/sprites/1.spr32");
1391         precache_model ("models/sprites/2.spr32");
1392         precache_model ("models/sprites/3.spr32");
1393         precache_model ("models/sprites/4.spr32");
1394         precache_model ("models/sprites/5.spr32");
1395         precache_model ("models/sprites/6.spr32");
1396         precache_model ("models/sprites/7.spr32");
1397         precache_model ("models/sprites/8.spr32");
1398         precache_model ("models/sprites/9.spr32");
1399         precache_model ("models/sprites/10.spr32");
1400         precache_sound ("announcer/robotic/1.wav");
1401         precache_sound ("announcer/robotic/2.wav");
1402         precache_sound ("announcer/robotic/3.wav");
1403         precache_sound ("announcer/robotic/4.wav");
1404         precache_sound ("announcer/robotic/5.wav");
1405         precache_sound ("announcer/robotic/6.wav");
1406         precache_sound ("announcer/robotic/7.wav");
1407         precache_sound ("announcer/robotic/8.wav");
1408         precache_sound ("announcer/robotic/9.wav");
1409         precache_sound ("announcer/robotic/10.wav");
1410
1411         // common weapon precaches
1412         precache_sound ("weapons/weapon_switch.wav");
1413         precache_sound ("weapons/weaponpickup.wav");
1414         if (cvar("g_grappling_hook"))
1415         {
1416                 precache_sound ("weapons/hook_fire.wav"); // hook
1417                 precache_sound ("weapons/hook_impact.wav"); // hook
1418         }
1419
1420         if (cvar("sv_precacheweapons") || g_nixnex)
1421         {
1422                 //precache weapon models/sounds
1423                 local float wep;
1424                 wep = WEP_FIRST;
1425                 while (wep <= WEP_LAST)
1426                 {
1427                         weapon_action(wep, WR_PRECACHE);
1428                         wep = wep + 1;
1429                 }
1430         }
1431
1432 #if 0
1433         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1434
1435         if (!self.noise && self.music) // quake 3 uses the music field
1436                 self.noise = self.music;
1437
1438         // plays music for the level if there is any
1439         if (self.noise)
1440         {
1441                 precache_sound (self.noise);
1442                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1443         }
1444 #endif
1445 }
1446
1447 // sorry, but using \ in macros breaks line numbers
1448 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1449 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1450 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1451
1452 vector ExactTriggerHit_mins;
1453 vector ExactTriggerHit_maxs;
1454 float ExactTriggerHit_Recurse()
1455 {
1456         float s;
1457         entity se;
1458         float f;
1459
1460         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1461         if not(trace_ent)
1462                 return 0;
1463         if(trace_ent == self)
1464                 return 1;
1465
1466         se = trace_ent;
1467         s = se.solid;
1468         se.solid = SOLID_NOT;
1469         f = ExactTriggerHit_Recurse();
1470         se.solid = s;
1471
1472         return f;
1473 }
1474
1475 float ExactTriggerHit()
1476 {
1477         float f, s;
1478
1479         if not(self.modelindex)
1480                 return 1;
1481
1482         s = self.solid;
1483         self.solid = SOLID_BSP;
1484         ExactTriggerHit_mins = other.absmin;
1485         ExactTriggerHit_maxs = other.absmax;
1486         f = ExactTriggerHit_Recurse();
1487         self.solid = s;
1488
1489         return f;
1490 }
1491
1492 // WARNING: this kills the trace globals
1493 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1494 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1495
1496 #define INITPRIO_FIRST              0
1497 #define INITPRIO_GAMETYPE           0
1498 #define INITPRIO_GAMETYPE_FALLBACK  1
1499 #define INITPRIO_CVARS              5
1500 #define INITPRIO_FINDTARGET        10
1501 #define INITPRIO_DROPTOFLOOR       20
1502 #define INITPRIO_SETLOCATION       90
1503 #define INITPRIO_LINKDOORS         91
1504 #define INITPRIO_LAST              99
1505
1506 .void(void) initialize_entity;
1507 .float initialize_entity_order;
1508 .entity initialize_entity_next;
1509 entity initialize_entity_first;
1510
1511 void make_safe_for_remove(entity e)
1512 {
1513         if(e.initialize_entity)
1514         {
1515                 entity ent, prev;
1516                 for(ent = initialize_entity_first; ent; )
1517                 {
1518                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1519                         {
1520                                 print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1521                                 // skip it in linked list
1522                                 if(prev)
1523                                 {
1524                                         prev.initialize_entity_next = ent.initialize_entity_next;
1525                                         ent = prev.initialize_entity_next;
1526                                 }
1527                                 else
1528                                 {
1529                                         initialize_entity_first = ent.initialize_entity_next;
1530                                         ent = initialize_entity_first;
1531                                 }
1532                         }
1533                         else
1534                         {
1535                                 prev = ent;
1536                                 ent = ent.initialize_entity_next;
1537                         }
1538                 }
1539         }
1540 }
1541
1542 void objerror(string s)
1543 {
1544         make_safe_for_remove(self);
1545         objerror_builtin(s);
1546 }
1547
1548 void remove_unsafely(entity e)
1549 {
1550         remove_builtin(e);
1551 }
1552
1553 void remove_safely(entity e)
1554 {
1555         make_safe_for_remove(e);
1556         remove_builtin(e);
1557 }
1558
1559 void InitializeEntity(entity e, void(void) func, float order)
1560 {
1561         entity prev, cur;
1562
1563         if(!e || e.initialize_entity)
1564         {
1565                 // make a proxy initializer entity
1566                 entity e_old;
1567                 e_old = e;
1568                 e = spawn();
1569                 e.classname = "initialize_entity";
1570                 e.enemy = e_old;
1571         }
1572
1573         e.initialize_entity = func;
1574         e.initialize_entity_order = order;
1575
1576         cur = initialize_entity_first;
1577         for(;;)
1578         {
1579                 if(!cur || cur.initialize_entity_order > order)
1580                 {
1581                         // insert between prev and cur
1582                         if(prev)
1583                                 prev.initialize_entity_next = e;
1584                         else
1585                                 initialize_entity_first = e;
1586                         e.initialize_entity_next = cur;
1587                         return;
1588                 }
1589                 prev = cur;
1590                 cur = cur.initialize_entity_next;
1591         }
1592 }
1593 void InitializeEntitiesRun()
1594 {
1595         entity startoflist;
1596         startoflist = initialize_entity_first;
1597         initialize_entity_first = world;
1598         for(self = startoflist; self; )
1599         {
1600                 entity e;
1601                 var void(void) func;
1602                 e = self.initialize_entity_next;
1603                 func = self.initialize_entity;
1604                 self.initialize_entity_order = 0;
1605                 self.initialize_entity = func_null;
1606                 self.initialize_entity_next = world;
1607                 if(self.classname == "initialize_entity")
1608                 {
1609                         entity e_old;
1610                         e_old = self.enemy;
1611                         remove_builtin(self);
1612                         self = e_old;
1613                 }
1614                 //dprint("Delayed initialization: ", self.classname, "\n");
1615                 func();
1616                 self = e;
1617         }
1618 }
1619
1620 .float uncustomizeentityforclient_set;
1621 .void(void) uncustomizeentityforclient;
1622 void(void) SUB_Nullpointer = #0;
1623 void UncustomizeEntitiesRun()
1624 {
1625         entity oldself;
1626         oldself = self;
1627         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1628                 self.uncustomizeentityforclient();
1629         self = oldself;
1630 }
1631 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1632 {
1633         e.customizeentityforclient = customizer;
1634         e.uncustomizeentityforclient = uncustomizer;
1635         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1636 }
1637
1638 .float nottargeted;
1639 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1640
1641 void Net_LinkEntity(entity e)
1642 {
1643         setmodel(e, "null");
1644         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
1645 }
1646
1647 void adaptor_think2touch()
1648 {
1649         entity o;
1650         o = other;
1651         other = world;
1652         self.touch();
1653         other = o;
1654 }
1655
1656 void adaptor_think2use()
1657 {
1658         entity o, a;
1659         o = other;
1660         a = activator;
1661         activator = world;
1662         other = world;
1663         self.use();
1664         other = o;
1665         activator = a;
1666 }
1667
1668 // deferred dropping
1669 void DropToFloor_Handler()
1670 {
1671         droptofloor_builtin();
1672         self.dropped_origin = self.origin;
1673 }
1674
1675 void droptofloor()
1676 {
1677         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1678 }
1679
1680
1681
1682 float trace_hits_box_a0, trace_hits_box_a1;
1683
1684 float trace_hits_box_1d(float end, float thmi, float thma)
1685 {
1686         if(end == 0)
1687         {
1688                 // just check if x is in range
1689                 if(0 < thmi)
1690                         return FALSE;
1691                 if(0 > thma)
1692                         return FALSE;
1693         }
1694         else
1695         {
1696                 // do the trace with respect to x
1697                 // 0 -> end has to stay in thmi -> thma
1698                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1699                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1700                 if(trace_hits_box_a0 > trace_hits_box_a1)
1701                         return FALSE;
1702         }
1703         return TRUE;
1704 }
1705
1706 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1707 {
1708         end -= start;
1709         thmi -= start;
1710         thma -= start;
1711         // now it is a trace from 0 to end
1712
1713         trace_hits_box_a0 = 0;
1714         trace_hits_box_a1 = 1;
1715
1716         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1717                 return FALSE;
1718         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1719                 return FALSE;
1720         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1721                 return FALSE;
1722
1723         return TRUE;
1724 }
1725
1726 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1727 {
1728         return trace_hits_box(start, end, thmi - ma, thma - mi);
1729 }
1730
1731 float SUB_NoImpactCheck()
1732 {
1733         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1734                 return 1;
1735         if(other == world && self.size != '0 0 0')
1736         {
1737                 vector tic;
1738                 tic = self.velocity * sys_ticrate;
1739                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1740                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1741                 if(trace_fraction >= 1)
1742                 {
1743                         dprint("Odd... did not hit...?\n");
1744                 }
1745                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1746                 {
1747                         dprint("Detected and prevented the sky-grapple bug.\n");
1748                         return 1;
1749                 }
1750         }
1751
1752         return 0;
1753 }
1754
1755 #define SUB_OwnerCheck() (other && (other == self.owner))
1756
1757 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } } while(0)
1758 #define PROJECTILE_TOUCH_NOSOUND do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { stopsound(self, CHAN_PAIN); remove(self); return; } } while(0)
1759
1760 float MAX_IPBAN_URIS = 16;
1761
1762 float URI_GET_DISCARD   = 0;
1763 float URI_GET_IPBAN     = 1;
1764 float URI_GET_IPBAN_END = 16;
1765
1766 void URI_Get_Callback(float id, float status, string data)
1767 {
1768         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1769         dprint(data);
1770         dprint("\nEnd of data.\n");
1771
1772         if(id == URI_GET_DISCARD)
1773         {
1774                 // discard
1775         }
1776         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1777         {
1778                 // online ban list
1779                 OnlineBanList_URI_Get_Callback(id, status, data);
1780         }
1781         else
1782         {
1783                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1784         }
1785 }
1786
1787 void print_to(entity e, string s)
1788 {
1789         if(e)
1790                 sprint(e, strcat(s, "\n"));
1791         else
1792                 print(s, "\n");
1793 }
1794
1795 string getrecords()
1796 {
1797         float rec;
1798         string h;
1799         float r;
1800         float i;
1801         string s;
1802
1803         rec = 0;
1804
1805         s = "";
1806
1807         if(g_ctf)
1808         {
1809                 for(i = 0; i < MapInfo_count; ++i)
1810                 {
1811                         if(MapInfo_Get_ByID(i))
1812                         {
1813                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1814                                 if(r == 0)
1815                                         continue;
1816                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1817                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1818                                 ++rec;
1819                         }
1820                 }
1821         }
1822
1823         if(g_race)
1824         {
1825                 for(i = 0; i < MapInfo_count; ++i)
1826                 {
1827                         if(MapInfo_Get_ByID(i))
1828                         {
1829                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1830                                 if(r == 0)
1831                                         continue;
1832                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1833                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1834                                 ++rec;
1835                         }
1836                 }
1837         }
1838
1839         if(s == "")
1840                 return "No records are available on this server.\n";
1841         else
1842                 return strcat("Records on this server:\n", s);
1843 }