data/qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2
   3 #if 0
   4 // TODO make this algorithm work (no idea why it is failing), it would be much faster
   5 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   6 {
   7         vector c;
   8         float d;
   9         if(a_z > b_z)
  10                 return 0;
  11         tracebox(a, mi, ma, b, MOVE_WORLDONLY, world);
  12         if(trace_startsolid)
  13         {
  14                 // a leaves solid, then hits trace_endpos
  15                 // where does a leave solid?
  16                 c = trace_endpos;
  17                 tracebox(c, mi, ma, a, MOVE_WORLDONLY, world);
  18                 // a to trace_endpos is solid
  19                 // trace_endpos to c is not solid
  20                 d = trace_endpos_z - a_z;
  21                 return FullTraceFraction(c + '0 0 1', mi, ma, b) + d;
  22         }
  23         else
  24         {
  25                 // a hits trace_endpos
  26                 return FullTraceFraction(trace_endpos + '0 0 1', mi, ma, b);
  27         }
  28 }
  29
  30 float RoughMapAtPoint(float x, float y, float w, float h)
  31 {
  32         vector a, b, mi, ma;
  33         mi = '0 0 0';
  34         ma = '1 0 0' * w + '0 1 0' * h;
  35         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * world.mins_z;
  36         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * world.maxs_z;
  37         return floor(FullTraceFraction(a, mi, ma, b) / (world.maxs_z - world.mins_z) * 255);
  38 }
  39 #else
  40 float RoughMapAtPoint(float x, float y, float w, float h, float zmin, float zsize)
  41 {
  42         vector o, mi, ma;
  43         float i, r;
  44         vector dz;
  45         mi = '0 0 0';
  46         dz = (zsize / 256) * '0 0 1';
  47         ma = '1 0 0' * w + '0 1 0' * h + dz;
  48         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49
  50         if(x < world.mins_x - w)
  51                 return 0;
  52         if(y < world.mins_y - h)
  53                 return 0;
  54         if(x > world.maxs_x)
  55                 return 0;
  56         if(y > world.maxs_y)
  57                 return 0;
  58
  59         r = 0;
  60         for(i = 0; i < 255; ++i)
  61         {
  62                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
  63                 if(trace_startsolid)
  64                         ++r;
  65         }
  66         return r; // 0 .. 255
  67 }
  68 #endif
  69
  70 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFF";
  71
  72 entity roughmapper;
  73 // rough map entity
  74 //   cnt: current line
  75 //   size: pixel width/height
  76 //   maxs: cell width/height
  77 //   frame: counter
  78 void RoughMap_Think()
  79 {
  80         float i, x, l;
  81         string si;
  82
  83         if(self.frame == 0)
  84         {
  85                 // initialize
  86                 get_mi_min_max();
  87                 self.size_x = 512;
  88                 self.size_y = 512;
  89                 self.mins = mi_picmin;
  90                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
  91                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
  92                 self.maxs_z = mi_max_z - mi_min_z;
  93                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
  94                 self.netname = strzone(strcat("gfx/", mi_shortname, "_mini.xpm"));
  95                 if(!(self.count & 1))
  96                 {
  97                         self.cnt = fopen(self.netname, FILE_READ);
  98                         if(self.cnt >= 0)
  99                         {
 100                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 101                                 if(self.count & 4)
 102                                 {
 103                                         localcmd("quit\n");
 104                                 }
 105                                 else if(self.count & 2)
 106                                 {
 107                                         if(self.count & 1)
 108                                                 localcmd("defer 1 \"sv_cmd roughmap --force --loop\"\n");
 109                                         else
 110                                                 localcmd("defer 1 \"sv_cmd roughmap --loop\"\n");
 111                                         GotoNextMap();
 112                                 }
 113                                 remove(self);
 114                                 roughmapper = world;
 115                                 return;
 116                         }
 117                 }
 118                 self.cnt = fopen(self.netname, FILE_WRITE);
 119                 if(self.cnt < 0)
 120                 {
 121                         print("Error writing ", self.netname, "\n");
 122                         remove(self);
 123                         roughmapper = world;
 124                         return;
 125                 }
 126                 print("Writing to ", self.netname, "...\n");
 127                 fputs(self.cnt, "/* XPM */\n");
 128                 fputs(self.cnt, "static char *RoughMap[] = {\n");
 129                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 130                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 131                 for(i = 0; i < 256; ++i)
 132                 {
 133                         si = substring(doublehex, i*2, 2);
 134                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 135                 }
 136                 self.frame += 1;
 137                 self.nextthink = time;
 138         }
 139         else if(self.frame <= self.size_y)
 140         {
 141                 // write a pixel line
 142                 fputs(self.cnt, "\"");
 143                 for(x = 0; x < self.size_x; ++x)
 144                 {
 145                         l = RoughMapAtPoint(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z);
 146                         fputs(self.cnt, substring(doublehex, 2 * l, 2));
 147                 }
 148                 if(self.frame == self.size_y)
 149                         fputs(self.cnt, "\"\n");
 150                 else
 151                 {
 152                         fputs(self.cnt, "\",\n");
 153                         print(ftos(self.size_y - self.frame), " lines left\n");
 154                 }
 155                 self.frame += 1;
 156                 self.nextthink = time;
 157         }
 158         else
 159         {
 160                 // close the file
 161                 fputs(self.cnt, "};\n");
 162                 fclose(self.cnt);
 163                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 164                 if(self.count & 4)
 165                 {
 166                         localcmd("quit\n");
 167                 }
 168                 else if(self.count & 2)
 169                 {
 170                         if(self.count & 1)
 171                                 localcmd("defer 1 \"sv_cmd roughmap --force --loop\"\n");
 172                         else
 173                                 localcmd("defer 1 \"sv_cmd roughmap --loop\"\n");
 174                         GotoNextMap();
 175                 }
 176                 remove(self);
 177                 roughmapper = world;
 178         }
 179 }
 180
 181 void RoughMap(float argc)
 182 {
 183         if(roughmapper)
 184                 return;
 185         float i;
 186         roughmapper = spawn();
 187         roughmapper.classname = "roughmapper";
 188         roughmapper.think = RoughMap_Think;
 189         roughmapper.nextthink = time;
 190         roughmapper.count = 0;
 191
 192         for(i = 1; i < argc; ++i)
 193         {
 194                 if(argv(i) == "--force")
 195                         roughmapper.count |= 1;
 196                 if(argv(i) == "--loop")
 197                         roughmapper.count |= 2;
 198                 if(argv(i) == "--quit")
 199                         roughmapper.count |= 4;
 200         }
 201 }
 202
 203 void EffectIndexDump()
 204 {
 205         float d;
 206         float fh;
 207         string s;
 208
 209         d = db_create();
 210
 211         print("begin of effects list\n");
 212         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 213         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 214         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 215         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 216         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 217         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 218         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 219         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 220         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 221         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 222         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 223         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 224         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 225         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 226         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 227         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 228         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 229         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 230         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 231         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 232         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 233         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 234         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 235         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 236         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 237         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 238         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 239         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 240         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 241         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 242         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 243         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 244         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 245         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 246         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 247
 248         fh = fopen("effectinfo.txt", FILE_READ);
 249         while((s = fgets(fh)))
 250         {
 251                 tokenize(s);
 252                 if(argv(0) == "effect")
 253                 {
 254                         if(db_get(d, argv(1)) != "1")
 255                         {
 256                                 if(particleeffectnum(argv(1)) >= 0)
 257                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 258                                 db_put(d, argv(1), "1");
 259                         }
 260                 }
 261         }
 262         print("end of effects list\n");
 263
 264         db_close(d);
 265 }
 266
 267 void make_mapinfo_Think()
 268 {
 269         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 1))
 270         {
 271                 print("Done rebuiling mapinfos.\n");
 272                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 273                 remove(self);
 274         }
 275         else
 276         {
 277                 self.think = make_mapinfo_Think;
 278                 self.nextthink = time;
 279         }
 280 }
 281
 282 void GameCommand(string command)
 283 {
 284         float argc;
 285         entity client;
 286         float entno;
 287         argc = tokenize(command);
 288
 289         if(argv(0) == "help" || argc == 0)
 290         {
 291                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
 292                 print("  adminmsg clientnumber \"message\"\n");
 293                 print("  teamstatus\n");
 294                 print("  printstats\n");
 295                 print("  make_mapinfo\n");
 296                 print("  gametype dm|ctf|...\n");
 297                 print("  savedb filename\n");
 298                 print("  dumpdb filename\n");
 299                 print("  loaddb filename\n");
 300                 print("  allready\n");
 301                 print("  effectindexdump\n");
 302                 print("  roughmap\n");
 303                 GameCommand_Vote("help", world);
 304                 GameCommand_Ban("help");
 305                 GameCommand_Generic("help");
 306                 return;
 307         }
 308
 309         if(GameCommand_Vote(command, world))
 310                 return;
 311
 312         if(GameCommand_Ban(command))
 313                 return;
 314
 315         if(GameCommand_Generic(command))
 316                 return;
 317
 318         if(argv(0) == "printstats")
 319         {
 320                 DumpStats(FALSE);
 321                 return;
 322         }
 323
 324         if(argv(0) == "make_mapinfo")
 325         {
 326                 entity e;
 327                 e = spawn();
 328                 e.classname = "make_mapinfo";
 329                 e.think = make_mapinfo_Think;
 330                 e.nextthink = time;
 331                 MapInfo_Enumerate();
 332                 return;
 333         }
 334
 335         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
 336         {
 337                 CampaignLevelWarp(stof(argv(1)));
 338                 return;
 339         }
 340
 341         if(argv(0) == "gotomap") if(argc == 2)
 342         {
 343                 print(GotoMap(argv(1)), "\n");
 344                 return;
 345         }
 346
 347         if(argv(0) == "gametype") if(argc == 2)
 348         {
 349                 float t, tsave;
 350                 string s;
 351                 s = argv(1);
 352                 t = MapInfo_Type_FromString(s);
 353                 tsave = MapInfo_CurrentGametype();
 354                 if(t)
 355                 {
 356                         MapInfo_SwitchGameType(t);
 357                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 358                         if(MapInfo_count > 0)
 359                         {
 360                                 bprint("Game type successfully switched to ", s, "\n");
 361                         }
 362                         else
 363                         {
 364                                 bprint("Cannot use this game type: no map for it found\n");
 365                                 MapInfo_SwitchGameType(tsave);
 366                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 367                         }
 368                 }
 369                 else
 370                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 371                 return;
 372         }
 373
 374         if(argv(0) == "adminmsg") if(argc == 3)
 375         {
 376                 entno = stof(argv(1));
 377                 client = world;
 378                 if(entno <= maxclients)
 379                         client = edict_num(entno);
 380                 if(client.flags & FL_CLIENT)
 381                 {
 382                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
 383                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
 384                         print("Message sent to ", client.netname, "\n");
 385                 }
 386                 else
 387                         print("Client not found\n");
 388                 return;
 389         }
 390
 391         if(argv(0) == "savedb") if(argc == 2)
 392         {
 393                 db_save(ServerProgsDB, argv(1));
 394                 print("DB saved.\n");
 395                 return;
 396         }
 397
 398         if(argv(0) == "dumpdb") if(argc == 2)
 399         {
 400                 db_dump(ServerProgsDB, argv(1));
 401                 print("DB dumped.\n");
 402                 return;
 403         }
 404
 405         if(argv(0) == "loaddb") if(argc == 2)
 406         {
 407                 db_close(ServerProgsDB);
 408                 ServerProgsDB = db_load(argv(1));
 409                 print("DB loaded.\n");
 410                 return;
 411         }
 412         if (argv(0) == "nospectators")
 413         {
 414                 blockSpectators = 1;
 415                 local entity plr;
 416                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 417                 {
 418                         if(plr.classname == "spectator" || plr.classname == "observer")
 419                         {
 420                                 plr.spectatortime = time;
 421                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 422                         }
 423                 }
 424                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
 425                 return;
 426         }
 427         if (argv(0) == "lockteams")
 428         {
 429                 if(teamplay)
 430                 {
 431                         lockteams = 1;
 432                         bprint("^1The teams are now locked.\n");
 433                 }
 434                 else
 435                         bprint("That command can only be used in a team-based gamemode.\n");
 436                 return;
 437         }
 438         if (argv(0) == "unlockteams")
 439         {
 440                 if(teamplay)
 441                 {
 442                         lockteams = 0;
 443                         bprint("^1The teams are now unlocked.\n");
 444                 }
 445                 else
 446                         bprint("That command can only be used in a team-based gamemode.\n");
 447                 return;
 448         }
 449         if (argv(0) == "movetoteam") if(argc == 3)
 450         {
 451                 entno = stof(argv(1));
 452                 client = world;
 453                 if(entno <= maxclients)
 454                         client = edict_num(entno);
 455                 if(client.flags & FL_CLIENT)
 456                 {
 457                         float lt;
 458                         lt = lockteams;
 459                         lockteams = 0;
 460
 461                         self = client;
 462                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
 463
 464                         lockteams = lt;
 465                 }
 466                 else
 467                         print("Client not found\n");
 468                 return;
 469         }
 470         if (argv(0) == "teamstatus")
 471         {
 472                 Score_NicePrint(world);
 473                 return;
 474         }
 475         if (argv(0) == "allready")
 476         {
 477                 ReadyRestart();
 478                 return;
 479         }
 480         if (argv(0) == "effectindexdump")
 481         {
 482                 EffectIndexDump();
 483                 return;
 484         }
 485         if (argv(0) == "roughmap")
 486         {
 487                 RoughMap(argc);
 488                 return;
 489         }
 490         if (argv(0) == "cvar_changes")
 491         {
 492                 print(cvar_changes);
 493                 return;
 494         }
 495
 496         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
 497 }
 498