data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58 .float kh_previous_owner_playerid;
  59
  60 string kh_sound_capture = "sound/kh/capture.wav";
  61 string kh_sound_destroy = "sound/kh/destroy.wav";
  62 string kh_sound_drop = "sound/kh/drop.wav";
  63 string kh_sound_collect = "sound/kh/collect.wav";
  64 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  65
  66 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  67 float kh_key_dropped, kh_key_carried;
  68
  69 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  70 {
  71         if(t == e)           return kh_sprite_friend;
  72         if(t == COLOR_TEAM1) return kh_sprite_red;
  73         if(t == COLOR_TEAM2) return kh_sprite_blue;
  74         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  75         if(t == COLOR_TEAM4) return kh_sprite_pink;
  76         return 0;
  77 }
  78
  79 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  80 {
  81         kh_Controller_Thinkfunc = func;
  82         kh_controller.cnt = t;
  83         if(kh_Controller_Waitmsg != "")
  84                 strunzone(kh_Controller_Waitmsg);
  85         if(msg == "")
  86                 kh_Controller_Waitmsg = "";
  87         else
  88                 kh_Controller_Waitmsg = strzone(msg);
  89         if(t == 0)
  90                 kh_controller.nextthink = time; // force
  91 }
  92
  93 void kh_Controller_Think()  // called a lot
  94 {
  95         entity e;
  96         if(intermission_running)
  97                 return;
  98         if(self.cnt > 0)
  99         {
 100                 if(kh_Controller_Waitmsg != "")
 101                 {
 102                         string s;
 103                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 104                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 105                         else
 106                                 s = kh_Controller_Waitmsg;
 107
 108                         //dprint(s, "\n");
 109
 110                         FOR_EACH_PLAYER(e)
 111                                 if(clienttype(e) == CLIENTTYPE_REAL)
 112                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 113                 }
 114                 self.cnt -= 1;
 115         }
 116         else if(self.cnt == 0)
 117         {
 118                 self.cnt -= 1;
 119                 kh_Controller_Thinkfunc();
 120         }
 121         self.nextthink = time + 1;
 122 }
 123
 124 // frags f: take from cvar * f
 125 // frags 0: no frags
 126 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 127 {
 128         string s;
 129         if(intermission_running)
 130                 return;
 131         if(frags_player)
 132                 UpdateFrags(player, frags_player);
 133         if(key && key.owner && frags_owner)
 134                 UpdateFrags(key.owner, frags_owner);
 135         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 136                 return;
 137         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 138         s = strcat(s, ":", ftos(frags_player));
 139         if(key && key.owner)
 140                 s = strcat(s, ":", ftos(key.owner.playerid));
 141         else
 142                 s = strcat(s, ":0");
 143         s = strcat(s, ":", ftos(frags_owner), ":");
 144         if(key)
 145                 s = strcat(s, key.netname);
 146         GameLogEcho(s, FALSE);
 147 }
 148
 149 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 150 {
 151         if(e.tag_entity)
 152         {
 153                 makevectors(e.tag_entity.angles);
 154                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 155         }
 156         else
 157                 return e.origin;
 158 }
 159
 160 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 161 {
 162 #ifdef KH_PLAYER_USE_ATTACHMENT
 163         entity first;
 164         first = key.owner.kh_next;
 165         if(key == first)
 166         {
 167                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 168                 if(key.kh_next)
 169                 {
 170                         setattachment(key.kh_next, key, "");
 171                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 173                         key.kh_next.angles = '0 0 0';
 174                 }
 175                 else
 176                         setorigin(key, KH_PLAYER_ATTACHMENT);
 177                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 178         }
 179         else
 180         {
 181                 setattachment(key, key.kh_prev, "");
 182                 if(key.kh_next)
 183                         setattachment(key.kh_next, key, "");
 184                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 185                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 186                 key.angles = '0 0 0';
 187         }
 188 #else
 189         setattachment(key, key.owner, "");
 190         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 191         key.angles_y -= key.owner.angles_y;
 192 #endif
 193         key.flags = 0;
 194         key.solid = SOLID_NOT;
 195         key.movetype = MOVETYPE_NONE;
 196         key.team = key.owner.team;
 197         key.nextthink = time;
 198         key.damageforcescale = 0;
 199         key.modelindex = kh_key_carried;
 200 }
 201
 202 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 203 {
 204         float i;
 205         i = test[key.owner.playerid];
 206                 if(key.netname == "^1red key")
 207                         i -= 1;
 208                 if(key.netname == "^4blue key")
 209                         i -= 2;
 210                 if(key.netname == "^3yellow key")
 211                         i -= 4;
 212                 if(key.netname == "^6pink key")
 213                         i -= 8;
 214         test[key.owner.playerid] = i;
 215
 216         kh_show_temp();
 217         if(key.owner)
 218                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 219         //key.owner.kh_state += test[key.owner.playerid];
 220
 221 #ifdef KH_PLAYER_USE_ATTACHMENT
 222         entity first;
 223         first = key.owner.kh_next;
 224         if(key == first)
 225         {
 226                 if(key.kh_next)
 227                 {
 228                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 229                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 230                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231                 }
 232         }
 233         else
 234         {
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key.kh_prev, "");
 237                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238         }
 239         // in any case:
 240         setattachment(key, world, "");
 241         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 242         key.angles = key.owner.angles;
 243 #else
 244         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 245         setattachment(key, world, "");
 246         key.angles_y += key.owner.angles_y;
 247 #endif
 248         key.aiment = world;
 249         key.flags = FL_ITEM;
 250         key.solid = SOLID_TRIGGER;
 251         key.movetype = MOVETYPE_TOSS;
 252         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 253         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 254         // let key.team stay
 255         key.modelindex = kh_key_dropped;
 256         key.kh_previous_owner = key.owner;
 257         key.kh_previous_owner_playerid = key.owner.playerid;
 258 }
 259
 260 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 261 {
 262         if(key.owner == player)
 263                 return;
 264
 265         if(key.owner)
 266         {
 267                 kh_Key_Detach(key);
 268
 269                 // remove from linked list
 270                 if(key.kh_next)
 271                         key.kh_next.kh_prev = key.kh_prev;
 272                 key.kh_prev.kh_next = key.kh_next;
 273                 key.kh_next = world;
 274                 key.kh_prev = world;
 275
 276                 if(key.owner.kh_next == world)
 277                 {
 278                         // No longer a key carrier
 279                         WaypointSprite_DetachCarrier(key.owner);
 280                 }
 281         }
 282
 283         key.owner = player;
 284
 285         if(player)
 286         {
 287                 // insert into linked list
 288                 key.kh_next = player.kh_next;
 289                 key.kh_prev = player;
 290                 player.kh_next = key;
 291                 if(key.kh_next)
 292                         key.kh_next.kh_prev = key;
 293
 294                 float i;
 295                 i = test[key.owner.playerid];
 296                         if(key.netname == "^1red key")
 297                                 i += 1;
 298                         if(key.netname == "^4blue key")
 299                                 i += 2;
 300                         if(key.netname == "^3yellow key")
 301                                 i += 4;
 302                         if(key.netname == "^6pink key")
 303                                 i += 8;
 304                 test[key.owner.playerid] = i;
 305
 306                 kh_Key_Attach(key);
 307
 308                 if(key.kh_next == world)
 309                 {
 310                         // player is now a key carrier
 311                         WaypointSprite_AttachCarrier("", player);
 312                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 313                         player.waypointsprite_attachedforcarrier.team = player.team;
 314                 }
 315         }
 316
 317         // moved that here, also update if there's no player
 318         kh_show_temp();
 319         if(key.owner)
 320                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 321
 322         key.pusher = world;
 323 }
 324
 325 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 326 {
 327         if(self.owner)
 328                 return;
 329         if(vlen(force) <= 0)
 330                 return;
 331         if(time > self.pushltime)
 332                 if(attacker.classname == "player")
 333                         self.team = attacker.team;
 334 }
 335
 336 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 337 {
 338         entity key;
 339         key = spawn();
 340         key.classname = STR_ITEM_KH_KEY;
 341         key.touch = kh_Key_Touch;
 342         key.think = kh_Key_Think;
 343         key.nextthink = time;
 344         key.items = IT_KEY1 | IT_KEY2;
 345         key.cnt = angle;
 346         key.angles = '0 360 0' * random();
 347         key.event_damage = kh_Key_Damage;
 348         key.takedamage = DAMAGE_YES;
 349         key.modelindex = kh_key_dropped;
 350         key.model = "key";
 351         key.kh_dropperteam = 0;
 352         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 353         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 354         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 355
 356         switch(initial_owner.team)
 357         {
 358                 case COLOR_TEAM1:
 359                         key.netname = "^1red key";
 360                         break;
 361                 case COLOR_TEAM2:
 362                         key.netname = "^4blue key";
 363                         break;
 364                 case COLOR_TEAM3:
 365                         key.netname = "^3yellow key";
 366                         break;
 367                 case COLOR_TEAM4:
 368                         key.netname = "^6pink key";
 369                         break;
 370                 default:
 371                         key.netname = "NETGIER key";
 372                         break;
 373         }
 374
 375         // link into key list
 376         key.kh_worldkeynext = kh_worldkeylist;
 377         kh_worldkeylist = key;
 378
 379         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 380
 381         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 382         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 383
 384         kh_Key_AssignTo(key, initial_owner);
 385 }
 386
 387 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 388 {
 389         entity o;
 390         o = key.owner;
 391         kh_Key_AssignTo(key, world);
 392         if(o) // it was attached
 393                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 394         else // it was dropped
 395                 WaypointSprite_DetachCarrier(key);
 396
 397         // remove key from key list
 398         if (kh_worldkeylist == key)
 399                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 400         else
 401         {
 402                 o = kh_worldkeylist;
 403                 while (o)
 404                 {
 405                         if (o.kh_worldkeynext == key)
 406                         {
 407                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 408                                 break;
 409                         }
 410                         o = o.kh_worldkeynext;
 411                 }
 412         }
 413
 414         remove(key);
 415 }
 416
 417 // -1 when no team completely owns all keys yet
 418 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 419 {
 420         entity key;
 421         float teem;
 422
 423         teem = -1;
 424         FOR_EACH_KH_KEY(key)
 425         {
 426                 if(!key.owner)
 427                         return -1;
 428                 if(teem == -1)
 429                         teem = key.team;
 430                 else if(teem != key.team)
 431                         return -1;
 432         }
 433         return teem;
 434 }
 435
 436 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 437 {
 438         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 439
 440         if(key.kh_dropperteam != player.team)
 441         {
 442                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 443                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 444         }
 445         key.kh_dropperteam = 0;
 446         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 447
 448         kh_Key_AssignTo(key, player); // this also updates .kh_state
 449
 450         if(kh_Key_AllOwnedByWhichTeam() != -1)
 451         {
 452                 kh_interferemsg_time = time + 0.2;
 453                 kh_interferemsg_team = player.team;
 454         }
 455 }
 456
 457 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 458 {
 459         entity key;
 460         entity mypusher;
 461         if(player.kh_next)
 462         {
 463                 mypusher = world;
 464                 if(player.pusher)
 465                         if(time < player.pushltime)
 466                                 mypusher = player.pusher;
 467                 while((key = player.kh_next))
 468                 {
 469                         kh_Scores_Event(player, key, "losekey", 0, 0);
 470                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 471                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 472                         kh_Key_AssignTo(key, world);
 473                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 474                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 475                         key.pusher = mypusher;
 476                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 477                         if(suicide)
 478                                 key.kh_dropperteam = player.team;
 479                 }
 480                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 481         }
 482 }
 483
 484 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 485 {
 486         if(intermission_running)
 487                 return;
 488
 489         if(self.owner) // already carried
 490                 return;
 491         if(other.classname != "player")
 492                 return;
 493         if(other.deadflag != DEAD_NO)
 494                 return;
 495         if(other == self.enemy)
 496                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 497                         return;  // you just dropped it!
 498         kh_Key_Collect(self, other);
 499 }
 500
 501 void kh_Key_Think()  // runs all the time
 502 {
 503         entity head;
 504         //entity player;  // needed by FOR_EACH_PLAYER
 505
 506         if(intermission_running)
 507                 return;
 508         /*
 509         if(time > self.stuff_time)
 510         {
 511                 FOR_EACH_PLAYER(player)
 512                         player.kh_state = test[0]*256 + (player.kh_state&255);
 513
 514                 self.stuff_time = time + 1;  // repeat in 1 second
 515         }
 516         */
 517
 518 #ifdef KH_KEY_ATTACHMENT_DEBUG
 519         if(self.kh_prev == self.owner)
 520         {
 521                 if(cvar_string("_angles") != "")
 522                 {
 523                         self.angles = stov(cvar_string("_angles"));
 524                         self.origin = stov(cvar_string("_origin"));
 525                 }
 526         }
 527 #endif
 528
 529         if(self.owner)
 530         {
 531 #ifndef KH_PLAYER_USE_ATTACHMENT
 532                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 533                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 534 #endif
 535
 536                 if(self.owner.BUTTON_USE)
 537                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 538                 {
 539                         self.owner.kh_droptime = time;
 540                         self.kh_droptime = time;  // prevent collecting this one for some time
 541                         self.enemy = self.owner;
 542                         self.pusher = world;
 543                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 544                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 545                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 546                         makevectors(self.owner.v_angle);
 547                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 548                         kh_Key_AssignTo(self, world);
 549                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 550                         self.kh_dropperteam = self.team;
 551                 }
 552         }
 553
 554         // if in nodrop or time over, end the round
 555         if(!self.owner)
 556                 if(time > self.pain_finished)
 557                         kh_LoserTeam(self.team, self);
 558
 559         if(self.owner)
 560         if(kh_Key_AllOwnedByWhichTeam() != -1)
 561         {
 562                 if(self.siren_time < time)
 563                 {
 564                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 565                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 566                 }
 567
 568                 entity key;
 569                 vector p;
 570                 p = self.owner.origin;
 571                 FOR_EACH_KH_KEY(key)
 572                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 573                                 goto not_winning;
 574                 kh_WinnerTeam(self.team);
 575 :not_winning
 576         }
 577
 578         if(kh_interferemsg_time && time > kh_interferemsg_time)
 579         {
 580                 kh_interferemsg_time = 0;
 581                 FOR_EACH_PLAYER(head)
 582                 {
 583                         if(head.team == kh_interferemsg_team)
 584                                 if(head.kh_next)
 585                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 586                                 else
 587                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 588                         else
 589                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 590                 }
 591         }
 592
 593         self.nextthink = time + 0.05;
 594 }
 595
 596 void kh_WinnerTeam(float teem)  // runs when a team wins
 597 {
 598         // all key carriers get some points
 599         vector firstorigin, lastorigin, midpoint;
 600         float first;
 601         entity key;
 602         float score;
 603         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 604         DistributeEvenly_Init(score, kh_teams);
 605         // twice the score for 3 team games, three times the score for 4 team games!
 606         // note: for a win by destroying the key, this should NOT be applied
 607         FOR_EACH_KH_KEY(key)
 608         {
 609                 float f;
 610                 f = DistributeEvenly_Get(1);
 611                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 612                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 613         }
 614
 615         first = TRUE;
 616         FOR_EACH_KH_KEY(key)
 617                 if(key.owner.kh_next == key)
 618                 {
 619                         if(!first)
 620                                 bprint("^7, ");
 621                         bprint(key.owner.netname);
 622                         first = FALSE;
 623                 }
 624         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 625
 626         first = TRUE;
 627         midpoint = '0 0 0';
 628         FOR_EACH_KH_KEY(key)
 629         {
 630                 vector thisorigin;
 631
 632                 thisorigin = kh_AttachedOrigin(key);
 633                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 634                 midpoint += thisorigin;
 635
 636                 if(!first)
 637                         te_lightning2(world, lastorigin, thisorigin);
 638                 lastorigin = thisorigin;
 639                 if(first)
 640                         firstorigin = thisorigin;
 641                 first = FALSE;
 642         }
 643         if(kh_teams > 2)
 644         {
 645                 te_lightning2(world, lastorigin, firstorigin);
 646         }
 647         midpoint = midpoint * (1 / kh_teams);
 648         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 649
 650         play2all(kh_sound_capture);
 651         kh_FinishRound();
 652 }
 653
 654 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 655 {
 656         entity player, key, attacker;
 657         float players;
 658         float keys;
 659         float f;
 660
 661         attacker = world;
 662         if(lostkey.pusher)
 663                 if(lostkey.pusher.team != teem)
 664                         if(lostkey.pusher.classname == "player")
 665                                 attacker = lostkey.pusher;
 666
 667         players = keys = 0;
 668
 669         if(attacker)
 670         {
 671                 if(lostkey.kh_previous_owner)
 672                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 673                         // don't actually GIVE him the -nn points, just log
 674                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 675                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 676                 centerprint(attacker, "Your push is the best!\n\n\n");
 677                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 678         }
 679         else
 680         {
 681                 float of, fragsleft, i, j, thisteam;
 682                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 683
 684                 FOR_EACH_PLAYER(player)
 685                         if(player.team != teem)
 686                                 ++players;
 687
 688                 FOR_EACH_KH_KEY(key)
 689                         if(key.owner && key.team != teem)
 690                                 ++keys;
 691
 692                 if(lostkey.kh_previous_owner)
 693                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 694                         // don't actually GIVE him the -nn points, just log
 695
 696                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 697                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 698
 699                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 700
 701                 FOR_EACH_KH_KEY(key)
 702                         if(key.owner && key.team != teem)
 703                         {
 704                                 f = DistributeEvenly_Get(of);
 705                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 706                         }
 707
 708                 fragsleft = DistributeEvenly_Get(players);
 709
 710                 // Now distribute these among all other teams...
 711                 j = kh_teams - 1;
 712                 for(i = 0; i < kh_teams; ++i)
 713                 {
 714                         thisteam = kh_Team_ByID(i);
 715                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 716                                 continue;
 717
 718                         players = 0;
 719                         FOR_EACH_PLAYER(player)
 720                                 if(player.team == thisteam)
 721                                         ++players;
 722
 723                         DistributeEvenly_Init(fragsleft, j);
 724                         fragsleft = DistributeEvenly_Get(j - 1);
 725                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 726
 727                         FOR_EACH_PLAYER(player)
 728                                 if(player.team == thisteam)
 729                                 {
 730                                         f = DistributeEvenly_Get(1);
 731                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 732                                 }
 733
 734                         --j;
 735                 }
 736
 737                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 738         }
 739         play2all(kh_sound_destroy);
 740         te_tarexplosion(lostkey.origin);
 741
 742         kh_FinishRound();
 743 }
 744
 745 void kh_FinishRound()  // runs when a team captures the keys
 746 {
 747         // prepare next round
 748         kh_interferemsg_time = 0;
 749         entity key;
 750         FOR_EACH_KH_KEY(key)
 751                 kh_Key_Remove(key);
 752
 753         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 754 }
 755
 756 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 757 {
 758         float i, players, teem;
 759         entity player;
 760         string result;
 761         result = "";
 762
 763         // find a random player per team
 764         for(i = 0; i < kh_teams; ++i)
 765         {
 766                 teem = kh_Team_ByID(i);
 767                 players = 0;
 768                 FOR_EACH_PLAYER(player)
 769                         if(player.deadflag == DEAD_NO)
 770                                 if(!player.BUTTON_CHAT)
 771                                         if(player.team == teem)
 772                                                 ++players;
 773                 if(players == 0)
 774                 {
 775                         if(result != "")
 776                                 result = strcat(result, ", ");
 777                         result = strcat(result, ColoredTeamName(teem));
 778                 }
 779         }
 780         return result;
 781 }
 782
 783 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 784 {
 785         string teams_missing;
 786         teams_missing = kh_CheckEnoughPlayers();
 787         if(teams_missing == "")
 788                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 789         else
 790                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 791 }
 792
 793 void kh_StartRound()  // runs at the start of each round
 794 {
 795         string teams_missing;
 796         float i, players, teem;
 797         entity player;
 798
 799         teams_missing = kh_CheckEnoughPlayers();
 800         if(teams_missing != "")
 801         {
 802                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 803                 return;
 804         }
 805
 806         FOR_EACH_PLAYER(player)
 807                 if(clienttype(player) == CLIENTTYPE_REAL)
 808                         centerprint_expire(player, CENTERPRIO_SPAM);
 809
 810         for(i = 0; i < kh_teams; ++i)
 811         {
 812                 teem = kh_Team_ByID(i);
 813                 players = 0;
 814                 entity my_player;
 815                 FOR_EACH_PLAYER(player)
 816                         if(player.deadflag == DEAD_NO)
 817                                 if(!player.BUTTON_CHAT)
 818                                         if(player.team == teem)
 819                                         {
 820                                                 ++players;
 821                                                 if(random() * players <= 1)
 822                                                         my_player = player;
 823                                         }
 824                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 825                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 826                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 827         }
 828
 829         kh_tracking_enabled = FALSE;
 830         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 831 }
 832
 833 void kh_setstatus()  // runs all the time
 834 {
 835         if(kh_teams)
 836         {
 837                 float kh_KEY;
 838                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 839                 if(self.kh_next)
 840                         self.items = self.items | kh_KEY;
 841                 else
 842                         self.items = self.items - (self.items & kh_KEY);
 843         }
 844 }
 845
 846 void kh_EnableTrackingDevice()  // runs after each round
 847 {
 848         entity player;
 849
 850         FOR_EACH_PLAYER(player)
 851                 if(clienttype(player) == CLIENTTYPE_REAL)
 852                         centerprint_expire(player, CENTERPRIO_SPAM);
 853
 854         kh_tracking_enabled = TRUE;
 855 }
 856
 857 float kh_Key_waypointsprite_for_player(entity e) // ??
 858 {
 859         if(!kh_tracking_enabled)
 860                 return 0;
 861         if(!self.owner)
 862                 return kh_sprite_dropped;
 863         if(!self.owner.owner)
 864                 return kh_sprite_dropped;
 865         return 0;  // draw only when key is not owned
 866 }
 867
 868 float kh_KeyCarrier_waypointsprite_for_player(entity e)  // runs all the time
 869 {
 870         if(e.classname != "player" || self.team != e.team)
 871                 if(!kh_tracking_enabled)
 872                         return 0;
 873
 874         // e is spectator? That's no team mate...
 875         if(e.classname != "player")
 876                 return kh_GetCarrierSprite(self.team, -1);
 877
 878         // e is no key carrier: simple case...
 879         if(!e.kh_next)
 880                 return kh_GetCarrierSprite(self.team, e.team);
 881
 882         // e is a key carrier: if any key is dropped or owned by another team, show
 883         // the carrier sprite; otherwise show run here
 884         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 885                 return kh_sprite_finish;
 886
 887         return kh_GetCarrierSprite(self.team, e.team);
 888 }
 889
 890 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 891 {
 892         if(attacker == targ)
 893                 return f;
 894
 895         if(targ.kh_next)
 896         {
 897                 if(attacker.team == targ.team)
 898                 {
 899                         entity k;
 900                         float nk;
 901                         nk = 0;
 902                         for(k = targ.kh_next; k != world; k = k.kh_next)
 903                                 ++nk;
 904                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 905                 }
 906                 else
 907                 {
 908                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 909                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 910                         // the frag gets added later
 911                 }
 912         }
 913
 914         return f;
 915 }
 916
 917 void kh_init()  // sets up th KH environment
 918 {
 919         precache_sound(kh_sound_capture);
 920         precache_sound(kh_sound_destroy);
 921         precache_sound(kh_sound_drop);
 922         precache_sound(kh_sound_collect);
 923         precache_sound(kh_sound_alarm);  // the new siren
 924
 925         precache_model("models/sprites/key-dropped.sp2");
 926         precache_model("models/sprites/keycarrier-finish.sp2");
 927         precache_model("models/sprites/keycarrier-friend.sp2");
 928         precache_model("models/sprites/keycarrier-red.sp2");
 929         precache_model("models/sprites/keycarrier-blue.sp2");
 930         precache_model("models/sprites/keycarrier-yellow.sp2");
 931         precache_model("models/sprites/keycarrier-pink.sp2");
 932 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 933         precache_model("models/keyhunt/key-carried.md3");
 934 #endif
 935         precache_model("models/keyhunt/key.md3");
 936
 937         // setup variables
 938         kh_teams = cvar("g_keyhunt_teams_override");
 939         if(kh_teams < 2)
 940                 kh_teams = cvar("g_keyhunt_teams");
 941         kh_teams = bound(2, kh_teams, 4);
 942
 943         // make a KH entity for controlling the game
 944         kh_controller = spawn();
 945         kh_controller.think = kh_Controller_Think;
 946         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 947
 948         setmodel(kh_controller, "models/keyhunt/key.md3");
 949         kh_key_dropped = kh_controller.modelindex;
 950         /*
 951         dprint(vtos(kh_controller.mins));
 952         dprint(vtos(kh_controller.maxs));
 953         dprint("\n");
 954         */
 955 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 956         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 957         kh_key_carried = kh_controller.modelindex;
 958 #else
 959         kh_key_carried = kh_key_dropped;
 960 #endif
 961         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 962         kh_sprite_dropped = kh_controller.modelindex;
 963         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 964         kh_sprite_finish = kh_controller.modelindex;
 965         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 966         kh_sprite_friend = kh_controller.modelindex;
 967         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 968         kh_sprite_red = kh_controller.modelindex;
 969         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 970         kh_sprite_blue = kh_controller.modelindex;
 971         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 972         kh_sprite_pink = kh_controller.modelindex;
 973         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 974         kh_sprite_yellow = kh_controller.modelindex;
 975         setmodel(kh_controller, "");
 976
 977         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 978
 979         ScoreRules_kh(kh_teams);
 980 }
 981
 982 void kh_finalize()
 983 {
 984         // to be called before intermission
 985         kh_FinishRound();
 986         remove(kh_controller);
 987         kh_controller = world;
 988 }
 989
 990 /**
 991  * kh_show_temp originally by victim.
 992  * changed it to use the kh_state stat var
 993  * Updates the general key stat bits for each player
 994  */
 995 void kh_show_temp()
 996 {
 997         entity player;
 998         float i, j;
 999
1000         j = 0;  // reset/blank j
1001         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1002                 j += test[i];
1003
1004         test[0] = j;
1005
1006         j *= 256;
1007         FOR_EACH_PLAYER(player)
1008                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1009 }