data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25 float kh_no_radar_circles;
  26
  27 // kh_state
  28 //     bits 0-7: player's key status
  29 //     bits 8-15: general key status
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  35 //test[0] = status of dropped keys, test[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      test[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return COLOR_TEAM1;
  43         if(t == 1) return COLOR_TEAM2;
  44         if(t == 2) return COLOR_TEAM3;
  45         if(t == 3) return COLOR_TEAM4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60
  61 string kh_sound_capture = "sound/kh/capture.wav";
  62 string kh_sound_destroy = "sound/kh/destroy.wav";
  63 string kh_sound_drop = "sound/kh/drop.wav";
  64 string kh_sound_collect = "sound/kh/collect.wav";
  65 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  66
  67 float kh_key_dropped, kh_key_carried;
  68
  69 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  70 {
  71         kh_Controller_Thinkfunc = func;
  72         kh_controller.cnt = t;
  73         if(kh_Controller_Waitmsg != "")
  74                 strunzone(kh_Controller_Waitmsg);
  75         if(msg == "")
  76                 kh_Controller_Waitmsg = "";
  77         else
  78                 kh_Controller_Waitmsg = strzone(msg);
  79         if(t == 0)
  80                 kh_controller.nextthink = time; // force
  81 }
  82
  83 void kh_Controller_Think()  // called a lot
  84 {
  85         entity e;
  86         if(intermission_running)
  87                 return;
  88         if(self.cnt > 0)
  89         {
  90                 if(kh_Controller_Waitmsg != "")
  91                 {
  92                         string s;
  93                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  94                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  95                         else
  96                                 s = kh_Controller_Waitmsg;
  97
  98                         //dprint(s, "\n");
  99
 100                         FOR_EACH_PLAYER(e)
 101                                 if(clienttype(e) == CLIENTTYPE_REAL)
 102                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 103                 }
 104                 self.cnt -= 1;
 105         }
 106         else if(self.cnt == 0)
 107         {
 108                 self.cnt -= 1;
 109                 kh_Controller_Thinkfunc();
 110         }
 111         self.nextthink = time + 1;
 112 }
 113
 114 // frags f: take from cvar * f
 115 // frags 0: no frags
 116 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 117 {
 118         string s;
 119         if(intermission_running)
 120                 return;
 121         if(frags_player)
 122                 UpdateFrags(player, frags_player);
 123         if(key && key.owner && frags_owner)
 124                 UpdateFrags(key.owner, frags_owner);
 125         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 126                 return;
 127         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 128         s = strcat(s, ":", ftos(frags_player));
 129         if(key && key.owner)
 130                 s = strcat(s, ":", ftos(key.owner.playerid));
 131         else
 132                 s = strcat(s, ":0");
 133         s = strcat(s, ":", ftos(frags_owner), ":");
 134         if(key)
 135                 s = strcat(s, key.netname);
 136         GameLogEcho(s);
 137 }
 138
 139 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 140 {
 141         if(e.tag_entity)
 142         {
 143                 makevectors(e.tag_entity.angles);
 144                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 145         }
 146         else
 147                 return e.origin;
 148 }
 149
 150 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 151 {
 152 #ifdef KH_PLAYER_USE_ATTACHMENT
 153         entity first;
 154         first = key.owner.kh_next;
 155         if(key == first)
 156         {
 157                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 158                 if(key.kh_next)
 159                 {
 160                         setattachment(key.kh_next, key, "");
 161                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 162                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 163                         key.kh_next.angles = '0 0 0';
 164                 }
 165                 else
 166                         setorigin(key, KH_PLAYER_ATTACHMENT);
 167                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 168         }
 169         else
 170         {
 171                 setattachment(key, key.kh_prev, "");
 172                 if(key.kh_next)
 173                         setattachment(key.kh_next, key, "");
 174                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 175                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 176                 key.angles = '0 0 0';
 177         }
 178 #else
 179         setattachment(key, key.owner, "");
 180         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 181         key.angles_y -= key.owner.angles_y;
 182 #endif
 183         key.flags = 0;
 184         key.solid = SOLID_NOT;
 185         key.movetype = MOVETYPE_NONE;
 186         key.team = key.owner.team;
 187         key.nextthink = time;
 188         key.damageforcescale = 0;
 189         key.modelindex = kh_key_carried;
 190 }
 191
 192 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 193 {
 194         float i;
 195         i = test[key.owner.playerid];
 196                 if(key.netname == "^1red key")
 197                         i -= 1;
 198                 if(key.netname == "^4blue key")
 199                         i -= 2;
 200                 if(key.netname == "^3yellow key")
 201                         i -= 4;
 202                 if(key.netname == "^6pink key")
 203                         i -= 8;
 204         test[key.owner.playerid] = i;
 205
 206         kh_show_temp();
 207         if(key.owner)
 208                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 209         //key.owner.kh_state += test[key.owner.playerid];
 210
 211 #ifdef KH_PLAYER_USE_ATTACHMENT
 212         entity first;
 213         first = key.owner.kh_next;
 214         if(key == first)
 215         {
 216                 if(key.kh_next)
 217                 {
 218                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 219                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 220                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 221                 }
 222         }
 223         else
 224         {
 225                 if(key.kh_next)
 226                         setattachment(key.kh_next, key.kh_prev, "");
 227                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 228         }
 229         // in any case:
 230         setattachment(key, world, "");
 231         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 232         key.angles = key.owner.angles;
 233 #else
 234         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 235         setattachment(key, world, "");
 236         key.angles_y += key.owner.angles_y;
 237 #endif
 238         key.flags = FL_ITEM;
 239         key.solid = SOLID_TRIGGER;
 240         key.movetype = MOVETYPE_TOSS;
 241         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 242         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 243         // let key.team stay
 244         key.modelindex = kh_key_dropped;
 245         key.kh_previous_owner = key.owner;
 246         key.kh_previous_owner_playerid = key.owner.playerid;
 247 }
 248
 249 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 250 {
 251         entity k;
 252         float ownerteam0, ownerteam;
 253         if(key.owner == player)
 254                 return;
 255
 256         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 257
 258         if(key.owner)
 259         {
 260                 kh_Key_Detach(key);
 261
 262                 // remove from linked list
 263                 if(key.kh_next)
 264                         key.kh_next.kh_prev = key.kh_prev;
 265                 key.kh_prev.kh_next = key.kh_next;
 266                 key.kh_next = world;
 267                 key.kh_prev = world;
 268
 269                 if(key.owner.kh_next == world)
 270                 {
 271                         // No longer a key carrier
 272                         if(!kh_no_radar_circles)
 273                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 274                         WaypointSprite_DetachCarrier(key.owner);
 275                 }
 276         }
 277
 278         key.owner = player;
 279
 280         if(player)
 281         {
 282                 // insert into linked list
 283                 key.kh_next = player.kh_next;
 284                 key.kh_prev = player;
 285                 player.kh_next = key;
 286                 if(key.kh_next)
 287                         key.kh_next.kh_prev = key;
 288
 289                 float i;
 290                 i = test[key.owner.playerid];
 291                         if(key.netname == "^1red key")
 292                                 i += 1;
 293                         if(key.netname == "^4blue key")
 294                                 i += 2;
 295                         if(key.netname == "^3yellow key")
 296                                 i += 4;
 297                         if(key.netname == "^6pink key")
 298                                 i += 8;
 299                 test[key.owner.playerid] = i;
 300
 301                 kh_Key_Attach(key);
 302
 303                 if(key.kh_next == world)
 304                 {
 305                         // player is now a key carrier
 306                         WaypointSprite_AttachCarrier("", player);
 307                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 308                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 309                         if(player.team == COLOR_TEAM1)
 310                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "");
 311                         else if(player.team == COLOR_TEAM2)
 312                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "");
 313                         else if(player.team == COLOR_TEAM3)
 314                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "");
 315                         else if(player.team == COLOR_TEAM4)
 316                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "");
 317                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 318                         if(!kh_no_radar_circles)
 319                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 320                 }
 321         }
 322
 323         // moved that here, also update if there's no player
 324         kh_show_temp();
 325         if(key.owner)
 326                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 327
 328         key.pusher = world;
 329
 330         ownerteam = kh_Key_AllOwnedByWhichTeam();
 331         if(ownerteam != ownerteam0)
 332         {
 333                 if(ownerteam != -1)
 334                 {
 335                         kh_interferemsg_time = time + 0.2;
 336                         kh_interferemsg_team = player.team;
 337
 338                         // audit all key carrier sprites, update them to RUN HERE
 339                         FOR_EACH_KH_KEY(k)
 340                         {
 341                                 if(k.owner)
 342                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-finish", "");
 343                         }
 344                 }
 345                 else
 346                 {
 347                         kh_interferemsg_time = 0;
 348
 349                         // audit all key carrier sprites, update them to RUN HERE
 350                         FOR_EACH_KH_KEY(k)
 351                         {
 352                                 if(k.owner)
 353                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-friend", "");
 354                         }
 355                 }
 356         }
 357 }
 358
 359 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 360 {
 361         if(self.owner)
 362                 return;
 363         if(vlen(force) <= 0)
 364                 return;
 365         if(time > self.pushltime)
 366                 if(attacker.classname == "player")
 367                         self.team = attacker.team;
 368 }
 369
 370 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 371 {
 372         entity key;
 373         key = spawn();
 374         key.classname = STR_ITEM_KH_KEY;
 375         key.touch = kh_Key_Touch;
 376         key.think = kh_Key_Think;
 377         key.nextthink = time;
 378         key.items = IT_KEY1 | IT_KEY2;
 379         key.cnt = angle;
 380         key.angles = '0 360 0' * random();
 381         key.event_damage = kh_Key_Damage;
 382         key.takedamage = DAMAGE_YES;
 383         key.modelindex = kh_key_dropped;
 384         key.model = "key";
 385         key.kh_dropperteam = 0;
 386         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 387         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 388         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 389
 390         switch(initial_owner.team)
 391         {
 392                 case COLOR_TEAM1:
 393                         key.netname = "^1red key";
 394                         break;
 395                 case COLOR_TEAM2:
 396                         key.netname = "^4blue key";
 397                         break;
 398                 case COLOR_TEAM3:
 399                         key.netname = "^3yellow key";
 400                         break;
 401                 case COLOR_TEAM4:
 402                         key.netname = "^6pink key";
 403                         break;
 404                 default:
 405                         key.netname = "NETGIER key";
 406                         break;
 407         }
 408
 409         // link into key list
 410         key.kh_worldkeynext = kh_worldkeylist;
 411         kh_worldkeylist = key;
 412
 413         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 414
 415         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 416         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 417         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 418
 419         kh_Key_AssignTo(key, initial_owner);
 420 }
 421
 422 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 423 {
 424         entity o;
 425         o = key.owner;
 426         kh_Key_AssignTo(key, world);
 427         if(o) // it was attached
 428                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 429         else // it was dropped
 430                 WaypointSprite_DetachCarrier(key);
 431
 432         // remove key from key list
 433         if (kh_worldkeylist == key)
 434                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 435         else
 436         {
 437                 o = kh_worldkeylist;
 438                 while (o)
 439                 {
 440                         if (o.kh_worldkeynext == key)
 441                         {
 442                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 443                                 break;
 444                         }
 445                         o = o.kh_worldkeynext;
 446                 }
 447         }
 448
 449         remove(key);
 450 }
 451
 452 // -1 when no team completely owns all keys yet
 453 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 454 {
 455         entity key;
 456         float teem;
 457         float keys;
 458
 459         teem = -1;
 460         keys = kh_teams;
 461         FOR_EACH_KH_KEY(key)
 462         {
 463                 if(!key.owner)
 464                         return -1;
 465                 if(teem == -1)
 466                         teem = key.team;
 467                 else if(teem != key.team)
 468                         return -1;
 469                 --keys;
 470         }
 471         if(keys != 0)
 472                 return -1;
 473         return teem;
 474 }
 475
 476 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 477 {
 478         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 479
 480         if(key.kh_dropperteam != player.team)
 481         {
 482                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 483                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 484         }
 485         key.kh_dropperteam = 0;
 486         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 487
 488         kh_Key_AssignTo(key, player); // this also updates .kh_state
 489 }
 490
 491 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 492 {
 493         entity key;
 494         entity mypusher;
 495         if(player.kh_next)
 496         {
 497                 mypusher = world;
 498                 if(player.pusher)
 499                         if(time < player.pushltime)
 500                                 mypusher = player.pusher;
 501                 while((key = player.kh_next))
 502                 {
 503                         kh_Scores_Event(player, key, "losekey", 0, 0);
 504                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 505                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 506                         kh_Key_AssignTo(key, world);
 507                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 508                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 509                         key.pusher = mypusher;
 510                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 511                         if(suicide)
 512                                 key.kh_dropperteam = player.team;
 513                 }
 514                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 515         }
 516 }
 517
 518 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 519 {
 520         if(intermission_running)
 521                 return;
 522
 523         if(self.owner) // already carried
 524                 return;
 525         if(other.classname != "player")
 526                 return;
 527         if(other.deadflag != DEAD_NO)
 528                 return;
 529         if(other == self.enemy)
 530                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 531                         return;  // you just dropped it!
 532         kh_Key_Collect(self, other);
 533 }
 534
 535 void kh_Key_Think()  // runs all the time
 536 {
 537         entity head;
 538         //entity player;  // needed by FOR_EACH_PLAYER
 539
 540         if(intermission_running)
 541                 return;
 542         /*
 543         if(time > self.stuff_time)
 544         {
 545                 FOR_EACH_PLAYER(player)
 546                         player.kh_state = test[0]*256 + (player.kh_state&255);
 547
 548                 self.stuff_time = time + 1;  // repeat in 1 second
 549         }
 550         */
 551
 552 #ifdef KH_KEY_ATTACHMENT_DEBUG
 553         if(self.kh_prev == self.owner)
 554         {
 555                 if(cvar_string("_angles") != "")
 556                 {
 557                         self.angles = stov(cvar_string("_angles"));
 558                         self.origin = stov(cvar_string("_origin"));
 559                 }
 560         }
 561 #endif
 562
 563         if(self.owner)
 564         {
 565 #ifndef KH_PLAYER_USE_ATTACHMENT
 566                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 567                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 568 #endif
 569
 570                 if(self.owner.BUTTON_USE)
 571                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 572                 {
 573                         self.owner.kh_droptime = time;
 574                         self.kh_droptime = time;  // prevent collecting this one for some time
 575                         self.enemy = self.owner;
 576                         self.pusher = world;
 577                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 578                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 579                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 580                         makevectors(self.owner.v_angle);
 581                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 582                         kh_Key_AssignTo(self, world);
 583                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 584                         self.kh_dropperteam = self.team;
 585                 }
 586         }
 587
 588         // if in nodrop or time over, end the round
 589         if(!self.owner)
 590                 if(time > self.pain_finished)
 591                         kh_LoserTeam(self.team, self);
 592
 593         if(self.owner)
 594         if(kh_Key_AllOwnedByWhichTeam() != -1)
 595         {
 596                 if(self.siren_time < time)
 597                 {
 598                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 599                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 600                 }
 601
 602                 entity key;
 603                 vector p;
 604                 p = self.owner.origin;
 605                 FOR_EACH_KH_KEY(key)
 606                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 607                                 goto not_winning;
 608                 kh_WinnerTeam(self.team);
 609 :not_winning
 610         }
 611
 612         if(kh_interferemsg_time && time > kh_interferemsg_time)
 613         {
 614                 kh_interferemsg_time = 0;
 615                 FOR_EACH_PLAYER(head)
 616                 {
 617                         if(head.team == kh_interferemsg_team)
 618                                 if(head.kh_next)
 619                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 620                                 else
 621                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 622                         else
 623                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 624                 }
 625         }
 626
 627         self.nextthink = time + 0.05;
 628 }
 629
 630 void kh_WinnerTeam(float teem)  // runs when a team wins
 631 {
 632         // all key carriers get some points
 633         vector firstorigin, lastorigin, midpoint;
 634         float first;
 635         entity key;
 636         float score;
 637         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 638         DistributeEvenly_Init(score, kh_teams);
 639         // twice the score for 3 team games, three times the score for 4 team games!
 640         // note: for a win by destroying the key, this should NOT be applied
 641         FOR_EACH_KH_KEY(key)
 642         {
 643                 float f;
 644                 f = DistributeEvenly_Get(1);
 645                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 646                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 647         }
 648
 649         first = TRUE;
 650         FOR_EACH_KH_KEY(key)
 651                 if(key.owner.kh_next == key)
 652                 {
 653                         if(!first)
 654                                 bprint("^7, ");
 655                         bprint(key.owner.netname);
 656                         first = FALSE;
 657                 }
 658         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 659
 660         first = TRUE;
 661         midpoint = '0 0 0';
 662         FOR_EACH_KH_KEY(key)
 663         {
 664                 vector thisorigin;
 665
 666                 thisorigin = kh_AttachedOrigin(key);
 667                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 668                 midpoint += thisorigin;
 669
 670                 if(!first)
 671                         te_lightning2(world, lastorigin, thisorigin);
 672                 lastorigin = thisorigin;
 673                 if(first)
 674                         firstorigin = thisorigin;
 675                 first = FALSE;
 676         }
 677         if(kh_teams > 2)
 678         {
 679                 te_lightning2(world, lastorigin, firstorigin);
 680         }
 681         midpoint = midpoint * (1 / kh_teams);
 682         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 683
 684         play2all(kh_sound_capture);
 685         kh_FinishRound();
 686 }
 687
 688 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 689 {
 690         entity player, key, attacker;
 691         float players;
 692         float keys;
 693         float f;
 694
 695         attacker = world;
 696         if(lostkey.pusher)
 697                 if(lostkey.pusher.team != teem)
 698                         if(lostkey.pusher.classname == "player")
 699                                 attacker = lostkey.pusher;
 700
 701         players = keys = 0;
 702
 703         if(attacker)
 704         {
 705                 if(lostkey.kh_previous_owner)
 706                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 707                         // don't actually GIVE him the -nn points, just log
 708                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 709                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 710                 centerprint(attacker, "Your push is the best!\n\n\n");
 711                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 712         }
 713         else
 714         {
 715                 float of, fragsleft, i, j, thisteam;
 716                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 717
 718                 FOR_EACH_PLAYER(player)
 719                         if(player.team != teem)
 720                                 ++players;
 721
 722                 FOR_EACH_KH_KEY(key)
 723                         if(key.owner && key.team != teem)
 724                                 ++keys;
 725
 726                 if(lostkey.kh_previous_owner)
 727                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 728                         // don't actually GIVE him the -nn points, just log
 729
 730                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 731                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 732
 733                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 734
 735                 FOR_EACH_KH_KEY(key)
 736                         if(key.owner && key.team != teem)
 737                         {
 738                                 f = DistributeEvenly_Get(of);
 739                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 740                         }
 741
 742                 fragsleft = DistributeEvenly_Get(players);
 743
 744                 // Now distribute these among all other teams...
 745                 j = kh_teams - 1;
 746                 for(i = 0; i < kh_teams; ++i)
 747                 {
 748                         thisteam = kh_Team_ByID(i);
 749                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 750                                 continue;
 751
 752                         players = 0;
 753                         FOR_EACH_PLAYER(player)
 754                                 if(player.team == thisteam)
 755                                         ++players;
 756
 757                         DistributeEvenly_Init(fragsleft, j);
 758                         fragsleft = DistributeEvenly_Get(j - 1);
 759                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 760
 761                         FOR_EACH_PLAYER(player)
 762                                 if(player.team == thisteam)
 763                                 {
 764                                         f = DistributeEvenly_Get(1);
 765                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 766                                 }
 767
 768                         --j;
 769                 }
 770
 771                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 772         }
 773         play2all(kh_sound_destroy);
 774         te_tarexplosion(lostkey.origin);
 775
 776         kh_FinishRound();
 777 }
 778
 779 void kh_FinishRound()  // runs when a team captures the keys
 780 {
 781         // prepare next round
 782         kh_interferemsg_time = 0;
 783         entity key;
 784
 785         kh_no_radar_circles = TRUE;
 786         FOR_EACH_KH_KEY(key)
 787                 kh_Key_Remove(key);
 788         kh_no_radar_circles = FALSE;
 789
 790         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 791 }
 792
 793 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 794 {
 795         float i, players, teem;
 796         entity player;
 797         string result;
 798         result = "";
 799
 800         // find a random player per team
 801         for(i = 0; i < kh_teams; ++i)
 802         {
 803                 teem = kh_Team_ByID(i);
 804                 players = 0;
 805                 FOR_EACH_PLAYER(player)
 806                         if(player.deadflag == DEAD_NO)
 807                                 if(!player.BUTTON_CHAT)
 808                                         if(player.team == teem)
 809                                                 ++players;
 810                 if(players == 0)
 811                 {
 812                         if(result != "")
 813                                 result = strcat(result, ", ");
 814                         result = strcat(result, ColoredTeamName(teem));
 815                 }
 816         }
 817         return result;
 818 }
 819
 820 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 821 {
 822         string teams_missing;
 823         teams_missing = kh_CheckEnoughPlayers();
 824         if(teams_missing == "")
 825                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 826         else
 827                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 828 }
 829
 830 void kh_StartRound()  // runs at the start of each round
 831 {
 832         string teams_missing;
 833         float i, players, teem;
 834         entity player;
 835
 836         teams_missing = kh_CheckEnoughPlayers();
 837         if(teams_missing != "")
 838         {
 839                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 840                 return;
 841         }
 842
 843         FOR_EACH_PLAYER(player)
 844                 if(clienttype(player) == CLIENTTYPE_REAL)
 845                         centerprint_expire(player, CENTERPRIO_SPAM);
 846
 847         for(i = 0; i < kh_teams; ++i)
 848         {
 849                 teem = kh_Team_ByID(i);
 850                 players = 0;
 851                 entity my_player;
 852                 FOR_EACH_PLAYER(player)
 853                         if(player.deadflag == DEAD_NO)
 854                                 if(!player.BUTTON_CHAT)
 855                                         if(player.team == teem)
 856                                         {
 857                                                 ++players;
 858                                                 if(random() * players <= 1)
 859                                                         my_player = player;
 860                                         }
 861                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 862                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 863                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 864         }
 865
 866         kh_tracking_enabled = FALSE;
 867         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 868 }
 869
 870 void kh_setstatus()  // runs all the time
 871 {
 872         if(kh_teams)
 873         {
 874                 float kh_KEY;
 875                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 876                 if(self.kh_next)
 877                         self.items = self.items | kh_KEY;
 878                 else
 879                         self.items = self.items - (self.items & kh_KEY);
 880         }
 881 }
 882
 883 void kh_EnableTrackingDevice()  // runs after each round
 884 {
 885         entity player;
 886
 887         FOR_EACH_PLAYER(player)
 888                 if(clienttype(player) == CLIENTTYPE_REAL)
 889                         centerprint_expire(player, CENTERPRIO_SPAM);
 890
 891         kh_tracking_enabled = TRUE;
 892 }
 893
 894 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 895 {
 896         if(!kh_tracking_enabled)
 897                 return FALSE;
 898         if(!self.owner)
 899                 return TRUE;
 900         if(!self.owner.owner)
 901                 return TRUE;
 902         return FALSE;  // draw only when key is not owned
 903 }
 904
 905 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 906 {
 907         if(e.classname != "player" || self.team != e.team)
 908                 if(!kh_tracking_enabled)
 909                         return FALSE;
 910
 911         return TRUE;
 912 }
 913
 914 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 915 {
 916         if(attacker == targ)
 917                 return f;
 918
 919         if(targ.kh_next)
 920         {
 921                 if(attacker.team == targ.team)
 922                 {
 923                         entity k;
 924                         float nk;
 925                         nk = 0;
 926                         for(k = targ.kh_next; k != world; k = k.kh_next)
 927                                 ++nk;
 928                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 929                 }
 930                 else
 931                 {
 932                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 933                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 934                         // the frag gets added later
 935                 }
 936         }
 937
 938         return f;
 939 }
 940
 941 void kh_init()  // sets up th KH environment
 942 {
 943         precache_sound(kh_sound_capture);
 944         precache_sound(kh_sound_destroy);
 945         precache_sound(kh_sound_drop);
 946         precache_sound(kh_sound_collect);
 947         precache_sound(kh_sound_alarm);  // the new siren
 948
 949 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 950         precache_model("models/keyhunt/key-carried.md3");
 951 #endif
 952         precache_model("models/keyhunt/key.md3");
 953
 954         // setup variables
 955         kh_teams = cvar("g_keyhunt_teams_override");
 956         if(kh_teams < 2)
 957                 kh_teams = cvar("g_keyhunt_teams");
 958         kh_teams = bound(2, kh_teams, 4);
 959
 960         // make a KH entity for controlling the game
 961         kh_controller = spawn();
 962         kh_controller.think = kh_Controller_Think;
 963         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 964
 965         setmodel(kh_controller, "models/keyhunt/key.md3");
 966         kh_key_dropped = kh_controller.modelindex;
 967         /*
 968         dprint(vtos(kh_controller.mins));
 969         dprint(vtos(kh_controller.maxs));
 970         dprint("\n");
 971         */
 972 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 973         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 974         kh_key_carried = kh_controller.modelindex;
 975 #else
 976         kh_key_carried = kh_key_dropped;
 977 #endif
 978
 979         kh_controller.model = "";
 980         kh_controller.modelindex = 0;
 981
 982         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 983
 984         ScoreRules_kh(kh_teams);
 985 }
 986
 987 void kh_finalize()
 988 {
 989         // to be called before intermission
 990         kh_FinishRound();
 991         remove(kh_controller);
 992         kh_controller = world;
 993 }
 994
 995 /**
 996  * kh_show_temp originally by victim.
 997  * changed it to use the kh_state stat var
 998  * Updates the general key stat bits for each player
 999  */
1000 void kh_show_temp()
1001 {
1002         entity player;
1003         float i, j;
1004
1005         j = 0;  // reset/blank j
1006         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1007                 j += test[i];
1008
1009         test[0] = j;
1010
1011         j *= 256;
1012         FOR_EACH_PLAYER(player)
1013                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1014 }