data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 2;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44 .float kh_dropperteam;
  45 .entity kh_previous_owner;
  46
  47 string kh_sound_capture = "sound/kh/capture.wav";
  48 string kh_sound_destroy = "sound/kh/destroy.wav";
  49 string kh_sound_drop = "sound/kh/drop.wav";
  50 string kh_sound_collect = "sound/kh/collect.wav";
  51
  52 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  53 float kh_key_dropped, kh_key_carried;
  54
  55 float kh_GetCarrierSprite(float t, float e)
  56 {
  57         if(t == e)           return kh_sprite_friend;
  58         if(t == COLOR_TEAM1) return kh_sprite_red;
  59         if(t == COLOR_TEAM2) return kh_sprite_blue;
  60         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  61         if(t == COLOR_TEAM4) return kh_sprite_pink;
  62         return 0;
  63 }
  64
  65 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  66 {
  67         kh_Controller_Thinkfunc = func;
  68         kh_controller.cnt = t;
  69         if(kh_Controller_Waitmsg != "")
  70                 strunzone(kh_Controller_Waitmsg);
  71         if(msg == "")
  72                 kh_Controller_Waitmsg = "";
  73         else
  74                 kh_Controller_Waitmsg = strzone(msg);
  75         if(t == 0)
  76                 kh_controller.nextthink = time; // force
  77 }
  78
  79 void kh_Controller_Think()
  80 {
  81         entity e;
  82         if(intermission_running)
  83                 return;
  84         if(self.cnt > 0)
  85         {
  86                 if(kh_Controller_Waitmsg != "")
  87                 {
  88                         string s;
  89                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  90                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  91                         else
  92                                 s = kh_Controller_Waitmsg;
  93
  94                         //dprint(s, "\n");
  95
  96                         FOR_EACH_PLAYER(e)
  97                                 if(clienttype(e) == CLIENTTYPE_REAL)
  98                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  99                 }
 100                 self.cnt -= 1;
 101         }
 102         else if(self.cnt == 0)
 103         {
 104                 self.cnt -= 1;
 105                 kh_Controller_Thinkfunc();
 106         }
 107         self.nextthink = time + 1;
 108 }
 109
 110 // frags f: take from cvar * f
 111 // frags 0: no frags
 112 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 113 {
 114         string s;
 115         if(intermission_running)
 116                 return;
 117         if(frags_player)
 118                 UpdateFrags(player, frags_player);
 119         if(key && key.owner && frags_owner)
 120                 UpdateFrags(key.owner, frags_owner);
 121         if(!cvar("sv_eventlog"))
 122                 return;
 123         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 124         s = strcat(s, ":", ftos(frags_player));
 125         if(key && key.owner)
 126                 s = strcat(s, ":", ftos(key.owner.playerid));
 127         else
 128                 s = strcat(s, ":0");
 129         s = strcat(s, ":", ftos(frags_owner), ":");
 130         if(key)
 131                 s = strcat(s, key.netname);
 132         GameLogEcho(s, FALSE);
 133 }
 134
 135 vector kh_AttachedOrigin(entity e)
 136 {
 137         if(e.tag_entity)
 138         {
 139                 makevectors(e.tag_entity.angles);
 140                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 141         }
 142         else
 143                 return e.origin;
 144 }
 145
 146 void kh_Key_Attach(entity key)
 147 {
 148 #ifdef KH_PLAYER_USE_ATTACHMENT
 149         entity first;
 150         first = key.owner.kh_next;
 151         if(key == first)
 152         {
 153                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 154                 if(key.kh_next)
 155                 {
 156                         setattachment(key.kh_next, key, "");
 157                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 158                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 159                         key.kh_next.angles = '0 0 0';
 160                 }
 161                 else
 162                         setorigin(key, KH_PLAYER_ATTACHMENT);
 163                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 164         }
 165         else
 166         {
 167                 setattachment(key, key.kh_prev, "");
 168                 if(key.kh_next)
 169                         setattachment(key.kh_next, key, "");
 170                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 171                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                 key.angles = '0 0 0';
 173         }
 174 #else
 175         setattachment(key, key.owner, "");
 176         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 177         key.angles_y -= key.owner.angles_y;
 178 #endif
 179         key.flags = 0;
 180         key.solid = SOLID_NOT;
 181         key.movetype = MOVETYPE_NONE;
 182         key.team = key.owner.team;
 183         key.nextthink = time;
 184         key.damageforcescale = 0;
 185         key.modelindex = kh_key_carried;
 186 }
 187
 188 void kh_Key_Detach(entity key)
 189 {
 190 #ifdef KH_PLAYER_USE_ATTACHMENT
 191         entity first;
 192         first = key.owner.kh_next;
 193         if(key == first)
 194         {
 195                 if(key.kh_next)
 196                 {
 197                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 198                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 199                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 200                 }
 201         }
 202         else
 203         {
 204                 if(key.kh_next)
 205                         setattachment(key.kh_next, key.kh_prev, "");
 206                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 207         }
 208         // in any case:
 209         setattachment(key, world, "");
 210         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 211         key.angles = key.owner.angles;
 212 #else
 213         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 214         setattachment(key, world, "");
 215         key.angles_y += key.owner.angles_y;
 216 #endif
 217         key.aiment = world;
 218         key.flags = FL_ITEM;
 219         key.solid = SOLID_TRIGGER;
 220         key.movetype = MOVETYPE_TOSS;
 221         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 222         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 223         // let key.team stay
 224         key.modelindex = kh_key_dropped;
 225         key.kh_previous_owner = key.owner;
 226 }
 227
 228 void kh_Key_AssignTo(entity key, entity player)
 229 {
 230         if(key.owner == player)
 231                 return;
 232
 233         if(key.owner)
 234         {
 235                 kh_Key_Detach(key);
 236
 237                 // remove from linked list
 238                 if(key.kh_next)
 239                         key.kh_next.kh_prev = key.kh_prev;
 240                 key.kh_prev.kh_next = key.kh_next;
 241                 key.kh_next = world;
 242                 key.kh_prev = world;
 243
 244                 if(key.owner.kh_next == world)
 245                 {
 246                         // No longer a key carrier
 247                         WaypointSprite_DetachCarrier(key.owner);
 248                 }
 249         }
 250
 251         key.owner = player;
 252
 253         if(player)
 254         {
 255                 // insert into linked list
 256                 key.kh_next = player.kh_next;
 257                 key.kh_prev = player;
 258                 player.kh_next = key;
 259                 if(key.kh_next)
 260                         key.kh_next.kh_prev = key;
 261
 262                 kh_Key_Attach(key);
 263
 264                 if(key.kh_next == world)
 265                 {
 266                         // player is now a key carrier
 267                         WaypointSprite_AttachCarrier("", player);
 268                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 269                         player.waypointsprite_attachedforcarrier.team = player.team;
 270                 }
 271         }
 272
 273         key.pusher = world;
 274 }
 275
 276 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 277 {
 278         if(self.owner)
 279                 return;
 280         if(vlen(force) <= 0)
 281                 return;
 282         if(time > self.pushltime)
 283                 if(attacker.classname == "player")
 284                         self.team = attacker.team;
 285 }
 286
 287 vector kh_TeamColor(float teem)
 288 {
 289         switch(teem)
 290         {
 291                 case COLOR_TEAM1:
 292                         return '1 0.0625 0.0625';
 293                 case COLOR_TEAM2:
 294                         return '0.0625 0.0625 1';
 295                 case COLOR_TEAM3:
 296                         return '1 1 0.0625';
 297                 case COLOR_TEAM4:
 298                         return '1 0.0625 1';
 299                 default:
 300                         return '1 1 1';
 301         }
 302 }
 303
 304 void kh_Key_Spawn(entity initial_owner, float angle)
 305 {
 306         entity key;
 307         key = spawn();
 308         key.classname = STR_ITEM_KH_KEY;
 309         key.touch = kh_Key_Touch;
 310         key.think = kh_Key_Think;
 311         key.nextthink = time;
 312         key.items = IT_KEY1 | IT_KEY2;
 313         key.cnt = angle;
 314         key.angles = '0 360 0' * random();
 315         key.event_damage = kh_Key_Damage;
 316         key.modelindex = kh_key_dropped;
 317         key.model = "key";
 318         key.kh_dropperteam = 0;
 319         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 320         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 321         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 322
 323         switch(initial_owner.team)
 324         {
 325                 case COLOR_TEAM1:
 326                         key.netname = "^1red key";
 327                         break;
 328                 case COLOR_TEAM2:
 329                         key.netname = "^4blue key";
 330                         break;
 331                 case COLOR_TEAM3:
 332                         key.netname = "^3yellow key";
 333                         break;
 334                 case COLOR_TEAM4:
 335                         key.netname = "^6pink key";
 336                         break;
 337                 default:
 338                         key.netname = "NETGIER key";
 339                         break;
 340         }
 341
 342         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 343
 344         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 345         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 346
 347         kh_Key_AssignTo(key, initial_owner);
 348 }
 349
 350 void kh_Key_Remove(entity key)
 351 {
 352         entity o;
 353         o = key.owner;
 354         kh_Key_AssignTo(key, world);
 355         if(o) // it was attached
 356                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 357         else // it was dropped
 358                 WaypointSprite_DetachCarrier(key);
 359
 360         remove(key);
 361 }
 362
 363 // -1 when no team completely owns all keys yet
 364 float kh_Key_AllOwnedByWhichTeam()
 365 {
 366         entity key;
 367         float teem;
 368
 369         teem = -1;
 370         FOR_EACH_KH_KEY(key)
 371         {
 372                 if(!key.owner)
 373                         return -1;
 374                 if(teem == -1)
 375                         teem = key.team;
 376                 else if(teem != key.team)
 377                         return -1;
 378         }
 379         return teem;
 380 }
 381
 382 void kh_Key_Collect(entity key, entity player)
 383 {
 384         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 385
 386         if(key.kh_dropperteam != player.team)
 387                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 388         key.kh_dropperteam = 0;
 389         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 390         kh_Key_AssignTo(key, player);
 391
 392         if(kh_Key_AllOwnedByWhichTeam() != -1)
 393         {
 394                 kh_interferemsg_time = time + 0.2;
 395                 kh_interferemsg_team = player.team;
 396         }
 397 }
 398
 399 void kh_Key_DropAll(entity player, float suicide)
 400 {
 401         entity key;
 402         entity mypusher;
 403         if(player.kh_next)
 404         {
 405                 mypusher = world;
 406                 if(player.pusher)
 407                         if(time < player.pushltime)
 408                                 mypusher = player.pusher;
 409                 while((key = player.kh_next))
 410                 {
 411                         kh_Scores_Event(player, key, "losekey", 0, 0);
 412                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 413                         kh_Key_AssignTo(key, world);
 414                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 415                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 416                         key.pusher = mypusher;
 417                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 418                         if(suicide)
 419                                 key.kh_dropperteam = player.team;
 420                 }
 421                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 422         }
 423 }
 424
 425 void kh_Key_Touch()
 426 {
 427         if(intermission_running)
 428                 return;
 429
 430         if(self.owner) // already carried
 431                 return;
 432         if(other.classname != "player")
 433                 return;
 434         if(other.deadflag != DEAD_NO)
 435                 return;
 436         if(other == self.enemy)
 437                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 438                         return; // you just dropped it!
 439         kh_Key_Collect(self, other);
 440 }
 441
 442 void kh_Key_Think()
 443 {
 444         entity head;
 445
 446         if(intermission_running)
 447                 return;
 448
 449 #ifdef KH_KEY_ATTACHMENT_DEBUG
 450         if(self.kh_prev == self.owner)
 451         {
 452                 if(cvar_string("_angles") != "")
 453                 {
 454                         self.angles = stov(cvar_string("_angles"));
 455                         self.origin = stov(cvar_string("_origin"));
 456                 }
 457         }
 458 #endif
 459
 460         if(self.owner)
 461         {
 462 #ifndef KH_PLAYER_USE_ATTACHMENT
 463                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 464                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 465 #endif
 466
 467                 if(self.owner.buttonuse)
 468                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 469                 {
 470                         self.owner.kh_droptime = time;
 471                         self.kh_droptime = time; // prevent collecting this one for some time
 472                         self.enemy = self.owner;
 473                         self.pusher = world;
 474                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 475                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 476                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 477                         makevectors(self.owner.v_angle);
 478                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 479                         kh_Key_AssignTo(self, world);
 480                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 481                         self.kh_dropperteam = self.team;
 482                 }
 483         }
 484
 485         // if in nodrop or time over, end the round
 486         if(!self.owner)
 487                 if(time > self.pain_finished)
 488                         kh_LoserTeam(self.team, self);
 489
 490         if(self.owner)
 491         if(kh_Key_AllOwnedByWhichTeam() != -1)
 492         {
 493                 entity key;
 494                 vector p;
 495                 p = self.owner.origin;
 496                 FOR_EACH_KH_KEY(key)
 497                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 498                                 goto not_winning;
 499                 kh_WinnerTeam(self.team);
 500 :not_winning
 501         }
 502
 503         if(kh_interferemsg_time && time > kh_interferemsg_time)
 504         {
 505                 kh_interferemsg_time = 0;
 506                 FOR_EACH_PLAYER(head)
 507                 {
 508                         if(head.team == kh_interferemsg_team)
 509                                 if(head.kh_next)
 510                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 511                                 else
 512                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 513                         else
 514                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 515                 }
 516         }
 517
 518         self.nextthink = time + 0.05;
 519 }
 520
 521 void kh_WinnerTeam(float teem)
 522 {
 523         // all key carriers get some points
 524         vector firstorigin, lastorigin, midpoint;
 525         float first;
 526         entity key;
 527         float score;
 528         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 529         DistributeEvenly_Init(score, kh_teams);
 530         // twice the score for 3 team games, three times the score for 4 team games!
 531         // note: for a win by destroying the key, this should NOT be applied
 532         FOR_EACH_KH_KEY(key)
 533                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 534
 535         first = TRUE;
 536         FOR_EACH_KH_KEY(key)
 537                 if(key.owner.kh_next == key)
 538                 {
 539                         if(!first)
 540                                 bprint("^7, ");
 541                         bprint(key.owner.netname);
 542                         first = FALSE;
 543                 }
 544         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 545
 546         first = TRUE;
 547         midpoint = '0 0 0';
 548         FOR_EACH_KH_KEY(key)
 549         {
 550                 vector thisorigin;
 551
 552                 thisorigin = kh_AttachedOrigin(key);
 553                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 554                 midpoint += thisorigin;
 555
 556                 if(!first)
 557                         te_lightning2(world, lastorigin, thisorigin);
 558                 lastorigin = thisorigin;
 559                 if(first)
 560                         firstorigin = thisorigin;
 561                 first = FALSE;
 562         }
 563         if(kh_teams > 2)
 564         {
 565                 te_lightning2(world, lastorigin, firstorigin);
 566         }
 567         midpoint = midpoint * (1 / kh_teams);
 568         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 569
 570         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 571         kh_FinishRound();
 572 }
 573
 574 void kh_LoserTeam(float teem, entity lostkey)
 575 {
 576         entity player, key, attacker;
 577         float players;
 578         float keys;
 579
 580         attacker = world;
 581         if(lostkey.pusher)
 582                 if(lostkey.pusher.team != teem)
 583                         if(lostkey.pusher.classname == "player")
 584                                 attacker = lostkey.pusher;
 585
 586         players = keys = 0;
 587
 588         if(attacker)
 589         {
 590                 if(lostkey.kh_previous_owner)
 591                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 592                         // don't actually GIVE him the -nn points, just log
 593                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 594                 centerprint(attacker, "Your push is the best!\n\n\n");
 595                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 596         }
 597         else
 598         {
 599                 float of, fragsleft, i, j, thisteam;
 600                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 601
 602                 FOR_EACH_PLAYER(player)
 603                         if(player.team != teem)
 604                                 ++players;
 605
 606                 FOR_EACH_KH_KEY(key)
 607                         if(key.owner && key.team != teem)
 608                                 ++keys;
 609
 610                 if(lostkey.kh_previous_owner)
 611                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 612                         // don't actually GIVE him the -nn points, just log
 613
 614                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 615
 616                 FOR_EACH_KH_KEY(key)
 617                         if(key.owner && key.team != teem)
 618                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 619
 620                 fragsleft = DistributeEvenly_Get(players);
 621
 622                 // Now distribute these among all other teams...
 623                 j = kh_teams - 1;
 624                 for(i = 0; i < kh_teams; ++i)
 625                 {
 626                         thisteam = kh_Team_ByID(i);
 627                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 628                                 continue;
 629
 630                         players = 0;
 631                         FOR_EACH_PLAYER(player)
 632                                 if(player.team == thisteam)
 633                                         ++players;
 634
 635                         DistributeEvenly_Init(fragsleft, j);
 636                         fragsleft = DistributeEvenly_Get(j - 1);
 637                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 638
 639                         FOR_EACH_PLAYER(player)
 640                                 if(player.team == thisteam)
 641                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 642
 643                         --j;
 644                 }
 645
 646                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 647         }
 648         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 649         te_tarexplosion(lostkey.origin);
 650
 651         kh_FinishRound();
 652 }
 653
 654 void kh_FinishRound()
 655 {
 656         // prepare next round
 657         kh_interferemsg_time = 0;
 658         entity key;
 659         FOR_EACH_KH_KEY(key)
 660                 kh_Key_Remove(key);
 661
 662         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 663 }
 664
 665 string kh_CheckEnoughPlayers()
 666 {
 667         float i, players, teem;
 668         entity player;
 669         string result;
 670         result = "";
 671
 672         // find a random player per team
 673         for(i = 0; i < kh_teams; ++i)
 674         {
 675                 teem = kh_Team_ByID(i);
 676                 players = 0;
 677                 FOR_EACH_PLAYER(player)
 678                         if(player.deadflag == DEAD_NO)
 679                                 if(!player.buttonchat)
 680                                         if(player.team == teem)
 681                                                 ++players;
 682                 if(players == 0)
 683                 {
 684                         if(result != "")
 685                                 result = strcat(result, ", ");
 686                         result = strcat(result, ColoredTeamName(teem));
 687                 }
 688         }
 689         return result;
 690 }
 691
 692 void kh_WaitForPlayers()
 693 {
 694         string teams_missing;
 695         teams_missing = kh_CheckEnoughPlayers();
 696         if(teams_missing == "")
 697                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 698         else
 699                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 700 }
 701
 702 void kh_StartRound()
 703 {
 704         string teams_missing;
 705         float i, players, teem;
 706         entity player;
 707
 708         teams_missing = kh_CheckEnoughPlayers();
 709         if(teams_missing != "")
 710         {
 711                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 712                 return;
 713         }
 714
 715         FOR_EACH_PLAYER(player)
 716                 if(clienttype(player) == CLIENTTYPE_REAL)
 717                         centerprint_expire(player, CENTERPRIO_SPAM);
 718
 719         for(i = 0; i < kh_teams; ++i)
 720         {
 721                 teem = kh_Team_ByID(i);
 722                 players = 0;
 723                 entity my_player;
 724                 FOR_EACH_PLAYER(player)
 725                         if(player.deadflag == DEAD_NO)
 726                                 if(!player.buttonchat)
 727                                         if(player.team == teem)
 728                                         {
 729                                                 ++players;
 730                                                 if(random() * players <= 1)
 731                                                         my_player = player;
 732                                         }
 733                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 734                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 735                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 736         }
 737
 738         kh_tracking_enabled = FALSE;
 739         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 740 }
 741
 742 void kh_setstatus()
 743 {
 744         if(kh_teams)
 745         {
 746                 float kh_KEY;
 747                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 748                 if(self.kh_next)
 749                         self.items = self.items | kh_KEY;
 750                 else
 751                         self.items = self.items - (self.items & kh_KEY);
 752         }
 753 }
 754
 755 void kh_EnableTrackingDevice()
 756 {
 757         entity player;
 758
 759         FOR_EACH_PLAYER(player)
 760                 if(clienttype(player) == CLIENTTYPE_REAL)
 761                         centerprint_expire(player, CENTERPRIO_SPAM);
 762
 763         kh_tracking_enabled = TRUE;
 764 }
 765
 766 float kh_Key_waypointsprite_for_player(entity e)
 767 {
 768         if(!kh_tracking_enabled)
 769                 return 0;
 770         if(!self.owner)
 771                 return kh_sprite_dropped;
 772         if(!self.owner.owner)
 773                 return kh_sprite_dropped;
 774         return 0; // draw only when key is not owned
 775 }
 776
 777 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 778 {
 779         if(e.classname != "player" || self.team != e.team)
 780                 if(!kh_tracking_enabled)
 781                         return 0;
 782
 783         // e is spectator? That's no team mate...
 784         if(e.classname != "player")
 785                 return kh_GetCarrierSprite(self.team, -1);
 786
 787         // e is no key carrier: simple case...
 788         if(!e.kh_next)
 789                 return kh_GetCarrierSprite(self.team, e.team);
 790
 791         // e is a key carrier: if any key is dropped or owned by another team, show
 792         // the carrier sprite; otherwise show run here
 793         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 794                 return kh_sprite_finish;
 795
 796         return kh_GetCarrierSprite(self.team, e.team);
 797 }
 798
 799 float kh_HandleFrags(entity attacker, entity targ, float f)
 800 {
 801         if(attacker == targ)
 802                 return f;
 803
 804         if(targ.kh_next)
 805         {
 806                 if(attacker.team == targ.team)
 807                 {
 808                         entity k;
 809                         float nk;
 810                         nk = 0;
 811                         for(k = targ.kh_next; k != world; k = k.kh_next)
 812                                 ++nk;
 813                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 814                 }
 815                 else
 816                 {
 817                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 818                 }
 819         }
 820
 821         return f;
 822 }
 823
 824 void kh_init()
 825 {
 826         precache_sound(kh_sound_capture);
 827         precache_sound(kh_sound_destroy);
 828         precache_sound(kh_sound_drop);
 829         precache_sound(kh_sound_collect);
 830
 831         precache_model("models/sprites/key-dropped.sp2");
 832         precache_model("models/sprites/keycarrier-finish.sp2");
 833         precache_model("models/sprites/keycarrier-friend.sp2");
 834         precache_model("models/sprites/keycarrier-red.sp2");
 835         precache_model("models/sprites/keycarrier-blue.sp2");
 836         precache_model("models/sprites/keycarrier-yellow.sp2");
 837         precache_model("models/sprites/keycarrier-pink.sp2");
 838 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 839         precache_model("models/keyhunt/key-carried.md3");
 840 #endif
 841         precache_model("models/keyhunt/key.md3");
 842
 843         // setup variables
 844         kh_teams = cvar("g_keyhunt_teams_override");
 845         if(kh_teams < 2)
 846                 kh_teams = cvar("g_keyhunt_teams");
 847         kh_teams = bound(2, kh_teams, 4);
 848
 849         // make a KH entity for controlling the game
 850         kh_controller = spawn();
 851         kh_controller.think = kh_Controller_Think;
 852         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 853
 854         setmodel(kh_controller, "models/keyhunt/key.md3");
 855         kh_key_dropped = kh_controller.modelindex;
 856         /*
 857         dprint(vtos(kh_controller.mins));
 858         dprint(vtos(kh_controller.maxs));
 859         dprint("\n");
 860         */
 861 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 862         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 863         kh_key_carried = kh_controller.modelindex;
 864 #else
 865         kh_key_carried = kh_key_dropped;
 866 #endif
 867         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 868         kh_sprite_dropped = kh_controller.modelindex;
 869         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 870         kh_sprite_finish = kh_controller.modelindex;
 871         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 872         kh_sprite_friend = kh_controller.modelindex;
 873         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 874         kh_sprite_red = kh_controller.modelindex;
 875         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 876         kh_sprite_blue = kh_controller.modelindex;
 877         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 878         kh_sprite_pink = kh_controller.modelindex;
 879         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 880         kh_sprite_yellow = kh_controller.modelindex;
 881         setmodel(kh_controller, "");
 882 }
 883
 884 void kh_finalize()
 885 {
 886         // to be called before intermission
 887         kh_FinishRound();
 888         remove(kh_controller);
 889         kh_controller = world;
 890 }