data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         dprint_load(); // load dprint status from cvar
 345         world_initialized = -1; // don't complain
 346         remove = remove_unsafely;
 347
 348         entity e;
 349         e = spawn();
 350         e.think = GotoFirstMap;
 351         e.nextthink = time; // this is usually 1 at this point
 352
 353         e = spawn();
 354         e.classname = "info_player_deathmatch"; // safeguard against player joining
 355
 356         self.classname = "worldspawn"; // safeguard against various stuff ;)
 357
 358         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 359         MapInfo_Enumerate();
 360         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 361 }
 362
 363 void Map_MarkAsRecent(string m);
 364 float world_already_spawned;
 365 void RegisterWeapons();
 366 void Nagger_Init();
 367 void ClientInit_Spawn();
 368 void spawnfunc_worldspawn (void)
 369 {
 370         float fd, l, i, j, n;
 371         string s, col;
 372
 373         dprint_load(); // load dprint status from cvar
 374
 375         if(world_already_spawned)
 376                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 377         world_already_spawned = TRUE;
 378
 379         remove = remove_safely; // during spawning, watch what you remove!
 380
 381         if(cvar_string("cvar_check_default") != "bypass")
 382         {
 383                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 384                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 385
 386                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 387                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 388         }
 389
 390         compressShortVector_init();
 391
 392         local entity head;
 393         head = nextent(world);
 394         maxclients = 0;
 395         while(head)
 396         {
 397                 ++maxclients;
 398                 head = nextent(head);
 399         }
 400
 401         // needs to be done so early as they would still spawn
 402         RegisterWeapons();
 403
 404         if(sv_cheats)
 405                 ServerProgsDB = db_create();
 406         else
 407                 ServerProgsDB = db_load("server.db");
 408
 409         TemporaryDB = db_create();
 410
 411         /*
 412         TODO sound pack system
 413         // initialize sound pack system
 414         soundpack = cvar_string("g_soundpack");
 415         if(soundpack != "")
 416                 soundpack = strcat(soundpack, "/");
 417         soundpack = strzone(soundpack);
 418         */
 419
 420         // 0 normal
 421         lightstyle(0, "m");
 422
 423         // 1 FLICKER (first variety)
 424         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 425
 426         // 2 SLOW STRONG PULSE
 427         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 428
 429         // 3 CANDLE (first variety)
 430         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 431
 432         // 4 FAST STROBE
 433         lightstyle(4, "mamamamamama");
 434
 435         // 5 GENTLE PULSE 1
 436         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 437
 438         // 6 FLICKER (second variety)
 439         lightstyle(6, "nmonqnmomnmomomno");
 440
 441         // 7 CANDLE (second variety)
 442         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 443
 444         // 8 CANDLE (third variety)
 445         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 446
 447         // 9 SLOW STROBE (fourth variety)
 448         lightstyle(9, "aaaaaaaazzzzzzzz");
 449
 450         // 10 FLUORESCENT FLICKER
 451         lightstyle(10, "mmamammmmammamamaaamammma");
 452
 453         // 11 SLOW PULSE NOT FADE TO BLACK
 454         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 455
 456         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 457
 458         // 63 testing
 459         lightstyle(63, "a");
 460
 461         if(cvar("g_campaign"))
 462                 CampaignPreInit();
 463
 464         Map_MarkAsRecent(mapname);
 465
 466         precache_model ("null"); // we need this one before InitGameplayMode
 467         InitGameplayMode();
 468         readlevelcvars();
 469         GrappleHookInit();
 470
 471         player_count = 0;
 472         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 473         if(bot_waypoints_for_items == 1)
 474                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 475                         bot_waypoints_for_items = 0;
 476
 477         // for setting by mapinfo
 478         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 479         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 480
 481         precache();
 482
 483         WaypointSprite_Init();
 484
 485         //if (g_domination)
 486         //      dom_init();
 487
 488         GameLogInit(); // prepare everything
 489         if(cvar("sv_eventlog"))
 490         {
 491                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 492                 s = strcat(s, ftos(random()));
 493                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 494                 s = ":gameinfo:mutators:LIST";
 495                 if(cvar("g_grappling_hook"))
 496                         s = strcat(s, ":grappling_hook");
 497                 if(!cvar("g_use_ammunition"))
 498                         s = strcat(s, ":no_use_ammunition");
 499                 if(!cvar("g_pickup_items"))
 500                         s = strcat(s, ":no_pickup_items");
 501                 if(cvar("g_instagib"))
 502                         s = strcat(s, ":instagib");
 503                 if(cvar_string("g_weaponarena") != "0")
 504                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 505                 if(cvar("g_nixnex"))
 506                         s = strcat(s, ":nixnex");
 507                 if(cvar("g_vampire"))
 508                         s = strcat(s, ":vampire");
 509                 if(cvar("g_laserguided_missile"))
 510                         s = strcat(s, ":laserguided_missile");
 511                 if(cvar("g_norecoil"))
 512                         s = strcat(s, ":norecoil");
 513                 if(cvar("g_midair"))
 514                         s = strcat(s, ":midair");
 515                 if(cvar("g_minstagib"))
 516                         s = strcat(s, ":minstagib");
 517                 GameLogEcho(s);
 518                 GameLogEcho(":gameinfo:end");
 519         }
 520
 521         cvar_set("nextmap", "");
 522
 523         SetDefaultAlpha();
 524
 525         if(cvar("g_campaign"))
 526                 CampaignPostInit();
 527
 528         fteqcc_testbugs();
 529
 530         Ban_LoadBans();
 531
 532         //initialise globals related to sv_timeout
 533         sys_ticrate = cvar("sys_ticrate");
 534         orig_slowmo = cvar("slowmo");
 535
 536         MapInfo_Enumerate();
 537         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 538
 539         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 540         {
 541                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 542                 if(fd != -1)
 543                 {
 544                         while((s = fgets(fd)))
 545                         {
 546                                 l = tokenize_sane(s);
 547                                 if(l < 2)
 548                                         continue;
 549                                 if(argv(0) == "cd")
 550                                 {
 551                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 552                                         print("  cdtrack ", argv(2), "\n");
 553                                 }
 554                                 else if(argv(0) == "fog")
 555                                 {
 556                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 557                                         print("  \"fog\" \"", s, "\"\n");
 558                                 }
 559                                 else if(argv(0) == "set")
 560                                 {
 561                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 562                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 563                                 }
 564                                 else if(argv(0) != "//")
 565                                 {
 566                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 567                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 568                                 }
 569                         }
 570                         fclose(fd);
 571                 }
 572         }
 573
 574         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 575         addstat(STAT_WEAPONS, AS_INT, weapons);
 576         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 577         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 578         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 579         Nagger_Init();
 580
 581         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 582         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 583
 584         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 585
 586         next_pingtime = time + 5;
 587         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 588
 589         detect_maptype();
 590
 591         lsmaps_reply = "^7Maps available: ";
 592         for(i = 0, j = 0; i < MapInfo_count; ++i)
 593         {
 594                 if(MapInfo_Get_ByID(i))
 595                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 596                         {
 597                                 if(mod(i, 2))
 598                                         col = "^2";
 599                                 else
 600                                         col = "^3";
 601                                 ++j;
 602                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 603                         }
 604         }
 605         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 606
 607         maplist_reply = "^7Maps in list: ";
 608         n = tokenize_sane(cvar_string("g_maplist"));
 609         for(i = 0, j = 0; i < n; ++i)
 610         {
 611                 if(MapInfo_CheckMap(argv(i)))
 612                 {
 613                         if(mod(j, 2))
 614                                 col = "^2";
 615                         else
 616                                 col = "^3";
 617                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 618                         ++j;
 619                 }
 620         }
 621         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 622
 623         records_reply = strzone(getrecords());
 624
 625         ClientInit_Spawn();
 626         RandomSeed_Spawn();
 627
 628         world_initialized = 1;
 629 }
 630
 631 void spawnfunc_light (void)
 632 {
 633         //makestatic (self); // Who the f___ did that?
 634         remove(self);
 635 }
 636
 637 float TryFile( string pFilename )
 638 {
 639         local float lHandle;
 640         dprint("TryFile(\"", pFilename, "\")\n");
 641         lHandle = fopen( pFilename, FILE_READ );
 642         if( lHandle != -1 ) {
 643                 fclose( lHandle );
 644                 return TRUE;
 645         } else {
 646                 return FALSE;
 647         }
 648 };
 649
 650 string GetGametype()
 651 {
 652         return GametypeNameFromType(game);
 653 }
 654
 655 string getmapname_stored;
 656 string GetMapname()
 657 {
 658         return mapname;
 659 }
 660
 661 float Map_Count, Map_Current;
 662 string Map_Current_Name;
 663
 664 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 665 float GetMaplistPosition()
 666 {
 667         float pos, idx;
 668         string map;
 669
 670         map = GetMapname();
 671         idx = cvar("g_maplist_index");
 672
 673         if(idx >= 0)
 674                 if(idx < Map_Count)
 675                         if(map == argv(idx))
 676                                 return idx;
 677
 678         for(pos = 0; pos < Map_Count; ++pos)
 679                 if(map == argv(pos))
 680                         return pos;
 681
 682         // resume normal maplist rotation if current map is not in g_maplist
 683         return idx;
 684 }
 685
 686 float MapHasRightSize(string map)
 687 {
 688         float fh;
 689         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 690         if(cvar("g_maplist_check_waypoints"))
 691         {
 692                 dprint("checkwp "); dprint(map);
 693                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 694                 if(fh < 0)
 695                 {
 696                         dprint(": no waypoints\n");
 697                         return FALSE;
 698                 }
 699                 dprint(": has waypoints\n");
 700                 fclose(fh);
 701         }
 702
 703         // open map size restriction file
 704         dprint("opensize "); dprint(map);
 705         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 706         if(fh >= 0)
 707         {
 708                 float mapmin, mapmax;
 709                 dprint(": ok, ");
 710                 mapmin = stof(fgets(fh));
 711                 mapmax = stof(fgets(fh));
 712                 fclose(fh);
 713                 if(player_count < mapmin)
 714                 {
 715                         dprint("not enough\n");
 716                         return FALSE;
 717                 }
 718                 if(player_count > mapmax)
 719                 {
 720                         dprint("too many\n");
 721                         return FALSE;
 722                 }
 723                 dprint("right size\n");
 724                 return TRUE;
 725         }
 726         dprint(": not found\n");
 727         return TRUE;
 728 }
 729
 730 string Map_Filename(float position)
 731 {
 732         return strcat("maps/", argv(position), ".bsp");
 733 }
 734
 735 string strwords(string s, float w)
 736 {
 737         float endpos;
 738         for(endpos = 0; w && endpos >= 0; --w)
 739                 endpos = strstrofs(s, " ", endpos + 1);
 740         if(endpos < 0)
 741                 return s;
 742         else
 743                 return substring(s, 0, endpos);
 744 }
 745
 746 float strhasword(string s, string w)
 747 {
 748         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 749 }
 750
 751 void Map_MarkAsRecent(string m)
 752 {
 753         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 754 }
 755
 756 float Map_IsRecent(string m)
 757 {
 758         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 759 }
 760
 761 float Map_Check(float position, float pass)
 762 {
 763         string filename;
 764         string map_next;
 765         map_next = argv(position);
 766         if(pass <= 1)
 767         {
 768                 if(Map_IsRecent(map_next))
 769                         return 0;
 770         }
 771         filename = Map_Filename(position);
 772         if(MapInfo_CheckMap(map_next))
 773         {
 774                 if(pass == 2)
 775                         return 1;
 776                 if(MapHasRightSize(map_next))
 777                         return 1;
 778                 return 0;
 779         }
 780         else
 781                 dprint( "Couldn't select '", filename, "'..\n" );
 782
 783         return 0;
 784 }
 785
 786 void Map_Goto_SetStr(string nextmapname)
 787 {
 788         if(getmapname_stored != "")
 789                 strunzone(getmapname_stored);
 790         if(nextmapname == "")
 791                 getmapname_stored = "";
 792         else
 793                 getmapname_stored = strzone(nextmapname);
 794 }
 795
 796 void Map_Goto_SetFloat(float position)
 797 {
 798         cvar_set("g_maplist_index", ftos(position));
 799         Map_Goto_SetStr(argv(position));
 800 }
 801
 802 void GameResetCfg()
 803 {
 804         // settings persist, except...
 805         if(cvar("g_campaign"))
 806                 localcmd("\nexec mutator_reset.cfg\n");
 807         localcmd("\nsettemp_restore\n");
 808 };
 809
 810 void Map_Goto()
 811 {
 812         GameResetCfg();
 813         MapInfo_LoadMap(getmapname_stored);
 814 }
 815
 816 // return codes of map selectors:
 817 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 818 //   -2 = permanent failure
 819 float() MaplistMethod_Iterate = // usual method
 820 {
 821         float pass, i;
 822
 823         for(pass = 1; pass <= 2; ++pass)
 824         {
 825                 for(i = 1; i < Map_Count; ++i)
 826                 {
 827                         float mapindex;
 828                         mapindex = mod(i + Map_Current, Map_Count);
 829                         if(Map_Check(mapindex, pass))
 830                                 return mapindex;
 831                 }
 832         }
 833         return -1;
 834 }
 835
 836 float() MaplistMethod_Repeat = // fallback method
 837 {
 838         if(Map_Check(Map_Current, 2))
 839                 return Map_Current;
 840         return -2;
 841 }
 842
 843 float() MaplistMethod_Random = // random map selection
 844 {
 845         float i, imax;
 846
 847         imax = 42;
 848
 849         for(i = 0; i <= imax; ++i)
 850         {
 851                 float mapindex;
 852                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 853                 if(Map_Check(mapindex, 1))
 854                         return mapindex;
 855         }
 856         return -1;
 857 }
 858
 859 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 860 // the exponent sets a bias on the map selection:
 861 // the higher the exponent, the less likely "shortly repeated" same maps are
 862 {
 863         float i, j, imax, insertpos;
 864
 865         imax = 42;
 866
 867         for(i = 0; i <= imax; ++i)
 868         {
 869                 string newlist;
 870
 871                 // now reinsert this at another position
 872                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 873                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 874                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 875                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 876
 877                 // insert the current map there
 878                 newlist = "";
 879                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 880                         newlist = strcat(newlist, " ", argv(j));
 881                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 882                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 883                         newlist = strcat(newlist, " ", argv(j));
 884                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 885                 cvar_set("g_maplist", newlist);
 886                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 887
 888                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 889                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 890                 if(Map_Check(Map_Current, 1))
 891                         return Map_Current;
 892         }
 893         return -1;
 894 }
 895
 896 void Maplist_Init()
 897 {
 898         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 899         if(Map_Count == 0)
 900         {
 901                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 902                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 903                 if(cvar("g_maplist_shuffle"))
 904                         ShuffleMaplist();
 905                 localcmd("\nmenu_cmd sync\n");
 906                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 907         }
 908         if(Map_Count == 0)
 909                 error("empty maplist, cannot select a new map");
 910         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 911
 912         if(Map_Current_Name)
 913                 strunzone(Map_Current_Name);
 914         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 915         // this may or may not be correct, but who cares, in the worst case a map
 916         // isn't chosen in the first pass that should have been
 917 }
 918
 919 string GetNextMap()
 920 {
 921         float nextMap;
 922
 923         Maplist_Init();
 924         nextMap = -1;
 925
 926         if(nextMap == -1)
 927                 if(cvar("g_maplist_shuffle") > 0)
 928                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 929
 930         if(nextMap == -1)
 931                 if(cvar("g_maplist_selectrandom"))
 932                         nextMap = MaplistMethod_Random();
 933
 934         if(nextMap == -1)
 935                 nextMap = MaplistMethod_Iterate();
 936
 937         if(nextMap == -1)
 938                 nextMap = MaplistMethod_Repeat();
 939
 940         if(nextMap >= 0)
 941         {
 942                 Map_Goto_SetFloat(nextMap);
 943                 return getmapname_stored;
 944         }
 945
 946         return "";
 947 };
 948
 949 float DoNextMapOverride()
 950 {
 951         if(cvar("g_campaign"))
 952         {
 953                 CampaignPostIntermission();
 954                 alreadychangedlevel = TRUE;
 955                 return TRUE;
 956         }
 957         if(cvar("quit_when_empty"))
 958         {
 959                 if(player_count <= currentbots)
 960                 {
 961                         localcmd("quit\n");
 962                         alreadychangedlevel = TRUE;
 963                         return TRUE;
 964                 }
 965         }
 966         if(cvar_string("quit_and_redirect") != "")
 967         {
 968                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 969                 alreadychangedlevel = TRUE;
 970                 return TRUE;
 971         }
 972         if (cvar("samelevel")) // if samelevel is set, stay on same level
 973         {
 974                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 975                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 976                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 977                 localcmd("restart\n");
 978                 //changelevel (mapname);
 979                 alreadychangedlevel = TRUE;
 980                 return TRUE;
 981         }
 982         if(cvar_string("nextmap") != "")
 983                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 984                 {
 985                         Map_Goto_SetStr(cvar_string("nextmap"));
 986                         Map_Goto();
 987                         alreadychangedlevel = TRUE;
 988                         return TRUE;
 989                 }
 990         if(cvar("lastlevel"))
 991         {
 992                 GameResetCfg();
 993                 localcmd("set lastlevel 0\ntogglemenu\n");
 994                 alreadychangedlevel = TRUE;
 995                 return TRUE;
 996         }
 997         return FALSE;
 998 };
 999
