data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float h;
 160         string k, v, d;
 161         float n, i;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         for(i = 0; i < n; ++i)
 172         {
 173                 k = bufstr_get(h, i);
 174
 175 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 176 #define BADCVAR(p) if(k == p) continue
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184
 185                 // client
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("g_campaign");
 189                 BADPREFIX("gl_");
 190                 BADPREFIX("joy");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("userbind");
 197                 BADPREFIX("v_");
 198                 BADPREFIX("vid_");
 199                 BADCVAR("mod_q3bsp_lightmapmergepower");
 200                 BADCVAR("mod_q3bsp_nolightmaps");
 201
 202                 // private
 203                 BADPREFIX("g_ban_");
 204                 BADPREFIX("g_chat_flood_");
 205                 BADPREFIX("rcon_");
 206                 BADPREFIX("settemp_");
 207                 BADPREFIX("sv_allowdownloads_");
 208                 BADPREFIX("sv_autodemo");
 209                 BADPREFIX("sv_curl_");
 210                 BADPREFIX("sv_eventlog");
 211                 BADPREFIX("sv_logscores_");
 212                 BADPREFIX("sv_master");
 213                 BADCVAR("g_banned_list");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("log_file");
 216                 BADCVAR("net_address");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("sv_heartbeatperoid");
 220                 BADCVAR("sv_vote_master_password");
 221                 BADCVAR("sys_colortranslation");
 222                 BADCVAR("sys_specialcharactertranslation");
 223                 BADCVAR("timestamps");
 224
 225                 // mapinfo
 226                 BADCVAR("timelimit");
 227                 BADCVAR("fraglimit");
 228                 BADCVAR("g_arena");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ctf");
 231                 BADCVAR("g_dm");
 232                 BADCVAR("g_domination");
 233                 BADCVAR("g_keyhunt");
 234                 BADCVAR("g_keyhunt_teams");
 235                 BADCVAR("g_onslaught");
 236                 BADCVAR("g_race");
 237                 BADCVAR("g_runematch");
 238                 BADCVAR("g_tdm");
 239                 BADCVAR("teamplay");
 240
 241                 // long
 242                 BADCVAR("hostname");
 243                 BADCVAR("g_maplist");
 244                 BADCVAR("g_maplist_mostrecent");
 245                 BADCVAR("sv_motd");
 246 #undef BADPREFIX
 247 #undef BADCVAR
 248
 249                 v = cvar_string(k);
 250                 d = cvar_defstring(k);
 251                 if(v != d)
 252                 {
 253                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 254                         if(strlen(cvar_changes) > 16384)
 255                         {
 256                                 cvar_changes = "// too many settings have been changed to show them here\n";
 257                                 break;
 258                         }
 259                 }
 260         }
 261         buf_del(h);
 262         if(cvar_changes == "")
 263                 cvar_changes = "// this server runs at default settings\n";
 264         else
 265                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 266         cvar_changes = strzone(cvar_changes);
 267 }
 268
 269 void detect_maptype()
 270 {
 271 #if 0
 272         vector o, v;
 273         float i;
 274
 275         for(;;)
 276         {
 277                 o = world.mins;
 278                 o_x += random() * (world.maxs_x - world.mins_x);
 279                 o_y += random() * (world.maxs_y - world.mins_y);
 280                 o_z += random() * (world.maxs_z - world.mins_z);
 281
 282                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 283                 if(trace_fraction == 1)
 284                         continue;
 285
 286                 v = trace_endpos;
 287
 288                 for(i = 0; i < 64; i += 4)
 289                 {
 290                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 291         if(trace_fraction == 1)
 292                 continue;
 293                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 294                 }
 295
 296                 break;
 297         }
 298 #endif
 299 }
 300
 301 entity randomseed;
 302 float RandomSeed_Send(entity to, float sf)
 303 {
 304         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 305         WriteShort(MSG_ENTITY, self.cnt);
 306         return TRUE;
 307 }
 308 void RandomSeed_Think()
 309 {
 310         self.cnt = bound(0, floor(random() * 65536), 65535);
 311         self.nextthink = time + 5;
 312
 313         self.SendFlags |= 1;
 314 }
 315 void RandomSeed_Spawn()
 316 {
 317         randomseed = spawn();
 318         randomseed.think = RandomSeed_Think;
 319         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 320
 321         entity oldself;
 322         oldself = self;
 323         self = randomseed;
 324         self.think(); // sets random seed and nextthink
 325         self = oldself;
 326 }
 327
 328 float world_already_spawned;
 329 void RegisterWeapons();
 330 void Nagger_Init();
 331 void ClientInit_Spawn();
 332 void spawnfunc_worldspawn (void)
 333 {
 334         float fd, l, i, j, n;
 335         string s, col;
 336
 337         dprint_load(); // load dprint status from cvar
 338
 339         if(world_already_spawned)
 340                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 341         world_already_spawned = TRUE;
 342
 343         remove = remove_safely; // during spawning, watch what you remove!
 344
 345         if(cvar_string("cvar_check_default") != "bypass")
 346         {
 347                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 348                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 349
 350                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 351                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 352         }
 353
 354         compressShortVector_init();
 355
 356         local entity head;
 357         head = nextent(world);
 358         maxclients = 0;
 359         while(head)
 360         {
 361                 ++maxclients;
 362                 head = nextent(head);
 363         }
 364
 365         // needs to be done so early as they would still spawn
 366         RegisterWeapons();
 367
 368         if(GotoFirstMap())
 369         {
 370                 world_initialized = -1; // don't complain
 371                 return;
 372         }
 373
 374         if(sv_cheats)
 375                 ServerProgsDB = db_create();
 376         else
 377                 ServerProgsDB = db_load("server.db");
 378
 379         TemporaryDB = db_create();
 380
 381         /*
 382         TODO sound pack system
 383         // initialize sound pack system
 384         soundpack = cvar_string("g_soundpack");
 385         if(soundpack != "")
 386                 soundpack = strcat(soundpack, "/");
 387         soundpack = strzone(soundpack);
 388         */
 389
 390         // 0 normal
 391         lightstyle(0, "m");
 392
 393         // 1 FLICKER (first variety)
 394         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 395
 396         // 2 SLOW STRONG PULSE
 397         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 398
 399         // 3 CANDLE (first variety)
 400         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 401
 402         // 4 FAST STROBE
 403         lightstyle(4, "mamamamamama");
 404
 405         // 5 GENTLE PULSE 1
 406         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 407
 408         // 6 FLICKER (second variety)
 409         lightstyle(6, "nmonqnmomnmomomno");
 410
 411         // 7 CANDLE (second variety)
 412         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 413
 414         // 8 CANDLE (third variety)
 415         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 416
 417         // 9 SLOW STROBE (fourth variety)
 418         lightstyle(9, "aaaaaaaazzzzzzzz");
 419
 420         // 10 FLUORESCENT FLICKER
 421         lightstyle(10, "mmamammmmammamamaaamammma");
 422
 423         // 11 SLOW PULSE NOT FADE TO BLACK
 424         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 425
 426         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 427
 428         // 63 testing
 429         lightstyle(63, "a");
 430
 431         if(cvar("g_campaign"))
 432                 CampaignPreInit();
 433
 434         InitGameplayMode();
 435         readlevelcvars();
 436         GrappleHookInit();
 437
 438         player_count = 0;
 439         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 440         if(bot_waypoints_for_items == 1)
 441                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 442                         bot_waypoints_for_items = 0;
 443
 444         // for setting by mapinfo
 445         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 446         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 447
 448         precache();
 449
 450         WaypointSprite_Init();
 451
 452         //if (g_domination)
 453         //      dom_init();
 454
 455         GameLogInit(); // prepare everything
 456         if(cvar("sv_eventlog"))
 457         {
 458                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 459                 s = strcat(s, ftos(random()));
 460                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 461                 s = ":gameinfo:mutators:LIST";
 462                 if(cvar("g_grappling_hook"))
 463                         s = strcat(s, ":grappling_hook");
 464                 if(!cvar("g_use_ammunition"))
 465                         s = strcat(s, ":no_use_ammunition");
 466                 if(!cvar("g_pickup_items"))
 467                         s = strcat(s, ":no_pickup_items");
 468                 if(cvar("g_instagib"))
 469                         s = strcat(s, ":instagib");
 470                 if(cvar_string("g_weaponarena") != "0")
 471                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 472                 if(cvar("g_nixnex"))
 473                         s = strcat(s, ":nixnex");
 474                 if(cvar("g_vampire"))
 475                         s = strcat(s, ":vampire");
 476                 if(cvar("g_laserguided_missile"))
 477                         s = strcat(s, ":laserguided_missile");
 478                 if(cvar("g_norecoil"))
 479                         s = strcat(s, ":norecoil");
 480                 if(cvar("g_midair"))
 481                         s = strcat(s, ":midair");
 482                 if(cvar("g_minstagib"))
 483                         s = strcat(s, ":minstagib");
 484                 GameLogEcho(s);
 485                 GameLogEcho(":gameinfo:end");
 486         }
 487
 488         cvar_set("nextmap", "");
 489
 490         SetDefaultAlpha();
 491
 492         if(cvar("g_campaign"))
 493                 CampaignPostInit();
 494
 495         fteqcc_testbugs();
 496
 497         Ban_LoadBans();
 498
 499         //initialise globals related to sv_timeout
 500         sys_ticrate = cvar("sys_ticrate");
 501         orig_slowmo = cvar("slowmo");
 502
 503         MapInfo_Enumerate();
 504         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 505
 506         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 507         {
 508                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 509                 if(fd != -1)
 510                 {
 511                         while((s = fgets(fd)))
 512                         {
 513                                 l = tokenize_sane(s);
 514                                 if(l < 2)
 515                                         continue;
 516                                 if(argv(0) == "cd")
 517                                 {
 518                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 519                                         print("  cdtrack ", argv(2), "\n");
 520                                 }
 521                                 else if(argv(0) == "fog")
 522                                 {
 523                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 524                                         print("  \"fog\" \"", s, "\"\n");
 525                                 }
 526                                 else if(argv(0) == "set")
 527                                 {
 528                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 529                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 530                                 }
 531                                 else if(argv(0) != "//")
 532                                 {
 533                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 534                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 535                                 }
 536                         }
 537                         fclose(fd);
 538                 }
 539         }
 540
 541         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 542         addstat(STAT_WEAPONS, AS_INT, weapons);
 543         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 544         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 545         Nagger_Init();
 546
 547         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 548         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 549
 550         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 551
 552         next_pingtime = time + 5;
 553         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 554
 555         detect_maptype();
 556
 557         lsmaps_reply = "^7Maps available: ";
 558         for(i = 0, j = 0; i < MapInfo_count; ++i)
 559         {
 560                 if(MapInfo_Get_ByID(i))
 561                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 562                         {
 563                                 if(mod(i, 2))
 564                                         col = "^2";
 565                                 else
 566                                         col = "^3";
 567                                 ++j;
 568                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 569                         }
 570         }
 571         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 572
 573         maplist_reply = "^7Maps in list: ";
 574         n = tokenize_sane(cvar_string("g_maplist"));
 575         for(i = 0, j = 0; i < n; ++i)
 576         {
 577                 if(MapInfo_CheckMap(argv(i)))
 578                 {
 579                         if(mod(j, 2))
 580                                 col = "^2";
 581                         else
 582                                 col = "^3";
 583                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 584                         ++j;
 585                 }
 586         }
 587         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 588
 589         records_reply = strzone(getrecords());
 590
 591         ClientInit_Spawn();
 592         RandomSeed_Spawn();
 593
 594         world_initialized = 1;
 595 }
 596
 597 void spawnfunc_light (void)
 598 {
 599         //makestatic (self); // Who the f___ did that?
 600         remove(self);
 601 }
 602
 603 float TryFile( string pFilename )
 604 {
 605         local float lHandle;
 606         dprint("TryFile(\"", pFilename, "\")\n");
 607         lHandle = fopen( pFilename, FILE_READ );
 608         if( lHandle != -1 ) {
 609                 fclose( lHandle );
 610                 return TRUE;
 611         } else {
 612                 return FALSE;
 613         }
 614 };
 615
 616 string GetGametype()
 617 {
 618         return GametypeNameFromType(game);
 619 }
 620
 621 string getmapname_stored;
 622 string GetMapname()
 623 {
 624         return mapname;
 625 }
 626
 627 float Map_Count, Map_Current;
 628 string Map_Current_Name;
 629
 630 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 631 float GetMaplistPosition()
 632 {
 633         float pos, idx;
 634         string map;
 635
 636         map = GetMapname();
 637         idx = cvar("g_maplist_index");
 638
 639         if(idx >= 0)
 640                 if(idx < Map_Count)
 641                         if(map == argv(idx))
 642                                 return idx;
 643
 644         for(pos = 0; pos < Map_Count; ++pos)
 645                 if(map == argv(pos))
 646                         return pos;
 647
 648         // resume normal maplist rotation if current map is not in g_maplist
 649         return idx;
 650 }
 651
 652 float MapHasRightSize(string map)
 653 {
 654         float fh;
 655         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 656         if(cvar("g_maplist_check_waypoints"))
 657         {
 658                 dprint("checkwp "); dprint(map);
 659                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 660                 if(fh < 0)
 661                 {
 662                         dprint(": no waypoints\n");
 663                         return FALSE;
 664                 }
 665                 dprint(": has waypoints\n");
 666                 fclose(fh);
 667         }
 668
 669         // open map size restriction file
 670         dprint("opensize "); dprint(map);
 671         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 672         if(fh >= 0)
 673         {
 674                 float mapmin, mapmax;
 675                 dprint(": ok, ");
 676                 mapmin = stof(fgets(fh));
 677                 mapmax = stof(fgets(fh));
 678                 fclose(fh);
 679                 if(player_count < mapmin)
 680                 {
 681                         dprint("not enough\n");
 682                         return FALSE;
 683                 }
 684                 if(player_count > mapmax)
 685                 {
 686                         dprint("too many\n");
 687                         return FALSE;
 688                 }
 689                 dprint("right size\n");
 690                 return TRUE;
 691         }
 692         dprint(": not found\n");
 693         return TRUE;
 694 }
 695
 696 string Map_Filename(float position)
 697 {
 698         return strcat("maps/", argv(position), ".bsp");
 699 }
 700
 701 string strwords(string s, float w)
 702 {
 703         float endpos;
 704         for(endpos = 0; w && endpos >= 0; --w)
 705                 endpos = strstrofs(s, " ", endpos + 1);
 706         if(endpos < 0)
 707                 return s;
 708         else
 709                 return substring(s, 0, endpos);
 710 }
 711
 712 float strhasword(string s, string w)
 713 {
 714         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 715 }
 716
 717 void Map_MarkAsRecent(string m)
 718 {
 719         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 720 }
 721
 722 float Map_IsRecent(string m)
 723 {
 724         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 725 }
 726
 727 float Map_Check(float position, float pass)
 728 {
 729         string filename;
 730         string map_next;
 731         map_next = argv(position);
 732         if(pass <= 1)
 733         {
 734                 if(map_next == Map_Current_Name) // same map again in first pass?
 735                         return 0;
 736                 if(Map_IsRecent(map_next))
 737                         return 0;
 738         }
 739         filename = Map_Filename(position);
 740         if(MapInfo_CheckMap(map_next))
 741         {
 742                 if(pass == 2)
 743                         return 1;
 744                 if(MapHasRightSize(map_next))
 745                         return 1;
 746                 return 0;
 747         }
 748         else
 749                 dprint( "Couldn't select '", filename, "'..\n" );
 750
 751         return 0;
 752 }
 753
 754 void Map_Goto_SetStr(string nextmapname)
 755 {
 756         if(getmapname_stored != "")
 757                 strunzone(getmapname_stored);
 758         if(nextmapname == "")
 759                 getmapname_stored = "";
 760         else
 761                 getmapname_stored = strzone(nextmapname);
 762 }
 763
 764 void Map_Goto_SetFloat(float position)
 765 {
 766         cvar_set("g_maplist_index", ftos(position));
 767         Map_Goto_SetStr(argv(position));
 768 }
 769
 770 void GameResetCfg()
 771 {
 772         // settings persist, except...
 773         if(cvar("g_campaign"))
 774                 localcmd("\nexec mutator_reset.cfg\n");
 775         localcmd("\nsettemp_restore\n");
 776 };
 777
 778 void Map_Goto()
 779 {
 780         Map_MarkAsRecent(getmapname_stored);
 781         GameResetCfg();
 782         MapInfo_LoadMap(getmapname_stored);
 783 }
 784
 785 // return codes of map selectors:
 786 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 787 //   -2 = permanent failure
 788 float() MaplistMethod_Iterate = // usual method
 789 {
 790         float pass, i;
 791
 792         for(pass = 1; pass <= 2; ++pass)
 793         {
 794                 for(i = 1; i < Map_Count; ++i)
 795                 {
 796                         float mapindex;
 797                         mapindex = mod(i + Map_Current, Map_Count);
 798                         if(Map_Check(mapindex, pass))
 799                                 return mapindex;
 800                 }
 801         }
 802         return -1;
 803 }
 804
 805 float() MaplistMethod_Repeat = // fallback method
 806 {
 807         if(Map_Check(Map_Current, 2))
 808                 return Map_Current;
 809         return -2;
 810 }
 811
 812 float() MaplistMethod_Random = // random map selection
 813 {
 814         float i, imax;
 815
 816         imax = 42;
 817
 818         for(i = 0; i <= imax; ++i)
 819         {
 820                 float mapindex;
 821                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 822                 if(Map_Check(mapindex, 1))
 823                         return mapindex;
 824         }
 825         return -1;
 826 }
 827
 828 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 829 // the exponent sets a bias on the map selection:
 830 // the higher the exponent, the less likely "shortly repeated" same maps are
 831 {
 832         float i, j, imax, insertpos;
 833
 834         imax = 42;
 835
 836         for(i = 0; i <= imax; ++i)
 837         {
 838                 string newlist;
 839
 840                 // now reinsert this at another position
 841                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 842                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 843                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 844                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 845
 846                 // insert the current map there
 847                 newlist = "";
 848                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 849                         newlist = strcat(newlist, " ", argv(j));
 850                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 851                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 852                         newlist = strcat(newlist, " ", argv(j));
 853                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 854                 cvar_set("g_maplist", newlist);
 855                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 856
 857                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 858                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 859                 if(Map_Check(Map_Current, 1))
 860                         return Map_Current;
 861         }
 862         return -1;
 863 }
 864
 865 void Maplist_Init()
 866 {
 867         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 868         if(Map_Count == 0)
 869         {
 870                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 871                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 872                 if(cvar("g_maplist_shuffle"))
 873                         ShuffleMaplist();
 874                 localcmd("\nmenu_cmd sync\n");
 875                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 876         }
 877         if(Map_Count == 0)
 878                 error("empty maplist, cannot select a new map");
 879         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 880
 881         if(Map_Current_Name)
 882                 strunzone(Map_Current_Name);
 883         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 884         // this may or may not be correct, but who cares, in the worst case a map
 885         // isn't chosen in the first pass that should have been
 886 }
 887
 888 string GetNextMap()
 889 {
 890         float nextMap;
 891
 892         Maplist_Init();
 893         nextMap = -1;
 894
 895         if(nextMap == -1)
 896                 if(cvar("g_maplist_shuffle") > 0)
 897                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 898
 899         if(nextMap == -1)
 900                 if(cvar("g_maplist_selectrandom"))
 901                         nextMap = MaplistMethod_Random();
 902
 903         if(nextMap == -1)
 904                 nextMap = MaplistMethod_Iterate();
 905
 906         if(nextMap == -1)
 907                 nextMap = MaplistMethod_Repeat();
 908
 909         if(nextMap >= 0)
 910         {
 911                 Map_Goto_SetFloat(nextMap);
 912                 return getmapname_stored;
 913         }
 914
 915         return "";
 916 };
 917
 918 float DoNextMapOverride()
 919 {
 920         if(cvar("g_campaign"))
 921         {
 922                 CampaignPostIntermission();
 923                 alreadychangedlevel = TRUE;
 924                 return TRUE;
 925         }
 926         if(cvar("quit_when_empty"))
 927         {
 928                 if(player_count <= currentbots)
 929                 {
 930                         localcmd("quit\n");
 931                         alreadychangedlevel = TRUE;
 932                         return TRUE;
 933                 }
 934         }
 935         if(cvar_string("quit_and_redirect") != "")
 936         {
 937                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 938                 alreadychangedlevel = TRUE;
 939                 return TRUE;
 940         }
 941         if (cvar("samelevel")) // if samelevel is set, stay on same level
 942         {
 943                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 944                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 945                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 946                 localcmd("restart\n");
 947                 //changelevel (mapname);
 948                 alreadychangedlevel = TRUE;
 949                 return TRUE;
 950         }
 951         if(cvar_string("nextmap") != "")
 952                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 953                 {
 954                         Map_Goto_SetStr(cvar_string("nextmap"));
 955                         Map_Goto();
 956                         alreadychangedlevel = TRUE;
 957                         return TRUE;
 958                 }
 959         if(cvar("lastlevel"))
 960         {
 961                 GameResetCfg();
 962                 localcmd("set lastlevel 0\ntogglemenu\n");
 963                 alreadychangedlevel = TRUE;
 964                 return TRUE;
 965         }
 966         return FALSE;
 967 };
 968
 969 void GotoNextMap()
 970 {
 971         //local string nextmap;
 972         //local float n, nummaps;
 973         //local string s;
 974         if (alreadychangedlevel)
 975                 return;
 976         alreadychangedlevel = TRUE;
 977
 978         {
 979                 string nextMap;
 980                 float allowReset;
 981
 982                 for(allowReset = 1; allowReset >= 0; --allowReset)
 983                 {
 984                         nextMap = GetNextMap();
 985                         if(nextMap != "")
 986                                 break;
 987
 988                         if(allowReset)
 989                         {
 990                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 991                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 992                                 if(cvar("g_maplist_shuffle"))
 993                                         ShuffleMaplist();
 994                                 localcmd("\nmenu_cmd sync\n");
 995                         }
 996                         else
 997                         {
 998                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 999                         }
1000                 }
1001                 Map_Goto();
1002         }
1003 };
1004
1005
1006 /*
1007 ============
1008 IntermissionThink
1009
1010 When the player presses attack or jump, change to the next level
1011 ============
1012 */
1013 .float autoscreenshot;
1014 void() MapVote_Start;
1015 void() MapVote_Think;
1016 float mapvote_initialized;
1017 void IntermissionThink()
1018 {
1019         FixIntermissionClient(self);
1020
1021         if(cvar("sv_autoscreenshot"))
1022         if(self.autoscreenshot > 0)
1023         if(time > self.autoscreenshot)
1024         {
1025                 self.autoscreenshot = -1;
1026                 if(clienttype(self) == CLIENTTYPE_REAL)
1027                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1028                 return;
1029         }
1030
1031         if (time < intermission_exittime)
1032                 return;
1033
1034         if(!mapvote_initialized)
1035                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1036                         return;
1037
1038         MapVote_Start();
1039 };
1040
1041 /*
1042 ============
1043 FindIntermission
1044
1045 Returns the entity to view from
1046 ============
1047 */
1048 /*
1049 entity FindIntermission()
1050 {
1051         local   entity spot;
1052         local   float cyc;
1053
1054 // look for info_intermission first
1055         spot = find (world, classname, "info_intermission");
1056         if (spot)
1057         {       // pick a random one
1058                 cyc = random() * 4;
1059                 while (cyc > 1)
1060                 {
1061                         spot = find (spot, classname, "info_intermission");
1062                         if (!spot)
1063                                 spot = find (spot, classname, "info_intermission");
1064                         cyc = cyc - 1;
1065                 }
1066                 return spot;
1067         }
1068
1069 // then look for the start position
1070         spot = find (world, classname, "info_player_start");
1071         if (spot)
1072                 return spot;
1073
1074 // testinfo_player_start is only found in regioned levels
1075         spot = find (world, classname, "testplayerstart");
1076         if (spot)
1077                 return spot;
1078
1079 // then look for the start position
1080         spot = find (world, classname, "info_player_deathmatch");
1081         if (spot)
1082                 return spot;
1083
1084         //objerror ("FindIntermission: no spot");
1085         return world;
1086 };
1087 */
1088
1089 /*
1090 ===============================================================================
1091
1092 RULES
1093
1094 ===============================================================================
1095 */
1096
1097 void DumpStats(float final)
1098 {
1099         local float file;
1100         local string s;
1101         local float to_console;
1102         local float to_eventlog;
1103         local float to_file;
1104         local float i;
1105
1106         to_console = cvar("sv_logscores_console");
1107         to_eventlog = cvar("sv_eventlog");
1108         to_file = cvar("sv_logscores_file");
1109
1110         if(!final)
1111         {
1112                 to_console = TRUE; // always print printstats replies
1113                 to_eventlog = FALSE; // but never print them to the event log
1114         }
1115
1116         if(to_eventlog)
1117                 if(cvar("sv_eventlog_console"))
1118                         to_console = FALSE; // otherwise we get the output twice
1119
1120         if(final)
1121                 s = ":scores:";
1122         else
1123                 s = ":status:";
1124         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1125
1126         if(to_console)
1127                 print(s, "\n");
1128         if(to_eventlog)
1129                 GameLogEcho(s);
1130         if(to_file)
1131         {
1132                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1133                 if(file == -1)
1134                         to_file = FALSE;
1135                 else
1136                         fputs(file, strcat(s, "\n"));
1137         }
1138
1139         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1140         if(to_console)
1141                 print(s, "\n");
1142         if(to_eventlog)
1143                 GameLogEcho(s);
1144         if(to_file)
1145                 fputs(file, strcat(s, "\n"));
1146
1147         FOR_EACH_CLIENT(other)
1148         {
1149                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1150                 {
1151                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1152                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1153                         if(other.classname == "player" || g_arena || g_lms)
1154                                 s = strcat(s, ftos(other.team), ":");
1155                         else
1156                                 s = strcat(s, "spectator:");
1157
1158                         if(to_console)
1159                                 print(s, other.netname, "\n");
1160                         if(to_eventlog)
1161                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1162                         if(to_file)
1163                                 fputs(file, strcat(s, other.netname, "\n"));
1164                 }
1165         }
1166
1167         if(teamplay)
1168         {
1169                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1170                 if(to_console)
1171                         print(s, "\n");
1172                 if(to_eventlog)
1173                         GameLogEcho(s);
1174                 if(to_file)
1175                         fputs(file, strcat(s, "\n"));
1176
1177                 for(i = 1; i < 16; ++i)
1178                 {
1179                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1180                         s = strcat(s, ":", ftos(i));
1181                         if(to_console)
1182                                 print(s, "\n");
1183                         if(to_eventlog)
1184                                 GameLogEcho(s);
1185                         if(to_file)
1186                                 fputs(file, strcat(s, "\n"));
1187                 }
1188         }
1189
1190         if(to_console)
1191                 print(":end\n");
1192         if(to_eventlog)
1193                 GameLogEcho(":end");
1194         if(to_file)
1195         {
1196                 fputs(file, ":end\n");
1197                 fclose(file);
1198         }
1199 }
1200
1201 void FixIntermissionClient(entity e)
1202 {
1203         string s;
1204         if(!e.autoscreenshot) // initial call
1205         {
1206                 e.angles = e.v_angle;
1207                 e.angles_x = -e.angles_x;
1208                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1209                 e.health = -2342;
1210                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1211                 e.solid = SOLID_NOT;
1212                 e.movetype = MOVETYPE_NONE;
1213                 e.takedamage = DAMAGE_NO;
1214                 if(e.weaponentity)
1215                         e.weaponentity.effects = EF_NODRAW;
1216                 if(clienttype(e) == CLIENTTYPE_REAL)
1217                 {
1218                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1219                         s = cvar_string("sv_intermission_cdtrack");
1220                         if(s != "")
1221                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1222                         msg_entity = e;
1223                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1224                 }
1225         }
1226
1227         //e.velocity = '0 0 0';
1228         //e.fixangle = TRUE;
1229
1230         // TODO halt weapon animation
1231 }
1232
1233
1234 /*
1235 go to the next level for deathmatch
1236 only called if a time or frag limit has expired
1237 */
1238 void NextLevel()
1239 {
1240         float minTotalFrags;
1241         float maxTotalFrags;
1242         float score;
1243         float f;
1244
1245         gameover = TRUE;
1246
1247         intermission_running = 1;
1248
1249 // enforce a wait time before allowing changelevel
1250         if(player_count > 0)
1251                 intermission_exittime = time + cvar("sv_mapchange_delay");
1252         else
1253                 intermission_exittime = -1;
1254
1255         /*
1256         WriteByte (MSG_ALL, SVC_CDTRACK);
1257         WriteByte (MSG_ALL, 3);
1258         WriteByte (MSG_ALL, 3);
1259         // done in FixIntermission
1260         */
1261
1262         //pos = FindIntermission ();
1263
1264         VoteReset();
1265
1266         DumpStats(TRUE);
1267
1268         if(cvar("sv_eventlog"))
1269                 GameLogEcho(":gameover");
1270
1271         GameLogClose();
1272
1273         FOR_EACH_CLIENT(other)
1274         {
1275                 FixIntermissionClient(other);
1276
1277                 if(other.winning)
1278                         bprint(other.netname, " ^7wins.\n");
1279         }
1280
1281         minTotalFrags = 0;
1282         maxTotalFrags = 0;
1283         FOR_EACH_PLAYER(other)
1284         {
1285                 if(maxTotalFrags < other.totalfrags)
1286                         maxTotalFrags = other.totalfrags;
1287                 if(minTotalFrags > other.totalfrags)
1288                         minTotalFrags = other.totalfrags;
1289         }
1290
1291         if(!currentbots)
1292         {
1293                 FOR_EACH_PLAYER(other)
1294                 {
1295                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1296                         f = bound(0, other.play_time / max(time, 1), 1);
1297                         // store some statistics?
1298                 }
1299         }
1300
1301         if(cvar("g_campaign"))
1302                 CampaignPreIntermission();
1303
1304         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1305 };
1306
1307 /*
1308 ============
1309 CheckRules_Player
1310
1311 Exit deathmatch games upon conditions
1312 ============
1313 */
1314 void CheckRules_Player()
1315 {
1316         if (gameover)   // someone else quit the game already
1317                 return;
1318
1319         if(self.deadflag == DEAD_NO)
1320                 self.play_time += frametime;
1321
1322         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1323         //   (div0: and that in CheckRules_World please)
1324 };
1325
1326 float checkrules_oneminutewarning;
1327
1328 float checkrules_equality;
1329 float checkrules_suddendeathwarning;
1330 float checkrules_suddendeathend;
1331 float checkrules_overtimesadded; //how many overtimes have been already added
1332 float checkrules_status;
1333
1334 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1335 float WINNING_YES = 1; // winner found
1336 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1337 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1338
1339 void InitiateOvertime()
1340 {
1341         // Check first whether normal overtimes could be added before initiating suddendeath mode
1342         // - for this timelimit_overtime needs to be >0 of course
1343         // - also check the winning condition calculated in the previous frame and only add normal overtime
1344         //   again, if at the point at which timelimit would be extended again, still no winner was found
1345         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1346         {
1347                 checkrules_overtimesadded++;
1348                 //add one more overtime by simply extending the timelimit
1349                 float tl;
1350                 tl = cvar("timelimit");
1351                 tl += cvar("timelimit_overtime");
1352                 cvar_set("timelimit", ftos(tl));
1353                 string minutesPlural;
1354                 if (cvar("timelimit_overtime") == 1)
1355                         minutesPlural = " ^3minute";
1356                 else
1357                         minutesPlural = " ^3minutes";
1358
1359                 bcenterprint(
1360                         strcat(
1361                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1362                                 ftos(cvar("timelimit_overtime")),
1363                                 minutesPlural,
1364                                 " to the game!"
1365                         )
1366                 );
1367         }
1368         else
1369         {
1370                 if(!checkrules_suddendeathend)
1371                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1372         }
1373 }
1374
1375 float GetWinningCode(float fraglimitreached, float equality)
1376 {
1377         if(equality)
1378                 if(fraglimitreached)
1379                         return WINNING_STARTSUDDENDEATHOVERTIME;
1380                 else
1381                         return WINNING_NEVER;
1382         else
1383                 if(fraglimitreached)
1384                         return WINNING_YES;
1385                 else
1386                         return WINNING_NO;
1387 }
1388
1389 // set the .winning flag for exactly those players with a given field value
1390 void SetWinners(.float field, float value)
1391 {
1392         entity head;
1393         FOR_EACH_PLAYER(head)
1394                 head.winning = (head.field == value);
1395 }
1396
1397 // set the .winning flag for those players with a given field value
1398 void AddWinners(.float field, float value)
1399 {
1400         entity head;
1401         FOR_EACH_PLAYER(head)
1402                 if(head.field == value)
1403                         head.winning = 1;
1404 }
1405
1406 // clear the .winning flags
1407 void ClearWinners(void)
1408 {
1409         entity head;
1410         FOR_EACH_PLAYER(head)
1411                 head.winning = 0;
1412 }
1413
1414 // Onslaught winning condition:
1415 // game terminates if only one team has a working generator (or none)
1416 float WinningCondition_Onslaught()
1417 {
1418         entity head;
1419         local float t1, t2, t3, t4;
1420
1421         WinningConditionHelper(); // set worldstatus
1422
1423         // first check if the game has ended
1424         t1 = t2 = t3 = t4 = 0;
1425         head = find(world, classname, "onslaught_generator");
1426         while (head)
1427         {
1428                 if (head.health > 0)
1429                 {
1430                         if (head.team == COLOR_TEAM1) t1 = 1;
1431                         if (head.team == COLOR_TEAM2) t2 = 1;
1432                         if (head.team == COLOR_TEAM3) t3 = 1;
1433                         if (head.team == COLOR_TEAM4) t4 = 1;
1434                 }
1435                 head = find(head, classname, "onslaught_generator");
1436         }
1437         if (t1 + t2 + t3 + t4 < 2)
1438         {
1439                 // game over, only one team remains (or none)
1440                 ClearWinners();
1441                 if (t1) SetWinners(team, COLOR_TEAM1);
1442                 if (t2) SetWinners(team, COLOR_TEAM2);
1443                 if (t3) SetWinners(team, COLOR_TEAM3);
1444                 if (t4) SetWinners(team, COLOR_TEAM4);
1445                 dprint("Have a winner, ending game.\n");
1446                 return WINNING_YES;
1447         }
1448
1449         // Two or more teams remain
1450         return WINNING_NO;
1451 }
1452
1453 float LMS_NewPlayerLives()
1454 {
1455         float fl;
1456         fl = cvar("fraglimit");
1457         if(fl == 0)
1458                 fl = 999;
1459
1460         // first player has left the game for dying too much? Nobody else can get in.
1461         if(lms_lowest_lives < 1)
1462                 return 0;
1463
1464         if(!cvar("g_lms_join_anytime"))
1465                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1466                         return 0;
1467
1468         return bound(1, lms_lowest_lives, fl);
1469 }
1470
1471 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1472 // they win. Otherwise the defending team wins once the timelimit passes.
1473 void assault_new_round();
1474 float WinningCondition_Assault()
1475 {
1476         local float status;
1477
1478         WinningConditionHelper(); // set worldstatus
1479
1480         status = WINNING_NO;
1481         // as the timelimit has not yet passed just assume the defending team will win
1482         if(assault_attacker_team == COLOR_TEAM1)
1483         {
1484                 SetWinners(team, COLOR_TEAM2);
1485         }
1486         else
1487         {
1488                 SetWinners(team, COLOR_TEAM1);
1489         }
1490
1491         local entity ent;
1492         ent = find(world, classname, "target_assault_roundend");
1493         if(ent)
1494         {
1495                 if(ent.winning) // round end has been triggered by attacking team
1496                 {
1497                         bprint("ASSAULT: round completed...\n");
1498                         SetWinners(team, assault_attacker_team);
1499
1500                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1501
1502                         if(ent.cnt == 1) // this was the second round
1503                         {
1504                                 status = WINNING_YES;
1505                         }
1506                         else
1507                         {
1508                                 local entity oldself;
1509                                 oldself = self;
1510                                 self = ent;
1511                                 assault_new_round();
1512                                 self = oldself;
1513                         }
1514                 }
1515         }
1516
1517         return status;
1518 }
1519
1520 // LMS winning condition: game terminates if and only if there's at most one
1521 // one player who's living lives. Top two scores being equal cancels the time
1522 // limit.
1523 float WinningCondition_LMS()
1524 {
1525         entity head, head2;
1526         float have_player;
1527         float have_players;
1528         float l;
1529
1530         have_player = FALSE;
1531         have_players = FALSE;
1532         l = LMS_NewPlayerLives();
1533
1534         head = find(world, classname, "player");
1535         if(head)
1536                 have_player = TRUE;
1537         head2 = find(head, classname, "player");
1538         if(head2)
1539                 have_players = TRUE;
1540
1541         if(have_player)
1542         {
1543                 // we have at least one player
1544                 if(have_players)
1545                 {
1546                         // two or more active players - continue with the game
1547                 }
1548                 else
1549                 {
1550                         // exactly one player?
1551
1552                         ClearWinners();
1553                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1554
1555                         if(l)
1556                         {
1557                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1558                                 return WINNING_NO;
1559                         }
1560                         else
1561                         {
1562                                 // a winner!
1563                                 // and assign him his first place
1564                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1565                                 return WINNING_YES;
1566                         }
1567                 }
1568         }
1569         else
1570         {
1571                 // nobody is playing at all...
1572                 if(l)
1573                 {
1574                         // wait for players...
1575                 }
1576                 else
1577                 {
1578                         // SNAFU (maybe a draw game?)
1579                         ClearWinners();
1580                         dprint("No players, ending game.\n");
1581                         return WINNING_YES;
1582                 }
1583         }
1584
1585         // When we get here, we have at least two players who are actually LIVING,
1586         // now check if the top two players have equal score.
1587         WinningConditionHelper();
1588
1589         ClearWinners();
1590         if(WinningConditionHelper_winner)
1591                 WinningConditionHelper_winner.winning = TRUE;
1592         if(WinningConditionHelper_equality)
1593                 return WINNING_NEVER;
1594
1595         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1596         return WINNING_NO;
1597 }
1598
1599 void ShuffleMaplist()
1600 {
1601         string result;
1602         float start;
1603         float litems;
1604         float selected;
1605         float i;
1606
1607         result = cvar_string("g_maplist");
1608         litems = tokenizebyseparator(result, " ");
1609
1610         for(start = 0; start < litems - 1; ++start)
1611         {
1612                 result = "";
1613
1614                 // select a random item
1615                 selected = floor(random() * (litems - start) + start);
1616
1617                 // shift this item to the place start
1618                 for(i = 0; i < start; ++i)
1619                         result = strcat(result, " ", argv(i));
1620                 result = strcat(result, " ", argv(selected));
1621                 for(i = start; i < litems; ++i)
1622                         if(i != selected)
1623                                 result = strcat(result, " ", argv(i));
1624                 result = substring(result, 1, strlen(result) - 1);
1625
1626                 litems = tokenizebyseparator(result, " ");
1627
1628                 //dprint(result, "\n");
1629         }
1630
1631         cvar_set("g_maplist", result);
1632 }
1633
1634 float leaderfrags;
1635 float WinningCondition_Scores(float limit)
1636 {
1637         // TODO make everything use THIS winning condition (except LMS)
1638         WinningConditionHelper();
1639
1640         if(teams_matter)
1641         {
1642                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1643                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1644                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1645                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1646         }
1647
1648         ClearWinners();
1649         if(WinningConditionHelper_winner)
1650                 WinningConditionHelper_winner.winning = 1;
1651         if(WinningConditionHelper_winnerteam >= 0)
1652                 SetWinners(team, WinningConditionHelper_winnerteam);
1653
1654         if(WinningConditionHelper_lowerisbetter)
1655         {
1656                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1657                 limit = -limit;
1658         }
1659
1660         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1661         // these modes always score in increments of 1, thus this makes sense
1662         {
1663                 if(leaderfrags != WinningConditionHelper_topscore)
1664                 {
1665                         leaderfrags = WinningConditionHelper_topscore;
1666
1667                         if (limit)
1668                         if (leaderfrags == limit - 1)
1669                                 play2all("announcer/robotic/1fragleft.wav");
1670                         else if (leaderfrags == limit - 2)
1671                                 play2all("announcer/robotic/2fragsleft.wav");
1672                         else if (leaderfrags == limit - 3)
1673                                 play2all("announcer/robotic/3fragsleft.wav");
1674                 }
1675         }
1676
1677         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1678 }
1679
1680 float WinningCondition_Race(float fraglimit)
1681 {
1682         float wc;
1683         entity p;
1684         wc = WinningCondition_Scores(fraglimit);
1685
1686         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1687         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1688         // do NOT support equality when the laps are all raced!
1689         {
1690                 FOR_EACH_PLAYER(p)
1691                         if not(p.race_completed)
1692                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1693                 return WINNING_YES;
1694         }
1695         return wc;
1696 }
1697
1698 void ReadyRestart();
1699 float WinningCondition_QualifyingThenRace(float limit)
1700 {
1701         float wc;
1702         wc = WinningCondition_Scores(limit);
1703
1704         // NEVER initiate overtime
1705         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1706         {
1707                 return WINNING_YES;
1708         }
1709
1710         return wc;
1711 }
1712
1713 float WinningCondition_RanOutOfSpawns()
1714 {
1715         entity head;
1716
1717         if(!have_team_spawns)
1718                 return WINNING_NO;
1719
1720         if(!some_spawn_has_been_used)
1721                 return WINNING_NO;
1722
1723         team1_score = team2_score = team3_score = team4_score = 0;
1724
1725         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1726         {
1727                 if(head.team == COLOR_TEAM1)
1728                         team1_score = 1;
1729                 else if(head.team == COLOR_TEAM2)
1730                         team2_score = 1;
1731                 else if(head.team == COLOR_TEAM3)
1732                         team3_score = 1;
1733                 else if(head.team == COLOR_TEAM4)
1734                         team4_score = 1;
1735         }
1736
1737         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1738         {
1739                 if(head.team == COLOR_TEAM1)
1740                         team1_score = 1;
1741                 else if(head.team == COLOR_TEAM2)
1742                         team2_score = 1;
1743                 else if(head.team == COLOR_TEAM3)
1744                         team3_score = 1;
1745                 else if(head.team == COLOR_TEAM4)
1746                         team4_score = 1;
1747         }
1748
1749         ClearWinners();
1750         if(team1_score + team2_score + team3_score + team4_score == 0)
1751         {
1752                 checkrules_equality = TRUE;
1753                 return WINNING_YES;
1754         }
1755         else if(team1_score + team2_score + team3_score + team4_score == 1)
1756         {
1757                 float t, i;
1758                 if(team1_score) t = COLOR_TEAM1;
1759                 if(team2_score) t = COLOR_TEAM2;
1760                 if(team3_score) t = COLOR_TEAM3;
1761                 if(team4_score) t = COLOR_TEAM4;
1762                 CheckAllowedTeams(world);
1763                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1764                 {
1765                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1766                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1767                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1768                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1769                 }
1770
1771                 AddWinners(team, t);
1772                 return WINNING_YES;
1773         }
1774         else
1775                 return WINNING_NO;
1776 }
1777
1778 /*
1779 ============
1780 CheckRules_World
1781
1782 Exit deathmatch games upon conditions
1783 ============
1784 */
1785 void CheckRules_World()
1786 {
1787         local float timelimit;
1788         local float fraglimit;
1789
1790         VoteThink();
1791         MapVote_Think();
1792
1793         SetDefaultAlpha();
1794
1795         /*
1796         MapVote_Think should now do that part
1797         if (intermission_running)
1798                 if (time >= intermission_exittime + 60)
1799                 {
1800                         if(!DoNextMapOverride())
1801                                 GotoNextMap();
1802                         return;
1803                 }
1804         */
1805
1806         if (gameover)   // someone else quit the game already
1807         {
1808                 if(player_count == 0) // Nobody there? Then let's go to the next map
1809                         MapVote_Start();
1810                         // this will actually check the player count in the next frame
1811                         // again, but this shouldn't hurt
1812                 return;
1813         }
1814
1815         timelimit = cvar("timelimit") * 60;
1816         fraglimit = cvar("fraglimit");
1817
1818         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1819         {
1820                 if(timelimit > 0)
1821                         timelimit = 0; // timelimit is not made for warmup
1822                 if(fraglimit > 0)
1823                         fraglimit = 0; // no fraglimit for now
1824         }
1825
1826         if(timelimit > 0)
1827         {
1828                 timelimit += game_starttime;
1829         }
1830         else if (timelimit < 0)
1831         {
1832                 // endmatch
1833                 NextLevel();
1834                 return;
1835         }
1836
1837         if(checkrules_suddendeathend)
1838         {
1839                 if(!checkrules_suddendeathwarning)
1840                 {
1841                         checkrules_suddendeathwarning = TRUE;
1842                         if(g_race && !g_race_qualifying)
1843                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1844                         else
1845                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1846                 }
1847         }
1848         else
1849         {
1850                 if (timelimit && time >= timelimit)
1851                 {
1852                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1853                         {
1854                                 float totalplayers;
1855                                 float playerswithlaps;
1856                                 float readyplayers;
1857                                 entity head;
1858                                 totalplayers = playerswithlaps = readyplayers = 0;
1859                                 FOR_EACH_PLAYER(head)
1860                                 {
1861                                         ++totalplayers;
1862                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1863                                                 ++playerswithlaps;
1864                                         if(head.ready)
1865                                                 ++readyplayers;
1866                                 }
1867
1868                                 // at least 2/3 of the players have completed a lap: start the RACE
1869                                 // otherwise, the players should end the qualifying on their own
1870                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1871                                 {
1872                                         checkrules_suddendeathend = 0;
1873                                         ReadyRestart(); // go to race
1874                                 }
1875                                 else
1876                                         InitiateOvertime();
1877                         }
1878                         else
1879                                 InitiateOvertime();
1880                 }
1881         }
1882
1883         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1884         {
1885                 NextLevel();
1886                 return;
1887         }
1888
1889         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1890         {
1891                 checkrules_oneminutewarning = TRUE;
1892                 play2all("announcer/robotic/1minuteremains.wav");
1893         }
1894
1895         checkrules_status = WinningCondition_RanOutOfSpawns();
1896         if(checkrules_status == WINNING_YES)
1897         {
1898                 bprint("Hey! Someone ran out of spawns!\n");
1899         }
1900         else if(g_race && !g_race_qualifying && timelimit >= 0)
1901         {
1902                 checkrules_status = WinningCondition_Race(fraglimit);
1903         }
1904         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1905         {
1906                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1907         }
1908         else if(g_assault)
1909         {
1910                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1911         }
1912         else if(g_lms)
1913         {
1914                 checkrules_status = WinningCondition_LMS();
1915         }
1916         else if (g_onslaught)
1917         {
1918                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1919         }
1920         else
1921         {
1922                 checkrules_status = WinningCondition_Scores(fraglimit);
1923         }
1924
1925         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1926         {
1927                 checkrules_status = WINNING_NEVER;
1928                 InitiateOvertime();
1929         }
1930
1931         if(checkrules_status == WINNING_NEVER)
1932                 // equality cases! Nobody wins if the overtime ends in a draw.
1933                 ClearWinners();
1934
1935         if(checkrules_suddendeathend)
1936                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1937                         checkrules_status = WINNING_YES;
1938
1939         if(checkrules_status == WINNING_YES)
1940                 NextLevel();
1941 };
1942
1943 float mapvote_nextthink;
1944 float mapvote_initialized;
1945 float mapvote_keeptwotime;
1946 float mapvote_timeout;
1947 string mapvote_message;
1948 string mapvote_screenshot_dir;
1949
1950 float mapvote_count;
1951 float mapvote_count_real;
1952 string mapvote_maps[MAPVOTE_COUNT];
1953 float mapvote_maps_suggested[MAPVOTE_COUNT];
1954 string mapvote_suggestions[MAPVOTE_COUNT];
1955 float mapvote_suggestion_ptr;
1956 float mapvote_maxlen;
1957 float mapvote_voters;
1958 float mapvote_votes[MAPVOTE_COUNT];
1959 float mapvote_run;
1960 float mapvote_detail;
1961 float mapvote_abstain;
1962 .float mapvote;
1963
1964 void MapVote_ClearAllVotes()
1965 {
1966         FOR_EACH_CLIENT(other)
1967                 other.mapvote = 0;
1968 }
1969
1970 string MapVote_Suggest(string m)
1971 {
1972         float i;
1973         if(m == "")
1974                 return "That's not how to use this command.";
1975         if(!cvar("g_maplist_votable_suggestions"))
1976                 return "Suggestions are not accepted on this server.";
1977         if(mapvote_initialized)
1978                 return "Can't suggest - voting is already in progress!";
1979         m = MapInfo_FixName(m);
1980         if(!m)
1981                 return "The map you suggested is not available on this server.";
1982         if(!cvar("g_maplist_votable_override_mostrecent"))
1983                 if(Map_IsRecent(m))
1984                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1985
1986         if(!MapInfo_CheckMap(m))
1987                 return "The map you suggested does not support the current game mode.";
1988         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1989                 if(mapvote_suggestions[i] == m)
1990                         return "This map was already suggested.";
1991         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1992         {
1993                 i = floor(random() * mapvote_suggestion_ptr);
1994         }
1995         else
1996         {
1997                 i = mapvote_suggestion_ptr;
1998                 mapvote_suggestion_ptr += 1;
1999         }
2000         if(mapvote_suggestions[i] != "")
2001                 strunzone(mapvote_suggestions[i]);
2002         mapvote_suggestions[i] = strzone(m);
2003         if(cvar("sv_eventlog"))
2004                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2005         return strcat("Suggestion of ", m, " accepted.");
2006 }
2007
2008 void MapVote_AddVotable(string nextMap, float isSuggestion)
2009 {
2010         float j;
2011         if(nextMap == "")
2012                 return;
2013         for(j = 0; j < mapvote_count; ++j)
2014                 if(mapvote_maps[j] == nextMap)
2015                         return;
2016         if(strlen(nextMap) > mapvote_maxlen)
2017                 mapvote_maxlen = strlen(nextMap);
2018         mapvote_maps[mapvote_count] = strzone(nextMap);
2019         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2020         mapvote_count += 1;
2021 }
2022
2023 void MapVote_Spawn();
2024 void MapVote_Init()
2025 {
2026         float i;
2027         float nmax, smax;
2028
2029         MapVote_ClearAllVotes();
2030
2031         mapvote_count = 0;
2032         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2033         mapvote_abstain = cvar("g_maplist_votable_abstain");
2034
2035         if(mapvote_abstain)
2036                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2037         else
2038                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2039         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2040
2041         if(mapvote_suggestion_ptr)
2042                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2043                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2044
2045         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2046                 MapVote_AddVotable(GetNextMap(), FALSE);
2047
2048         if(mapvote_count == 0)
2049         {
2050                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2051                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2052                 if(cvar("g_maplist_shuffle"))
2053                         ShuffleMaplist();
2054                 localcmd("\nmenu_cmd sync\n");
2055                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2056                         MapVote_AddVotable(GetNextMap(), FALSE);
2057         }
2058
2059         mapvote_count_real = mapvote_count;
2060         if(mapvote_abstain)
2061                 MapVote_AddVotable("don't care", 0);
2062
2063         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2064
2065         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2066         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2067         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2068                 mapvote_keeptwotime = 0;
2069         mapvote_message = "Choose a map and press its key!";
2070
2071         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2072         if(mapvote_screenshot_dir == "")
2073                 mapvote_screenshot_dir = "maps";
2074         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2075
2076         MapVote_Spawn();
2077 }
2078
2079 void MapVote_SendPicture(float id)
2080 {
2081         msg_entity = self;
2082         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2083         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2084         WriteByte(MSG_ONE, id);
2085         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2086 }
2087
2088 float GameCommand_MapVote(string cmd)
2089 {
2090         if(!intermission_running)
2091                 return FALSE;
2092
2093         if(cmd == "mv_getpic")
2094         {
2095                 MapVote_SendPicture(stof(argv(1)));
2096                 return TRUE;
2097         }
2098
2099         return FALSE;
2100 }
2101
2102 float MapVote_GetMapMask()
2103 {
2104         float mask, i, power;
2105         mask = 0;
2106         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2107                 if(mapvote_maps[i] != "")
2108                         mask |= power;
2109         return mask;
2110 }
2111
2112 entity mapvote_ent;
2113 float MapVote_SendEntity(entity to, float sf)
2114 {
2115         string mapfile, pakfile;
2116         float i, o;
2117
2118         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2119         WriteByte(MSG_ENTITY, sf);
2120
2121         if(sf & 1)
2122         {
2123                 // flag 1 == initialization
2124                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2125                 WriteByte(MSG_ENTITY, mapvote_count);
2126                 WriteByte(MSG_ENTITY, mapvote_abstain);
2127                 WriteByte(MSG_ENTITY, mapvote_detail);
2128                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2129                 if(mapvote_count <= 8)
2130                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2131                 else
2132                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2133                 for(i = 0; i < mapvote_count; ++i)
2134                         if(mapvote_maps[i] != "")
2135                         {
2136                                 WriteString(MSG_ENTITY, mapvote_maps[i]);
2137                                 mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2138                                 pakfile = whichpack(strcat(mapfile, ".tga"));
2139                                 if(pakfile == "")
2140                                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2141                                 if(pakfile == "")
2142                                         pakfile = whichpack(strcat(mapfile, ".png"));
2143                                 for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2144                                         pakfile = substring(pakfile, o, 999);
2145                                 WriteString(MSG_ENTITY, pakfile);
2146                         }
2147         }
2148
2149         if(sf & 2)
2150         {
2151                 // flag 2 == update of mask
2152                 if(mapvote_count <= 8)
2153                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2154                 else
2155                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2156         }
2157
2158         if(sf & 4)
2159         {
2160                 if(mapvote_detail)
2161                         for(i = 0; i < mapvote_count; ++i)
2162                                 if(mapvote_maps[i] != "")
2163                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2164
2165                 WriteByte(MSG_ENTITY, to.mapvote);
2166         }
2167
2168         return TRUE;
2169 }
2170
2171 void MapVote_Spawn()
2172 {
2173         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2174 }
2175
2176 void MapVote_TouchMask()
2177 {
2178         mapvote_ent.SendFlags |= 2;
2179 }
2180
2181 void MapVote_TouchVotes(entity voter)
2182 {
2183         mapvote_ent.SendFlags |= 4;
2184 }
2185
2186 float MapVote_Finished(float mappos)
2187 {
2188         string result;
2189         float i;
2190         float didntvote;
2191
2192         if(cvar("sv_eventlog"))
2193         {
2194                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2195                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2196                 didntvote = mapvote_voters;
2197                 for(i = 0; i < mapvote_count; ++i)
2198                         if(mapvote_maps[i] != "")
2199                         {
2200                                 didntvote -= mapvote_votes[i];
2201                                 if(i != mappos)
2202                                 {
2203                                         result = strcat(result, ":", mapvote_maps[i]);
2204                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2205                                 }
2206                         }
2207                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2208
2209                 GameLogEcho(result);
2210                 if(mapvote_maps_suggested[mappos])
2211                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2212         }
2213
2214         FOR_EACH_REALCLIENT(other)
2215                 FixClientCvars(other);
2216
2217         Map_Goto_SetStr(mapvote_maps[mappos]);
2218         Map_Goto();
2219         alreadychangedlevel = TRUE;
2220         return TRUE;
2221 }
2222 void MapVote_CheckRules_1()
2223 {
2224         float i;
2225
2226         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2227         {
2228                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2229                 mapvote_votes[i] = 0;
2230         }
2231
2232         mapvote_voters = 0;
2233         FOR_EACH_REALCLIENT(other)
2234         {
2235                 ++mapvote_voters;
2236                 if(other.mapvote)
2237                 {
2238                         i = other.mapvote - 1;
2239                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2240                         mapvote_votes[i] = mapvote_votes[i] + 1;
2241                 }
2242         }
2243 }
2244
2245 float MapVote_CheckRules_2()
2246 {
2247         float i;
2248         float firstPlace, secondPlace;
2249         float firstPlaceVotes, secondPlaceVotes;
2250         float mapvote_voters_real;
2251         string result;
2252
2253         mapvote_voters_real = mapvote_voters;
2254         if(mapvote_abstain)
2255                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2256
2257         RandomSelection_Init();
2258         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2259                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2260         firstPlace = RandomSelection_chosen_float;
2261         firstPlaceVotes = RandomSelection_best_priority;
2262         //dprint("First place: ", ftos(firstPlace), "\n");
2263         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2264
2265         RandomSelection_Init();
2266         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2267                 if(i != firstPlace)
2268                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2269         secondPlace = RandomSelection_chosen_float;
2270         secondPlaceVotes = RandomSelection_best_priority;
2271         //dprint("Second place: ", ftos(secondPlace), "\n");
2272         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2273
2274         if(firstPlace == -1)
2275                 error("No first place in map vote... WTF?");
2276
2277         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2278                 return MapVote_Finished(firstPlace);
2279
2280         if(mapvote_keeptwotime)
2281                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2282                 {
2283                         float didntvote;
2284                         MapVote_TouchMask();
2285                         mapvote_message = "Now decide between the TOP TWO!";
2286                         mapvote_keeptwotime = 0;
2287                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2288                         result = strcat(result, ":", ftos(firstPlaceVotes));
2289                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2290                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2291                         didntvote = mapvote_voters;
2292                         for(i = 0; i < mapvote_count; ++i)
2293                                 if(mapvote_maps[i] != "")
2294                                 {
2295                                         didntvote -= mapvote_votes[i];
2296                                         if(i != firstPlace)
2297                                                 if(i != secondPlace)
2298                                                 {
2299                                                         result = strcat(result, ":", mapvote_maps[i]);
2300                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2301                                                         if(i < mapvote_count_real)
2302                                                         {
2303                                                                 strunzone(mapvote_maps[i]);
2304                                                                 mapvote_maps[i] = "";
2305                                                         }
2306                                                 }
2307                                 }
2308                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2309                         if(cvar("sv_eventlog"))
2310                                 GameLogEcho(result);
2311                 }
2312
2313         return FALSE;
2314 }
2315 void MapVote_Tick()
2316 {
2317         float keeptwo;
2318         float totalvotes;
2319
2320         keeptwo = mapvote_keeptwotime;
2321         MapVote_CheckRules_1(); // count
2322         if(MapVote_CheckRules_2()) // decide
2323                 return;
2324
2325         totalvotes = 0;
2326         FOR_EACH_REALCLIENT(other)
2327         {
2328                 // hide scoreboard again
2329                 if(other.health != 2342)
2330                 {
2331                         other.health = 2342;
2332                         other.impulse = 0;
2333                         if(clienttype(other) == CLIENTTYPE_REAL)
2334                         {
2335                                 msg_entity = other;
2336                                 WriteByte(MSG_ONE, SVC_FINALE);
2337                                 WriteString(MSG_ONE, "");
2338                         }
2339                 }
2340
2341                 // notify about keep-two
2342                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2343                         play2(other, "misc/invshot.wav");
2344
2345                 // clear possibly invalid votes
2346                 if(mapvote_maps[other.mapvote - 1] == "")
2347                         other.mapvote = 0;
2348                 // use impulses as new vote
2349                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2350                         if(mapvote_maps[other.impulse - 1] != "")
2351                         {
2352                                 other.mapvote = other.impulse;
2353                                 MapVote_TouchVotes(other);
2354                         }
2355                 other.impulse = 0;
2356
2357                 if(other.mapvote)
2358                         ++totalvotes;
2359         }
2360
2361         MapVote_CheckRules_1(); // just count
2362 }
2363 void MapVote_Start()
2364 {
2365         if(mapvote_run)
2366                 return;
2367
2368         MapInfo_Enumerate();
2369         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2370                 mapvote_run = TRUE;
2371 }
2372 void MapVote_Think()
2373 {
2374         if(!mapvote_run)
2375                 return;
2376
2377         if(alreadychangedlevel)
2378                 return;
2379
2380         if(time < mapvote_nextthink)
2381                 return;
2382         //dprint("tick\n");
2383
2384         mapvote_nextthink = time + 0.5;
2385
2386         if(!mapvote_initialized)
2387         {
2388                 mapvote_initialized = TRUE;
2389                 if(DoNextMapOverride())
2390                         return;
2391                 if(!cvar("g_maplist_votable") || player_count <= 0)
2392                 {
2393                         GotoNextMap();
2394                         return;
2395                 }
2396                 MapVote_Init();
2397         }
2398
2399         MapVote_Tick();
2400 };
2401
2402 string GotoMap(string m)
2403 {
2404         if(!MapInfo_CheckMap(m))
2405                 return "The map you chose is not available on this server.";
2406         cvar_set("nextmap", m);
2407         cvar_set("timelimit", "-1");
2408         if(mapvote_initialized || alreadychangedlevel)
2409         {
2410                 if(DoNextMapOverride())
2411                         return "Map switch initiated.";
2412                 else
2413                         return "Hm... no. For some reason I like THIS map more.";
2414         }
2415         else
2416                 return "Map switch will happen after scoreboard.";
2417 }
2418
2419
2420 void EndFrame()
2421 {
2422         FOR_EACH_REALCLIENT(self)
2423         {
2424                 if(self.classname == "spectator")
2425                 {
2426                         if(self.enemy.typehitsound)
2427                                 play2(self, "misc/typehit.wav");
2428                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2429                                 play2(self, "misc/hit.wav");
2430                 }
2431                 else
2432                 {
2433                         if(self.typehitsound)
2434                                 play2(self, "misc/typehit.wav");
2435                         else if(self.hitsound && self.cvar_cl_hitsound)
2436                                 play2(self, "misc/hit.wav");
2437                 }
2438         }
2439         FOR_EACH_CLIENT(self)
2440         {
2441                 self.hitsound = FALSE;
2442                 self.typehitsound = FALSE;
2443         }
2444 }
2445
2446
2447 /*
2448  * RedirectionThink:
2449  * returns TRUE if redirecting
2450  */
2451 float redirection_timeout;
2452 float redirection_nextthink;
2453 float RedirectionThink()
2454 {
2455         float clients_found;
2456
2457         if(redirection_target == "")
2458                 return FALSE;
2459
2460         if(!redirection_timeout)
2461         {
2462                 cvar_set("sv_public", "-2");
2463                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2464                 if(redirection_target == "self")
2465                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2466                 else
2467                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2468         }
2469
2470         if(time < redirection_nextthink)
2471                 return TRUE;
2472
2473         redirection_nextthink = time + 1;
2474
2475         clients_found = 0;
2476         FOR_EACH_REALCLIENT(self)
2477         {
2478                 print("Redirecting: sending connect command to ", self.netname, "\n");
2479                 if(redirection_target == "self")
2480                         stuffcmd(self, "\ndisconnect; reconnect\n");
2481                 else
2482                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2483                 ++clients_found;
2484         }
2485
2486         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2487
2488         if(time > redirection_timeout || clients_found == 0)
2489                 localcmd("\nwait; wait; wait; quit\n");
2490
2491         return TRUE;
2492 }
2493
2494 void RestoreGame()
2495 {
2496         // Loaded from a save game
2497         // some things then break, so let's work around them...
2498
2499         // Progs DB (capture records)
2500         if(sv_cheats)
2501                 ServerProgsDB = db_create();
2502         else
2503                 ServerProgsDB = db_load("server.db");
2504
2505         // Mapinfo
2506         MapInfo_Shutdown();
2507         MapInfo_Enumerate();
2508         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2509 }
2510
2511 void SV_Shutdown()
2512 {
2513         if(world_initialized > 0)
2514         {
2515                 world_initialized = 0;
2516                 print("Saving persistent data...\n");
2517                 Ban_SaveBans();
2518                 if(!sv_cheats)
2519                         db_save(ServerProgsDB, "server.db");
2520                 if(cvar("developer"))
2521                         db_save(TemporaryDB, "server-temp.db");
2522                 db_close(ServerProgsDB);
2523                 db_close(TemporaryDB);
2524                 print("done!\n");
2525                 // tell the bot system the game is ending now
2526                 bot_endgame();
2527
2528                 MapInfo_Shutdown();
2529         }
2530         else if(world_initialized == 0)
2531         {
2532                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2533         }
2534 }