data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58
  59 string kh_sound_capture = "sound/kh/capture.wav";
  60 string kh_sound_destroy = "sound/kh/destroy.wav";
  61 string kh_sound_drop = "sound/kh/drop.wav";
  62 string kh_sound_collect = "sound/kh/collect.wav";
  63 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  64
  65 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  66 float kh_key_dropped, kh_key_carried;
  67
  68 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  69 {
  70         if(t == e)           return kh_sprite_friend;
  71         if(t == COLOR_TEAM1) return kh_sprite_red;
  72         if(t == COLOR_TEAM2) return kh_sprite_blue;
  73         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  74         if(t == COLOR_TEAM4) return kh_sprite_pink;
  75         return 0;
  76 }
  77
  78 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  79 {
  80         kh_Controller_Thinkfunc = func;
  81         kh_controller.cnt = t;
  82         if(kh_Controller_Waitmsg != "")
  83                 strunzone(kh_Controller_Waitmsg);
  84         if(msg == "")
  85                 kh_Controller_Waitmsg = "";
  86         else
  87                 kh_Controller_Waitmsg = strzone(msg);
  88         if(t == 0)
  89                 kh_controller.nextthink = time; // force
  90 }
  91
  92 void kh_Controller_Think()  // called a lot
  93 {
  94         entity e;
  95         if(intermission_running)
  96                 return;
  97         if(self.cnt > 0)
  98         {
  99                 if(kh_Controller_Waitmsg != "")
 100                 {
 101                         string s;
 102                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 103                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 104                         else
 105                                 s = kh_Controller_Waitmsg;
 106
 107                         //dprint(s, "\n");
 108
 109                         FOR_EACH_PLAYER(e)
 110                                 if(clienttype(e) == CLIENTTYPE_REAL)
 111                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 112                 }
 113                 self.cnt -= 1;
 114         }
 115         else if(self.cnt == 0)
 116         {
 117                 self.cnt -= 1;
 118                 kh_Controller_Thinkfunc();
 119         }
 120         self.nextthink = time + 1;
 121 }
 122
 123 // frags f: take from cvar * f
 124 // frags 0: no frags
 125 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 126 {
 127         string s;
 128         if(intermission_running)
 129                 return;
 130         if(frags_player)
 131                 UpdateFrags(player, frags_player);
 132         if(key && key.owner && frags_owner)
 133                 UpdateFrags(key.owner, frags_owner);
 134         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 135                 return;
 136         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 137         s = strcat(s, ":", ftos(frags_player));
 138         if(key && key.owner)
 139                 s = strcat(s, ":", ftos(key.owner.playerid));
 140         else
 141                 s = strcat(s, ":0");
 142         s = strcat(s, ":", ftos(frags_owner), ":");
 143         if(key)
 144                 s = strcat(s, key.netname);
 145         GameLogEcho(s, FALSE);
 146 }
 147
 148 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 149 {
 150         if(e.tag_entity)
 151         {
 152                 makevectors(e.tag_entity.angles);
 153                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 154         }
 155         else
 156                 return e.origin;
 157 }
 158
 159 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 160 {
 161 #ifdef KH_PLAYER_USE_ATTACHMENT
 162         entity first;
 163         first = key.owner.kh_next;
 164         if(key == first)
 165         {
 166                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 167                 if(key.kh_next)
 168                 {
 169                         setattachment(key.kh_next, key, "");
 170                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 171                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 172                         key.kh_next.angles = '0 0 0';
 173                 }
 174                 else
 175                         setorigin(key, KH_PLAYER_ATTACHMENT);
 176                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 177         }
 178         else
 179         {
 180                 setattachment(key, key.kh_prev, "");
 181                 if(key.kh_next)
 182                         setattachment(key.kh_next, key, "");
 183                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 184                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 185                 key.angles = '0 0 0';
 186         }
 187 #else
 188         setattachment(key, key.owner, "");
 189         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 190         key.angles_y -= key.owner.angles_y;
 191 #endif
 192         key.flags = 0;
 193         key.solid = SOLID_NOT;
 194         key.movetype = MOVETYPE_NONE;
 195         key.team = key.owner.team;
 196         key.nextthink = time;
 197         key.damageforcescale = 0;
 198         key.modelindex = kh_key_carried;
 199 }
 200
 201 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 202 {
 203         float i;
 204         i = test[key.owner.playerid];
 205                 if(key.netname == "^1red key")
 206                         i -= 1;
 207                 if(key.netname == "^4blue key")
 208                         i -= 2;
 209                 if(key.netname == "^3yellow key")
 210                         i -= 4;
 211                 if(key.netname == "^6pink key")
 212                         i -= 8;
 213         test[key.owner.playerid] = i;
 214
 215         kh_show_temp();
 216         if(key.owner)
 217                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 218         //key.owner.kh_state += test[key.owner.playerid];
 219
 220 #ifdef KH_PLAYER_USE_ATTACHMENT
 221         entity first;
 222         first = key.owner.kh_next;
 223         if(key == first)
 224         {
 225                 if(key.kh_next)
 226                 {
 227                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 228                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 229                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 230                 }
 231         }
 232         else
 233         {
 234                 if(key.kh_next)
 235                         setattachment(key.kh_next, key.kh_prev, "");
 236                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 237         }
 238         // in any case:
 239         setattachment(key, world, "");
 240         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 241         key.angles = key.owner.angles;
 242 #else
 243         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 244         setattachment(key, world, "");
 245         key.angles_y += key.owner.angles_y;
 246 #endif
 247         key.aiment = world;
 248         key.flags = FL_ITEM;
 249         key.solid = SOLID_TRIGGER;
 250         key.movetype = MOVETYPE_TOSS;
 251         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 252         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 253         // let key.team stay
 254         key.modelindex = kh_key_dropped;
 255         key.kh_previous_owner = key.owner;
 256 }
 257
 258 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 259 {
 260         if(key.owner == player)
 261                 return;
 262
 263         if(key.owner)
 264         {
 265                 kh_Key_Detach(key);
 266
 267                 // remove from linked list
 268                 if(key.kh_next)
 269                         key.kh_next.kh_prev = key.kh_prev;
 270                 key.kh_prev.kh_next = key.kh_next;
 271                 key.kh_next = world;
 272                 key.kh_prev = world;
 273
 274                 if(key.owner.kh_next == world)
 275                 {
 276                         // No longer a key carrier
 277                         WaypointSprite_DetachCarrier(key.owner);
 278                 }
 279         }
 280
 281         key.owner = player;
 282
 283         if(player)
 284         {
 285                 // insert into linked list
 286                 key.kh_next = player.kh_next;
 287                 key.kh_prev = player;
 288                 player.kh_next = key;
 289                 if(key.kh_next)
 290                         key.kh_next.kh_prev = key;
 291
 292                 float i;
 293                 i = test[key.owner.playerid];
 294                         if(key.netname == "^1red key")
 295                                 i += 1;
 296                         if(key.netname == "^4blue key")
 297                                 i += 2;
 298                         if(key.netname == "^3yellow key")
 299                                 i += 4;
 300                         if(key.netname == "^6pink key")
 301                                 i += 8;
 302                 test[key.owner.playerid] = i;
 303
 304                 kh_Key_Attach(key);
 305
 306                 if(key.kh_next == world)
 307                 {
 308                         // player is now a key carrier
 309                         WaypointSprite_AttachCarrier("", player);
 310                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 311                         player.waypointsprite_attachedforcarrier.team = player.team;
 312                 }
 313         }
 314
 315         // moved that here, also update if there's no player
 316         kh_show_temp();
 317         if(key.owner)
 318                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 319
 320         key.pusher = world;
 321 }
 322
 323 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 324 {
 325         if(self.owner)
 326                 return;
 327         if(vlen(force) <= 0)
 328                 return;
 329         if(time > self.pushltime)
 330                 if(attacker.classname == "player")
 331                         self.team = attacker.team;
 332 }
 333
 334 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 335 {
 336         entity key;
 337         key = spawn();
 338         key.classname = STR_ITEM_KH_KEY;
 339         key.touch = kh_Key_Touch;
 340         key.think = kh_Key_Think;
 341         key.nextthink = time;
 342         key.items = IT_KEY1 | IT_KEY2;
 343         key.cnt = angle;
 344         key.angles = '0 360 0' * random();
 345         key.event_damage = kh_Key_Damage;
 346         key.takedamage = DAMAGE_YES;
 347         key.modelindex = kh_key_dropped;
 348         key.model = "key";
 349         key.kh_dropperteam = 0;
 350         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 351         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 352         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 353
 354         switch(initial_owner.team)
 355         {
 356                 case COLOR_TEAM1:
 357                         key.netname = "^1red key";
 358                         break;
 359                 case COLOR_TEAM2:
 360                         key.netname = "^4blue key";
 361                         break;
 362                 case COLOR_TEAM3:
 363                         key.netname = "^3yellow key";
 364                         break;
 365                 case COLOR_TEAM4:
 366                         key.netname = "^6pink key";
 367                         break;
 368                 default:
 369                         key.netname = "NETGIER key";
 370                         break;
 371         }
 372
 373         // link into key list
 374         key.kh_worldkeynext = kh_worldkeylist;
 375         kh_worldkeylist = key;
 376
 377         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 378
 379         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 380         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 381
 382         kh_Key_AssignTo(key, initial_owner);
 383 }
 384
 385 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 386 {
 387         entity o;
 388         o = key.owner;
 389         kh_Key_AssignTo(key, world);
 390         if(o) // it was attached
 391                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 392         else // it was dropped
 393                 WaypointSprite_DetachCarrier(key);
 394
 395         // remove key from key list
 396         if (kh_worldkeylist == key)
 397                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 398         else
 399         {
 400                 o = kh_worldkeylist;
 401                 while (o)
 402                 {
 403                         if (o.kh_worldkeynext == key)
 404                         {
 405                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 406                                 break;
 407                         }
 408                         o = o.kh_worldkeynext;
 409                 }
 410         }
 411
 412         remove(key);
 413 }
 414
 415 // -1 when no team completely owns all keys yet
 416 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 417 {
 418         entity key;
 419         float teem;
 420
 421         teem = -1;
 422         FOR_EACH_KH_KEY(key)
 423         {
 424                 if(!key.owner)
 425                         return -1;
 426                 if(teem == -1)
 427                         teem = key.team;
 428                 else if(teem != key.team)
 429                         return -1;
 430         }
 431         return teem;
 432 }
 433
 434 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 435 {
 436         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 437
 438         if(key.kh_dropperteam != player.team)
 439                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 440         key.kh_dropperteam = 0;
 441         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 442
 443         kh_Key_AssignTo(key, player); // this also updates .kh_state
 444
 445         if(kh_Key_AllOwnedByWhichTeam() != -1)
 446         {
 447                 kh_interferemsg_time = time + 0.2;
 448                 kh_interferemsg_team = player.team;
 449         }
 450 }
 451
 452 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 453 {
 454         entity key;
 455         entity mypusher;
 456         if(player.kh_next)
 457         {
 458                 mypusher = world;
 459                 if(player.pusher)
 460                         if(time < player.pushltime)
 461                                 mypusher = player.pusher;
 462                 while((key = player.kh_next))
 463                 {
 464                         kh_Scores_Event(player, key, "losekey", 0, 0);
 465                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 466                         kh_Key_AssignTo(key, world);
 467                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 468                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 469                         key.pusher = mypusher;
 470                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 471                         if(suicide)
 472                                 key.kh_dropperteam = player.team;
 473                 }
 474                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 475         }
 476 }
 477
 478 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 479 {
 480         if(intermission_running)
 481                 return;
 482
 483         if(self.owner) // already carried
 484                 return;
 485         if(other.classname != "player")
 486                 return;
 487         if(other.deadflag != DEAD_NO)
 488                 return;
 489         if(other == self.enemy)
 490                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 491                         return;  // you just dropped it!
 492         kh_Key_Collect(self, other);
 493 }
 494
 495 void kh_Key_Think()  // runs all the time
 496 {
 497         entity head;
 498         //entity player;  // needed by FOR_EACH_PLAYER
 499
 500         if(intermission_running)
 501                 return;
 502         /*
 503         if(time > self.stuff_time)
 504         {
 505                 FOR_EACH_PLAYER(player)
 506                         player.kh_state = test[0]*256 + (player.kh_state&255);
 507
 508                 self.stuff_time = time + 1;  // repeat in 1 second
 509         }
 510         */
 511
 512 #ifdef KH_KEY_ATTACHMENT_DEBUG
 513         if(self.kh_prev == self.owner)
 514         {
 515                 if(cvar_string("_angles") != "")
 516                 {
 517                         self.angles = stov(cvar_string("_angles"));
 518                         self.origin = stov(cvar_string("_origin"));
 519                 }
 520         }
 521 #endif
 522
 523         if(self.owner)
 524         {
 525 #ifndef KH_PLAYER_USE_ATTACHMENT
 526                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 527                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 528 #endif
 529
 530                 if(self.owner.BUTTON_USE)
 531                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 532                 {
 533                         self.owner.kh_droptime = time;
 534                         self.kh_droptime = time;  // prevent collecting this one for some time
 535                         self.enemy = self.owner;
 536                         self.pusher = world;
 537                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 538                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 539                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 540                         makevectors(self.owner.v_angle);
 541                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 542                         kh_Key_AssignTo(self, world);
 543                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 544                         self.kh_dropperteam = self.team;
 545                 }
 546         }
 547
 548         // if in nodrop or time over, end the round
 549         if(!self.owner)
 550                 if(time > self.pain_finished)
 551                         kh_LoserTeam(self.team, self);
 552
 553         if(self.owner)
 554         if(kh_Key_AllOwnedByWhichTeam() != -1)
 555         {
 556                 if(self.siren_time < time)
 557                 {
 558                         sound(world, CHAN_AUTO, kh_sound_alarm, 1, ATTN_NORM);  // play a simple alarm
 559                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 560                 }
 561
 562                 entity key;
 563                 vector p;
 564                 p = self.owner.origin;
 565                 FOR_EACH_KH_KEY(key)
 566                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 567                                 goto not_winning;
 568                 kh_WinnerTeam(self.team);
 569 :not_winning
 570         }
 571
 572         if(kh_interferemsg_time && time > kh_interferemsg_time)
 573         {
 574                 kh_interferemsg_time = 0;
 575                 FOR_EACH_PLAYER(head)
 576                 {
 577                         if(head.team == kh_interferemsg_team)
 578                                 if(head.kh_next)
 579                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 580                                 else
 581                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 582                         else
 583                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 584                 }
 585         }
 586
 587         self.nextthink = time + 0.05;
 588 }
 589
 590 void kh_WinnerTeam(float teem)  // runs when a team wins
 591 {
 592         // all key carriers get some points
 593         vector firstorigin, lastorigin, midpoint;
 594         float first;
 595         entity key;
 596         float score;
 597         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 598         DistributeEvenly_Init(score, kh_teams);
 599         // twice the score for 3 team games, three times the score for 4 team games!
 600         // note: for a win by destroying the key, this should NOT be applied
 601         FOR_EACH_KH_KEY(key)
 602                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 603
 604         first = TRUE;
 605         FOR_EACH_KH_KEY(key)
 606                 if(key.owner.kh_next == key)
 607                 {
 608                         if(!first)
 609                                 bprint("^7, ");
 610                         bprint(key.owner.netname);
 611                         first = FALSE;
 612                 }
 613         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 614
 615         first = TRUE;
 616         midpoint = '0 0 0';
 617         FOR_EACH_KH_KEY(key)
 618         {
 619                 vector thisorigin;
 620
 621                 thisorigin = kh_AttachedOrigin(key);
 622                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 623                 midpoint += thisorigin;
 624
 625                 if(!first)
 626                         te_lightning2(world, lastorigin, thisorigin);
 627                 lastorigin = thisorigin;
 628                 if(first)
 629                         firstorigin = thisorigin;
 630                 first = FALSE;
 631         }
 632         if(kh_teams > 2)
 633         {
 634                 te_lightning2(world, lastorigin, firstorigin);
 635         }
 636         midpoint = midpoint * (1 / kh_teams);
 637         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 638
 639         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 640         kh_FinishRound();
 641 }
 642
 643 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 644 {
 645         entity player, key, attacker;
 646         float players;
 647         float keys;
 648
 649         attacker = world;
 650         if(lostkey.pusher)
 651                 if(lostkey.pusher.team != teem)
 652                         if(lostkey.pusher.classname == "player")
 653                                 attacker = lostkey.pusher;
 654
 655         players = keys = 0;
 656
 657         if(attacker)
 658         {
 659                 if(lostkey.kh_previous_owner)
 660                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 661                         // don't actually GIVE him the -nn points, just log
 662                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 663                 centerprint(attacker, "Your push is the best!\n\n\n");
 664                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 665         }
 666         else
 667         {
 668                 float of, fragsleft, i, j, thisteam;
 669                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 670
 671                 FOR_EACH_PLAYER(player)
 672                         if(player.team != teem)
 673                                 ++players;
 674
 675                 FOR_EACH_KH_KEY(key)
 676                         if(key.owner && key.team != teem)
 677                                 ++keys;
 678
 679                 if(lostkey.kh_previous_owner)
 680                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 681                         // don't actually GIVE him the -nn points, just log
 682
 683                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 684
 685                 FOR_EACH_KH_KEY(key)
 686                         if(key.owner && key.team != teem)
 687                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 688
 689                 fragsleft = DistributeEvenly_Get(players);
 690
 691                 // Now distribute these among all other teams...
 692                 j = kh_teams - 1;
 693                 for(i = 0; i < kh_teams; ++i)
 694                 {
 695                         thisteam = kh_Team_ByID(i);
 696                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 697                                 continue;
 698
 699                         players = 0;
 700                         FOR_EACH_PLAYER(player)
 701                                 if(player.team == thisteam)
 702                                         ++players;
 703
 704                         DistributeEvenly_Init(fragsleft, j);
 705                         fragsleft = DistributeEvenly_Get(j - 1);
 706                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 707
 708                         FOR_EACH_PLAYER(player)
 709                                 if(player.team == thisteam)
 710                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 711
 712                         --j;
 713                 }
 714
 715                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 716         }
 717         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 718         te_tarexplosion(lostkey.origin);
 719
 720         kh_FinishRound();
 721 }
 722
 723 void kh_FinishRound()  // runs when a team captures the keys
 724 {
 725         // prepare next round
 726         kh_interferemsg_time = 0;
 727         entity key;
 728         FOR_EACH_KH_KEY(key)
 729                 kh_Key_Remove(key);
 730
 731         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 732 }
 733
 734 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 735 {
 736         float i, players, teem;
 737         entity player;
 738         string result;
 739         result = "";
 740
 741         // find a random player per team
 742         for(i = 0; i < kh_teams; ++i)
 743         {
 744                 teem = kh_Team_ByID(i);
 745                 players = 0;
 746                 FOR_EACH_PLAYER(player)
 747                         if(player.deadflag == DEAD_NO)
 748                                 if(!player.BUTTON_CHAT)
 749                                         if(player.team == teem)
 750                                                 ++players;
 751                 if(players == 0)
 752                 {
 753                         if(result != "")
 754                                 result = strcat(result, ", ");
 755                         result = strcat(result, ColoredTeamName(teem));
 756                 }
 757         }
 758         return result;
 759 }
 760
 761 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 762 {
 763         string teams_missing;
 764         teams_missing = kh_CheckEnoughPlayers();
 765         if(teams_missing == "")
 766                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 767         else
 768                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 769 }
 770
 771 void kh_StartRound()  // runs at the start of each round
 772 {
 773         string teams_missing;
 774         float i, players, teem;
 775         entity player;
 776
 777         teams_missing = kh_CheckEnoughPlayers();
 778         if(teams_missing != "")
 779         {
 780                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 781                 return;
 782         }
 783
 784         FOR_EACH_PLAYER(player)
 785                 if(clienttype(player) == CLIENTTYPE_REAL)
 786                         centerprint_expire(player, CENTERPRIO_SPAM);
 787
 788         for(i = 0; i < kh_teams; ++i)
 789         {
 790                 teem = kh_Team_ByID(i);
 791                 players = 0;
 792                 entity my_player;
 793                 FOR_EACH_PLAYER(player)
 794                         if(player.deadflag == DEAD_NO)
 795                                 if(!player.BUTTON_CHAT)
 796                                         if(player.team == teem)
 797                                         {
 798                                                 ++players;
 799                                                 if(random() * players <= 1)
 800                                                         my_player = player;
 801                                         }
 802                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 803                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 804                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 805         }
 806
 807         kh_tracking_enabled = FALSE;
 808         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 809 }
 810
 811 void kh_setstatus()  // runs all the time
 812 {
 813         if(kh_teams)
 814         {
 815                 float kh_KEY;
 816                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 817                 if(self.kh_next)
 818                         self.items = self.items | kh_KEY;
 819                 else
 820                         self.items = self.items - (self.items & kh_KEY);
 821         }
 822 }
 823
 824 void kh_EnableTrackingDevice()  // runs after each round
 825 {
 826         entity player;
 827
 828         FOR_EACH_PLAYER(player)
 829                 if(clienttype(player) == CLIENTTYPE_REAL)
 830                         centerprint_expire(player, CENTERPRIO_SPAM);
 831
 832         kh_tracking_enabled = TRUE;
 833 }
 834
 835 float kh_Key_waypointsprite_for_player(entity e) // ??
 836 {
 837         if(!kh_tracking_enabled)
 838                 return 0;
 839         if(!self.owner)
 840                 return kh_sprite_dropped;
 841         if(!self.owner.owner)
 842                 return kh_sprite_dropped;
 843         return 0;  // draw only when key is not owned
 844 }
 845
 846 float kh_KeyCarrier_waypointsprite_for_player(entity e)  // runs all the time
 847 {
 848         if(e.classname != "player" || self.team != e.team)
 849                 if(!kh_tracking_enabled)
 850                         return 0;
 851
 852         // e is spectator? That's no team mate...
 853         if(e.classname != "player")
 854                 return kh_GetCarrierSprite(self.team, -1);
 855
 856         // e is no key carrier: simple case...
 857         if(!e.kh_next)
 858                 return kh_GetCarrierSprite(self.team, e.team);
 859
 860         // e is a key carrier: if any key is dropped or owned by another team, show
 861         // the carrier sprite; otherwise show run here
 862         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 863                 return kh_sprite_finish;
 864
 865         return kh_GetCarrierSprite(self.team, e.team);
 866 }
 867
 868 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 869 {
 870         if(attacker == targ)
 871                 return f;
 872
 873         if(targ.kh_next)
 874         {
 875                 if(attacker.team == targ.team)
 876                 {
 877                         entity k;
 878                         float nk;
 879                         nk = 0;
 880                         for(k = targ.kh_next; k != world; k = k.kh_next)
 881                                 ++nk;
 882                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 883                 }
 884                 else
 885                 {
 886                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 887                 }
 888         }
 889
 890         return f;
 891 }
 892
 893 void kh_init()  // sets up th KH environment
 894 {
 895         precache_sound(kh_sound_capture);
 896         precache_sound(kh_sound_destroy);
 897         precache_sound(kh_sound_drop);
 898         precache_sound(kh_sound_collect);
 899         precache_sound(kh_sound_alarm);  // the new siren
 900
 901         precache_model("models/sprites/key-dropped.sp2");
 902         precache_model("models/sprites/keycarrier-finish.sp2");
 903         precache_model("models/sprites/keycarrier-friend.sp2");
 904         precache_model("models/sprites/keycarrier-red.sp2");
 905         precache_model("models/sprites/keycarrier-blue.sp2");
 906         precache_model("models/sprites/keycarrier-yellow.sp2");
 907         precache_model("models/sprites/keycarrier-pink.sp2");
 908 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 909         precache_model("models/keyhunt/key-carried.md3");
 910 #endif
 911         precache_model("models/keyhunt/key.md3");
 912
 913         // setup variables
 914         kh_teams = cvar("g_keyhunt_teams_override");
 915         if(kh_teams < 2)
 916                 kh_teams = cvar("g_keyhunt_teams");
 917         kh_teams = bound(2, kh_teams, 4);
 918
 919         // make a KH entity for controlling the game
 920         kh_controller = spawn();
 921         kh_controller.think = kh_Controller_Think;
 922         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 923
 924         setmodel(kh_controller, "models/keyhunt/key.md3");
 925         kh_key_dropped = kh_controller.modelindex;
 926         /*
 927         dprint(vtos(kh_controller.mins));
 928         dprint(vtos(kh_controller.maxs));
 929         dprint("\n");
 930         */
 931 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 932         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 933         kh_key_carried = kh_controller.modelindex;
 934 #else
 935         kh_key_carried = kh_key_dropped;
 936 #endif
 937         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 938         kh_sprite_dropped = kh_controller.modelindex;
 939         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 940         kh_sprite_finish = kh_controller.modelindex;
 941         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 942         kh_sprite_friend = kh_controller.modelindex;
 943         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 944         kh_sprite_red = kh_controller.modelindex;
 945         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 946         kh_sprite_blue = kh_controller.modelindex;
 947         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 948         kh_sprite_pink = kh_controller.modelindex;
 949         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 950         kh_sprite_yellow = kh_controller.modelindex;
 951         setmodel(kh_controller, "");
 952
 953         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 954 }
 955
 956 void kh_finalize()
 957 {
 958         // to be called before intermission
 959         kh_FinishRound();
 960         remove(kh_controller);
 961         kh_controller = world;
 962 }
 963
 964 /**
 965  * kh_show_temp originally by victim.
 966  * changed it to use the kh_state stat var
 967  * Updates the general key stat bits for each player
 968  */
 969 void kh_show_temp()
 970 {
 971         entity player;
 972         float i, j;
 973
 974         j = 0;  // reset/blank j
 975         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
 976                 j += test[i];
 977
 978         test[0] = j;
 979
 980         j *= 256;
 981         FOR_EACH_PLAYER(player)
 982                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
 983 }