data/qcsrc/server/gamec/t_items.c

   1 void Item_ClearRespawnEffect (void) {
   2         self.effects = self.effects - (self.effects & EF_STARDUST);
   3 }
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // Savage: Add simple Respawn effect and make sure it gets removed
  13         self.effects = self.effects | EF_STARDUST;
  14         self.think = Item_ClearRespawnEffect;
  15         self.nextthink = time + 0.1;
  16 }
  17
  18 void Item_Touch (void)
  19 {
  20         local entity oldself;
  21         local float     _switchweapon;
  22
  23         if (other.classname != "player")
  24                 return;
  25         if (other.deadflag)
  26                 return;
  27         if (self.solid != SOLID_TRIGGER)
  28                 return;
  29         if (self.health && other.health >= other.max_health)
  30                 return;
  31         // Savage: Remove the respawn effect if still present
  32         self.effects = self.effects - (self.effects & EF_STARDUST);
  33
  34         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  35
  36         // in case the player has autoswitch enabled do the following:
  37         // if the player is using their best weapon before items are given, they
  38         // probably want to switch to an even better weapon after items are given
  39         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)));
  40
  41         if (cvar("g_minstagib"))
  42         {
  43                 if (self.ammo_cells)
  44                 {
  45                         // play some cool sounds ;)
  46                         centerprint(other, "\n");
  47                         if(other.health <= 5)
  48                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  49                         else if(other.health < 50)
  50                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  51                         // sound not available
  52                         // else if(self.items == IT_CELLS)
  53                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  54
  55                         if (self.items & IT_NEX)
  56                                 W_GiveWeapon (other, IT_NEX, "Nex");
  57                         if (self.ammo_cells)
  58                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  59                         other.health = 100;
  60                 }
  61
  62                 // extralife powerup
  63                 if (self.max_health)
  64                 {
  65                         // sound not available
  66                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  67                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  68                         other.armorvalue = other.extralives;
  69                         sprint(other, "^3You picked up some extra lives\n");
  70                 }
  71
  72                 // invis powerup
  73                 if (self.strength_finished)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  77                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  78                 }
  79
  80                 // speed powerup
  81                 if (self.invincible_finished)
  82                 {
  83                         // sound not available
  84                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  85                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  86                 }
  87         }
  88         else
  89         {
  90                 if (self.ammo_shells)
  91                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
  92                 if (self.ammo_nails)
  93                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
  94                 if (self.ammo_rockets)
  95                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
  96                 if (self.ammo_cells)
  97                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
  98
  99                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, "Machine gun");
 100                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, "Shotgun");
 101                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, "Mortar");
 102                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, "Electro");
 103                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, "Nex");
 104                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, "Hagar");
 105                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, "Rocket Launcher");
 106                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, "Crylink");
 107
 108                 if (self.strength_finished)
 109                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 110                 if (self.invincible_finished)
 111                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 112                 //if (self.speed_finished)
 113                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 114                 //if (self.slowmo_finished)
 115                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 116
 117                 if (self.max_health)
 118                 {
 119                         other.health = other.health + self.max_health;
 120                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + 5);
 121                 }
 122                 if (self.health && other.health < other.max_health)
 123                         other.health = min(other.health + self.health, other.max_health);
 124                 if (self.armorvalue)
 125                 {
 126                         other.armorvalue = other.armorvalue + self.armorvalue;
 127                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + 5);
 128                 }
 129         }
 130
 131         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 132
 133         oldself = self;
 134         self = other;
 135
 136         if (_switchweapon)
 137                 self.switchweapon = w_getbestweapon(self);
 138
 139         //w_updateweapon ();
 140         //w_updateammo ();
 141         weapon_action(self.weapon, WR_UPDATECOUNTS);
 142
 143         self = oldself;
 144
 145         if (self.classname == "droppedweapon")
 146                 remove (self);
 147         else
 148         {
 149                 self.solid = SOLID_NOT;
 150                 self.model = string_null;
 151                 self.nextthink = time + self.respawntime;
 152                 self.think = Item_Respawn;
 153                 setorigin (self, self.origin);
 154         }
 155 }
 156
 157 // Savage: used for item garbage-collection
 158 // TODO: perhaps nice special effect?
 159 void RemoveItem(void) = {
 160         remove(self);
 161 }
 162
 163
 164 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 165 {
 166         if (!cvar("g_pickup_items") && !cvar("g_minstagib") && !cvar("g_lms"))
 167         {
 168                 remove (self);
 169                 return;
 170         }
 171
 172         if (cvar("g_minstagib"))
 173         {
 174                 // don't remove dropped items and powerups
 175                 if (self.classname != "droppedweapon" &&
 176                     self.classname != "minstagib")
 177                 {
 178                         remove (self);
 179                         return;
 180                 }
 181         }
 182
 183         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 184         {
 185                 remove(self);
 186                 return;
 187         }
 188
 189         if(cvar("g_instagib") || cvar("g_rocketarena"))
 190         {
 191                 remove(self);
 192                 return;
 193         }
 194
 195         self.mdl = itemmodel;
 196         //self.noise = pickupsound;
 197         self.item_pickupsound = pickupsound;
 198         // let mappers override respawntime
 199         if (!self.respawntime)
 200                 self.respawntime = defaultrespawntime;
 201         self.netname = itemname;
 202         self.items = itemid;
 203         self.flags = FL_ITEM | itemflags;
 204         setmodel (self, self.mdl);
 205         if (itemflags & FL_WEAPON)
 206         {
 207                 setorigin (self, self.origin + '0 0 22');
 208                 setsize (self, '-12 -12 -12', '12 12 12');
 209
 210                 // neutral team color for pickup weapons
 211                 self.colormap = 160 * 1024 + 160;
 212         }
 213         else
 214         {
 215                 setorigin (self, self.origin + '0 0 15');
 216         //      setsize (self, '-8 -8 -5', '8 8 8');
 217         }
 218         self.movetype = MOVETYPE_TOSS;
 219         self.solid = SOLID_TRIGGER;
 220         self.touch = Item_Touch;
 221
 222         // Savage: remove thrown items after a certain period of time ("garbage collection")
 223         if (self.classname == "droppedweapon")
 224         {
 225                 self.think = RemoveItem;
 226                 self.nextthink = time + 60;
 227         }
 228
 229         if (cvar("g_fullbrightitems"))
 230                 self.effects = self.effects | EF_FULLBRIGHT;
 231
 232 }
 233
 234 /* replace items in minstagib
 235  * IT_STRENGTH   = invisibility
 236  * IT_NAILS      = extra lives
 237  * IT_INVINCIBLE = speed
 238  */
 239 void minstagib_items (float itemid)
 240 {
 241         // we don't want to replace dropped weapons ;)
 242         if (self.classname == "droppedweapon")
 243         {
 244                 self.ammo_cells = 25;
 245                 StartItem ("models/weapons/g_nex.md3",
 246                         "weapons/weaponpickup.ogg", 15,
 247                         "Nex Gun", IT_NEX, FL_WEAPON);
 248                 return;
 249         }
 250
 251         local float rnd;
 252         self.classname = "minstagib";
 253
 254         // replace rocket launchers and nex guns with ammo cells
 255         if (itemid == IT_CELLS)
 256         {
 257                 self.ammo_cells = 1;
 258                 StartItem ("models/items/a_cells.md3",
 259                         "misc/itempickup.ogg", 45,
 260                         "Nex Ammo", IT_CELLS, 0);
 261                 return;
 262         }
 263
 264         // randomize
 265         rnd = random() * 3;
 266         if (rnd <= 1)
 267                 itemid = IT_STRENGTH;
 268         else if (rnd <= 2)
 269                 itemid = IT_NAILS;
 270         else
 271                 itemid = IT_INVINCIBLE;
 272
 273         // replace with invis
 274         if (itemid == IT_STRENGTH)
 275         {
 276                 self.effects = EF_ADDITIVE;
 277                 self.strength_finished = 30;
 278                 StartItem ("models/items/g_strength.md3",
 279                         "misc/powerup.ogg", 120,
 280                         "Invisibility", IT_STRENGTH, FL_POWERUP);
 281         }
 282         // replace with extra lives
 283         if (itemid == IT_NAILS)
 284         {
 285                 self.max_health = 1;
 286                 StartItem ("models/items/g_h100.md3",
 287                         "misc/megahealth.ogg", 120,
 288                         "Extralife", IT_NAILS, FL_POWERUP);
 289
 290         }
 291         // replace with ammo
 292         if (itemid == IT_INVINCIBLE)
 293         {
 294                 self.effects = EF_ADDITIVE;
 295                 self.invincible_finished = 30;
 296                 StartItem ("models/items/g_invincible.md3",
 297                         "misc/powerup_shield.ogg", 120,
 298                         "Speed", IT_INVINCIBLE, FL_POWERUP);
 299         }
 300
 301 }
 302
 303 void weapon_uzi (void) {
 304         self.ammo_nails = 120;
 305         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, "Uzi", IT_UZI, FL_WEAPON);
 306 }
 307
 308 void weapon_shotgun (void) {
 309         self.ammo_shells = 15;
 310         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, "Shotgun", IT_SHOTGUN, FL_WEAPON);
 311 }
 312
 313 void weapon_grenadelauncher (void) {
 314         self.ammo_rockets = 15;
 315         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, "Grenade Launcher", IT_GRENADE_LAUNCHER, FL_WEAPON);
 316 }
 317
 318 void weapon_electro (void) {
 319         self.ammo_cells = 25;
 320         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, "Electro", IT_ELECTRO, FL_WEAPON);
 321 }
 322
 323 void weapon_crylink (void) {
 324         self.ammo_cells = 25;
 325         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, "Crylink", IT_CRYLINK, FL_WEAPON);
 326 }
 327
 328 void weapon_nex (void) {
 329         if (cvar("g_minstagib")) {
 330                 minstagib_items(IT_CELLS);
 331         } else {
 332                 self.ammo_cells = 25;
 333                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, "Nex Gun", IT_NEX, FL_WEAPON);
 334         }
 335 }
 336
 337 void weapon_hagar (void) {
 338         self.ammo_rockets = 15;
 339         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, "Hagar", IT_HAGAR, FL_WEAPON);
 340 }
 341
 342 void weapon_rocketlauncher (void) {
 343         if (cvar("g_minstagib")) {
 344                 minstagib_items(IT_CELLS);
 345         } else {
 346                 self.ammo_rockets = 15;
 347                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, "Rocket Launcher", IT_ROCKET_LAUNCHER, FL_WEAPON);
 348         }
 349 }
 350
 351 void item_rockets (void) {
 352         self.ammo_rockets = 15;
 353         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0);
 354 }
 355
 356 void item_bullets (void) {
 357         self.ammo_nails = 120;
 358         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0);
 359 }
 360
 361 void item_cells (void) {
 362         self.ammo_cells = 25;
 363         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0);
 364 }
 365
 366 void item_shells (void) {
 367         self.ammo_shells = 15;
 368         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0);
 369 }
 370
 371 void item_armor1 (void) {
 372         self.armorvalue = 5;
 373         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", 0, 0);
 374 }
 375
 376 void item_armor25 (void) {
 377         self.armorvalue = 100;
 378         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", 0, 0);
 379 }
 380
 381 void item_health1 (void) {
 382         self.max_health = 5;
 383         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", 0, 0);
 384 }
 385
 386 void item_health25 (void) {
 387         self.max_health = 25;
 388         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", 0, 0);
 389 }
 390
 391 void item_health100 (void) {
 392         if(cvar("g_minstagib")) {
 393                 minstagib_items(IT_NAILS);
 394         } else {
 395                 self.max_health = 100;
 396                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", 0, 0);
 397         }
 398 }
 399
 400 void item_strength (void) {
 401         if(cvar("g_minstagib")) {
 402                 minstagib_items(IT_STRENGTH);
 403         } else {
 404                 self.strength_finished = 30;
 405                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);
 406         }
 407 }
 408
 409 void item_invincible (void) {
 410         if(cvar("g_minstagib")) {
 411                 minstagib_items(IT_INVINCIBLE);
 412         } else {
 413                 self.invincible_finished = 30;
 414                 self.effects = EF_ADDITIVE;
 415                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);
 416         }
 417 }
 418 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 419 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 420
 421 void misc_models (void)
 422 {
 423         precache_model (self.model);
 424         setmodel (self, self.model);
 425         setsize (self, self.mins, self.maxs);
 426 }
 427
 428