data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p, p1, p2;
 399         float n;
 400         string escape;
 401         string replacement;
 402         p = 0;
 403         n = 7;
 404         while(1)
 405         {
 406                 if(n < 1)
 407                         break; // too many replacements
 408                 n = n - 1;
 409                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 410                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 411
 412                 if(p1 < 0)
 413                         p1 = p2;
 414                 if(p2 < 0)
 415                         p2 = p1;
 416                 p = min(p1, p2);
 417
 418                 if(p < 0)
 419                         break;
 420                 replacement = substring(msg, p, 2);
 421                 escape = substring(msg, p + 1, 1);
 422                 if(escape == "%")
 423                         replacement = "%";
 424                 else if(escape == "\\")
 425                         replacement = "\\";
 426                 else if(escape == "n")
 427                         replacement = "\n";
 428                 else if(escape == "a")
 429                         replacement = ftos(floor(self.armorvalue));
 430                 else if(escape == "h")
 431                         replacement = ftos(floor(self.health));
 432                 else if(escape == "l")
 433                         replacement = NearestLocation(self.origin);
 434                 else if(escape == "y")
 435                         replacement = NearestLocation(self.cursor_trace_endpos);
 436                 else if(escape == "d")
 437                         replacement = NearestLocation(self.death_origin);
 438                 else if(escape == "w")
 439                 {
 440                         float wep;
 441                         wep = self.weapon;
 442                         if(!wep)
 443                                 wep = self.switchweapon;
 444                         if(!wep)
 445                                 wep = self.cnt;
 446                         replacement = W_Name(wep);
 447                 }
 448                 else if(escape == "W")
 449                 {
 450                         if(self.items & IT_SHELLS) replacement = "shells";
 451                         else if(self.items & IT_NAILS) replacement = "bullets";
 452                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 453                         else if(self.items & IT_CELLS) replacement = "cells";
 454                         else replacement = "batteries"; // ;)
 455                 }
 456                 else if(escape == "x")
 457                 {
 458                         replacement = self.cursor_trace_ent.netname;
 459                         if(!replacement || !self.cursor_trace_ent)
 460                                 replacement = "nothing";
 461                 }
 462                 else if(escape == "p")
 463                 {
 464                         if(self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 }
 469                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 470                 p = p + strlen(replacement);
 471         }
 472         return msg;
 473 }
 474
 475 /*
 476 =============
 477 GetCvars
 478 =============
 479 Called with:
 480   0:  sends the request
 481   >0: receives a cvar from name=argv(f) value=argv(f+1)
 482 */
 483 void GetCvars_handleString(string thisname, float f, .string field, string name)
 484 {
 485         if(f < 0)
 486         {
 487                 if(self.field)
 488                         strunzone(self.field);
 489                 self.field = string_null;
 490         }
 491         else if(f > 0)
 492         {
 493                 if(thisname == name)
 494                 {
 495                         if(self.field)
 496                                 strunzone(self.field);
 497                         self.field = strzone(argv(f + 1));
 498                 }
 499         }
 500         else
 501                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 504 {
 505         GetCvars_handleString(thisname, f, field, name);
 506         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 507         if(thisname == name)
 508         {
 509                 string s;
 510                 s = func(strcat1(self.field));
 511                 if(s != self.field)
 512                 {
 513                         strunzone(self.field);
 514                         self.field = strzone(s);
 515                 }
 516         }
 517 }
 518 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 519 {
 520         if(f < 0)
 521         {
 522         }
 523         else if(f > 0)
 524         {
 525                 if(thisname == name)
 526                         self.field = stof(argv(f + 1));
 527         }
 528         else
 529                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 530 }
 531 string W_FixWeaponOrder_ForceComplete(string s);
 532 string W_FixWeaponOrder_AllowIncomplete(string s);
 533 float w_getbestweapon(entity e);
 534 void GetCvars(float f)
 535 {
 536         string s;
 537         if(f > 0)
 538                 s = strcat1(argv(f));
 539         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 542         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 543         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 544         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 560
 561         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 562         if(f > 0)
 563         {
 564                 if(s == "cl_weaponpriority")
 565                         self.switchweapon = w_getbestweapon(self);
 566         }
 567 }
 568
 569 float fexists(string f)
 570 {
 571         float fh;
 572         fh = fopen(f, FILE_READ);
 573         if(fh < 0)
 574                 return FALSE;
 575         fclose(fh);
 576         return TRUE;
 577 }
 578
 579 void backtrace(string msg)
 580 {
 581         float dev;
 582         dev = cvar("developer");
 583         cvar_set("developer", "1");
 584         dprint("\n");
 585         dprint("--- CUT HERE ---\nWARNING: ");
 586         dprint(msg);
 587         dprint("\n");
 588         remove(world); // isn't there any better way to cause a backtrace?
 589         dprint("\n--- CUT UNTIL HERE ---\n");
 590         cvar_set("developer", ftos(dev));
 591 }
 592
 593 string Team_ColorCode(float teamid)
 594 {
 595         if(teamid == COLOR_TEAM1)
 596                 return "^1";
 597         else if(teamid == COLOR_TEAM2)
 598                 return "^4";
 599         else if(teamid == COLOR_TEAM3)
 600                 return "^3";
 601         else if(teamid == COLOR_TEAM4)
 602                 return "^6";
 603         else
 604                 return "^7";
 605 }
 606 string Team_ColorName(float t)
 607 {
 608         // fixme: Search for team entities and get their .netname's!
 609         if(t == COLOR_TEAM1)
 610                 return "Red";
 611         if(t == COLOR_TEAM2)
 612                 return "Blue";
 613         if(t == COLOR_TEAM3)
 614                 return "Yellow";
 615         if(t == COLOR_TEAM4)
 616                 return "Pink";
 617         return "Neutral";
 618 }
 619 string Team_ColorNameLowerCase(float t)
 620 {
 621         // fixme: Search for team entities and get their .netname's!
 622         if(t == COLOR_TEAM1)
 623                 return "red";
 624         if(t == COLOR_TEAM2)
 625                 return "blue";
 626         if(t == COLOR_TEAM3)
 627                 return "yellow";
 628         if(t == COLOR_TEAM4)
 629                 return "pink";
 630         return "neutral";
 631 }
 632
 633 #define CENTERPRIO_POINT 1
 634 #define CENTERPRIO_SPAM 2
 635 #define CENTERPRIO_VOTE 4
 636 #define CENTERPRIO_NORMAL 5
 637 #define CENTERPRIO_SHIELDING 7
 638 #define CENTERPRIO_MAPVOTE 9
 639 #define CENTERPRIO_IDLEKICK 50
 640 #define CENTERPRIO_ADMIN 99
 641 .float centerprint_priority;
 642 .float centerprint_expires;
 643 void centerprint_atprio(entity e, float prio, string s)
 644 {
 645         if(intermission_running)
 646                 if(prio < CENTERPRIO_MAPVOTE)
 647                         return;
 648         if(time > e.centerprint_expires)
 649                 e.centerprint_priority = 0;
 650         if(prio >= e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = prio;
 653                 if(timeoutStatus == 2)
 654                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 655                 else
 656                         e.centerprint_expires = time + e.cvar_scr_centertime;
 657                 centerprint_builtin(e, s);
 658         }
 659 }
 660 void centerprint_expire(entity e, float prio)
 661 {
 662         if(prio == e.centerprint_priority)
 663         {
 664                 e.centerprint_priority = 0;
 665                 centerprint_builtin(e, "");
 666         }
 667 }
 668 void centerprint(entity e, string s)
 669 {
 670         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 671 }
 672
 673 // decolorizes and team colors the player name when needed
 674 string playername(entity p)
 675 {
 676         string t;
 677         if(teams_matter && !intermission_running && p.classname == "player")
 678         {
 679                 t = Team_ColorCode(p.team);
 680                 return strcat(t, strdecolorize(p.netname));
 681         }
 682         else
 683                 return p.netname;
 684 }
 685
 686 vector randompos(vector m1, vector m2)
 687 {
 688         local vector v;
 689         m2 = m2 - m1;
 690         v_x = m2_x * random() + m1_x;
 691         v_y = m2_y * random() + m1_y;
 692         v_z = m2_z * random() + m1_z;
 693         return  v;
 694 };
 695
 696 float g_pickup_shells;
 697 float g_pickup_shells_max;
 698 float g_pickup_nails;
 699 float g_pickup_nails_max;
 700 float g_pickup_rockets;
 701 float g_pickup_rockets_max;
 702 float g_pickup_cells;
 703 float g_pickup_cells_max;
 704 float g_pickup_armorsmall;
 705 float g_pickup_armorsmall_max;
 706 float g_pickup_armormedium;
 707 float g_pickup_armormedium_max;
 708 float g_pickup_armorbig;
 709 float g_pickup_armorbig_max;
 710 float g_pickup_armorlarge;
 711 float g_pickup_armorlarge_max;
 712 float g_pickup_healthsmall;
 713 float g_pickup_healthsmall_max;
 714 float g_pickup_healthmedium;
 715 float g_pickup_healthmedium_max;
 716 float g_pickup_healthlarge;
 717 float g_pickup_healthlarge_max;
 718 float g_pickup_healthmega;
 719 float g_pickup_healthmega_max;
 720 float g_weaponarena;
 721 string g_weaponarena_list;
 722
 723 float start_weapons;
 724 float start_items;
 725 float start_ammo_shells;
 726 float start_ammo_nails;
 727 float start_ammo_rockets;
 728 float start_ammo_cells;
 729 float start_health;
 730 float start_armorvalue;
 731 float warmup_start_weapons;
 732 float warmup_start_ammo_shells;
 733 float warmup_start_ammo_nails;
 734 float warmup_start_ammo_rockets;
 735 float warmup_start_ammo_cells;
 736 float warmup_start_health;
 737 float warmup_start_armorvalue;
 738 float g_weapon_stay;
 739
 740 entity get_weaponinfo(float w);
 741
 742 void readplayerstartcvars()
 743 {
 744         entity e;
 745         float i, j, t;
 746         string s;
 747
 748         // initialize starting values for players
 749         start_weapons = 0;
 750         start_items = 0;
 751         start_ammo_shells = 0;
 752         start_ammo_nails = 0;
 753         start_ammo_rockets = 0;
 754         start_ammo_cells = 0;
 755         start_health = cvar("g_balance_health_start");
 756         start_armorvalue = cvar("g_balance_armor_start");
 757
 758         if(g_jetpack)
 759                 g_grappling_hook = 0;
 760
 761         g_weaponarena = 0;
 762         s = cvar_string("g_weaponarena");
 763         if(s == "0")
 764         {
 765         }
 766         else if(s == "all")
 767         {
 768                 g_weaponarena_list = "All Weapons";
 769                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 770                 {
 771                         e = get_weaponinfo(j);
 772                         g_weaponarena |= e.weapons;
 773                         weapon_action(e.weapon, WR_PRECACHE);
 774                 }
 775         }
 776         else if(s == "most")
 777         {
 778                 g_weaponarena_list = "Most Weapons";
 779                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 780                 {
 781                         e = get_weaponinfo(j);
 782                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 783                         {
 784                                 g_weaponarena |= e.weapons;
 785                                 weapon_action(e.weapon, WR_PRECACHE);
 786                         }
 787                 }
 788         }
 789         else
 790         {
 791                 t = tokenize_sane(s);
 792                 g_weaponarena_list = "";
 793                 for(i = 0; i < t; ++i)
 794                 {
 795                         s = argv(i);
 796                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 797                         {
 798                                 e = get_weaponinfo(j);
 799                                 if(e.netname == s)
 800                                 {
 801                                         g_weaponarena |= e.weapons;
 802                                         weapon_action(e.weapon, WR_PRECACHE);
 803                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 804                                         break;
 805                                 }
 806                         }
 807                         if(j > WEP_LAST)
 808                         {
 809                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 810                         }
 811                 }
 812                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 813         }
 814
 815         if(g_weaponarena)
 816         {
 817                 start_weapons = g_weaponarena;
 818                 start_ammo_rockets = 999;
 819                 start_ammo_shells = 999;
 820                 start_ammo_cells = 999;
 821                 start_ammo_nails = 999;
 822                 start_items |= IT_UNLIMITED_AMMO;
 823         }
 824         else if(g_nixnex)
 825         {
 826                 start_weapons = 0;
 827                 // will be done later
 828                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 829                 {
 830                         e = get_weaponinfo(i);
 831                         if(!(e.weapon))
 832                                 continue;
 833                         weapon_action(e.weapon, WR_PRECACHE);
 834                 }
 835         }
 836         else if(g_minstagib)
 837         {
 838                 start_health = 100;
 839                 start_armorvalue = 0;
 840                 start_weapons = WEPBIT_MINSTANEX;
 841                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 842                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 843                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 844
 845                 if(g_minstagib_invis_alpha <= 0)
 846                         g_minstagib_invis_alpha = -1;
 847         }
 848         else
 849         {
 850                 if(g_lms)
 851                 {
 852                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 853                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 854                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 855                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 856                         start_health = cvar("g_lms_start_health");
 857                         start_armorvalue = cvar("g_lms_start_armor");
 858                 } else if (cvar("g_use_ammunition")) {
 859                         start_ammo_shells = cvar("g_start_ammo_shells");
 860                         start_ammo_nails = cvar("g_start_ammo_nails");
 861                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 862                         start_ammo_cells = cvar("g_start_ammo_cells");
 863                 } else {
 864                         start_ammo_shells = cvar("g_pickup_shells_max");
 865                         start_ammo_nails = cvar("g_pickup_nails_max");
 866                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 867                         start_ammo_cells = cvar("g_pickup_cells_max");
 868                         start_items |= IT_UNLIMITED_AMMO;
 869                 }
 870
 871                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 872                 {
 873                         e = get_weaponinfo(i);
 874                         if(!(e.weapon))
 875                                 continue;
 876
 877                         t = cvar(strcat("g_start_weapon_", e.netname));
 878
 879                         if(t < 0) // "default" weapon selection
 880                         {
 881                                 if(g_lms)
 882                                         t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 883                                 else if(g_race)
 884                                         t = (i == WEP_LASER);
 885                                 else
 886                                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 887                                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 888                                         t += (i == WEP_HOOK);
 889                         }
 890
 891                         if(t)
 892                         {
 893                                 start_weapons |= e.weapons;
 894                                 weapon_action(e.weapon, WR_PRECACHE);
 895                         }
 896                 }
 897         }
 898
 899         if(inWarmupStage)
 900         {
 901                 warmup_start_ammo_shells = start_ammo_shells;
 902                 warmup_start_ammo_nails = start_ammo_nails;
 903                 warmup_start_ammo_rockets = start_ammo_rockets;
 904                 warmup_start_ammo_cells = start_ammo_cells;
 905                 warmup_start_health = start_health;
 906                 warmup_start_armorvalue = start_armorvalue;
 907                 warmup_start_weapons = start_weapons;
 908
 909                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 910                 {
 911                         if(cvar("g_use_ammunition"))
 912                         {
 913                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 914                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 915                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 916                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 917                         }
 918                         warmup_start_health = cvar("g_warmup_start_health");
 919                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 920                         if(cvar("g_warmup_allguns"))
 921                         {
 922                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 923                                 {
 924                                         e = get_weaponinfo(i);
 925                                         if(!(e.weapon))
 926                                                 continue;
 927                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 928                                         {
 929                                                 warmup_start_weapons |= e.weapons;
 930                                                 weapon_action(e.weapon, WR_PRECACHE);
 931                                         }
 932                                 }
 933                         }
 934                 }
 935         }
 936
 937         if(start_weapons & WEPBIT_HOOK)
 938         {
 939                 // can't have off-hand hook, if hook weapon is enabled
 940
 941                 // note: if g_grappling_hook is 1, also give some initial cells
 942                 if(g_grappling_hook)
 943                 {
 944                         if(!start_ammo_cells)
 945                                 start_ammo_cells = g_pickup_cells;
 946                         if(!warmup_start_ammo_cells)
 947                                 warmup_start_ammo_cells = g_pickup_cells;
 948                 }
 949
 950                 g_grappling_hook = 0;
 951         }
 952
 953         if(g_jetpack)
 954         {
 955                 start_weapons &~= WEPBIT_HOOK;
 956                 warmup_start_weapons &~= WEPBIT_HOOK;
 957         }
 958
 959         if(g_weapon_stay == 2)
 960         {
 961                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 962                 if(!start_ammo_nails) start_ammo_shells = g_pickup_nails;
 963                 if(!start_ammo_cells) start_ammo_shells = g_pickup_cells;
 964                 if(!start_ammo_rockets) start_ammo_shells = g_pickup_rockets;
 965                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 966                 if(!warmup_start_ammo_nails) warmup_start_ammo_shells = g_pickup_nails;
 967                 if(!warmup_start_ammo_cells) warmup_start_ammo_shells = g_pickup_cells;
 968                 if(!warmup_start_ammo_rockets) warmup_start_ammo_shells = g_pickup_rockets;
 969         }
 970
 971         start_ammo_shells = max(0, start_ammo_shells);
 972         start_ammo_nails = max(0, start_ammo_nails);
 973         start_ammo_cells = max(0, start_ammo_cells);
 974         start_ammo_rockets = max(0, start_ammo_rockets);
 975
 976         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 977         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 978         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 979         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 980 }
 981
 982 float g_bugrigs;
 983 float g_bugrigs_planar_movement;
 984 float g_bugrigs_planar_movement_car_jumping;
 985 float g_bugrigs_reverse_spinning;
 986 float g_bugrigs_reverse_speeding;
 987 float g_bugrigs_reverse_stopping;
 988 float g_bugrigs_air_steering;
 989 float g_bugrigs_angle_smoothing;
 990 float g_bugrigs_friction_floor;
 991 float g_bugrigs_friction_brake;
 992 float g_bugrigs_friction_air;
 993 float g_bugrigs_accel;
 994 float g_bugrigs_speed_ref;
 995 float g_bugrigs_speed_pow;
 996 float g_bugrigs_steer;
 997
 998 float g_touchexplode;
 999 float g_touchexplode_radius;
1000 float g_touchexplode_damage;
1001 float g_touchexplode_edgedamage;
1002 float g_touchexplode_force;
1003
1004 void readlevelcvars(void)
1005 {
1006         g_bugrigs = cvar("g_bugrigs");
1007         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1008         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1009         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1010         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1011         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1012         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1013         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1014         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1015         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1016         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1017         g_bugrigs_accel = cvar("g_bugrigs_accel");
1018         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1019         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1020         g_bugrigs_steer = cvar("g_bugrigs_steer");
1021
1022         g_touchexplode = cvar("g_touchexplode");
1023         g_touchexplode_radius = cvar("g_touchexplode_radius");
1024         g_touchexplode_damage = cvar("g_touchexplode_damage");
1025         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1026         g_touchexplode_force = cvar("g_touchexplode_force");
1027
1028         sv_clones = cvar("sv_clones");
1029         sv_cheats = cvar("sv_cheats");
1030         sv_gentle = cvar("sv_gentle");
1031         sv_foginterval = cvar("sv_foginterval");
1032         g_cloaked = cvar("g_cloaked");
1033         g_jump_grunt = cvar("g_jump_grunt");
1034         g_footsteps = cvar("g_footsteps");
1035         g_grappling_hook = cvar("g_grappling_hook");
1036         g_jetpack = cvar("g_jetpack");
1037         g_laserguided_missile = cvar("g_laserguided_missile");
1038         g_midair = cvar("g_midair");
1039         g_minstagib = cvar("g_minstagib");
1040         g_nixnex = cvar("g_nixnex");
1041         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1042         g_norecoil = cvar("g_norecoil");
1043         g_vampire = cvar("g_vampire");
1044         g_bloodloss = cvar("g_bloodloss");
1045         sv_maxidle = cvar("sv_maxidle");
1046         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1047         sv_pogostick = cvar("sv_pogostick");
1048         sv_doublejump = cvar("sv_doublejump");
1049         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1050         g_ctf_reverse = cvar("g_ctf_reverse");
1051
1052         inWarmupStage = cvar("g_warmup");
1053         g_warmup_limit = cvar("g_warmup_limit");
1054         g_warmup_allguns = cvar("g_warmup_allguns");
1055         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1056
1057         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1058                 inWarmupStage = 0; // these modes cannot work together, sorry
1059
1060         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1061         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1062         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1063         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1064         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1065         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1066
1067         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1068         if(g_nixnex) g_weaponarena = 0;
1069         g_weaponarena = 0;
1070
1071         g_pickup_shells                    = cvar("g_pickup_shells");
1072         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1073         g_pickup_nails                     = cvar("g_pickup_nails");
1074         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1075         g_pickup_rockets                   = cvar("g_pickup_rockets");
1076         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1077         g_pickup_cells                     = cvar("g_pickup_cells");
1078         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1079         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1080         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1081         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1082         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1083         g_pickup_armorbig                  = cvar("g_pickup_armorbig");
1084         g_pickup_armorbig_max              = cvar("g_pickup_armorbig_max");
1085         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1086         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1087         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1088         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1089         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1090         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1091         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1092         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1093         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1094         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1095
1096         g_pinata = cvar("g_pinata");
1097
1098         g_weapon_stay = cvar("g_weapon_stay");
1099         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1100                 g_weapon_stay = 1;
1101
1102         if not(inWarmupStage)
1103                 game_starttime                 = cvar("g_start_delay");
1104
1105         readplayerstartcvars();
1106 }
1107
1108 /*
1109 // TODO sound pack system
1110 string soundpack;
1111
1112 string precache_sound_builtin (string s) = #19;
1113 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1114 string precache_sound(string s)
1115 {
1116         return precache_sound_builtin(strcat(soundpack, s));
1117 }
1118 void play2(entity e, string filename)
1119 {
1120         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1121 }
1122 void sound(entity e, float chan, string samp, float vol, float atten)
1123 {
1124         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1125 }
1126 */
1127
1128 // Sound functions
1129 string precache_sound (string s) = #19;
1130 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1131 float precache_sound_index (string s) = #19;
1132
1133 #define SND_VOLUME      1
1134 #define SND_ATTENUATION 2
1135 #define SND_LARGEENTITY 8
1136 #define SND_LARGESOUND  16
1137
1138 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1139 {
1140         float entno, idx;
1141         entno = num_for_edict(e);
1142         idx = precache_sound_index(samp);
1143
1144         float sflags;
1145         sflags = 0;
1146
1147         atten = floor(atten * 64);
1148         vol = floor(vol * 255);
1149
1150         if(vol != 255)
1151                 sflags |= SND_VOLUME;
1152         if(atten != 64)
1153                 sflags |= SND_ATTENUATION;
1154         if(entno >= 8192)
1155                 sflags |= SND_LARGEENTITY;
1156         if(idx >= 256)
1157                 sflags |= SND_LARGESOUND;
1158
1159         WriteByte(dest, SVC_SOUND);
1160         WriteByte(dest, sflags);
1161         if(sflags & SND_VOLUME)
1162                 WriteByte(dest, vol * 255);
1163         if(sflags & SND_ATTENUATION)
1164                 WriteByte(dest, atten);
1165         if(sflags & SND_LARGEENTITY)
1166         {
1167                 WriteShort(dest, entno);
1168                 WriteByte(dest, chan);
1169         }
1170         else
1171         {
1172                 WriteShort(dest, entno * 8 + chan);
1173         }
1174         if(sflags & SND_LARGESOUND)
1175                 WriteShort(dest, idx);
1176         else
1177                 WriteByte(dest, idx);
1178
1179         WriteCoord(dest, o_x);
1180         WriteCoord(dest, o_y);
1181         WriteCoord(dest, o_z);
1182 }
1183 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1184 {
1185         vector o;
1186         o = e.origin + 0.5 * (e.mins + e.maxs);
1187         soundtoat(dest, e, o, chan, samp, vol, atten);
1188 }
1189 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1190 {
1191         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1192 }
1193 void stopsoundto(float dest, entity e, float chan)
1194 {
1195         float entno;
1196         entno = num_for_edict(e);
1197
1198         if(entno >= 8192)
1199         {
1200                 float idx, sflags;
1201                 idx = precache_sound_index("misc/null.wav");
1202                 sflags = SND_LARGEENTITY;
1203                 if(idx >= 256)
1204                         sflags |= SND_LARGESOUND;
1205                 WriteByte(dest, SVC_SOUND);
1206                 WriteByte(dest, sflags);
1207                 WriteShort(dest, entno);
1208                 WriteByte(dest, chan);
1209                 if(sflags & SND_LARGESOUND)
1210                         WriteShort(dest, idx);
1211                 else
1212                         WriteByte(dest, idx);
1213                 WriteCoord(dest, e.origin_x);
1214                 WriteCoord(dest, e.origin_y);
1215                 WriteCoord(dest, e.origin_z);
1216         }
1217         else
1218         {
1219                 WriteByte(dest, SVC_STOPSOUND);
1220                 WriteShort(dest, entno * 8 + chan);
1221         }
1222 }
1223 void stopsound(entity e, float chan)
1224 {
1225         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1226         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1227 }
1228
1229 void play2(entity e, string filename)
1230 {
1231         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1232         msg_entity = e;
1233         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1234 }
1235
1236 .float announcetime;
1237 float announce(entity player, string msg)
1238 {
1239         if(time > player.announcetime)
1240         if(clienttype(player) == CLIENTTYPE_REAL)
1241         {
1242                 player.announcetime = time + 0.8;
1243                 play2(player, msg);
1244                 return TRUE;
1245         }
1246         return FALSE;
1247 }
1248
1249 void play2team(float t, string filename)
1250 {
1251         local entity head;
1252         FOR_EACH_REALPLAYER(head)
1253         {
1254                 if (head.team == t)
1255                         play2(head, filename);
1256         }
1257 }
1258
1259 void play2all(string samp)
1260 {
1261         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1262 }
1263
1264 void PrecachePlayerSounds(string f);
1265 void precache_all_models(string pattern)
1266 {
1267         float globhandle, i, n;
1268         string f;
1269
1270         globhandle = search_begin(pattern, TRUE, FALSE);
1271         if(globhandle < 0)
1272                 return;
1273         n = search_getsize(globhandle);
1274         for(i = 0; i < n; ++i)
1275         {
1276                 //print(search_getfilename(globhandle, i), "\n");
1277                 f = search_getfilename(globhandle, i);
1278                 precache_model(f);
1279                 PrecachePlayerSounds(strcat(f, ".sounds"));
1280         }
1281         search_end(globhandle);
1282 }
1283
1284 void precache()
1285 {
1286         // gamemode related things
1287         precache_model ("models/misc/chatbubble.spr");
1288         precache_model ("models/misc/teambubble.spr");
1289         if (g_runematch)
1290         {
1291                 precache_model ("models/runematch/curse.mdl");
1292                 precache_model ("models/runematch/rune.mdl");
1293         }
1294
1295 #ifdef TTURRETS_ENABLED
1296     if(cvar("g_turrets"))
1297         turrets_precash();
1298 #endif
1299
1300         // Precache all player models if desired
1301         if (cvar("sv_precacheplayermodels"))
1302         {
1303                 PrecachePlayerSounds("sound/player/default.sounds");
1304                 precache_all_models("models/player/*.zym");
1305                 precache_all_models("models/player/*.dpm");
1306                 precache_all_models("models/player/*.md3");
1307                 precache_all_models("models/player/*.psk");
1308                 //precache_model("models/player/carni.zym");
1309                 //precache_model("models/player/crash.zym");
1310                 //precache_model("models/player/grunt.zym");
1311                 //precache_model("models/player/headhunter.zym");
1312                 //precache_model("models/player/insurrectionist.zym");
1313                 //precache_model("models/player/jeandarc.zym");
1314                 //precache_model("models/player/lurk.zym");
1315                 //precache_model("models/player/lycanthrope.zym");
1316                 //precache_model("models/player/marine.zym");
1317                 //precache_model("models/player/nexus.zym");
1318                 //precache_model("models/player/pyria.zym");
1319                 //precache_model("models/player/shock.zym");
1320                 //precache_model("models/player/skadi.zym");
1321                 //precache_model("models/player/specop.zym");
1322                 //precache_model("models/player/visitant.zym");
1323         }
1324
1325         if(cvar("sv_defaultcharacter"))
1326         {
1327                 string s;
1328                 s = cvar_string("sv_defaultplayermodel_red");
1329                 if(s != "")
1330                 {
1331                         precache_model(s);
1332                         PrecachePlayerSounds(strcat(s, ".sounds"));
1333                 }
1334                 s = cvar_string("sv_defaultplayermodel_blue");
1335                 if(s != "")
1336                 {
1337                         precache_model(s);
1338                         PrecachePlayerSounds(strcat(s, ".sounds"));
1339                 }
1340                 s = cvar_string("sv_defaultplayermodel_yellow");
1341                 if(s != "")
1342                 {
1343                         precache_model(s);
1344                         PrecachePlayerSounds(strcat(s, ".sounds"));
1345                 }
1346                 s = cvar_string("sv_defaultplayermodel_pink");
1347                 if(s != "")
1348                 {
1349                         precache_model(s);
1350                         PrecachePlayerSounds(strcat(s, ".sounds"));
1351                 }
1352                 s = cvar_string("sv_defaultplayermodel");
1353                 if(s != "")
1354                 {
1355                         precache_model(s);
1356                         PrecachePlayerSounds(strcat(s, ".sounds"));
1357                 }
1358         }
1359
1360         if (g_footsteps)
1361         {
1362                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1363                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1364         }
1365
1366         // gore and miscellaneous sounds
1367         //precache_sound ("misc/h2ohit.wav");
1368         precache_model ("models/hook.md3");
1369         precache_sound ("misc/armorimpact.wav");
1370         precache_sound ("misc/bodyimpact1.wav");
1371         precache_sound ("misc/bodyimpact2.wav");
1372         precache_sound ("misc/gib.wav");
1373         precache_sound ("misc/gib_splat01.wav");
1374         precache_sound ("misc/gib_splat02.wav");
1375         precache_sound ("misc/gib_splat03.wav");
1376         precache_sound ("misc/gib_splat04.wav");
1377         precache_sound ("misc/hit.wav");
1378         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1379         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1380         precache_sound ("misc/null.wav");
1381         precache_sound ("misc/spawn.wav");
1382         precache_sound ("misc/talk.wav");
1383         precache_sound ("misc/teleport.wav");
1384         precache_sound ("player/lava.wav");
1385         precache_sound ("player/slime.wav");
1386
1387         // announcer sounds - male
1388         precache_sound ("announcer/male/electrobitch.wav");
1389         precache_sound ("announcer/male/airshot.wav");
1390         precache_sound ("announcer/male/03kills.wav");
1391         precache_sound ("announcer/male/05kills.wav");
1392         precache_sound ("announcer/male/10kills.wav");
1393         precache_sound ("announcer/male/15kills.wav");
1394         precache_sound ("announcer/male/20kills.wav");
1395         precache_sound ("announcer/male/25kills.wav");
1396         precache_sound ("announcer/male/30kills.wav");
1397         precache_sound ("announcer/male/botlike.wav");
1398         precache_sound ("announcer/male/yoda.wav");
1399         precache_sound ("announcer/male/headshot.wav");
1400         precache_sound ("announcer/male/impressive.wav");
1401
1402         // announcer sounds - robotic
1403         precache_sound ("announcer/robotic/prepareforbattle.wav");
1404         precache_sound ("announcer/robotic/begin.wav");
1405         precache_sound ("announcer/robotic/timeoutcalled.wav");
1406         precache_sound ("announcer/robotic/1fragleft.wav");
1407         precache_sound ("announcer/robotic/1minuteremains.wav");
1408         precache_sound ("announcer/robotic/2fragsleft.wav");
1409         precache_sound ("announcer/robotic/3fragsleft.wav");
1410         if (g_minstagib)
1411         {
1412                 precache_sound ("announcer/robotic/lastsecond.wav");
1413                 precache_sound ("announcer/robotic/narrowly.wav");
1414         }
1415
1416         precache_model ("models/sprites/1.spr32");
1417         precache_model ("models/sprites/2.spr32");
1418         precache_model ("models/sprites/3.spr32");
1419         precache_model ("models/sprites/4.spr32");
1420         precache_model ("models/sprites/5.spr32");
1421         precache_model ("models/sprites/6.spr32");
1422         precache_model ("models/sprites/7.spr32");
1423         precache_model ("models/sprites/8.spr32");
1424         precache_model ("models/sprites/9.spr32");
1425         precache_model ("models/sprites/10.spr32");
1426         precache_sound ("announcer/robotic/1.wav");
1427         precache_sound ("announcer/robotic/2.wav");
1428         precache_sound ("announcer/robotic/3.wav");
1429         precache_sound ("announcer/robotic/4.wav");
1430         precache_sound ("announcer/robotic/5.wav");
1431         precache_sound ("announcer/robotic/6.wav");
1432         precache_sound ("announcer/robotic/7.wav");
1433         precache_sound ("announcer/robotic/8.wav");
1434         precache_sound ("announcer/robotic/9.wav");
1435         precache_sound ("announcer/robotic/10.wav");
1436
1437         // common weapon precaches
1438         precache_sound ("weapons/weapon_switch.wav");
1439         precache_sound ("weapons/weaponpickup.wav");
1440         if(g_grappling_hook)
1441         {
1442                 precache_sound ("weapons/hook_fire.wav"); // hook
1443                 precache_sound ("weapons/hook_impact.wav"); // hook
1444         }
1445
1446         if (cvar("sv_precacheweapons") || g_nixnex)
1447         {
1448                 //precache weapon models/sounds
1449                 local float wep;
1450                 wep = WEP_FIRST;
1451                 while (wep <= WEP_LAST)
1452                 {
1453                         weapon_action(wep, WR_PRECACHE);
1454                         wep = wep + 1;
1455                 }
1456         }
1457
1458         precache_model("models/elaser.mdl");
1459         precache_model("models/laser.mdl");
1460         precache_model("models/ebomb.mdl");
1461
1462 #if 0
1463         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1464
1465         if (!self.noise && self.music) // quake 3 uses the music field
1466                 self.noise = self.music;
1467
1468         // plays music for the level if there is any
1469         if (self.noise)
1470         {
1471                 precache_sound (self.noise);
1472                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1473         }
1474 #endif
1475 }
1476
1477 // sorry, but using \ in macros breaks line numbers
1478 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1479 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1480 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1481
1482 vector ExactTriggerHit_mins;
1483 vector ExactTriggerHit_maxs;
1484 float ExactTriggerHit_Recurse()
1485 {
1486         float s;
1487         entity se;
1488         float f;
1489
1490         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1491         if not(trace_ent)
1492                 return 0;
1493         if(trace_ent == self)
1494                 return 1;
1495
1496         se = trace_ent;
1497         s = se.solid;
1498         se.solid = SOLID_NOT;
1499         f = ExactTriggerHit_Recurse();
1500         se.solid = s;
1501
1502         return f;
1503 }
1504
1505 float ExactTriggerHit()
1506 {
1507         float f, s;
1508
1509         if not(self.modelindex)
1510                 return 1;
1511
1512         s = self.solid;
1513         self.solid = SOLID_BSP;
1514         ExactTriggerHit_mins = other.absmin;
1515         ExactTriggerHit_maxs = other.absmax;
1516         f = ExactTriggerHit_Recurse();
1517         self.solid = s;
1518
1519         return f;
1520 }
1521
1522 // WARNING: this kills the trace globals
1523 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1524 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1525
1526 #define INITPRIO_FIRST              0
1527 #define INITPRIO_GAMETYPE           0
1528 #define INITPRIO_GAMETYPE_FALLBACK  1
1529 #define INITPRIO_CVARS              5
1530 #define INITPRIO_FINDTARGET        10
1531 #define INITPRIO_DROPTOFLOOR       20
1532 #define INITPRIO_SETLOCATION       90
1533 #define INITPRIO_LINKDOORS         91
1534 #define INITPRIO_LAST              99
1535
1536 .void(void) initialize_entity;
1537 .float initialize_entity_order;
1538 .entity initialize_entity_next;
1539 entity initialize_entity_first;
1540
1541 void make_safe_for_remove(entity e)
1542 {
1543         if(e.initialize_entity)
1544         {
1545                 entity ent, prev;
1546                 for(ent = initialize_entity_first; ent; )
1547                 {
1548                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1549                         {
1550                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1551                                 // skip it in linked list
1552                                 if(prev)
1553                                 {
1554                                         prev.initialize_entity_next = ent.initialize_entity_next;
1555                                         ent = prev.initialize_entity_next;
1556                                 }
1557                                 else
1558                                 {
1559                                         initialize_entity_first = ent.initialize_entity_next;
1560                                         ent = initialize_entity_first;
1561                                 }
1562                         }
1563                         else
1564                         {
1565                                 prev = ent;
1566                                 ent = ent.initialize_entity_next;
1567                         }
1568                 }
1569         }
1570 }
1571
1572 void objerror(string s)
1573 {
1574         make_safe_for_remove(self);
1575         objerror_builtin(s);
1576 }
1577
1578 void remove_unsafely(entity e)
1579 {
1580         remove_builtin(e);
1581 }
1582
1583 void remove_safely(entity e)
1584 {
1585         make_safe_for_remove(e);
1586         remove_builtin(e);
1587 }
1588
1589 void InitializeEntity(entity e, void(void) func, float order)
1590 {
1591         entity prev, cur;
1592
1593         if(!e || e.initialize_entity)
1594         {
1595                 // make a proxy initializer entity
1596                 entity e_old;
1597                 e_old = e;
1598                 e = spawn();
1599                 e.classname = "initialize_entity";
1600                 e.enemy = e_old;
1601         }
1602
1603         e.initialize_entity = func;
1604         e.initialize_entity_order = order;
1605
1606         cur = initialize_entity_first;
1607         for(;;)
1608         {
1609                 if(!cur || cur.initialize_entity_order > order)
1610                 {
1611                         // insert between prev and cur
1612                         if(prev)
1613                                 prev.initialize_entity_next = e;
1614                         else
1615                                 initialize_entity_first = e;
1616                         e.initialize_entity_next = cur;
1617                         return;
1618                 }
1619                 prev = cur;
1620                 cur = cur.initialize_entity_next;
1621         }
1622 }
1623 void InitializeEntitiesRun()
1624 {
1625         entity startoflist;
1626         startoflist = initialize_entity_first;
1627         initialize_entity_first = world;
1628         for(self = startoflist; self; )
1629         {
1630                 entity e;
1631                 var void(void) func;
1632                 e = self.initialize_entity_next;
1633                 func = self.initialize_entity;
1634                 self.initialize_entity_order = 0;
1635                 self.initialize_entity = func_null;
1636                 self.initialize_entity_next = world;
1637                 if(self.classname == "initialize_entity")
1638                 {
1639                         entity e_old;
1640                         e_old = self.enemy;
1641                         remove_builtin(self);
1642                         self = e_old;
1643                 }
1644                 //dprint("Delayed initialization: ", self.classname, "\n");
1645                 func();
1646                 self = e;
1647         }
1648 }
1649
1650 .float uncustomizeentityforclient_set;
1651 .void(void) uncustomizeentityforclient;
1652 void(void) SUB_Nullpointer = #0;
1653 void UncustomizeEntitiesRun()
1654 {
1655         entity oldself;
1656         oldself = self;
1657         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1658                 self.uncustomizeentityforclient();
1659         self = oldself;
1660 }
1661 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1662 {
1663         e.customizeentityforclient = customizer;
1664         e.uncustomizeentityforclient = uncustomizer;
1665         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1666 }
1667
1668 .float nottargeted;
1669 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1670
1671 void() SUB_Remove;
1672 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1673 {
1674         vector mi, ma;
1675
1676         if(e.classname == "")
1677                 e.classname = "net_linked";
1678
1679         if(e.model == "" || self.modelindex == 0)
1680         {
1681                 mi = e.mins;
1682                 ma = e.maxs;
1683                 setmodel(e, "null");
1684                 setsize(e, mi, ma);
1685         }
1686
1687         e.SendEntity = sendfunc;
1688         e.SendFlags = 0xFFFFFF;
1689
1690         if(!docull)
1691                 e.effects |= EF_NODEPTHTEST;
1692
1693         if(dt)
1694         {
1695                 e.nextthink = time + dt;
1696                 e.think = SUB_Remove;
1697         }
1698 }
1699
1700 void adaptor_think2touch()
1701 {
1702         entity o;
1703         o = other;
1704         other = world;
1705         self.touch();
1706         other = o;
1707 }
1708
1709 void adaptor_think2use()
1710 {
1711         entity o, a;
1712         o = other;
1713         a = activator;
1714         activator = world;
1715         other = world;
1716         self.use();
1717         other = o;
1718         activator = a;
1719 }
1720
1721 // deferred dropping
1722 void DropToFloor_Handler()
1723 {
1724         droptofloor_builtin();
1725         self.dropped_origin = self.origin;
1726 }
1727
1728 void droptofloor()
1729 {
1730         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1731 }
1732
1733
1734
1735 float trace_hits_box_a0, trace_hits_box_a1;
1736
1737 float trace_hits_box_1d(float end, float thmi, float thma)
1738 {
1739         if(end == 0)
1740         {
1741                 // just check if x is in range
1742                 if(0 < thmi)
1743                         return FALSE;
1744                 if(0 > thma)
1745                         return FALSE;
1746         }
1747         else
1748         {
1749                 // do the trace with respect to x
1750                 // 0 -> end has to stay in thmi -> thma
1751                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1752                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1753                 if(trace_hits_box_a0 > trace_hits_box_a1)
1754                         return FALSE;
1755         }
1756         return TRUE;
1757 }
1758
1759 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1760 {
1761         end -= start;
1762         thmi -= start;
1763         thma -= start;
1764         // now it is a trace from 0 to end
1765
1766         trace_hits_box_a0 = 0;
1767         trace_hits_box_a1 = 1;
1768
1769         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1770                 return FALSE;
1771         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1772                 return FALSE;
1773         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1774                 return FALSE;
1775
1776         return TRUE;
1777 }
1778
1779 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1780 {
1781         return trace_hits_box(start, end, thmi - ma, thma - mi);
1782 }
1783
1784 float SUB_NoImpactCheck()
1785 {
1786         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1787                 return 1;
1788         if(other == world && self.size != '0 0 0')
1789         {
1790                 vector tic;
1791                 tic = self.velocity * sys_ticrate;
1792                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1793                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1794                 if(trace_fraction >= 1)
1795                 {
1796                         dprint("Odd... did not hit...?\n");
1797                 }
1798                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1799                 {
1800                         dprint("Detected and prevented the sky-grapple bug.\n");
1801                         return 1;
1802                 }
1803         }
1804
1805         return 0;
1806 }
1807
1808 #define SUB_OwnerCheck() (other && (other == self.owner))
1809
1810 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } if(trace_ent && trace_ent.solid > SOLID_TRIGGER) UpdateCSQCProjectileNextFrame(self); } while(0)
1811
1812 float MAX_IPBAN_URIS = 16;
1813
1814 float URI_GET_DISCARD   = 0;
1815 float URI_GET_IPBAN     = 1;
1816 float URI_GET_IPBAN_END = 16;
1817
1818 void URI_Get_Callback(float id, float status, string data)
1819 {
1820         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1821         dprint(data);
1822         dprint("\nEnd of data.\n");
1823
1824         if(id == URI_GET_DISCARD)
1825         {
1826                 // discard
1827         }
1828         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1829         {
1830                 // online ban list
1831                 OnlineBanList_URI_Get_Callback(id, status, data);
1832         }
1833         else
1834         {
1835                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1836         }
1837 }
1838
1839 void print_to(entity e, string s)
1840 {
1841         if(e)
1842                 sprint(e, strcat(s, "\n"));
1843         else
1844                 print(s, "\n");
1845 }
1846
1847 string getrecords()
1848 {
1849         float rec;
1850         string h;
1851         float r;
1852         float i;
1853         string s;
1854
1855         rec = 0;
1856
1857         s = "";
1858
1859         if(g_ctf)
1860         {
1861                 for(i = 0; i < MapInfo_count; ++i)
1862                 {
1863                         if(MapInfo_Get_ByID(i))
1864                         {
1865                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1866                                 if(r == 0)
1867                                         continue;
1868                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1869                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1870                                 ++rec;
1871                         }
1872                 }
1873         }
1874
1875         if(g_race)
1876         {
1877                 for(i = 0; i < MapInfo_count; ++i)
1878                 {
1879                         if(MapInfo_Get_ByID(i))
1880                         {
1881                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1882                                 if(r == 0)
1883                                         continue;
1884                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1885                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1886                                 ++rec;
1887                         }
1888                 }
1889         }
1890         MapInfo_ClearTemps();
1891
1892         if(s == "")
1893                 return "No records are available on this server.\n";
1894         else
1895                 return strcat("Records on this server:\n", s);
1896 }
1897
1898 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1899 {
1900         float m, i;
1901         vector start, org, delta, end, enddown, mstart;
1902
1903         m = e.dphitcontentsmask;
1904         e.dphitcontentsmask = goodcontents | badcontents;
1905
1906         org = world.mins;
1907         delta = world.maxs - world.mins;
1908
1909         for(i = 0; i < attempts; ++i)
1910         {
1911                 start_x = org_x + random() * delta_x;
1912                 start_y = org_y + random() * delta_y;
1913                 start_z = org_z + random() * delta_z;
1914
1915                 // rule 1: start inside world bounds, and outside
1916                 // solid, and don't start from somewhere where you can
1917                 // fall down to evil
1918                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1919                 if(trace_fraction >= 1)
1920                         continue;
1921                 if(trace_startsolid)
1922                         continue;
1923                 if(trace_dphitcontents & badcontents)
1924                         continue;
1925                 if(trace_dphitq3surfaceflags & badsurfaceflags)
1926                         continue;
1927
1928                 // rule 2: if we are too high, lower the point
1929                 if(trace_fraction * delta_z > maxaboveground)
1930                         start = trace_endpos + '0 0 1' * maxaboveground;
1931                 enddown = trace_endpos;
1932
1933                 // rule 3: make sure we aren't outside the map. This only works
1934                 // for somewhat well formed maps. A good rule of thumb is that
1935                 // the map should have a convex outside hull.
1936                 // these can be traceLINES as we already verified the starting box
1937                 mstart = start + 0.5 * (e.mins + e.maxs);
1938                 traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1939                 if(trace_fraction >= 1)
1940                         continue;
1941                 traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1942                 if(trace_fraction >= 1)
1943                         continue;
1944                 traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1945                 if(trace_fraction >= 1)
1946                         continue;
1947                 traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1948                 if(trace_fraction >= 1)
1949                         continue;
1950                 traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1951                 if(trace_fraction >= 1)
1952                         continue;
1953
1954                 // find a random vector to "look at"
1955                 end_x = org_x + random() * delta_x;
1956                 end_y = org_y + random() * delta_y;
1957                 end_z = org_z + random() * delta_z;
1958                 end = start + normalize(end - start) * vlen(delta);
1959
1960                 // rule 4: start TO end must not be too short
1961                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1962                 if(trace_startsolid)
1963                         continue;
1964                 if(trace_fraction < minviewdistance / vlen(delta))
1965                         continue;
1966
1967                 // rule 5: don't want to look at sky
1968                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1969                         continue;
1970
1971                 // rule 6: we must not end up in trigger_hurt
1972                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1973                 {
1974                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
1975                         continue;
1976                 }
1977
1978                 break;
1979         }
1980
1981         e.dphitcontentsmask = m;
1982
1983         if(i < attempts)
1984         {
1985                 setorigin(e, start);
1986                 e.angles = vectoangles(end - start);
1987                 dprint("Needed ", ftos(i + 1), " attempts\n");
1988                 return TRUE;
1989         }
1990         else
1991                 return FALSE;
1992 }
1993
1994 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
1995 {
1996         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
1997         WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
1998         WriteShort(MSG_BROADCAST, effectno);
1999         WriteCoord(MSG_BROADCAST, start_x);
2000         WriteCoord(MSG_BROADCAST, start_y);
2001         WriteCoord(MSG_BROADCAST, start_z);
2002         WriteCoord(MSG_BROADCAST, end_x);
2003         WriteCoord(MSG_BROADCAST, end_y);
2004         WriteCoord(MSG_BROADCAST, end_z);
2005         WriteCoord(MSG_BROADCAST, end_dz);
2006         WriteShort(MSG_BROADCAST, spd / 16);
2007 }
2008
2009 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2010 {
2011         float end_dz;
2012         vector vecxy, velxy;
2013
2014         vecxy = end - start; vecxy_z = 0;
2015         velxy = vel;         velxy_z = 0;
2016
2017         if(vlen(velxy) < 0.000001 * fabs(vel_z))
2018         {
2019                 trailparticles(world, effectno, start, end);
2020                 return;
2021         }
2022
2023         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2024         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2025 }
2026
2027 string GetGametype(); // g_world.qc
2028 void write_recordmarker(entity pl, float tstart, float dt)
2029 {
2030         GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt / 10)));
2031
2032         // also write a marker into demo files for demotc-race-record-extractor to find
2033         stuffcmd(pl,
2034                 strcat(
2035                         strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", mmsss(dt * 10)),
2036                         " ", ftos(tstart), " ", ftos(dt), "\n"));
2037 }
2038
2039 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2040 {
2041         if (cvar("g_shootfromeye"))
2042         {
2043                 if(visual)
2044                 {
2045                         vecs_y = 0;
2046                         vecs_z -= 4;
2047                 }
2048                 else
2049                 {
2050                         vecs_y = 0;
2051                         vecs_z = 0;
2052                 }
2053         }
2054         else if (cvar("g_shootfromcenter"))
2055         {
2056                 vecs_y = 0;
2057                 vecs_z -= 4;
2058         }
2059         return vecs;
2060 }
2061
2062
2063
2064 void attach_sameorigin(entity e, entity to, string tag)
2065 {
2066         vector org, t_forward, t_left, t_up, e_forward, e_up;
2067         vector org0, ang0;
2068         float tagscale;
2069
2070         ang0 = e.angles;
2071         org0 = e.origin;
2072
2073         org = e.origin - gettaginfo(to, gettagindex(to, tag));
2074         tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2075         t_forward = v_forward * tagscale;
2076         t_left = v_right * -tagscale;
2077         t_up = v_up * tagscale;
2078
2079         e.origin_x = org * t_forward;
2080         e.origin_y = org * t_left;
2081         e.origin_z = org * t_up;
2082
2083         // current forward and up directions
2084         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2085                 e.angles_x = -e.angles_x;
2086         fixedmakevectors(e.angles);
2087
2088         // untransform forward, up!
2089         e_forward_x = v_forward * t_forward;
2090         e_forward_y = v_forward * t_left;
2091         e_forward_z = v_forward * t_up;
2092         e_up_x = v_up * t_forward;
2093         e_up_y = v_up * t_left;
2094         e_up_z = v_up * t_up;
2095
2096         e.angles = fixedvectoangles2(e_forward, e_up);
2097         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2098                 e.angles_x = -e.angles_x;
2099
2100         setattachment(e, to, tag);
2101         setorigin(e, e.origin);
2102 }
2103
2104 void detach_sameorigin(entity e)
2105 {
2106         vector org;
2107         org = gettaginfo(e, 0);
2108         e.angles = fixedvectoangles2(v_forward, v_up);
2109         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2110                 e.angles_x = -e.angles_x;
2111         e.origin = org;
2112         setattachment(e, world, "");
2113         setorigin(e, e.origin);
2114 }
2115
2116 void follow_sameorigin(entity e, entity to)
2117 {
2118         e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2119         e.aiment = to; // make the hole follow bmodel
2120         e.punchangle = to.angles; // the original angles of bmodel
2121         e.view_ofs = e.origin - to.origin; // relative origin
2122         e.v_angle = e.angles - to.angles; // relative angles
2123 }
2124
2125 void unfollow_sameorigin(entity e)
2126 {
2127         e.movetype = MOVETYPE_NONE;
2128 }
2129
2130 entity gettaginfo_relative_ent;
2131 vector gettaginfo_relative(entity e, float tag)
2132 {
2133         if(!gettaginfo_relative_ent)
2134         {
2135                 gettaginfo_relative_ent = spawn();
2136                 gettaginfo_relative_ent.effects = EF_NODRAW;
2137         }
2138         gettaginfo_relative_ent.model = e.model;
2139         gettaginfo_relative_ent.modelindex = e.modelindex;
2140         gettaginfo_relative_ent.frame = e.frame;
2141         return gettaginfo(gettaginfo_relative_ent, tag);
2142 }