data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25 float kh_no_radar_circles;
  26
  27 // kh_state
  28 //     bits 0-7: player's key status
  29 //     bits 8-15: general key status
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  35 //test[0] = status of dropped keys, test[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      test[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return COLOR_TEAM1;
  43         if(t == 1) return COLOR_TEAM2;
  44         if(t == 2) return COLOR_TEAM3;
  45         if(t == 3) return COLOR_TEAM4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60
  61 string kh_sound_capture = "kh/capture.wav";
  62 string kh_sound_destroy = "kh/destroy.wav";
  63 string kh_sound_drop = "kh/drop.wav";
  64 string kh_sound_collect = "kh/collect.wav";
  65 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  66
  67 float kh_key_dropped, kh_key_carried;
  68
  69 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  70 {
  71         kh_Controller_Thinkfunc = func;
  72         kh_controller.cnt = ceil(t);
  73         if(kh_Controller_Waitmsg != "")
  74                 strunzone(kh_Controller_Waitmsg);
  75         if(msg == "")
  76                 kh_Controller_Waitmsg = "";
  77         else
  78                 kh_Controller_Waitmsg = strzone(msg);
  79         if(t == 0)
  80                 kh_controller.nextthink = time; // force
  81 }
  82
  83 void kh_Controller_Think()  // called a lot
  84 {
  85         entity e;
  86         if(intermission_running)
  87                 return;
  88         if(self.cnt > 0)
  89         {
  90                 if(kh_Controller_Waitmsg != "")
  91                 {
  92                         string s;
  93                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  94                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  95                         else
  96                                 s = kh_Controller_Waitmsg;
  97
  98                         //dprint(s, "\n");
  99
 100                         FOR_EACH_PLAYER(e)
 101                                 if(clienttype(e) == CLIENTTYPE_REAL)
 102                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 103                 }
 104                 self.cnt -= 1;
 105         }
 106         else if(self.cnt == 0)
 107         {
 108                 self.cnt -= 1;
 109                 kh_Controller_Thinkfunc();
 110         }
 111         self.nextthink = time + 1;
 112 }
 113
 114 // frags f: take from cvar * f
 115 // frags 0: no frags
 116 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 117 {
 118         string s;
 119         if(intermission_running)
 120                 return;
 121         if(frags_player)
 122                 UpdateFrags(player, frags_player);
 123         if(key && key.owner && frags_owner)
 124                 UpdateFrags(key.owner, frags_owner);
 125         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 126                 return;
 127         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 128         s = strcat(s, ":", ftos(frags_player));
 129         if(key && key.owner)
 130                 s = strcat(s, ":", ftos(key.owner.playerid));
 131         else
 132                 s = strcat(s, ":0");
 133         s = strcat(s, ":", ftos(frags_owner), ":");
 134         if(key)
 135                 s = strcat(s, key.netname);
 136         GameLogEcho(s);
 137 }
 138
 139 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 140 {
 141         if(e.tag_entity)
 142         {
 143                 makevectors(e.tag_entity.angles);
 144                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 145         }
 146         else
 147                 return e.origin;
 148 }
 149
 150 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 151 {
 152 #ifdef KH_PLAYER_USE_ATTACHMENT
 153         entity first;
 154         first = key.owner.kh_next;
 155         if(key == first)
 156         {
 157                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 158                 if(key.kh_next)
 159                 {
 160                         setattachment(key.kh_next, key, "");
 161                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 162                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 163                         key.kh_next.angles = '0 0 0';
 164                 }
 165                 else
 166                         setorigin(key, KH_PLAYER_ATTACHMENT);
 167                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 168         }
 169         else
 170         {
 171                 setattachment(key, key.kh_prev, "");
 172                 if(key.kh_next)
 173                         setattachment(key.kh_next, key, "");
 174                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 175                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 176                 key.angles = '0 0 0';
 177         }
 178 #else
 179         setattachment(key, key.owner, "");
 180         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 181         key.angles_y -= key.owner.angles_y;
 182 #endif
 183         key.flags = 0;
 184         key.solid = SOLID_NOT;
 185         key.movetype = MOVETYPE_NONE;
 186         key.team = key.owner.team;
 187         key.nextthink = time;
 188         key.damageforcescale = 0;
 189         key.modelindex = kh_key_carried;
 190 }
 191
 192 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 193 {
 194         float i;
 195         i = test[key.owner.playerid];
 196                 if(key.netname == "^1red key")
 197                         i -= 1;
 198                 if(key.netname == "^4blue key")
 199                         i -= 2;
 200                 if(key.netname == "^3yellow key")
 201                         i -= 4;
 202                 if(key.netname == "^6pink key")
 203                         i -= 8;
 204         test[key.owner.playerid] = i;
 205
 206         kh_show_temp();
 207         if(key.owner)
 208                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 209         //key.owner.kh_state += test[key.owner.playerid];
 210
 211 #ifdef KH_PLAYER_USE_ATTACHMENT
 212         entity first;
 213         first = key.owner.kh_next;
 214         if(key == first)
 215         {
 216                 if(key.kh_next)
 217                 {
 218                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 219                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 220                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 221                 }
 222         }
 223         else
 224         {
 225                 if(key.kh_next)
 226                         setattachment(key.kh_next, key.kh_prev, "");
 227                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 228         }
 229         // in any case:
 230         setattachment(key, world, "");
 231         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 232         key.angles = key.owner.angles;
 233 #else
 234         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 235         setattachment(key, world, "");
 236         key.angles_y += key.owner.angles_y;
 237 #endif
 238         key.flags = FL_ITEM;
 239         key.solid = SOLID_TRIGGER;
 240         key.movetype = MOVETYPE_TOSS;
 241         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 242         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 243         // let key.team stay
 244         key.modelindex = kh_key_dropped;
 245         key.kh_previous_owner = key.owner;
 246         key.kh_previous_owner_playerid = key.owner.playerid;
 247 }
 248
 249 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 250 {
 251         entity k;
 252         float ownerteam0, ownerteam;
 253         if(key.owner == player)
 254                 return;
 255
 256         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 257
 258         if(key.owner)
 259         {
 260                 kh_Key_Detach(key);
 261
 262                 // remove from linked list
 263                 if(key.kh_next)
 264                         key.kh_next.kh_prev = key.kh_prev;
 265                 key.kh_prev.kh_next = key.kh_next;
 266                 key.kh_next = world;
 267                 key.kh_prev = world;
 268
 269                 if(key.owner.kh_next == world)
 270                 {
 271                         // No longer a key carrier
 272                         if(!kh_no_radar_circles)
 273                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 274                         WaypointSprite_DetachCarrier(key.owner);
 275                 }
 276         }
 277
 278         key.owner = player;
 279
 280         if(player)
 281         {
 282                 // insert into linked list
 283                 key.kh_next = player.kh_next;
 284                 key.kh_prev = player;
 285                 player.kh_next = key;
 286                 if(key.kh_next)
 287                         key.kh_next.kh_prev = key;
 288
 289                 float i;
 290                 i = test[key.owner.playerid];
 291                         if(key.netname == "^1red key")
 292                                 i += 1;
 293                         if(key.netname == "^4blue key")
 294                                 i += 2;
 295                         if(key.netname == "^3yellow key")
 296                                 i += 4;
 297                         if(key.netname == "^6pink key")
 298                                 i += 8;
 299                 test[key.owner.playerid] = i;
 300
 301                 kh_Key_Attach(key);
 302
 303                 if(key.kh_next == world)
 304                 {
 305                         // player is now a key carrier
 306                         WaypointSprite_AttachCarrier("", player);
 307                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 308                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 309                         if(player.team == COLOR_TEAM1)
 310                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 311                         else if(player.team == COLOR_TEAM2)
 312                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 313                         else if(player.team == COLOR_TEAM3)
 314                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 315                         else if(player.team == COLOR_TEAM4)
 316                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 317                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 318                         if(!kh_no_radar_circles)
 319                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 320                 }
 321         }
 322
 323         // moved that here, also update if there's no player
 324         kh_show_temp();
 325         if(key.owner)
 326                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 327
 328         key.pusher = world;
 329
 330         ownerteam = kh_Key_AllOwnedByWhichTeam();
 331         if(ownerteam != ownerteam0)
 332         {
 333                 if(ownerteam != -1)
 334                 {
 335                         kh_interferemsg_time = time + 0.2;
 336                         kh_interferemsg_team = player.team;
 337
 338                         // audit all key carrier sprites, update them to RUN HERE
 339                         FOR_EACH_KH_KEY(k)
 340                         {
 341                                 if(k.owner)
 342                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 343                         }
 344                 }
 345                 else
 346                 {
 347                         kh_interferemsg_time = 0;
 348
 349                         // audit all key carrier sprites, update them to RUN HERE
 350                         FOR_EACH_KH_KEY(k)
 351                         {
 352                                 if(k.owner)
 353                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 354                         }
 355                 }
 356         }
 357 }
 358
 359 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 360 {
 361         if(self.owner)
 362                 return;
 363         if(vlen(force) <= 0)
 364                 return;
 365         if(time > self.pushltime)
 366                 if(attacker.classname == "player")
 367                         self.team = attacker.team;
 368 }
 369
 370 void key_reset()
 371 {
 372         kh_Key_AssignTo(self, world);
 373         kh_Key_Remove(self);
 374 }
 375
 376 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 377 {
 378         entity key;
 379         key = spawn();
 380         key.classname = STR_ITEM_KH_KEY;
 381         key.touch = kh_Key_Touch;
 382         key.think = kh_Key_Think;
 383         key.nextthink = time;
 384         key.items = IT_KEY1 | IT_KEY2;
 385         key.cnt = angle;
 386         key.angles = '0 360 0' * random();
 387         key.event_damage = kh_Key_Damage;
 388         key.takedamage = DAMAGE_YES;
 389         key.modelindex = kh_key_dropped;
 390         key.model = "key";
 391         key.kh_dropperteam = 0;
 392         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 393         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 394         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 395         key.reset = key_reset;
 396
 397         switch(initial_owner.team)
 398         {
 399                 case COLOR_TEAM1:
 400                         key.netname = "^1red key";
 401                         break;
 402                 case COLOR_TEAM2:
 403                         key.netname = "^4blue key";
 404                         break;
 405                 case COLOR_TEAM3:
 406                         key.netname = "^3yellow key";
 407                         break;
 408                 case COLOR_TEAM4:
 409                         key.netname = "^6pink key";
 410                         break;
 411                 default:
 412                         key.netname = "NETGIER key";
 413                         break;
 414         }
 415
 416         // link into key list
 417         key.kh_worldkeynext = kh_worldkeylist;
 418         kh_worldkeylist = key;
 419
 420         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 421
 422         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 423         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 424         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 425
 426         kh_Key_AssignTo(key, initial_owner);
 427 }
 428
 429 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 430 {
 431         entity o;
 432         o = key.owner;
 433         kh_Key_AssignTo(key, world);
 434         if(o) // it was attached
 435                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 436         else // it was dropped
 437                 WaypointSprite_DetachCarrier(key);
 438
 439         // remove key from key list
 440         if (kh_worldkeylist == key)
 441                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 442         else
 443         {
 444                 o = kh_worldkeylist;
 445                 while (o)
 446                 {
 447                         if (o.kh_worldkeynext == key)
 448                         {
 449                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 450                                 break;
 451                         }
 452                         o = o.kh_worldkeynext;
 453                 }
 454         }
 455
 456         remove(key);
 457 }
 458
 459 // -1 when no team completely owns all keys yet
 460 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 461 {
 462         entity key;
 463         float teem;
 464         float keys;
 465
 466         teem = -1;
 467         keys = kh_teams;
 468         FOR_EACH_KH_KEY(key)
 469         {
 470                 if(!key.owner)
 471                         return -1;
 472                 if(teem == -1)
 473                         teem = key.team;
 474                 else if(teem != key.team)
 475                         return -1;
 476                 --keys;
 477         }
 478         if(keys != 0)
 479                 return -1;
 480         return teem;
 481 }
 482
 483 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 484 {
 485         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 486
 487         if(key.kh_dropperteam != player.team)
 488         {
 489                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 490                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 491         }
 492         key.kh_dropperteam = 0;
 493         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 494
 495         kh_Key_AssignTo(key, player); // this also updates .kh_state
 496 }
 497
 498 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 499 {
 500         entity key;
 501         entity mypusher;
 502         if(player.kh_next)
 503         {
 504                 mypusher = world;
 505                 if(player.pusher)
 506                         if(time < player.pushltime)
 507                                 mypusher = player.pusher;
 508                 while((key = player.kh_next))
 509                 {
 510                         kh_Scores_Event(player, key, "losekey", 0, 0);
 511                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 512                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 513                         kh_Key_AssignTo(key, world);
 514                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 515                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 516                         key.pusher = mypusher;
 517                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 518                         if(suicide)
 519                                 key.kh_dropperteam = player.team;
 520                 }
 521                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 522         }
 523 }
 524
 525 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 526 {
 527         if(intermission_running)
 528                 return;
 529
 530         if(self.owner) // already carried
 531                 return;
 532         if(other.classname != "player")
 533                 return;
 534         if(other.deadflag != DEAD_NO)
 535                 return;
 536         if(other == self.enemy)
 537                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 538                         return;  // you just dropped it!
 539         kh_Key_Collect(self, other);
 540 }
 541
 542 void kh_Key_Think()  // runs all the time
 543 {
 544         entity head;
 545         //entity player;  // needed by FOR_EACH_PLAYER
 546
 547         if(intermission_running)
 548                 return;
 549         /*
 550         if(time > self.stuff_time)
 551         {
 552                 FOR_EACH_PLAYER(player)
 553                         player.kh_state = test[0]*256 + (player.kh_state&255);
 554
 555                 self.stuff_time = time + 1;  // repeat in 1 second
 556         }
 557         */
 558
 559 #ifdef KH_KEY_ATTACHMENT_DEBUG
 560         if(self.kh_prev == self.owner)
 561         {
 562                 if(cvar_string("_angles") != "")
 563                 {
 564                         self.angles = stov(cvar_string("_angles"));
 565                         self.origin = stov(cvar_string("_origin"));
 566                 }
 567         }
 568 #endif
 569
 570         if(self.owner)
 571         {
 572 #ifndef KH_PLAYER_USE_ATTACHMENT
 573                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 574                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 575 #endif
 576
 577                 if(self.owner.BUTTON_USE)
 578                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 579                 {
 580                         self.owner.kh_droptime = time;
 581                         self.kh_droptime = time;  // prevent collecting this one for some time
 582                         self.enemy = self.owner;
 583                         self.pusher = world;
 584                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 585                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 586                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 587                         makevectors(self.owner.v_angle);
 588                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 589                         kh_Key_AssignTo(self, world);
 590                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 591                         self.kh_dropperteam = self.team;
 592                 }
 593         }
 594
 595         // if in nodrop or time over, end the round
 596         if(!self.owner)
 597                 if(time > self.pain_finished)
 598                         kh_LoserTeam(self.team, self);
 599
 600         if(self.owner)
 601         if(kh_Key_AllOwnedByWhichTeam() != -1)
 602         {
 603                 if(self.siren_time < time)
 604                 {
 605                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 606                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 607                 }
 608
 609                 entity key;
 610                 vector p;
 611                 p = self.owner.origin;
 612                 FOR_EACH_KH_KEY(key)
 613                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 614                                 goto not_winning;
 615                 kh_WinnerTeam(self.team);
 616 :not_winning
 617         }
 618
 619         if(kh_interferemsg_time && time > kh_interferemsg_time)
 620         {
 621                 kh_interferemsg_time = 0;
 622                 FOR_EACH_PLAYER(head)
 623                 {
 624                         if(head.team == kh_interferemsg_team)
 625                                 if(head.kh_next)
 626                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!");
 627                                 else
 628                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!");
 629                         else
 630                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"));
 631                 }
 632         }
 633
 634         self.nextthink = time + 0.05;
 635 }
 636
 637 void kh_WinnerTeam(float teem)  // runs when a team wins
 638 {
 639         // all key carriers get some points
 640         vector firstorigin, lastorigin, midpoint;
 641         float first;
 642         entity key;
 643         float score;
 644         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 645         DistributeEvenly_Init(score, kh_teams);
 646         // twice the score for 3 team games, three times the score for 4 team games!
 647         // note: for a win by destroying the key, this should NOT be applied
 648         FOR_EACH_KH_KEY(key)
 649         {
 650                 float f;
 651                 f = DistributeEvenly_Get(1);
 652                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 653                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 654         }
 655
 656         first = TRUE;
 657         FOR_EACH_KH_KEY(key)
 658                 if(key.owner.kh_next == key)
 659                 {
 660                         if(!first)
 661                                 bprint("^7, ");
 662                         bprint(key.owner.netname);
 663                         first = FALSE;
 664                 }
 665         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 666
 667         first = TRUE;
 668         midpoint = '0 0 0';
 669         FOR_EACH_KH_KEY(key)
 670         {
 671                 vector thisorigin;
 672
 673                 thisorigin = kh_AttachedOrigin(key);
 674                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 675                 midpoint += thisorigin;
 676
 677                 if(!first)
 678                         te_lightning2(world, lastorigin, thisorigin);
 679                 lastorigin = thisorigin;
 680                 if(first)
 681                         firstorigin = thisorigin;
 682                 first = FALSE;
 683         }
 684         if(kh_teams > 2)
 685         {
 686                 te_lightning2(world, lastorigin, firstorigin);
 687         }
 688         midpoint = midpoint * (1 / kh_teams);
 689         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 690
 691         play2all(kh_sound_capture);
 692         kh_FinishRound();
 693 }
 694
 695 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 696 {
 697         entity player, key, attacker;
 698         float players;
 699         float keys;
 700         float f;
 701
 702         attacker = world;
 703         if(lostkey.pusher)
 704                 if(lostkey.pusher.team != teem)
 705                         if(lostkey.pusher.classname == "player")
 706                                 attacker = lostkey.pusher;
 707
 708         players = keys = 0;
 709
 710         if(attacker)
 711         {
 712                 if(lostkey.kh_previous_owner)
 713                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 714                         // don't actually GIVE him the -nn points, just log
 715                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 716                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 717                 centerprint(attacker, "Your push is the best!");
 718                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 719         }
 720         else
 721         {
 722                 float of, fragsleft, i, j, thisteam;
 723                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 724
 725                 FOR_EACH_PLAYER(player)
 726                         if(player.team != teem)
 727                                 ++players;
 728
 729                 FOR_EACH_KH_KEY(key)
 730                         if(key.owner && key.team != teem)
 731                                 ++keys;
 732
 733                 if(lostkey.kh_previous_owner)
 734                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 735                         // don't actually GIVE him the -nn points, just log
 736
 737                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 738                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 739
 740                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 741
 742                 FOR_EACH_KH_KEY(key)
 743                         if(key.owner && key.team != teem)
 744                         {
 745                                 f = DistributeEvenly_Get(of);
 746                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 747                         }
 748
 749                 fragsleft = DistributeEvenly_Get(players);
 750
 751                 // Now distribute these among all other teams...
 752                 j = kh_teams - 1;
 753                 for(i = 0; i < kh_teams; ++i)
 754                 {
 755                         thisteam = kh_Team_ByID(i);
 756                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 757                                 continue;
 758
 759                         players = 0;
 760                         FOR_EACH_PLAYER(player)
 761                                 if(player.team == thisteam)
 762                                         ++players;
 763
 764                         DistributeEvenly_Init(fragsleft, j);
 765                         fragsleft = DistributeEvenly_Get(j - 1);
 766                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 767
 768                         FOR_EACH_PLAYER(player)
 769                                 if(player.team == thisteam)
 770                                 {
 771                                         f = DistributeEvenly_Get(1);
 772                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 773                                 }
 774
 775                         --j;
 776                 }
 777
 778                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 779         }
 780         play2all(kh_sound_destroy);
 781         te_tarexplosion(lostkey.origin);
 782
 783         kh_FinishRound();
 784 }
 785
 786 void kh_FinishRound()  // runs when a team captures the keys
 787 {
 788         // prepare next round
 789         kh_interferemsg_time = 0;
 790         entity key;
 791
 792         kh_no_radar_circles = TRUE;
 793         FOR_EACH_KH_KEY(key)
 794                 kh_Key_Remove(key);
 795         kh_no_radar_circles = FALSE;
 796
 797         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 798 }
 799
 800 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 801 {
 802         float i, players, teem;
 803         entity player;
 804         string result;
 805         result = "";
 806
 807         // find a random player per team
 808         for(i = 0; i < kh_teams; ++i)
 809         {
 810                 teem = kh_Team_ByID(i);
 811                 players = 0;
 812                 FOR_EACH_PLAYER(player)
 813                         if(player.deadflag == DEAD_NO)
 814                                 if(!player.BUTTON_CHAT)
 815                                         if(player.team == teem)
 816                                                 ++players;
 817                 if(players == 0)
 818                 {
 819                         if(result != "")
 820                                 result = strcat(result, ", ");
 821                         result = strcat(result, ColoredTeamName(teem));
 822                 }
 823         }
 824         return result;
 825 }
 826
 827 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 828 {
 829         string teams_missing;
 830
 831         if(time < game_starttime)
 832         {
 833                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 834                 return;
 835         }
 836
 837         teams_missing = kh_CheckEnoughPlayers();
 838         if(teams_missing == "")
 839                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 840         else
 841                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 842 }
 843
 844 void kh_StartRound()  // runs at the start of each round
 845 {
 846         string teams_missing;
 847         float i, players, teem;
 848         entity player;
 849
 850         if(time < game_starttime)
 851         {
 852                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 853                 return;
 854         }
 855
 856         teams_missing = kh_CheckEnoughPlayers();
 857         if(teams_missing != "")
 858         {
 859                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 860                 return;
 861         }
 862
 863         FOR_EACH_PLAYER(player)
 864                 if(clienttype(player) == CLIENTTYPE_REAL)
 865                         centerprint_expire(player, CENTERPRIO_SPAM);
 866
 867         for(i = 0; i < kh_teams; ++i)
 868         {
 869                 teem = kh_Team_ByID(i);
 870                 players = 0;
 871                 entity my_player;
 872                 FOR_EACH_PLAYER(player)
 873                         if(player.deadflag == DEAD_NO)
 874                                 if(!player.BUTTON_CHAT)
 875                                         if(player.team == teem)
 876                                         {
 877                                                 ++players;
 878                                                 if(random() * players <= 1)
 879                                                         my_player = player;
 880                                         }
 881                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 882                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 883                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 884         }
 885
 886         kh_tracking_enabled = FALSE;
 887         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 888 }
 889
 890 void kh_setstatus()  // runs all the time
 891 {
 892         if(kh_teams)
 893         {
 894                 float kh_KEY;
 895                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 896                 if(self.kh_next)
 897                         self.items = self.items | kh_KEY;
 898                 else
 899                         self.items = self.items - (self.items & kh_KEY);
 900         }
 901 }
 902
 903 void kh_EnableTrackingDevice()  // runs after each round
 904 {
 905         entity player;
 906
 907         FOR_EACH_PLAYER(player)
 908                 if(clienttype(player) == CLIENTTYPE_REAL)
 909                         centerprint_expire(player, CENTERPRIO_SPAM);
 910
 911         kh_tracking_enabled = TRUE;
 912 }
 913
 914 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 915 {
 916         if(!kh_tracking_enabled)
 917                 return FALSE;
 918         if(!self.owner)
 919                 return TRUE;
 920         if(!self.owner.owner)
 921                 return TRUE;
 922         return FALSE;  // draw only when key is not owned
 923 }
 924
 925 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 926 {
 927         if(e.classname != "player" || self.team != e.team)
 928                 if(!kh_tracking_enabled)
 929                         return FALSE;
 930
 931         return TRUE;
 932 }
 933
 934 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 935 {
 936         if(attacker == targ)
 937                 return f;
 938
 939         if(targ.kh_next)
 940         {
 941                 if(attacker.team == targ.team)
 942                 {
 943                         entity k;
 944                         float nk;
 945                         nk = 0;
 946                         for(k = targ.kh_next; k != world; k = k.kh_next)
 947                                 ++nk;
 948                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 949                 }
 950                 else
 951                 {
 952                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 953                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 954                         // the frag gets added later
 955                 }
 956         }
 957
 958         return f;
 959 }
 960
 961 void kh_init()  // sets up th KH environment
 962 {
 963         precache_sound(kh_sound_capture);
 964         precache_sound(kh_sound_destroy);
 965         precache_sound(kh_sound_drop);
 966         precache_sound(kh_sound_collect);
 967         precache_sound(kh_sound_alarm);  // the new siren
 968
 969 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 970         precache_model("models/keyhunt/key-carried.md3");
 971 #endif
 972         precache_model("models/keyhunt/key.md3");
 973
 974         // setup variables
 975         kh_teams = cvar("g_keyhunt_teams_override");
 976         if(kh_teams < 2)
 977                 kh_teams = cvar("g_keyhunt_teams");
 978         kh_teams = bound(2, kh_teams, 4);
 979
 980         // make a KH entity for controlling the game
 981         kh_controller = spawn();
 982         kh_controller.think = kh_Controller_Think;
 983         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 984
 985         setmodel(kh_controller, "models/keyhunt/key.md3");
 986         kh_key_dropped = kh_controller.modelindex;
 987         /*
 988         dprint(vtos(kh_controller.mins));
 989         dprint(vtos(kh_controller.maxs));
 990         dprint("\n");
 991         */
 992 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 993         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 994         kh_key_carried = kh_controller.modelindex;
 995 #else
 996         kh_key_carried = kh_key_dropped;
 997 #endif
 998
 999         kh_controller.model = "";
1000         kh_controller.modelindex = 0;
1001
1002         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1003
1004         ScoreRules_kh(kh_teams);
1005 }
1006
1007 void kh_finalize()
1008 {
1009         // to be called before intermission
1010         kh_FinishRound();
1011         remove(kh_controller);
1012         kh_controller = world;
1013 }
1014
1015 /**
1016  * kh_show_temp originally by victim.
1017  * changed it to use the kh_state stat var
1018  * Updates the general key stat bits for each player
1019  */
1020 void kh_show_temp()
1021 {
1022         entity player;
1023         float i, j;
1024
1025         j = 0;  // reset/blank j
1026         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1027                 j += test[i];
1028
1029         test[0] = j;
1030
1031         j *= 256;
1032         FOR_EACH_PLAYER(player)
1033                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1034 }