data/qcsrc/server/gamec/t_items.c

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  78                         other.armorvalue = other.extralives;
  79                         sprint(other, "^3You picked up some extra lives\n");
  80                 }
  81
  82                 // invis powerup
  83                 if (self.strength_finished)
  84                 {
  85                         // sound not available
  86                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         // sound not available
  94                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  95                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  96                 }
  97         }
  98         else
  99         {
 100                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 101                         return;
 102
 103                 if (self.ammo_shells)
 104                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 105                 if (self.ammo_nails)
 106                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 107                 if (self.ammo_rockets)
 108                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 109                 if (self.ammo_cells)
 110                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 111
 112                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 113                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 114                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 115                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 116                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 117                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 118                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 119                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 120
 121                 if (self.strength_finished)
 122                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 123                 if (self.invincible_finished)
 124                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 125                 //if (self.speed_finished)
 126                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 127                 //if (self.slowmo_finished)
 128                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 129
 130                 if (self.max_health)
 131                 {
 132                         other.health = other.health + self.max_health;
 133                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 134                 }
 135                 if (self.health && other.health < other.max_health)
 136                         other.health = min(other.health + self.health, other.max_health);
 137                 if (self.armorvalue)
 138                 {
 139                         other.armorvalue = other.armorvalue + self.armorvalue;
 140                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 141                 }
 142         }
 143
 144         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 145
 146         oldself = self;
 147         self = other;
 148
 149         if (_switchweapon)
 150                 self.switchweapon = w_getbestweapon(self);
 151         if (self.switchweapon != self.weapon)
 152                 self.cnt = self.weapon;
 153
 154         self = oldself;
 155
 156         if (self.classname == "droppedweapon")
 157                 remove (self);
 158         else
 159         {
 160                 self.solid = SOLID_NOT;
 161                 self.model = string_null;
 162                 self.nextthink = time + self.respawntime;
 163                 self.think = Item_Respawn;
 164                 setorigin (self, self.origin);
 165         }
 166 }
 167
 168 // Savage: used for item garbage-collection
 169 // TODO: perhaps nice special effect?
 170 void RemoveItem(void) = {
 171         remove(self);
 172 }
 173
 174 // pickup evaluation functions
 175 // these functions decide how desirable an item is to the bots
 176
 177 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 178
 179 float(entity player, entity item) weapon_pickupevalfunc =
 180 {
 181         // if we already have the weapon, rate it 1/5th normal value
 182         if ((player.items & item.items) == item.items)
 183                 return item.bot_pickupbasevalue * 0.2;
 184         return item.bot_pickupbasevalue;
 185 };
 186
 187 float(entity player, entity item) commodity_pickupevalfunc =
 188 {
 189         float c;
 190         c = 0;
 191         // TODO: figure out if the player even has the weapon this ammo is for?
 192         // may not affect strategy much though...
 193         // find out how much ammo the player has, in terms of this ammo pickup
 194         // (how many of these ammo pickups it would take to total the player's
 195         // current ammo)
 196         if (item.ammo_shells)
 197                 c = c + player.ammo_shells / item.ammo_shells;
 198         if (item.ammo_nails)
 199                 c = c + player.ammo_nails / item.ammo_nails;
 200         if (item.ammo_rockets)
 201                 c = c + player.ammo_rockets / item.ammo_rockets;
 202         if (item.ammo_cells)
 203                 c = c + player.ammo_cells / item.ammo_cells;
 204         if (item.armorvalue)
 205                 c = c + player.armorvalue / item.armorvalue;
 206         if (item.health)
 207                 c = c + player.health / item.health / 10;
 208         // the more ammo the player has, the less desirable this pickup becomes
 209         c = 1 / (1 + c);
 210         return item.bot_pickupbasevalue * c;
 211 };
 212
 213
 214 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 215 {
 216         vector org;
 217         org = self.origin;
 218
 219         if (self.classname != "droppedweapon" && !self.noalign)
 220         {
 221                 vector z_offset;
 222
 223                 z_offset = '0 0 1';
 224
 225                 if (itemid == IT_SHELLS)
 226                         z_offset = '0 0 4';
 227                 else if (itemid == IT_ROCKETS)
 228                         z_offset = '0 0 4';
 229                 else if (itemid == IT_NAILS)
 230                         z_offset = '0 0 0';
 231                 else if (itemid == IT_25HP)
 232                         z_offset = '0 0 5';
 233                 else if (itemid == IT_ARMOR)
 234                         z_offset = '0 0 3';
 235
 236                 org = find_floor(org) + z_offset;
 237                 setorigin(self, org);
 238         }
 239
 240         if (self.classname != "droppedweapon")
 241                 waypoint_spawnforitem(self);
 242
 243         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 244                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 245         {
 246                 remove (self);
 247                 return;
 248         }
 249
 250         if (cvar("g_minstagib"))
 251         {
 252                 // don't remove dropped items and powerups
 253                 if (self.classname != "droppedweapon" &&
 254                     self.classname != "minstagib")
 255                 {
 256                         remove (self);
 257                         return;
 258                 }
 259         }
 260
 261         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 262         {
 263                 remove(self);
 264                 return;
 265         }
 266
 267         if(cvar("g_instagib") || cvar("g_rocketarena"))
 268         {
 269                 remove(self);
 270                 return;
 271         }
 272
 273         if (self.classname == "droppedweapon")
 274         {
 275                 // don't drop if in a NODROP zone (such as lava)
 276                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 277                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 278                 {
 279                         remove(self);
 280                         return;
 281                 }
 282         }
 283
 284         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 285                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 286                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 287         {
 288                 self.target = "###item###"; // for finding the nearest item using find()
 289         }
 290         self.bot_pickup = TRUE;
 291         self.bot_pickupevalfunc = pickupevalfunc;
 292         self.bot_pickupbasevalue = pickupbasevalue;
 293         self.mdl = itemmodel;
 294         //self.noise = pickupsound;
 295         self.item_pickupsound = pickupsound;
 296         // let mappers override respawntime
 297         if (!self.respawntime)
 298                 self.respawntime = defaultrespawntime;
 299         self.netname = itemname;
 300         self.items = itemid;
 301         self.flags = FL_ITEM | itemflags;
 302         setmodel (self, self.mdl);
 303         if (itemflags & FL_WEAPON)
 304         {
 305                 setorigin (self, self.origin + '0 0 23');
 306                 setsize (self, '-12 -12 -12', '12 12 12');
 307
 308                 // neutral team color for pickup weapons
 309                 self.colormap = 160 * 1024 + 160;
 310         }
 311         else
 312         {
 313                 setorigin (self, self.origin + '0 0 25');
 314         //      setsize (self, '-8 -8 -5', '8 8 8');
 315         }
 316         self.movetype = MOVETYPE_TOSS;
 317         self.solid = SOLID_TRIGGER;
 318         self.touch = Item_Touch;
 319
 320         // Savage: remove thrown items after a certain period of time ("garbage collection")
 321         if (self.classname == "droppedweapon")
 322         {
 323                 self.think = RemoveItem;
 324                 self.nextthink = time + 60;
 325         }
 326         else
 327         {
 328                 self.movetype = MOVETYPE_NONE;
 329                 setorigin(self, org);
 330         }
 331
 332         if (cvar("g_fullbrightitems"))
 333                 self.effects = self.effects | EF_FULLBRIGHT;
 334 }
 335
 336 /* replace items in minstagib
 337  * IT_STRENGTH   = invisibility
 338  * IT_NAILS      = extra lives
 339  * IT_INVINCIBLE = speed
 340  */
 341 void minstagib_items (float itemid)
 342 {
 343         // we don't want to replace dropped weapons ;)
 344         if (self.classname == "droppedweapon")
 345         {
 346                 self.ammo_cells = 25;
 347                 StartItem ("models/weapons/g_nex.md3",
 348                         "weapons/weaponpickup.ogg", 15,
 349                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 350                 return;
 351         }
 352
 353         local float rnd;
 354         self.classname = "minstagib";
 355
 356         // replace rocket launchers and nex guns with ammo cells
 357         if (itemid == IT_CELLS)
 358         {
 359                 self.ammo_cells = 1;
 360                 StartItem ("models/items/a_cells.md3",
 361                         "misc/itempickup.ogg", 45,
 362                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 363                 return;
 364         }
 365
 366         // randomize
 367         rnd = random() * 3;
 368         if (rnd <= 1)
 369                 itemid = IT_STRENGTH;
 370         else if (rnd <= 2)
 371                 itemid = IT_NAILS;
 372         else
 373                 itemid = IT_INVINCIBLE;
 374
 375         // replace with invis
 376         if (itemid == IT_STRENGTH)
 377         {
 378                 self.effects = EF_ADDITIVE;
 379                 self.strength_finished = 30;
 380                 StartItem ("models/items/g_strength.md3",
 381                         "misc/powerup.ogg", 120,
 382                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 383         }
 384         // replace with extra lives
 385         if (itemid == IT_NAILS)
 386         {
 387                 self.max_health = 1;
 388                 StartItem ("models/items/g_h100.md3",
 389                         "misc/megahealth.ogg", 120,
 390                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 391
 392         }
 393         // replace with ammo
 394         if (itemid == IT_INVINCIBLE)
 395         {
 396                 self.effects = EF_ADDITIVE;
 397                 self.invincible_finished = 30;
 398                 StartItem ("models/items/g_invincible.md3",
 399                         "misc/powerup_shield.ogg", 120,
 400                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 401         }
 402
 403 }
 404
 405 void weapon_uzi (void) {
 406         self.ammo_nails = 120;
 407         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 408 }
 409
 410 void weapon_shotgun (void) {
 411         self.ammo_shells = 15;
 412         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 413 }
 414
 415 void weapon_grenadelauncher (void) {
 416         self.ammo_rockets = 15;
 417         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 418 }
 419
 420 void weapon_electro (void) {
 421         self.ammo_cells = 25;
 422         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 423 }
 424
 425 void weapon_crylink (void) {
 426         self.ammo_cells = 25;
 427         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 428 }
 429
 430 void weapon_nex (void) {
 431         if (cvar("g_minstagib")) {
 432                 minstagib_items(IT_CELLS);
 433         } else {
 434                 self.ammo_cells = 25;
 435                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 436         }
 437 }
 438
 439 void weapon_hagar (void) {
 440         self.ammo_rockets = 15;
 441         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 442 }
 443
 444 void weapon_rocketlauncher (void) {
 445         if (cvar("g_minstagib")) {
 446                 minstagib_items(IT_CELLS);
 447         } else {
 448                 self.ammo_rockets = 15;
 449                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 450         }
 451 }
 452
 453 void item_rockets (void) {
 454         self.ammo_rockets = 15;
 455         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 456 }
 457
 458 void item_bullets (void) {
 459         self.ammo_nails = 120;
 460         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 461 }
 462
 463 void item_cells (void) {
 464         self.ammo_cells = 25;
 465         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 466 }
 467
 468 void item_shells (void) {
 469         self.ammo_shells = 15;
 470         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 471 }
 472
 473 void item_armor1 (void) {
 474         self.armorvalue = 5;
 475         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 476 }
 477
 478 void item_armor25 (void) {
 479         self.armorvalue = 100;
 480         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 481 }
 482
 483 void item_health1 (void) {
 484         self.max_health = 5;
 485         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 486 }
 487
 488 void item_health25 (void) {
 489         self.max_health = 25;
 490         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 491 }
 492
 493 void item_health100 (void) {
 494         if(!cvar("g_powerup_superhealth"))
 495                 return;
 496
 497         if(cvar("g_minstagib")) {
 498                 minstagib_items(IT_NAILS);
 499         } else {
 500                 self.max_health = 100;
 501                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 502         }
 503 }
 504
 505 void item_strength (void) {
 506         if(!cvar("g_powerup_strength"))
 507                 return;
 508
 509         if(cvar("g_minstagib")) {
 510                 minstagib_items(IT_STRENGTH);
 511         } else {
 512                 self.strength_finished = 30;
 513                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 514         }
 515 }
 516
 517 void item_invincible (void) {
 518         if(!cvar("g_powerup_shield"))
 519                 return;
 520
 521         if(cvar("g_minstagib")) {
 522                 minstagib_items(IT_INVINCIBLE);
 523         } else {
 524                 self.invincible_finished = 30;
 525                 self.effects = EF_ADDITIVE;
 526                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 527         }
 528 }
 529 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 530 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 531
 532 void misc_models (void)
 533 {
 534         precache_model (self.model);
 535         setmodel (self, self.model);
 536         setsize (self, self.mins, self.maxs);
 537 }
 538
 539