1000 void GotoNextMap()
1001 {
1002         //local string nextmap;
1003         //local float n, nummaps;
1004         //local string s;
1005         if (alreadychangedlevel)
1006                 return;
1007         alreadychangedlevel = TRUE;
1008
1009         {
1010                 string nextMap;
1011                 float allowReset;
1012
1013                 for(allowReset = 1; allowReset >= 0; --allowReset)
1014                 {
1015                         nextMap = GetNextMap();
1016                         if(nextMap != "")
1017                                 break;
1018
1019                         if(allowReset)
1020                         {
1021                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1022                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1023                                 if(cvar("g_maplist_shuffle"))
1024                                         ShuffleMaplist();
1025                                 localcmd("\nmenu_cmd sync\n");
1026                         }
1027                         else
1028                         {
1029                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1030                         }
1031                 }
1032                 Map_Goto();
1033         }
1034 };
1035
1036
1037 /*
1038 ============
1039 IntermissionThink
1040
1041 When the player presses attack or jump, change to the next level
1042 ============
1043 */
1044 .float autoscreenshot;
1045 void() MapVote_Start;
1046 void() MapVote_Think;
1047 float mapvote_initialized;
1048 void IntermissionThink()
1049 {
1050         FixIntermissionClient(self);
1051
1052         if(cvar("sv_autoscreenshot"))
1053         if(self.autoscreenshot > 0)
1054         if(time > self.autoscreenshot)
1055         {
1056                 self.autoscreenshot = -1;
1057                 if(clienttype(self) == CLIENTTYPE_REAL)
1058                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1059                 return;
1060         }
1061
1062         if (time < intermission_exittime)
1063                 return;
1064
1065         if(!mapvote_initialized)
1066                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1067                         return;
1068
1069         MapVote_Start();
1070 };
1071
1072 /*
1073 ============
1074 FindIntermission
1075
1076 Returns the entity to view from
1077 ============
1078 */
1079 /*
1080 entity FindIntermission()
1081 {
1082         local   entity spot;
1083         local   float cyc;
1084
1085 // look for info_intermission first
1086         spot = find (world, classname, "info_intermission");
1087         if (spot)
1088         {       // pick a random one
1089                 cyc = random() * 4;
1090                 while (cyc > 1)
1091                 {
1092                         spot = find (spot, classname, "info_intermission");
1093                         if (!spot)
1094                                 spot = find (spot, classname, "info_intermission");
1095                         cyc = cyc - 1;
1096                 }
1097                 return spot;
1098         }
1099
1100 // then look for the start position
1101         spot = find (world, classname, "info_player_start");
1102         if (spot)
1103                 return spot;
1104
1105 // testinfo_player_start is only found in regioned levels
1106         spot = find (world, classname, "testplayerstart");
1107         if (spot)
1108                 return spot;
1109
1110 // then look for the start position
1111         spot = find (world, classname, "info_player_deathmatch");
1112         if (spot)
1113                 return spot;
1114
1115         //objerror ("FindIntermission: no spot");
1116         return world;
1117 };
1118 */
1119
1120 /*
1121 ===============================================================================
1122
1123 RULES
1124
1125 ===============================================================================
1126 */
1127
1128 void DumpStats(float final)
1129 {
1130         local float file;
1131         local string s;
1132         local float to_console;
1133         local float to_eventlog;
1134         local float to_file;
1135         local float i;
1136
1137         to_console = cvar("sv_logscores_console");
1138         to_eventlog = cvar("sv_eventlog");
1139         to_file = cvar("sv_logscores_file");
1140
1141         if(!final)
1142         {
1143                 to_console = TRUE; // always print printstats replies
1144                 to_eventlog = FALSE; // but never print them to the event log
1145         }
1146
1147         if(to_eventlog)
1148                 if(cvar("sv_eventlog_console"))
1149                         to_console = FALSE; // otherwise we get the output twice
1150
1151         if(final)
1152                 s = ":scores:";
1153         else
1154                 s = ":status:";
1155         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1156
1157         if(to_console)
1158                 print(s, "\n");
1159         if(to_eventlog)
1160                 GameLogEcho(s);
1161         if(to_file)
1162         {
1163                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1164                 if(file == -1)
1165                         to_file = FALSE;
1166                 else
1167                         fputs(file, strcat(s, "\n"));
1168         }
1169
1170         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1171         if(to_console)
1172                 print(s, "\n");
1173         if(to_eventlog)
1174                 GameLogEcho(s);
1175         if(to_file)
1176                 fputs(file, strcat(s, "\n"));
1177
1178         FOR_EACH_CLIENT(other)
1179         {
1180                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1181                 {
1182                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1183                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1184                         if(other.classname == "player" || g_arena || g_lms)
1185                                 s = strcat(s, ftos(other.team), ":");
1186                         else
1187                                 s = strcat(s, "spectator:");
1188
1189                         if(to_console)
1190                                 print(s, other.netname, "\n");
1191                         if(to_eventlog)
1192                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1193                         if(to_file)
1194                                 fputs(file, strcat(s, other.netname, "\n"));
1195                 }
1196         }
1197
1198         if(teams_matter)
1199         {
1200                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1201                 if(to_console)
1202                         print(s, "\n");
1203                 if(to_eventlog)
1204                         GameLogEcho(s);
1205                 if(to_file)
1206                         fputs(file, strcat(s, "\n"));
1207
1208                 for(i = 1; i < 16; ++i)
1209                 {
1210                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1211                         s = strcat(s, ":", ftos(i));
1212                         if(to_console)
1213                                 print(s, "\n");
1214                         if(to_eventlog)
1215                                 GameLogEcho(s);
1216                         if(to_file)
1217                                 fputs(file, strcat(s, "\n"));
1218                 }
1219         }
1220
1221         if(to_console)
1222                 print(":end\n");
1223         if(to_eventlog)
1224                 GameLogEcho(":end");
1225         if(to_file)
1226         {
1227                 fputs(file, ":end\n");
1228                 fclose(file);
1229         }
1230 }
1231
1232 void FixIntermissionClient(entity e)
1233 {
1234         string s;
1235         if(!e.autoscreenshot) // initial call
1236         {
1237                 e.angles = e.v_angle;
1238                 e.angles_x = -e.angles_x;
1239                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1240                 e.health = -2342;
1241                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1242                 e.solid = SOLID_NOT;
1243                 e.movetype = MOVETYPE_NONE;
1244                 e.takedamage = DAMAGE_NO;
1245                 if(e.weaponentity)
1246                 {
1247                         e.weaponentity.effects = EF_NODRAW;
1248                         if (e.weaponentity.weaponentity)
1249                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1250                 }
1251                 if(clienttype(e) == CLIENTTYPE_REAL)
1252                 {
1253                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1254                         s = cvar_string("sv_intermission_cdtrack");
1255                         if(s != "")
1256                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1257                         msg_entity = e;
1258                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1259                 }
1260         }
1261
1262         //e.velocity = '0 0 0';
1263         //e.fixangle = TRUE;
1264
1265         // TODO halt weapon animation
1266 }
1267
1268
1269 /*
1270 go to the next level for deathmatch
1271 only called if a time or frag limit has expired
1272 */
1273 void NextLevel()
1274 {
1275         float minTotalFrags;
1276         float maxTotalFrags;
1277         float score;
1278         float f;
1279
1280         gameover = TRUE;
1281
1282         intermission_running = 1;
1283
1284 // enforce a wait time before allowing changelevel
1285         if(player_count > 0)
1286                 intermission_exittime = time + cvar("sv_mapchange_delay");
1287         else
1288                 intermission_exittime = -1;
1289
1290         /*
1291         WriteByte (MSG_ALL, SVC_CDTRACK);
1292         WriteByte (MSG_ALL, 3);
1293         WriteByte (MSG_ALL, 3);
1294         // done in FixIntermission
1295         */
1296
1297         //pos = FindIntermission ();
1298
1299         VoteReset();
1300
1301         DumpStats(TRUE);
1302
1303         if(cvar("sv_eventlog"))
1304                 GameLogEcho(":gameover");
1305
1306         GameLogClose();
1307
1308         FOR_EACH_CLIENT(other)
1309         {
1310                 FixIntermissionClient(other);
1311
1312                 if(other.winning)
1313                         bprint(other.netname, " ^7wins.\n");
1314         }
1315
1316         minTotalFrags = 0;
1317         maxTotalFrags = 0;
1318         FOR_EACH_PLAYER(other)
1319         {
1320                 if(maxTotalFrags < other.totalfrags)
1321                         maxTotalFrags = other.totalfrags;
1322                 if(minTotalFrags > other.totalfrags)
1323                         minTotalFrags = other.totalfrags;
1324         }
1325
1326         if(!currentbots)
1327         {
1328                 FOR_EACH_PLAYER(other)
1329                 {
1330                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1331                         f = bound(0, other.play_time / max(time, 1), 1);
1332                         // store some statistics?
1333                 }
1334         }
1335
1336         if(cvar("g_campaign"))
1337                 CampaignPreIntermission();
1338
1339         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1340 };
1341
1342 /*
1343 ============
1344 CheckRules_Player
1345
1346 Exit deathmatch games upon conditions
1347 ============
1348 */
1349 void CheckRules_Player()
1350 {
1351         if (gameover)   // someone else quit the game already
1352                 return;
1353
1354         if(self.deadflag == DEAD_NO)
1355                 self.play_time += frametime;
1356
1357         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1358         //   (div0: and that in CheckRules_World please)
1359 };
1360
1361 float checkrules_oneminutewarning;
1362
1363 float checkrules_equality;
1364 float checkrules_suddendeathwarning;
1365 float checkrules_suddendeathend;
1366 float checkrules_overtimesadded; //how many overtimes have been already added
1367 float checkrules_status;
1368
1369 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1370 float WINNING_YES = 1; // winner found
1371 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1372 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1373
1374 void InitiateOvertime()
1375 {
1376         // Check first whether normal overtimes could be added before initiating suddendeath mode
1377         // - for this timelimit_overtime needs to be >0 of course
1378         // - also check the winning condition calculated in the previous frame and only add normal overtime
1379         //   again, if at the point at which timelimit would be extended again, still no winner was found
1380         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1381         {
1382                 ++checkrules_overtimesadded;
1383                 //add one more overtime by simply extending the timelimit
1384                 float tl;
1385                 tl = cvar("timelimit");
1386                 tl += cvar("timelimit_overtime");
1387                 cvar_set("timelimit", ftos(tl));
1388                 string minutesPlural;
1389                 if (cvar("timelimit_overtime") == 1)
1390                         minutesPlural = " ^3minute";
1391                 else
1392                         minutesPlural = " ^3minutes";
1393
1394                 bcenterprint(
1395                         strcat(
1396                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1397                                 ftos(cvar("timelimit_overtime")),
1398                                 minutesPlural,
1399                                 " to the game!"
1400                         )
1401                 );
1402         }
1403         else
1404         {
1405                 if(!checkrules_suddendeathend)
1406                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1407         }
1408 }
1409
1410 float GetWinningCode(float fraglimitreached, float equality)
1411 {
1412         if(equality)
1413                 if(fraglimitreached)
1414                         return WINNING_STARTSUDDENDEATHOVERTIME;
1415                 else
1416                         return WINNING_NEVER;
1417         else
1418                 if(fraglimitreached)
1419                         return WINNING_YES;
1420                 else
1421                         return WINNING_NO;
1422 }
1423
1424 // set the .winning flag for exactly those players with a given field value
1425 void SetWinners(.float field, float value)
1426 {
1427         entity head;
1428         FOR_EACH_PLAYER(head)
1429                 head.winning = (head.field == value);
1430 }
1431
1432 // set the .winning flag for those players with a given field value
1433 void AddWinners(.float field, float value)
1434 {
1435         entity head;
1436         FOR_EACH_PLAYER(head)
1437                 if(head.field == value)
1438                         head.winning = 1;
1439 }
1440
1441 // clear the .winning flags
1442 void ClearWinners(void)
1443 {
1444         entity head;
1445         FOR_EACH_PLAYER(head)
1446                 head.winning = 0;
1447 }
1448
1449 // Onslaught winning condition:
1450 // game terminates if only one team has a working generator (or none)
1451 float WinningCondition_Onslaught()
1452 {
1453         entity head;
1454         local float t1, t2, t3, t4;
1455
1456         WinningConditionHelper(); // set worldstatus
1457
1458         // first check if the game has ended
1459         t1 = t2 = t3 = t4 = 0;
1460         head = find(world, classname, "onslaught_generator");
1461         while (head)
1462         {
1463                 if (head.health > 0)
1464                 {
1465                         if (head.team == COLOR_TEAM1) t1 = 1;
1466                         if (head.team == COLOR_TEAM2) t2 = 1;
1467                         if (head.team == COLOR_TEAM3) t3 = 1;
1468                         if (head.team == COLOR_TEAM4) t4 = 1;
1469                 }
1470                 head = find(head, classname, "onslaught_generator");
1471         }
1472         if (t1 + t2 + t3 + t4 < 2)
1473         {
1474                 // game over, only one team remains (or none)
1475                 ClearWinners();
1476                 if (t1) SetWinners(team, COLOR_TEAM1);
1477                 if (t2) SetWinners(team, COLOR_TEAM2);
1478                 if (t3) SetWinners(team, COLOR_TEAM3);
1479                 if (t4) SetWinners(team, COLOR_TEAM4);
1480                 dprint("Have a winner, ending game.\n");
1481                 return WINNING_YES;
1482         }
1483
1484         // Two or more teams remain
1485         return WINNING_NO;
1486 }
1487
1488 float LMS_NewPlayerLives()
1489 {
1490         float fl;
1491         fl = cvar("fraglimit");
1492         if(fl == 0)
1493                 fl = 999;
1494
1495         // first player has left the game for dying too much? Nobody else can get in.
1496         if(lms_lowest_lives < 1)
1497                 return 0;
1498
1499         if(!cvar("g_lms_join_anytime"))
1500                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1501                         return 0;
1502
1503         return bound(1, lms_lowest_lives, fl);
1504 }
1505
1506 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1507 // they win. Otherwise the defending team wins once the timelimit passes.
1508 void assault_new_round();
1509 float WinningCondition_Assault()
1510 {
1511         local float status;
1512
1513         WinningConditionHelper(); // set worldstatus
1514
1515         status = WINNING_NO;
1516         // as the timelimit has not yet passed just assume the defending team will win
1517         if(assault_attacker_team == COLOR_TEAM1)
1518         {
1519                 SetWinners(team, COLOR_TEAM2);
1520         }
1521         else
1522         {
1523                 SetWinners(team, COLOR_TEAM1);
1524         }
1525
1526         local entity ent;
1527         ent = find(world, classname, "target_assault_roundend");
1528         if(ent)
1529         {
1530                 if(ent.winning) // round end has been triggered by attacking team
1531                 {
1532                         bprint("ASSAULT: round completed...\n");
1533                         SetWinners(team, assault_attacker_team);
1534
1535                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1536
1537                         if(ent.cnt == 1) // this was the second round
1538                         {
1539                                 status = WINNING_YES;
1540                         }
1541                         else
1542                         {
1543                                 local entity oldself;
1544                                 oldself = self;
1545                                 self = ent;
1546                                 assault_new_round();
1547                                 self = oldself;
1548                         }
1549                 }
1550         }
1551
1552         return status;
1553 }
1554
1555 // LMS winning condition: game terminates if and only if there's at most one
1556 // one player who's living lives. Top two scores being equal cancels the time
1557 // limit.
1558 float WinningCondition_LMS()
1559 {
1560         entity head, head2;
1561         float have_player;
1562         float have_players;
1563         float l;
1564
1565         have_player = FALSE;
1566         have_players = FALSE;
1567         l = LMS_NewPlayerLives();
1568
1569         head = find(world, classname, "player");
1570         if(head)
1571                 have_player = TRUE;
1572         head2 = find(head, classname, "player");
1573         if(head2)
1574                 have_players = TRUE;
1575
1576         if(have_player)
1577         {
1578                 // we have at least one player
1579                 if(have_players)
1580                 {
1581                         // two or more active players - continue with the game
1582                 }
1583                 else
1584                 {
1585                         // exactly one player?
1586
1587                         ClearWinners();
1588                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1589
1590                         if(l)
1591                         {
1592                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1593                                 return WINNING_NO;
1594                         }
1595                         else
1596                         {
1597                                 // a winner!
1598                                 // and assign him his first place
1599                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1600                                 return WINNING_YES;
1601                         }
1602                 }
1603         }
1604         else
1605         {
1606                 // nobody is playing at all...
1607                 if(l)
1608                 {
1609                         // wait for players...
1610                 }
1611                 else
1612                 {
1613                         // SNAFU (maybe a draw game?)
1614                         ClearWinners();
1615                         dprint("No players, ending game.\n");
1616                         return WINNING_YES;
1617                 }
1618         }
1619
1620         // When we get here, we have at least two players who are actually LIVING,
1621         // now check if the top two players have equal score.
1622         WinningConditionHelper();
1623
1624         ClearWinners();
1625         if(WinningConditionHelper_winner)
1626                 WinningConditionHelper_winner.winning = TRUE;
1627         if(WinningConditionHelper_equality)
1628                 return WINNING_NEVER;
1629
1630         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1631         return WINNING_NO;
1632 }
1633
1634 void ShuffleMaplist()
1635 {
1636         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1637 }
1638
1639 float leaderfrags;
1640 float WinningCondition_Scores(float limit)
1641 {
1642         // TODO make everything use THIS winning condition (except LMS)
1643         WinningConditionHelper();
1644
1645         if(teams_matter)
1646         {
1647                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1648                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1649                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1650                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1651         }
1652
1653         ClearWinners();
1654         if(WinningConditionHelper_winner)
1655                 WinningConditionHelper_winner.winning = 1;
1656         if(WinningConditionHelper_winnerteam >= 0)
1657                 SetWinners(team, WinningConditionHelper_winnerteam);
1658
1659         if(WinningConditionHelper_lowerisbetter)
1660         {
1661                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1662                 limit = -limit;
1663         }
1664
1665         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1666         // these modes always score in increments of 1, thus this makes sense
1667         {
1668                 if(leaderfrags != WinningConditionHelper_topscore)
1669                 {
1670                         leaderfrags = WinningConditionHelper_topscore;
1671
1672                         if (limit)
1673                         if (leaderfrags == limit - 1)
1674                                 play2all("announcer/robotic/1fragleft.wav");
1675                         else if (leaderfrags == limit - 2)
1676                                 play2all("announcer/robotic/2fragsleft.wav");
1677                         else if (leaderfrags == limit - 3)
1678                                 play2all("announcer/robotic/3fragsleft.wav");
1679                 }
1680         }
1681
1682         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1683 }
1684
1685 float WinningCondition_Race(float fraglimit)
1686 {
1687         float wc;
1688         entity p;
1689         wc = WinningCondition_Scores(fraglimit);
1690
1691         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1692         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1693         // do NOT support equality when the laps are all raced!
1694         {
1695                 FOR_EACH_PLAYER(p)
1696                         if not(p.race_completed)
1697                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1698                 return WINNING_YES;
1699         }
1700         return wc;
1701 }
1702
1703 void ReadyRestart();
1704 float WinningCondition_QualifyingThenRace(float limit)
1705 {
1706         float wc;
1707         wc = WinningCondition_Scores(limit);
1708
1709         // NEVER initiate overtime
1710         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1711         {
1712                 return WINNING_YES;
1713         }
1714
1715         return wc;
1716 }
1717
1718 float WinningCondition_RanOutOfSpawns()
1719 {
1720         entity head;
1721
1722         if(!have_team_spawns)
1723                 return WINNING_NO;
1724
1725         if(!some_spawn_has_been_used)
1726                 return WINNING_NO;
1727
1728         team1_score = team2_score = team3_score = team4_score = 0;
1729
1730         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1731         {
1732                 if(head.team == COLOR_TEAM1)
1733                         team1_score = 1;
1734                 else if(head.team == COLOR_TEAM2)
1735                         team2_score = 1;
1736                 else if(head.team == COLOR_TEAM3)
1737                         team3_score = 1;
1738                 else if(head.team == COLOR_TEAM4)
1739                         team4_score = 1;
1740         }
1741
1742         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1743         {
1744                 if(head.team == COLOR_TEAM1)
1745                         team1_score = 1;
1746                 else if(head.team == COLOR_TEAM2)
1747                         team2_score = 1;
1748                 else if(head.team == COLOR_TEAM3)
1749                         team3_score = 1;
1750                 else if(head.team == COLOR_TEAM4)
1751                         team4_score = 1;
1752         }
1753
1754         ClearWinners();
1755         if(team1_score + team2_score + team3_score + team4_score == 0)
1756         {
1757                 checkrules_equality = TRUE;
1758                 return WINNING_YES;
1759         }
1760         else if(team1_score + team2_score + team3_score + team4_score == 1)
1761         {
1762                 float t, i;
1763                 if(team1_score) t = COLOR_TEAM1;
1764                 if(team2_score) t = COLOR_TEAM2;
1765                 if(team3_score) t = COLOR_TEAM3;
1766                 if(team4_score) t = COLOR_TEAM4;
1767                 CheckAllowedTeams(world);
1768                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1769                 {
1770                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1771                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1772                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1773                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1774                 }
1775
1776                 AddWinners(team, t);
1777                 return WINNING_YES;
1778         }
1779         else
1780                 return WINNING_NO;
1781 }
1782
1783 /*
1784 ============
1785 CheckRules_World
1786
1787 Exit deathmatch games upon conditions
1788 ============
1789 */
1790 void CheckRules_World()
1791 {
1792         local float timelimit;
1793         local float fraglimit;
1794
1795         VoteThink();
1796         MapVote_Think();
1797
1798         SetDefaultAlpha();
1799
1800         /*
1801         MapVote_Think should now do that part
1802         if (intermission_running)
1803                 if (time >= intermission_exittime + 60)
1804                 {
1805                         if(!DoNextMapOverride())
1806                                 GotoNextMap();
1807                         return;
1808                 }
1809         */
1810
1811         if (gameover)   // someone else quit the game already
1812         {
1813                 if(player_count == 0) // Nobody there? Then let's go to the next map
1814                         MapVote_Start();
1815                         // this will actually check the player count in the next frame
1816                         // again, but this shouldn't hurt
1817                 return;
1818         }
1819
1820         timelimit = cvar("timelimit") * 60;
1821         fraglimit = cvar("fraglimit");
1822
1823         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1824         {
1825                 if(timelimit > 0)
1826                         timelimit = 0; // timelimit is not made for warmup
1827                 if(fraglimit > 0)
1828                         fraglimit = 0; // no fraglimit for now
1829         }
1830
1831         if(timelimit > 0)
1832         {
1833                 timelimit += game_starttime;
1834         }
1835         else if (timelimit < 0)
1836         {
1837                 // endmatch
1838                 NextLevel();
1839                 return;
1840         }
1841
1842         if(checkrules_suddendeathend)
1843         {
1844                 if(!checkrules_suddendeathwarning)
1845                 {
1846                         checkrules_suddendeathwarning = TRUE;
1847                         if(g_race && !g_race_qualifying)
1848                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1849                         else
1850                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1851                 }
1852         }
1853         else
1854         {
1855                 if (timelimit && time >= timelimit)
1856                 {
1857                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1858                         {
1859                                 float totalplayers;
1860                                 float playerswithlaps;
1861                                 float readyplayers;
1862                                 entity head;
1863                                 totalplayers = playerswithlaps = readyplayers = 0;
1864                                 FOR_EACH_PLAYER(head)
1865                                 {
1866                                         ++totalplayers;
1867                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1868                                                 ++playerswithlaps;
1869                                         if(head.ready)
1870                                                 ++readyplayers;
1871                                 }
1872
1873                                 // at least 2/3 of the players have completed a lap: start the RACE
1874                                 // otherwise, the players should end the qualifying on their own
1875                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1876                                 {
1877                                         checkrules_suddendeathend = 0;
1878                                         ReadyRestart(); // go to race
1879                                 }
1880                                 else
1881                                         InitiateOvertime();
1882                         }
1883                         else
1884                                 InitiateOvertime();
1885                 }
1886         }
1887
1888         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1889         {
1890                 NextLevel();
1891                 return;
1892         }
1893
1894         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1895         {
1896                 checkrules_oneminutewarning = TRUE;
1897                 play2all("announcer/robotic/1minuteremains.wav");
1898         }
1899
1900         checkrules_status = WinningCondition_RanOutOfSpawns();
1901         if(checkrules_status == WINNING_YES)
1902         {
1903                 bprint("Hey! Someone ran out of spawns!\n");
1904         }
1905         else if(g_race && !g_race_qualifying && timelimit >= 0)
1906         {
1907                 checkrules_status = WinningCondition_Race(fraglimit);
1908         }
1909         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1910         {
1911                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1912         }
1913         else if(g_assault)
1914         {
1915                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1916         }
1917         else if(g_lms)
1918         {
1919                 checkrules_status = WinningCondition_LMS();
1920         }
1921         else if (g_onslaught)
1922         {
1923                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1924         }
1925         else
1926         {
1927                 checkrules_status = WinningCondition_Scores(fraglimit);
1928         }
1929
1930         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1931         {
1932                 checkrules_status = WINNING_NEVER;
1933                 InitiateOvertime();
1934         }
1935
1936         if(checkrules_status == WINNING_NEVER)
1937                 // equality cases! Nobody wins if the overtime ends in a draw.
1938                 ClearWinners();
1939
1940         if(checkrules_suddendeathend)
1941                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1942                         checkrules_status = WINNING_YES;
1943
1944         if(checkrules_status == WINNING_YES)
1945                 NextLevel();
1946 };
1947
1948 float mapvote_nextthink;
1949 float mapvote_initialized;
1950 float mapvote_keeptwotime;
1951 float mapvote_timeout;
1952 string mapvote_message;
1953 string mapvote_screenshot_dir;
1954
1955 float mapvote_count;
1956 float mapvote_count_real;
1957 string mapvote_maps[MAPVOTE_COUNT];
1958 float mapvote_maps_suggested[MAPVOTE_COUNT];
1959 string mapvote_suggestions[MAPVOTE_COUNT];
1960 float mapvote_suggestion_ptr;
1961 float mapvote_maxlen;
1962 float mapvote_voters;
1963 float mapvote_votes[MAPVOTE_COUNT];
1964 float mapvote_run;
1965 float mapvote_detail;
1966 float mapvote_abstain;
1967 .float mapvote;
1968
1969 void MapVote_ClearAllVotes()
1970 {
1971         FOR_EACH_CLIENT(other)
1972                 other.mapvote = 0;
1973 }
1974
1975 string MapVote_Suggest(string m)
1976 {
1977         float i;
1978         if(m == "")
1979                 return "That's not how to use this command.";
1980         if(!cvar("g_maplist_votable_suggestions"))
1981                 return "Suggestions are not accepted on this server.";
1982         if(mapvote_initialized)
1983                 return "Can't suggest - voting is already in progress!";
1984         m = MapInfo_FixName(m);
1985         if(!m)
1986                 return "The map you suggested is not available on this server.";
1987         if(!cvar("g_maplist_votable_override_mostrecent"))
1988                 if(Map_IsRecent(m))
1989                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1990
1991         if(!MapInfo_CheckMap(m))
1992                 return "The map you suggested does not support the current game mode.";
1993         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1994                 if(mapvote_suggestions[i] == m)
1995                         return "This map was already suggested.";
1996         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1997         {
1998                 i = floor(random() * mapvote_suggestion_ptr);
1999         }
2000         else
2001         {
2002                 i = mapvote_suggestion_ptr;
2003                 mapvote_suggestion_ptr += 1;
2004         }
2005         if(mapvote_suggestions[i] != "")
2006                 strunzone(mapvote_suggestions[i]);
2007         mapvote_suggestions[i] = strzone(m);
2008         if(cvar("sv_eventlog"))
2009                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2010         return strcat("Suggestion of ", m, " accepted.");
2011 }
2012
2013 void MapVote_AddVotable(string nextMap, float isSuggestion)
2014 {
2015         float j;
2016         if(nextMap == "")
2017                 return;
2018         for(j = 0; j < mapvote_count; ++j)
2019                 if(mapvote_maps[j] == nextMap)
2020                         return;
2021         if(strlen(nextMap) > mapvote_maxlen)
2022                 mapvote_maxlen = strlen(nextMap);
2023         mapvote_maps[mapvote_count] = strzone(nextMap);
2024         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2025         mapvote_count += 1;
2026 }
2027
2028 void MapVote_Spawn();
2029 void MapVote_Init()
2030 {
2031         float i;
2032         float nmax, smax;
2033
2034         MapVote_ClearAllVotes();
2035
2036         mapvote_count = 0;
2037         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2038         mapvote_abstain = cvar("g_maplist_votable_abstain");
2039
2040         if(mapvote_abstain)
2041                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2042         else
2043                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2044         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2045
2046         if(mapvote_suggestion_ptr)
2047                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2048                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2049
2050         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2051                 MapVote_AddVotable(GetNextMap(), FALSE);
2052
2053         if(mapvote_count == 0)
2054         {
2055                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2056                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2057                 if(cvar("g_maplist_shuffle"))
2058                         ShuffleMaplist();
2059                 localcmd("\nmenu_cmd sync\n");
2060                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2061                         MapVote_AddVotable(GetNextMap(), FALSE);
2062         }
2063
2064         mapvote_count_real = mapvote_count;
2065         if(mapvote_abstain)
2066                 MapVote_AddVotable("don't care", 0);
2067
2068         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2069
2070         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2071         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2072         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2073                 mapvote_keeptwotime = 0;
2074         mapvote_message = "Choose a map and press its key!";
2075
2076         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2077         if(mapvote_screenshot_dir == "")
2078                 mapvote_screenshot_dir = "maps";
2079         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2080
2081         MapVote_Spawn();
2082 }
2083
2084 void MapVote_SendPicture(float id)
2085 {
2086         msg_entity = self;
2087         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2088         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2089         WriteByte(MSG_ONE, id);
2090         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2091 }
2092
2093 float GameCommand_MapVote(string cmd)
2094 {
2095         if(!intermission_running)
2096                 return FALSE;
2097
2098         if(cmd == "mv_getpic")
2099         {
2100                 MapVote_SendPicture(stof(argv(1)));
2101                 return TRUE;
2102         }
2103
2104         return FALSE;
2105 }
2106
2107 float MapVote_GetMapMask()
2108 {
2109         float mask, i, power;
2110         mask = 0;
2111         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2112                 if(mapvote_maps[i] != "")
2113                         mask |= power;
2114         return mask;
2115 }
2116
2117 entity mapvote_ent;
2118 float MapVote_SendEntity(entity to, float sf)
2119 {
2120         string mapfile, pakfile;
2121         float i, o;
2122
2123         if(sf & 1)
2124                 sf &~= 2; // if we send 1, we don't need to also send 2
2125
2126         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2127         WriteByte(MSG_ENTITY, sf);
2128
2129         if(sf & 1)
2130         {
2131                 // flag 1 == initialization
2132                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2133                 WriteByte(MSG_ENTITY, mapvote_count);
2134                 WriteByte(MSG_ENTITY, mapvote_abstain);
2135                 WriteByte(MSG_ENTITY, mapvote_detail);
2136                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2137                 if(mapvote_count <= 8)
2138                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2139                 else
2140                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2141                 for(i = 0; i < mapvote_count; ++i)
2142                         if(mapvote_maps[i] != "")
2143                         {
2144                                 if(mapvote_abstain && i == mapvote_count - 1)
2145                                 {
2146                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2147                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2148                                 }
2149                                 else
2150                                 {
2151                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2152                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2153                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2154                                         if(pakfile == "")
2155                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2156                                         if(pakfile == "")
2157                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2158                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2159                                                 pakfile = substring(pakfile, o, 999);
2160                                         WriteString(MSG_ENTITY, pakfile);
2161                                 }
2162                         }
2163         }
2164
2165         if(sf & 2)
2166         {
2167                 // flag 2 == update of mask
2168                 if(mapvote_count <= 8)
2169                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2170                 else
2171                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2172         }
2173
2174         if(sf & 4)
2175         {
2176                 if(mapvote_detail)
2177                         for(i = 0; i < mapvote_count; ++i)
2178                                 if(mapvote_maps[i] != "")
2179                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2180
2181                 WriteByte(MSG_ENTITY, to.mapvote);
2182         }
2183
2184         return TRUE;
2185 }
2186
2187 void MapVote_Spawn()
2188 {
2189         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2190 }
2191
2192 void MapVote_TouchMask()
2193 {
2194         mapvote_ent.SendFlags |= 2;
2195 }
2196
2197 void MapVote_TouchVotes(entity voter)
2198 {
2199         mapvote_ent.SendFlags |= 4;
2200 }
2201
2202 float MapVote_Finished(float mappos)
2203 {
2204         string result;
2205         float i;
2206         float didntvote;
2207
2208         if(cvar("sv_eventlog"))
2209         {
2210                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2211                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2212                 didntvote = mapvote_voters;
2213                 for(i = 0; i < mapvote_count; ++i)
2214                         if(mapvote_maps[i] != "")
2215                         {
2216                                 didntvote -= mapvote_votes[i];
2217                                 if(i != mappos)
2218                                 {
2219                                         result = strcat(result, ":", mapvote_maps[i]);
2220                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2221                                 }
2222                         }
2223                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2224
2225                 GameLogEcho(result);
2226                 if(mapvote_maps_suggested[mappos])
2227                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2228         }
2229
2230         FOR_EACH_REALCLIENT(other)
2231                 FixClientCvars(other);
2232
2233         Map_Goto_SetStr(mapvote_maps[mappos]);
2234         Map_Goto();
2235         alreadychangedlevel = TRUE;
2236         return TRUE;
2237 }
2238 void MapVote_CheckRules_1()
2239 {
2240         float i;
2241
2242         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2243         {
2244                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2245                 mapvote_votes[i] = 0;
2246         }
2247
2248         mapvote_voters = 0;
2249         FOR_EACH_REALCLIENT(other)
2250         {
2251                 ++mapvote_voters;
2252                 if(other.mapvote)
2253                 {
2254                         i = other.mapvote - 1;
2255                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2256                         mapvote_votes[i] = mapvote_votes[i] + 1;
2257                 }
2258         }
2259 }
2260
2261 float MapVote_CheckRules_2()
2262 {
2263         float i;
2264         float firstPlace, secondPlace;
2265         float firstPlaceVotes, secondPlaceVotes;
2266         float mapvote_voters_real;
2267         string result;
2268
2269         if(mapvote_count_real == 1)
2270                 return MapVote_Finished(0);
2271
2272         mapvote_voters_real = mapvote_voters;
2273         if(mapvote_abstain)
2274                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2275
2276         RandomSelection_Init();
2277         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2278                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2279         firstPlace = RandomSelection_chosen_float;
2280         firstPlaceVotes = RandomSelection_best_priority;
2281         //dprint("First place: ", ftos(firstPlace), "\n");
2282         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2283
2284         RandomSelection_Init();
2285         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2286                 if(i != firstPlace)
2287                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2288         secondPlace = RandomSelection_chosen_float;
2289         secondPlaceVotes = RandomSelection_best_priority;
2290         //dprint("Second place: ", ftos(secondPlace), "\n");
2291         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2292
2293         if(firstPlace == -1)
2294                 error("No first place in map vote... WTF?");
2295
2296         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2297                 return MapVote_Finished(firstPlace);
2298
2299         if(mapvote_keeptwotime)
2300                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2301                 {
2302                         float didntvote;
2303                         MapVote_TouchMask();
2304                         mapvote_message = "Now decide between the TOP TWO!";
2305                         mapvote_keeptwotime = 0;
2306                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2307                         result = strcat(result, ":", ftos(firstPlaceVotes));
2308                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2309                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2310                         didntvote = mapvote_voters;
2311                         for(i = 0; i < mapvote_count; ++i)
2312                                 if(mapvote_maps[i] != "")
2313                                 {
2314                                         didntvote -= mapvote_votes[i];
2315                                         if(i != firstPlace)
2316                                                 if(i != secondPlace)
2317                                                 {
2318                                                         result = strcat(result, ":", mapvote_maps[i]);
2319                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2320                                                         if(i < mapvote_count_real)
2321                                                         {
2322                                                                 strunzone(mapvote_maps[i]);
2323                                                                 mapvote_maps[i] = "";
2324                                                         }
2325                                                 }
2326                                 }
2327                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2328                         if(cvar("sv_eventlog"))
2329                                 GameLogEcho(result);
2330                 }
2331
2332         return FALSE;
2333 }
2334 void MapVote_Tick()
2335 {
2336         float keeptwo;
2337         float totalvotes;
2338
2339         keeptwo = mapvote_keeptwotime;
2340         MapVote_CheckRules_1(); // count
2341         if(MapVote_CheckRules_2()) // decide
2342                 return;
2343
2344         totalvotes = 0;
2345         FOR_EACH_REALCLIENT(other)
2346         {
2347                 // hide scoreboard again
2348                 if(other.health != 2342)
2349                 {
2350                         other.health = 2342;
2351                         other.impulse = 0;
2352                         if(clienttype(other) == CLIENTTYPE_REAL)
2353                         {
2354                                 msg_entity = other;
2355                                 WriteByte(MSG_ONE, SVC_FINALE);
2356                                 WriteString(MSG_ONE, "");
2357                         }
2358                 }
2359
2360                 // clear possibly invalid votes
2361                 if(mapvote_maps[other.mapvote - 1] == "")
2362                         other.mapvote = 0;
2363                 // use impulses as new vote
2364                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2365                         if(mapvote_maps[other.impulse - 1] != "")
2366                         {
2367                                 other.mapvote = other.impulse;
2368                                 MapVote_TouchVotes(other);
2369                         }
2370                 other.impulse = 0;
2371
2372                 if(other.mapvote)
2373                         ++totalvotes;
2374         }
2375
2376         MapVote_CheckRules_1(); // just count
2377 }
2378 void MapVote_Start()
2379 {
2380         if(mapvote_run)
2381                 return;
2382
2383         MapInfo_Enumerate();
2384         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2385                 mapvote_run = TRUE;
2386 }
2387 void MapVote_Think()
2388 {
2389         if(!mapvote_run)
2390                 return;
2391
2392         if(alreadychangedlevel)
2393                 return;
2394
2395         if(time < mapvote_nextthink)
2396                 return;
2397         //dprint("tick\n");
2398
2399         mapvote_nextthink = time + 0.5;
2400
2401         if(!mapvote_initialized)
2402         {
2403                 mapvote_initialized = TRUE;
2404                 if(DoNextMapOverride())
2405                         return;
2406                 if(!cvar("g_maplist_votable") || player_count <= 0)
2407                 {
2408                         GotoNextMap();
2409                         return;
2410                 }
2411                 MapVote_Init();
2412         }
2413
2414         MapVote_Tick();
2415 };
2416
2417 string GotoMap(string m)
2418 {
2419         if(!MapInfo_CheckMap(m))
2420                 return "The map you chose is not available on this server.";
2421         cvar_set("nextmap", m);
2422         cvar_set("timelimit", "-1");
2423         if(mapvote_initialized || alreadychangedlevel)
2424         {
2425                 if(DoNextMapOverride())
2426                         return "Map switch initiated.";
2427                 else
2428                         return "Hm... no. For some reason I like THIS map more.";
2429         }
2430         else
2431                 return "Map switch will happen after scoreboard.";
2432 }
2433
2434
2435 void EndFrame()
2436 {
2437         FOR_EACH_REALCLIENT(self)
2438         {
2439                 if(self.classname == "spectator")
2440                 {
2441                         if(self.enemy.typehitsound)
2442                                 play2(self, "misc/typehit.wav");
2443                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2444                                 play2(self, "misc/hit.wav");
2445                 }
2446                 else
2447                 {
2448                         if(self.typehitsound)
2449                                 play2(self, "misc/typehit.wav");
2450                         else if(self.hitsound && self.cvar_cl_hitsound)
2451                                 play2(self, "misc/hit.wav");
2452                 }
2453         }
2454         FOR_EACH_CLIENT(self)
2455         {
2456                 self.hitsound = FALSE;
2457                 self.typehitsound = FALSE;
2458         }
2459 }
2460
2461
2462 /*
2463  * RedirectionThink:
2464  * returns TRUE if redirecting
2465  */
2466 float redirection_timeout;
2467 float redirection_nextthink;
2468 float RedirectionThink()
2469 {
2470         float clients_found;
2471
2472         if(redirection_target == "")
2473                 return FALSE;
2474
2475         if(!redirection_timeout)
2476         {
2477                 cvar_set("sv_public", "-2");
2478                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2479                 if(redirection_target == "self")
2480                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2481                 else
2482                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2483         }
2484
2485         if(time < redirection_nextthink)
2486                 return TRUE;
2487
2488         redirection_nextthink = time + 1;
2489
2490         clients_found = 0;
2491         FOR_EACH_REALCLIENT(self)
2492         {
2493                 print("Redirecting: sending connect command to ", self.netname, "\n");
2494                 if(redirection_target == "self")
2495                         stuffcmd(self, "\ndisconnect; reconnect\n");
2496                 else
2497                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2498                 ++clients_found;
2499         }
2500
2501         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2502
2503         if(time > redirection_timeout || clients_found == 0)
2504                 localcmd("\nwait; wait; wait; quit\n");
2505
2506         return TRUE;
2507 }
2508
2509 void RestoreGame()
2510 {
2511         // Loaded from a save game
2512         // some things then break, so let's work around them...
2513
2514         // Progs DB (capture records)
2515         if(sv_cheats)
2516                 ServerProgsDB = db_create();
2517         else
2518                 ServerProgsDB = db_load("server.db");
2519
2520         // Mapinfo
2521         MapInfo_Shutdown();
2522         MapInfo_Enumerate();
2523         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2524 }
2525
2526 void SV_Shutdown()
2527 {
2528         if(world_initialized > 0)
2529         {
2530                 world_initialized = 0;
2531                 print("Saving persistent data...\n");
2532                 Ban_SaveBans();
2533                 if(!sv_cheats)
2534                         db_save(ServerProgsDB, "server.db");
2535                 if(cvar("developer"))
2536                         db_save(TemporaryDB, "server-temp.db");
2537                 db_close(ServerProgsDB);
2538                 db_close(TemporaryDB);
2539                 print("done!\n");
2540                 // tell the bot system the game is ending now
2541                 bot_endgame();
2542
2543                 MapInfo_Shutdown();
2544         }
2545         else if(world_initialized == 0)
2546         {
2547                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2548         }
2549 }