data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         world_initialized = -1; // don't complain
 345         cvar = cvar_builtin;
 346         cvar_string = cvar_string_builtin;
 347         cvar_set = cvar_set_builtin;
 348         dprint_load(); // load dprint status from cvar
 349
 350         remove = remove_unsafely;
 351
 352         entity e;
 353         e = spawn();
 354         e.think = GotoFirstMap;
 355         e.nextthink = time; // this is usually 1 at this point
 356
 357         e = spawn();
 358         e.classname = "info_player_deathmatch"; // safeguard against player joining
 359
 360         self.classname = "worldspawn"; // safeguard against various stuff ;)
 361
 362         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 363         MapInfo_Enumerate();
 364         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 365 }
 366
 367 void Map_MarkAsRecent(string m);
 368 float world_already_spawned;
 369 void RegisterWeapons();
 370 void Nagger_Init();
 371 void ClientInit_Spawn();
 372 void spawnfunc_worldspawn (void)
 373 {
 374         float fd, l, i, j, n;
 375         string s, col;
 376
 377         cvar = cvar_builtin;
 378         cvar_string = cvar_string_builtin;
 379         cvar_set = cvar_set_builtin;
 380         dprint_load(); // load dprint status from cvar
 381
 382         if(world_already_spawned)
 383                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 384         world_already_spawned = TRUE;
 385
 386         remove = remove_safely; // during spawning, watch what you remove!
 387
 388         if(cvar_string("cvar_check_default") != "bypass")
 389         {
 390                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 391                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 392
 393                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 394                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 395         }
 396
 397         compressShortVector_init();
 398
 399         local entity head;
 400         head = nextent(world);
 401         maxclients = 0;
 402         while(head)
 403         {
 404                 ++maxclients;
 405                 head = nextent(head);
 406         }
 407
 408         // needs to be done so early as they would still spawn
 409         RegisterWeapons();
 410
 411         if(sv_cheats)
 412                 ServerProgsDB = db_create();
 413         else
 414                 ServerProgsDB = db_load("server.db");
 415
 416         TemporaryDB = db_create();
 417
 418         /*
 419         TODO sound pack system
 420         // initialize sound pack system
 421         soundpack = cvar_string("g_soundpack");
 422         if(soundpack != "")
 423                 soundpack = strcat(soundpack, "/");
 424         soundpack = strzone(soundpack);
 425         */
 426
 427         // 0 normal
 428         lightstyle(0, "m");
 429
 430         // 1 FLICKER (first variety)
 431         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 432
 433         // 2 SLOW STRONG PULSE
 434         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 435
 436         // 3 CANDLE (first variety)
 437         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 438
 439         // 4 FAST STROBE
 440         lightstyle(4, "mamamamamama");
 441
 442         // 5 GENTLE PULSE 1
 443         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 444
 445         // 6 FLICKER (second variety)
 446         lightstyle(6, "nmonqnmomnmomomno");
 447
 448         // 7 CANDLE (second variety)
 449         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 450
 451         // 8 CANDLE (third variety)
 452         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 453
 454         // 9 SLOW STROBE (fourth variety)
 455         lightstyle(9, "aaaaaaaazzzzzzzz");
 456
 457         // 10 FLUORESCENT FLICKER
 458         lightstyle(10, "mmamammmmammamamaaamammma");
 459
 460         // 11 SLOW PULSE NOT FADE TO BLACK
 461         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 462
 463         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 464
 465         // 63 testing
 466         lightstyle(63, "a");
 467
 468         if(cvar("g_campaign"))
 469                 CampaignPreInit();
 470
 471         Map_MarkAsRecent(mapname);
 472
 473         precache_model ("null"); // we need this one before InitGameplayMode
 474         InitGameplayMode();
 475         readlevelcvars();
 476         GrappleHookInit();
 477
 478         player_count = 0;
 479         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 480         if(bot_waypoints_for_items == 1)
 481                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 482                         bot_waypoints_for_items = 0;
 483
 484         // for setting by mapinfo
 485         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 486         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 487
 488         precache();
 489
 490         WaypointSprite_Init();
 491
 492         //if (g_domination)
 493         //      dom_init();
 494
 495         GameLogInit(); // prepare everything
 496         if(cvar("sv_eventlog"))
 497         {
 498                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 499                 s = strcat(s, ftos(random()));
 500                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 501                 s = ":gameinfo:mutators:LIST";
 502                 if(cvar("g_grappling_hook"))
 503                         s = strcat(s, ":grappling_hook");
 504                 if(!cvar("g_use_ammunition"))
 505                         s = strcat(s, ":no_use_ammunition");
 506                 if(!cvar("g_pickup_items"))
 507                         s = strcat(s, ":no_pickup_items");
 508                 if(cvar("g_instagib"))
 509                         s = strcat(s, ":instagib");
 510                 if(cvar_string("g_weaponarena") != "0")
 511                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 512                 if(cvar("g_nixnex"))
 513                         s = strcat(s, ":nixnex");
 514                 if(cvar("g_vampire"))
 515                         s = strcat(s, ":vampire");
 516                 if(cvar("g_laserguided_missile"))
 517                         s = strcat(s, ":laserguided_missile");
 518                 if(cvar("g_norecoil"))
 519                         s = strcat(s, ":norecoil");
 520                 if(cvar("g_midair"))
 521                         s = strcat(s, ":midair");
 522                 if(cvar("g_minstagib"))
 523                         s = strcat(s, ":minstagib");
 524                 GameLogEcho(s);
 525                 GameLogEcho(":gameinfo:end");
 526         }
 527
 528         cvar_set("nextmap", "");
 529
 530         SetDefaultAlpha();
 531
 532         if(cvar("g_campaign"))
 533                 CampaignPostInit();
 534
 535         fteqcc_testbugs();
 536
 537         Ban_LoadBans();
 538
 539         //initialise globals related to sv_timeout
 540         sys_ticrate = cvar("sys_ticrate");
 541         orig_slowmo = cvar("slowmo");
 542
 543         MapInfo_Enumerate();
 544         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 545
 546         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 547         {
 548                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 549                 if(fd != -1)
 550                 {
 551                         while((s = fgets(fd)))
 552                         {
 553                                 l = tokenize_sane(s);
 554                                 if(l < 2)
 555                                         continue;
 556                                 if(argv(0) == "cd")
 557                                 {
 558                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 559                                         print("  cdtrack ", argv(2), "\n");
 560                                 }
 561                                 else if(argv(0) == "fog")
 562                                 {
 563                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 564                                         print("  \"fog\" \"", s, "\"\n");
 565                                 }
 566                                 else if(argv(0) == "set")
 567                                 {
 568                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 569                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 570                                 }
 571                                 else if(argv(0) != "//")
 572                                 {
 573                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 574                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 575                                 }
 576                         }
 577                         fclose(fd);
 578                 }
 579         }
 580
 581         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 582         addstat(STAT_WEAPONS, AS_INT, weapons);
 583         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 584         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 585         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 586         Nagger_Init();
 587
 588         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 589         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 590
 591         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 592
 593         next_pingtime = time + 5;
 594         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 595
 596         detect_maptype();
 597
 598         lsmaps_reply = "^7Maps available: ";
 599         for(i = 0, j = 0; i < MapInfo_count; ++i)
 600         {
 601                 if(MapInfo_Get_ByID(i))
 602                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 603                         {
 604                                 if(mod(i, 2))
 605                                         col = "^2";
 606                                 else
 607                                         col = "^3";
 608                                 ++j;
 609                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 610                         }
 611         }
 612         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 613
 614         maplist_reply = "^7Maps in list: ";
 615         n = tokenize_sane(cvar_string("g_maplist"));
 616         for(i = 0, j = 0; i < n; ++i)
 617         {
 618                 if(MapInfo_CheckMap(argv(i)))
 619                 {
 620                         if(mod(j, 2))
 621                                 col = "^2";
 622                         else
 623                                 col = "^3";
 624                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 625                         ++j;
 626                 }
 627         }
 628         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 629         MapInfo_ClearTemps();
 630
 631         records_reply = strzone(getrecords());
 632
 633         ClientInit_Spawn();
 634         RandomSeed_Spawn();
 635
 636         world_initialized = 1;
 637 }
 638
 639 void spawnfunc_light (void)
 640 {
 641         //makestatic (self); // Who the f___ did that?
 642         remove(self);
 643 }
 644
 645 float TryFile( string pFilename )
 646 {
 647         local float lHandle;
 648         dprint("TryFile(\"", pFilename, "\")\n");
 649         lHandle = fopen( pFilename, FILE_READ );
 650         if( lHandle != -1 ) {
 651                 fclose( lHandle );
 652                 return TRUE;
 653         } else {
 654                 return FALSE;
 655         }
 656 };
 657
 658 string GetGametype()
 659 {
 660         return GametypeNameFromType(game);
 661 }
 662
 663 string getmapname_stored;
 664 string GetMapname()
 665 {
 666         return mapname;
 667 }
 668
 669 float Map_Count, Map_Current;
 670 string Map_Current_Name;
 671
 672 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 673 float GetMaplistPosition()
 674 {
 675         float pos, idx;
 676         string map;
 677
 678         map = GetMapname();
 679         idx = cvar("g_maplist_index");
 680
 681         if(idx >= 0)
 682                 if(idx < Map_Count)
 683                         if(map == argv(idx))
 684                                 return idx;
 685
 686         for(pos = 0; pos < Map_Count; ++pos)
 687                 if(map == argv(pos))
 688                         return pos;
 689
 690         // resume normal maplist rotation if current map is not in g_maplist
 691         return idx;
 692 }
 693
 694 float MapHasRightSize(string map)
 695 {
 696         float fh;
 697         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 698         if(cvar("g_maplist_check_waypoints"))
 699         {
 700                 dprint("checkwp "); dprint(map);
 701                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 702                 if(fh < 0)
 703                 {
 704                         dprint(": no waypoints\n");
 705                         return FALSE;
 706                 }
 707                 dprint(": has waypoints\n");
 708                 fclose(fh);
 709         }
 710
 711         // open map size restriction file
 712         dprint("opensize "); dprint(map);
 713         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 714         if(fh >= 0)
 715         {
 716                 float mapmin, mapmax;
 717                 dprint(": ok, ");
 718                 mapmin = stof(fgets(fh));
 719                 mapmax = stof(fgets(fh));
 720                 fclose(fh);
 721                 if(player_count < mapmin)
 722                 {
 723                         dprint("not enough\n");
 724                         return FALSE;
 725                 }
 726                 if(player_count > mapmax)
 727                 {
 728                         dprint("too many\n");
 729                         return FALSE;
 730                 }
 731                 dprint("right size\n");
 732                 return TRUE;
 733         }
 734         dprint(": not found\n");
 735         return TRUE;
 736 }
 737
 738 string Map_Filename(float position)
 739 {
 740         return strcat("maps/", argv(position), ".bsp");
 741 }
 742
 743 string strwords(string s, float w)
 744 {
 745         float endpos;
 746         for(endpos = 0; w && endpos >= 0; --w)
 747                 endpos = strstrofs(s, " ", endpos + 1);
 748         if(endpos < 0)
 749                 return s;
 750         else
 751                 return substring(s, 0, endpos);
 752 }
 753
 754 float strhasword(string s, string w)
 755 {
 756         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 757 }
 758
 759 void Map_MarkAsRecent(string m)
 760 {
 761         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 762 }
 763
 764 float Map_IsRecent(string m)
 765 {
 766         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 767 }
 768
 769 float Map_Check(float position, float pass)
 770 {
 771         string filename;
 772         string map_next;
 773         map_next = argv(position);
 774         if(pass <= 1)
 775         {
 776                 if(Map_IsRecent(map_next))
 777                         return 0;
 778         }
 779         filename = Map_Filename(position);
 780         if(MapInfo_CheckMap(map_next))
 781         {
 782                 if(pass == 2)
 783                         return 1;
 784                 if(MapHasRightSize(map_next))
 785                         return 1;
 786                 return 0;
 787         }
 788         else
 789                 dprint( "Couldn't select '", filename, "'..\n" );
 790
 791         return 0;
 792 }
 793
 794 void Map_Goto_SetStr(string nextmapname)
 795 {
 796         if(getmapname_stored != "")
 797                 strunzone(getmapname_stored);
 798         if(nextmapname == "")
 799                 getmapname_stored = "";
 800         else
 801                 getmapname_stored = strzone(nextmapname);
 802 }
 803
 804 void Map_Goto_SetFloat(float position)
 805 {
 806         cvar_set("g_maplist_index", ftos(position));
 807         Map_Goto_SetStr(argv(position));
 808 }
 809
 810 void GameResetCfg()
 811 {
 812         // settings persist, except...
 813         localcmd("\nsettemp_restore\n");
 814 };
 815
 816 void Map_Goto()
 817 {
 818         GameResetCfg();
 819         MapInfo_LoadMap(getmapname_stored);
 820 }
 821
 822 // return codes of map selectors:
 823 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 824 //   -2 = permanent failure
 825 float() MaplistMethod_Iterate = // usual method
 826 {
 827         float pass, i;
 828
 829         for(pass = 1; pass <= 2; ++pass)
 830         {
 831                 for(i = 1; i < Map_Count; ++i)
 832                 {
 833                         float mapindex;
 834                         mapindex = mod(i + Map_Current, Map_Count);
 835                         if(Map_Check(mapindex, pass))
 836                                 return mapindex;
 837                 }
 838         }
 839         return -1;
 840 }
 841
 842 float() MaplistMethod_Repeat = // fallback method
 843 {
 844         if(Map_Check(Map_Current, 2))
 845                 return Map_Current;
 846         return -2;
 847 }
 848
 849 float() MaplistMethod_Random = // random map selection
 850 {
 851         float i, imax;
 852
 853         imax = 42;
 854
 855         for(i = 0; i <= imax; ++i)
 856         {
 857                 float mapindex;
 858                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 859                 if(Map_Check(mapindex, 1))
 860                         return mapindex;
 861         }
 862         return -1;
 863 }
 864
 865 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 866 // the exponent sets a bias on the map selection:
 867 // the higher the exponent, the less likely "shortly repeated" same maps are
 868 {
 869         float i, j, imax, insertpos;
 870
 871         imax = 42;
 872
 873         for(i = 0; i <= imax; ++i)
 874         {
 875                 string newlist;
 876
 877                 // now reinsert this at another position
 878                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 879                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 880                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 881                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 882
 883                 // insert the current map there
 884                 newlist = "";
 885                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 886                         newlist = strcat(newlist, " ", argv(j));
 887                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 888                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 889                         newlist = strcat(newlist, " ", argv(j));
 890                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 891                 cvar_set("g_maplist", newlist);
 892                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 893
 894                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 895                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 896                 if(Map_Check(Map_Current, 1))
 897                         return Map_Current;
 898         }
 899         return -1;
 900 }
 901
 902 void Maplist_Init()
 903 {
 904         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 905         if(Map_Count == 0)
 906         {
 907                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 908                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 909                 if(cvar("g_maplist_shuffle"))
 910                         ShuffleMaplist();
 911                 localcmd("\nmenu_cmd sync\n");
 912                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 913         }
 914         if(Map_Count == 0)
 915                 error("empty maplist, cannot select a new map");
 916         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 917
 918         if(Map_Current_Name)
 919                 strunzone(Map_Current_Name);
 920         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 921         // this may or may not be correct, but who cares, in the worst case a map
 922         // isn't chosen in the first pass that should have been
 923 }
 924
 925 string GetNextMap()
 926 {
 927         float nextMap;
 928
 929         Maplist_Init();
 930         nextMap = -1;
 931
 932         if(nextMap == -1)
 933                 if(cvar("g_maplist_shuffle") > 0)
 934                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 935
 936         if(nextMap == -1)
 937                 if(cvar("g_maplist_selectrandom"))
 938                         nextMap = MaplistMethod_Random();
 939
 940         if(nextMap == -1)
 941                 nextMap = MaplistMethod_Iterate();
 942
 943         if(nextMap == -1)
 944                 nextMap = MaplistMethod_Repeat();
 945
 946         if(nextMap >= 0)
 947         {
 948                 Map_Goto_SetFloat(nextMap);
 949                 return getmapname_stored;
 950         }
 951
 952         return "";
 953 };
 954
 955 float DoNextMapOverride()
 956 {
 957         if(cvar("g_campaign"))
 958         {
 959                 CampaignPostIntermission();
 960                 alreadychangedlevel = TRUE;
 961                 return TRUE;
 962         }
 963         if(cvar("quit_when_empty"))
 964         {
 965                 if(player_count <= currentbots)
 966                 {
 967                         localcmd("quit\n");
 968                         alreadychangedlevel = TRUE;
 969                         return TRUE;
 970                 }
 971         }
 972         if(cvar_string("quit_and_redirect") != "")
 973         {
 974                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 975                 alreadychangedlevel = TRUE;
 976                 return TRUE;
 977         }
 978         if (cvar("samelevel")) // if samelevel is set, stay on same level
 979         {
 980                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 981                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 982                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 983                 localcmd("restart\n");
 984                 //changelevel (mapname);
 985                 alreadychangedlevel = TRUE;
 986                 return TRUE;
 987         }
 988         if(cvar_string("nextmap") != "")
 989                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 990                 {
 991                         Map_Goto_SetStr(cvar_string("nextmap"));
 992                         Map_Goto();
 993                         alreadychangedlevel = TRUE;
 994                         return TRUE;
 995                 }
 996         if(cvar("lastlevel"))
 997         {
 998                 GameResetCfg();
 999                 localcmd("set lastlevel 0\ntogglemenu\n");
1000                 alreadychangedlevel = TRUE;
1001                 return TRUE;
1002         }
1003         return FALSE;
1004 };
1005
1006 void GotoNextMap()
1007 {
1008         //local string nextmap;
1009         //local float n, nummaps;
1010         //local string s;
1011         if (alreadychangedlevel)
1012                 return;
1013         alreadychangedlevel = TRUE;
1014
1015         {
1016                 string nextMap;
1017                 float allowReset;
1018
1019                 for(allowReset = 1; allowReset >= 0; --allowReset)
1020                 {
1021                         nextMap = GetNextMap();
1022                         if(nextMap != "")
1023                                 break;
1024
1025                         if(allowReset)
1026                         {
1027                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1028                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1029                                 if(cvar("g_maplist_shuffle"))
1030                                         ShuffleMaplist();
1031                                 localcmd("\nmenu_cmd sync\n");
1032                         }
1033                         else
1034                         {
1035                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1036                         }
1037                 }
1038                 Map_Goto();
1039         }
1040 };
1041
1042
1043 /*
1044 ============
1045 IntermissionThink
1046
1047 When the player presses attack or jump, change to the next level
1048 ============
1049 */
1050 .float autoscreenshot;
1051 void() MapVote_Start;
1052 void() MapVote_Think;
1053 float mapvote_initialized;
1054 void IntermissionThink()
1055 {
1056         FixIntermissionClient(self);
1057
1058         if(cvar("sv_autoscreenshot"))
1059         if(self.autoscreenshot > 0)
1060         if(time > self.autoscreenshot)
1061         {
1062                 self.autoscreenshot = -1;
1063                 if(clienttype(self) == CLIENTTYPE_REAL)
1064                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1065                 return;
1066         }
1067
1068         if (time < intermission_exittime)
1069                 return;
1070
1071         if(!mapvote_initialized)
1072                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1073                         return;
1074
1075         MapVote_Start();
1076 };
1077
1078 /*
1079 ============
1080 FindIntermission
1081
1082 Returns the entity to view from
1083 ============
1084 */
1085 /*
1086 entity FindIntermission()
1087 {
1088         local   entity spot;
1089         local   float cyc;
1090
1091 // look for info_intermission first
1092         spot = find (world, classname, "info_intermission");
1093         if (spot)
1094         {       // pick a random one
1095                 cyc = random() * 4;
1096                 while (cyc > 1)
1097                 {
1098                         spot = find (spot, classname, "info_intermission");
1099                         if (!spot)
1100                                 spot = find (spot, classname, "info_intermission");
1101                         cyc = cyc - 1;
1102                 }
1103                 return spot;
1104         }
1105
1106 // then look for the start position
1107         spot = find (world, classname, "info_player_start");
1108         if (spot)
1109                 return spot;
1110
1111 // testinfo_player_start is only found in regioned levels
1112         spot = find (world, classname, "testplayerstart");
1113         if (spot)
1114                 return spot;
1115
1116 // then look for the start position
1117         spot = find (world, classname, "info_player_deathmatch");
1118         if (spot)
1119                 return spot;
1120
1121         //objerror ("FindIntermission: no spot");
1122         return world;
1123 };
1124 */
1125
1126 /*
1127 ===============================================================================
1128
1129 RULES
1130
1131 ===============================================================================
1132 */
1133
1134 void DumpStats(float final)
1135 {
1136         local float file;
1137         local string s;
1138         local float to_console;
1139         local float to_eventlog;
1140         local float to_file;
1141         local float i;
1142
1143         to_console = cvar("sv_logscores_console");
1144         to_eventlog = cvar("sv_eventlog");
1145         to_file = cvar("sv_logscores_file");
1146
1147         if(!final)
1148         {
1149                 to_console = TRUE; // always print printstats replies
1150                 to_eventlog = FALSE; // but never print them to the event log
1151         }
1152
1153         if(to_eventlog)
1154                 if(cvar("sv_eventlog_console"))
1155                         to_console = FALSE; // otherwise we get the output twice
1156
1157         if(final)
1158                 s = ":scores:";
1159         else
1160                 s = ":status:";
1161         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1162
1163         if(to_console)
1164                 print(s, "\n");
1165         if(to_eventlog)
1166                 GameLogEcho(s);
1167         if(to_file)
1168         {
1169                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1170                 if(file == -1)
1171                         to_file = FALSE;
1172                 else
1173                         fputs(file, strcat(s, "\n"));
1174         }
1175
1176         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1177         if(to_console)
1178                 print(s, "\n");
1179         if(to_eventlog)
1180                 GameLogEcho(s);
1181         if(to_file)
1182                 fputs(file, strcat(s, "\n"));
1183
1184         FOR_EACH_CLIENT(other)
1185         {
1186                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1187                 {
1188                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1189                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1190                         if(other.classname == "player" || g_arena || g_lms)
1191                                 s = strcat(s, ftos(other.team), ":");
1192                         else
1193                                 s = strcat(s, "spectator:");
1194
1195                         if(to_console)
1196                                 print(s, other.netname, "\n");
1197                         if(to_eventlog)
1198                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1199                         if(to_file)
1200                                 fputs(file, strcat(s, other.netname, "\n"));
1201                 }
1202         }
1203
1204         if(teams_matter)
1205         {
1206                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1207                 if(to_console)
1208                         print(s, "\n");
1209                 if(to_eventlog)
1210                         GameLogEcho(s);
1211                 if(to_file)
1212                         fputs(file, strcat(s, "\n"));
1213
1214                 for(i = 1; i < 16; ++i)
1215                 {
1216                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1217                         s = strcat(s, ":", ftos(i));
1218                         if(to_console)
1219                                 print(s, "\n");
1220                         if(to_eventlog)
1221                                 GameLogEcho(s);
1222                         if(to_file)
1223                                 fputs(file, strcat(s, "\n"));
1224                 }
1225         }
1226
1227         if(to_console)
1228                 print(":end\n");
1229         if(to_eventlog)
1230                 GameLogEcho(":end");
1231         if(to_file)
1232         {
1233                 fputs(file, ":end\n");
1234                 fclose(file);
1235         }
1236 }
1237
1238 void FixIntermissionClient(entity e)
1239 {
1240         string s;
1241         if(!e.autoscreenshot) // initial call
1242         {
1243                 e.angles = e.v_angle;
1244                 e.angles_x = -e.angles_x;
1245                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1246                 e.health = -2342;
1247                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1248                 e.solid = SOLID_NOT;
1249                 e.movetype = MOVETYPE_NONE;
1250                 e.takedamage = DAMAGE_NO;
1251                 if(e.weaponentity)
1252                 {
1253                         e.weaponentity.effects = EF_NODRAW;
1254                         if (e.weaponentity.weaponentity)
1255                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1256                 }
1257                 if(clienttype(e) == CLIENTTYPE_REAL)
1258                 {
1259                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1260                         s = cvar_string("sv_intermission_cdtrack");
1261                         if(s != "")
1262                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1263                         msg_entity = e;
1264                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1265                 }
1266         }
1267
1268         //e.velocity = '0 0 0';
1269         //e.fixangle = TRUE;
1270
1271         // TODO halt weapon animation
1272 }
1273
1274
1275 /*
1276 go to the next level for deathmatch
1277 only called if a time or frag limit has expired
1278 */
1279 void NextLevel()
1280 {
1281         float minTotalFrags;
1282         float maxTotalFrags;
1283         float score;
1284         float f;
1285
1286         gameover = TRUE;
1287
1288         intermission_running = 1;
1289
1290 // enforce a wait time before allowing changelevel
1291         if(player_count > 0)
1292                 intermission_exittime = time + cvar("sv_mapchange_delay");
1293         else
1294                 intermission_exittime = -1;
1295
1296         /*
1297         WriteByte (MSG_ALL, SVC_CDTRACK);
1298         WriteByte (MSG_ALL, 3);
1299         WriteByte (MSG_ALL, 3);
1300         // done in FixIntermission
1301         */
1302
1303         //pos = FindIntermission ();
1304
1305         VoteReset();
1306
1307         DumpStats(TRUE);
1308
1309         if(cvar("sv_eventlog"))
1310                 GameLogEcho(":gameover");
1311
1312         GameLogClose();
1313
1314         FOR_EACH_CLIENT(other)
1315         {
1316                 FixIntermissionClient(other);
1317
1318                 if(other.winning)
1319                         bprint(other.netname, " ^7wins.\n");
1320         }
1321
1322         minTotalFrags = 0;
1323         maxTotalFrags = 0;
1324         FOR_EACH_PLAYER(other)
1325         {
1326                 if(maxTotalFrags < other.totalfrags)
1327                         maxTotalFrags = other.totalfrags;
1328                 if(minTotalFrags > other.totalfrags)
1329                         minTotalFrags = other.totalfrags;
1330         }
1331
1332         if(!currentbots)
1333         {
1334                 FOR_EACH_PLAYER(other)
1335                 {
1336                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1337                         f = bound(0, other.play_time / max(time, 1), 1);
1338                         // store some statistics?
1339                 }
1340         }
1341
1342         if(cvar("g_campaign"))
1343                 CampaignPreIntermission();
1344
1345         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1346 };
1347
1348 /*
1349 ============
1350 CheckRules_Player
1351
1352 Exit deathmatch games upon conditions
1353 ============
1354 */
1355 void CheckRules_Player()
1356 {
1357         if (gameover)   // someone else quit the game already
1358                 return;
1359
1360         if(self.deadflag == DEAD_NO)
1361                 self.play_time += frametime;
1362
1363         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1364         //   (div0: and that in CheckRules_World please)
1365 };
1366
1367 float checkrules_oneminutewarning;
1368
1369 float checkrules_equality;
1370 float checkrules_suddendeathwarning;
1371 float checkrules_suddendeathend;
1372 float checkrules_overtimesadded; //how many overtimes have been already added
1373 float checkrules_status;
1374
1375 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1376 float WINNING_YES = 1; // winner found
1377 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1378 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1379
1380 void InitiateOvertime()
1381 {
1382         // Check first whether normal overtimes could be added before initiating suddendeath mode
1383         // - for this timelimit_overtime needs to be >0 of course
1384         // - also check the winning condition calculated in the previous frame and only add normal overtime
1385         //   again, if at the point at which timelimit would be extended again, still no winner was found
1386         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1387         {
1388                 ++checkrules_overtimesadded;
1389                 //add one more overtime by simply extending the timelimit
1390                 float tl;
1391                 tl = cvar("timelimit");
1392                 tl += cvar("timelimit_overtime");
1393                 cvar_set("timelimit", ftos(tl));
1394                 string minutesPlural;
1395                 if (cvar("timelimit_overtime") == 1)
1396                         minutesPlural = " ^3minute";
1397                 else
1398                         minutesPlural = " ^3minutes";
1399
1400                 bcenterprint(
1401                         strcat(
1402                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1403                                 ftos(cvar("timelimit_overtime")),
1404                                 minutesPlural,
1405                                 " to the game!"
1406                         )
1407                 );
1408         }
1409         else
1410         {
1411                 if(!checkrules_suddendeathend)
1412                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1413         }
1414 }
1415
1416 float GetWinningCode(float fraglimitreached, float equality)
1417 {
1418         if(equality)
1419                 if(fraglimitreached)
1420                         return WINNING_STARTSUDDENDEATHOVERTIME;
1421                 else
1422                         return WINNING_NEVER;
1423         else
1424                 if(fraglimitreached)
1425                         return WINNING_YES;
1426                 else
1427                         return WINNING_NO;
1428 }
1429
1430 // set the .winning flag for exactly those players with a given field value
1431 void SetWinners(.float field, float value)
1432 {
1433         entity head;
1434         FOR_EACH_PLAYER(head)
1435                 head.winning = (head.field == value);
1436 }
1437
1438 // set the .winning flag for those players with a given field value
1439 void AddWinners(.float field, float value)
1440 {
1441         entity head;
1442         FOR_EACH_PLAYER(head)
1443                 if(head.field == value)
1444                         head.winning = 1;
1445 }
1446
1447 // clear the .winning flags
1448 void ClearWinners(void)
1449 {
1450         entity head;
1451         FOR_EACH_PLAYER(head)
1452                 head.winning = 0;
1453 }
1454
1455 // Onslaught winning condition:
1456 // game terminates if only one team has a working generator (or none)
1457 float WinningCondition_Onslaught()
1458 {
1459         entity head;
1460         local float t1, t2, t3, t4;
1461
1462         WinningConditionHelper(); // set worldstatus
1463
1464         // first check if the game has ended
1465         t1 = t2 = t3 = t4 = 0;
1466         head = find(world, classname, "onslaught_generator");
1467         while (head)
1468         {
1469                 if (head.health > 0)
1470                 {
1471                         if (head.team == COLOR_TEAM1) t1 = 1;
1472                         if (head.team == COLOR_TEAM2) t2 = 1;
1473                         if (head.team == COLOR_TEAM3) t3 = 1;
1474                         if (head.team == COLOR_TEAM4) t4 = 1;
1475                 }
1476                 head = find(head, classname, "onslaught_generator");
1477         }
1478         if (t1 + t2 + t3 + t4 < 2)
1479         {
1480                 // game over, only one team remains (or none)
1481                 ClearWinners();
1482                 if (t1) SetWinners(team, COLOR_TEAM1);
1483                 if (t2) SetWinners(team, COLOR_TEAM2);
1484                 if (t3) SetWinners(team, COLOR_TEAM3);
1485                 if (t4) SetWinners(team, COLOR_TEAM4);
1486                 dprint("Have a winner, ending game.\n");
1487                 return WINNING_YES;
1488         }
1489
1490         // Two or more teams remain
1491         return WINNING_NO;
1492 }
1493
1494 float LMS_NewPlayerLives()
1495 {
1496         float fl;
1497         fl = cvar("fraglimit");
1498         if(fl == 0)
1499                 fl = 999;
1500
1501         // first player has left the game for dying too much? Nobody else can get in.
1502         if(lms_lowest_lives < 1)
1503                 return 0;
1504
1505         if(!cvar("g_lms_join_anytime"))
1506                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1507                         return 0;
1508
1509         return bound(1, lms_lowest_lives, fl);
1510 }
1511
1512 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1513 // they win. Otherwise the defending team wins once the timelimit passes.
1514 void assault_new_round();
1515 float WinningCondition_Assault()
1516 {
1517         local float status;
1518
1519         WinningConditionHelper(); // set worldstatus
1520
1521         status = WINNING_NO;
1522         // as the timelimit has not yet passed just assume the defending team will win
1523         if(assault_attacker_team == COLOR_TEAM1)
1524         {
1525                 SetWinners(team, COLOR_TEAM2);
1526         }
1527         else
1528         {
1529                 SetWinners(team, COLOR_TEAM1);
1530         }
1531
1532         local entity ent;
1533         ent = find(world, classname, "target_assault_roundend");
1534         if(ent)
1535         {
1536                 if(ent.winning) // round end has been triggered by attacking team
1537                 {
1538                         bprint("ASSAULT: round completed...\n");
1539                         SetWinners(team, assault_attacker_team);
1540
1541                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1542
1543                         if(ent.cnt == 1) // this was the second round
1544                         {
1545                                 status = WINNING_YES;
1546                         }
1547                         else
1548                         {
1549                                 local entity oldself;
1550                                 oldself = self;
1551                                 self = ent;
1552                                 assault_new_round();
1553                                 self = oldself;
1554                         }
1555                 }
1556         }
1557
1558         return status;
1559 }
1560
1561 // LMS winning condition: game terminates if and only if there's at most one
1562 // one player who's living lives. Top two scores being equal cancels the time
1563 // limit.
1564 float WinningCondition_LMS()
1565 {
1566         entity head, head2;
1567         float have_player;
1568         float have_players;
1569         float l;
1570
1571         have_player = FALSE;
1572         have_players = FALSE;
1573         l = LMS_NewPlayerLives();
1574
1575         head = find(world, classname, "player");
1576         if(head)
1577                 have_player = TRUE;
1578         head2 = find(head, classname, "player");
1579         if(head2)
1580                 have_players = TRUE;
1581
1582         if(have_player)
1583         {
1584                 // we have at least one player
1585                 if(have_players)
1586                 {
1587                         // two or more active players - continue with the game
1588                 }
1589                 else
1590                 {
1591                         // exactly one player?
1592
1593                         ClearWinners();
1594                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1595
1596                         if(l)
1597                         {
1598                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1599                                 return WINNING_NO;
1600                         }
1601                         else
1602                         {
1603                                 // a winner!
1604                                 // and assign him his first place
1605                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1606                                 return WINNING_YES;
1607                         }
1608                 }
1609         }
1610         else
1611         {
1612                 // nobody is playing at all...
1613                 if(l)
1614                 {
1615                         // wait for players...
1616                 }
1617                 else
1618                 {
1619                         // SNAFU (maybe a draw game?)
1620                         ClearWinners();
1621                         dprint("No players, ending game.\n");
1622                         return WINNING_YES;
1623                 }
1624         }
1625
1626         // When we get here, we have at least two players who are actually LIVING,
1627         // now check if the top two players have equal score.
1628         WinningConditionHelper();
1629
1630         ClearWinners();
1631         if(WinningConditionHelper_winner)
1632                 WinningConditionHelper_winner.winning = TRUE;
1633         if(WinningConditionHelper_equality)
1634                 return WINNING_NEVER;
1635
1636         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1637         return WINNING_NO;
1638 }
1639
1640 void ShuffleMaplist()
1641 {
1642         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1643 }
1644
1645 float leaderfrags;
1646 float WinningCondition_Scores(float limit)
1647 {
1648         // TODO make everything use THIS winning condition (except LMS)
1649         WinningConditionHelper();
1650
1651         if(teams_matter)
1652         {
1653                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1654                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1655                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1656                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1657         }
1658
1659         ClearWinners();
1660         if(WinningConditionHelper_winner)
1661                 WinningConditionHelper_winner.winning = 1;
1662         if(WinningConditionHelper_winnerteam >= 0)
1663                 SetWinners(team, WinningConditionHelper_winnerteam);
1664
1665         if(WinningConditionHelper_lowerisbetter)
1666         {
1667                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1668                 limit = -limit;
1669         }
1670
1671         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1672         // these modes always score in increments of 1, thus this makes sense
1673         {
1674                 if(leaderfrags != WinningConditionHelper_topscore)
1675                 {
1676                         leaderfrags = WinningConditionHelper_topscore;
1677
1678                         if (limit)
1679                         if (leaderfrags == limit - 1)
1680                                 play2all("announcer/robotic/1fragleft.wav");
1681                         else if (leaderfrags == limit - 2)
1682                                 play2all("announcer/robotic/2fragsleft.wav");
1683                         else if (leaderfrags == limit - 3)
1684                                 play2all("announcer/robotic/3fragsleft.wav");
1685                 }
1686         }
1687
1688         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1689 }
1690
1691 float WinningCondition_Race(float fraglimit)
1692 {
1693         float wc;
1694         entity p;
1695         wc = WinningCondition_Scores(fraglimit);
1696
1697         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1698         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1699         // do NOT support equality when the laps are all raced!
1700         {
1701                 FOR_EACH_PLAYER(p)
1702                         if not(p.race_completed)
1703                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1704                 return WINNING_YES;
1705         }
1706         return wc;
1707 }
1708
1709 void ReadyRestart();
1710 float WinningCondition_QualifyingThenRace(float limit)
1711 {
1712         float wc;
1713         wc = WinningCondition_Scores(limit);
1714
1715         // NEVER initiate overtime
1716         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1717         {
1718                 return WINNING_YES;
1719         }
1720
1721         return wc;
1722 }
1723
1724 float WinningCondition_RanOutOfSpawns()
1725 {
1726         entity head;
1727
1728         if(!have_team_spawns)
1729                 return WINNING_NO;
1730
1731         if(!some_spawn_has_been_used)
1732                 return WINNING_NO;
1733
1734         team1_score = team2_score = team3_score = team4_score = 0;
1735
1736         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1737         {
1738                 if(head.team == COLOR_TEAM1)
1739                         team1_score = 1;
1740                 else if(head.team == COLOR_TEAM2)
1741                         team2_score = 1;
1742                 else if(head.team == COLOR_TEAM3)
1743                         team3_score = 1;
1744                 else if(head.team == COLOR_TEAM4)
1745                         team4_score = 1;
1746         }
1747
1748         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1749         {
1750                 if(head.team == COLOR_TEAM1)
1751                         team1_score = 1;
1752                 else if(head.team == COLOR_TEAM2)
1753                         team2_score = 1;
1754                 else if(head.team == COLOR_TEAM3)
1755                         team3_score = 1;
1756                 else if(head.team == COLOR_TEAM4)
1757                         team4_score = 1;
1758         }
1759
1760         ClearWinners();
1761         if(team1_score + team2_score + team3_score + team4_score == 0)
1762         {
1763                 checkrules_equality = TRUE;
1764                 return WINNING_YES;
1765         }
1766         else if(team1_score + team2_score + team3_score + team4_score == 1)
1767         {
1768                 float t, i;
1769                 if(team1_score) t = COLOR_TEAM1;
1770                 if(team2_score) t = COLOR_TEAM2;
1771                 if(team3_score) t = COLOR_TEAM3;
1772                 if(team4_score) t = COLOR_TEAM4;
1773                 CheckAllowedTeams(world);
1774                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1775                 {
1776                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1777                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1778                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1779                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1780                 }
1781
1782                 AddWinners(team, t);
1783                 return WINNING_YES;
1784         }
1785         else
1786                 return WINNING_NO;
1787 }
1788
1789 /*
1790 ============
1791 CheckRules_World
1792
1793 Exit deathmatch games upon conditions
1794 ============
1795 */
1796 void CheckRules_World()
1797 {
1798         local float timelimit;
1799         local float fraglimit;
1800
1801         VoteThink();
1802         MapVote_Think();
1803
1804         SetDefaultAlpha();
1805
1806         /*
1807         MapVote_Think should now do that part
1808         if (intermission_running)
1809                 if (time >= intermission_exittime + 60)
1810                 {
1811                         if(!DoNextMapOverride())
1812                                 GotoNextMap();
1813                         return;
1814                 }
1815         */
1816
1817         if (gameover)   // someone else quit the game already
1818         {
1819                 if(player_count == 0) // Nobody there? Then let's go to the next map
1820                         MapVote_Start();
1821                         // this will actually check the player count in the next frame
1822                         // again, but this shouldn't hurt
1823                 return;
1824         }
1825
1826         timelimit = cvar("timelimit") * 60;
1827         fraglimit = cvar("fraglimit");
1828
1829         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1830         {
1831                 if(timelimit > 0)
1832                         timelimit = 0; // timelimit is not made for warmup
1833                 if(fraglimit > 0)
1834                         fraglimit = 0; // no fraglimit for now
1835         }
1836
1837         if(timelimit > 0)
1838         {
1839                 timelimit += game_starttime;
1840         }
1841         else if (timelimit < 0)
1842         {
1843                 // endmatch
1844                 NextLevel();
1845                 return;
1846         }
1847
1848         if(checkrules_suddendeathend)
1849         {
1850                 if(!checkrules_suddendeathwarning)
1851                 {
1852                         checkrules_suddendeathwarning = TRUE;
1853                         if(g_race && !g_race_qualifying)
1854                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1855                         else
1856                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1857                 }
1858         }
1859         else
1860         {
1861                 if (timelimit && time >= timelimit)
1862                 {
1863                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1864                         {
1865                                 float totalplayers;
1866                                 float playerswithlaps;
1867                                 float readyplayers;
1868                                 entity head;
1869                                 totalplayers = playerswithlaps = readyplayers = 0;
1870                                 FOR_EACH_PLAYER(head)
1871                                 {
1872                                         ++totalplayers;
1873                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1874                                                 ++playerswithlaps;
1875                                         if(head.ready)
1876                                                 ++readyplayers;
1877                                 }
1878
1879                                 // at least 2/3 of the players have completed a lap: start the RACE
1880                                 // otherwise, the players should end the qualifying on their own
1881                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1882                                 {
1883                                         checkrules_suddendeathend = 0;
1884                                         ReadyRestart(); // go to race
1885                                 }
1886                                 else
1887                                         InitiateOvertime();
1888                         }
1889                         else
1890                                 InitiateOvertime();
1891                 }
1892         }
1893
1894         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1895         {
1896                 NextLevel();
1897                 return;
1898         }
1899
1900         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1901         {
1902                 checkrules_oneminutewarning = TRUE;
1903                 play2all("announcer/robotic/1minuteremains.wav");
1904         }
1905
1906         checkrules_status = WinningCondition_RanOutOfSpawns();
1907         if(checkrules_status == WINNING_YES)
1908         {
1909                 bprint("Hey! Someone ran out of spawns!\n");
1910         }
1911         else if(g_race && !g_race_qualifying && timelimit >= 0)
1912         {
1913                 checkrules_status = WinningCondition_Race(fraglimit);
1914         }
1915         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1916         {
1917                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1918         }
1919         else if(g_assault)
1920         {
1921                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1922         }
1923         else if(g_lms)
1924         {
1925                 checkrules_status = WinningCondition_LMS();
1926         }
1927         else if (g_onslaught)
1928         {
1929                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1930         }
1931         else
1932         {
1933                 checkrules_status = WinningCondition_Scores(fraglimit);
1934         }
1935
1936         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1937         {
1938                 checkrules_status = WINNING_NEVER;
1939                 InitiateOvertime();
1940         }
1941
1942         if(checkrules_status == WINNING_NEVER)
1943                 // equality cases! Nobody wins if the overtime ends in a draw.
1944                 ClearWinners();
1945
1946         if(checkrules_suddendeathend)
1947                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1948                         checkrules_status = WINNING_YES;
1949
1950         if(checkrules_status == WINNING_YES)
1951                 NextLevel();
1952 };
1953
1954 float mapvote_nextthink;
1955 float mapvote_initialized;
1956 float mapvote_keeptwotime;
1957 float mapvote_timeout;
1958 string mapvote_message;
1959 string mapvote_screenshot_dir;
1960
1961 float mapvote_count;
1962 float mapvote_count_real;
1963 string mapvote_maps[MAPVOTE_COUNT];
1964 float mapvote_maps_suggested[MAPVOTE_COUNT];
1965 string mapvote_suggestions[MAPVOTE_COUNT];
1966 float mapvote_suggestion_ptr;
1967 float mapvote_maxlen;
1968 float mapvote_voters;
1969 float mapvote_votes[MAPVOTE_COUNT];
1970 float mapvote_run;
1971 float mapvote_detail;
1972 float mapvote_abstain;
1973 .float mapvote;
1974
1975 void MapVote_ClearAllVotes()
1976 {
1977         FOR_EACH_CLIENT(other)
1978                 other.mapvote = 0;
1979 }
1980
1981 string MapVote_Suggest(string m)
1982 {
1983         float i;
1984         if(m == "")
1985                 return "That's not how to use this command.";
1986         if(!cvar("g_maplist_votable_suggestions"))
1987                 return "Suggestions are not accepted on this server.";
1988         if(mapvote_initialized)
1989                 return "Can't suggest - voting is already in progress!";
1990         m = MapInfo_FixName(m);
1991         if(!m)
1992                 return "The map you suggested is not available on this server.";
1993         if(!cvar("g_maplist_votable_override_mostrecent"))
1994                 if(Map_IsRecent(m))
1995                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1996
1997         if(!MapInfo_CheckMap(m))
1998                 return "The map you suggested does not support the current game mode.";
1999         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2000                 if(mapvote_suggestions[i] == m)
2001                         return "This map was already suggested.";
2002         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2003         {
2004                 i = floor(random() * mapvote_suggestion_ptr);
2005         }
2006         else
2007         {
2008                 i = mapvote_suggestion_ptr;
2009                 mapvote_suggestion_ptr += 1;
2010         }
2011         if(mapvote_suggestions[i] != "")
2012                 strunzone(mapvote_suggestions[i]);
2013         mapvote_suggestions[i] = strzone(m);
2014         if(cvar("sv_eventlog"))
2015                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2016         return strcat("Suggestion of ", m, " accepted.");
2017 }
2018
2019 void MapVote_AddVotable(string nextMap, float isSuggestion)
2020 {
2021         float j;
2022         if(nextMap == "")
2023                 return;
2024         for(j = 0; j < mapvote_count; ++j)
2025                 if(mapvote_maps[j] == nextMap)
2026                         return;
2027         if(strlen(nextMap) > mapvote_maxlen)
2028                 mapvote_maxlen = strlen(nextMap);
2029         mapvote_maps[mapvote_count] = strzone(nextMap);
2030         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2031         mapvote_count += 1;
2032 }
2033
2034 void MapVote_Spawn();
2035 void MapVote_Init()
2036 {
2037         float i;
2038         float nmax, smax;
2039
2040         MapVote_ClearAllVotes();
2041
2042         mapvote_count = 0;
2043         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2044         mapvote_abstain = cvar("g_maplist_votable_abstain");
2045
2046         if(mapvote_abstain)
2047                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2048         else
2049                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2050         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2051
2052         if(mapvote_suggestion_ptr)
2053                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2054                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2055
2056         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2057                 MapVote_AddVotable(GetNextMap(), FALSE);
2058
2059         if(mapvote_count == 0)
2060         {
2061                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2062                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2063                 if(cvar("g_maplist_shuffle"))
2064                         ShuffleMaplist();
2065                 localcmd("\nmenu_cmd sync\n");
2066                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2067                         MapVote_AddVotable(GetNextMap(), FALSE);
2068         }
2069
2070         mapvote_count_real = mapvote_count;
2071         if(mapvote_abstain)
2072                 MapVote_AddVotable("don't care", 0);
2073
2074         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2075
2076         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2077         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2078         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2079                 mapvote_keeptwotime = 0;
2080         mapvote_message = "Choose a map and press its key!";
2081
2082         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2083         if(mapvote_screenshot_dir == "")
2084                 mapvote_screenshot_dir = "maps";
2085         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2086
2087         MapVote_Spawn();
2088 }
2089
2090 void MapVote_SendPicture(float id)
2091 {
2092         msg_entity = self;
2093         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2094         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2095         WriteByte(MSG_ONE, id);
2096         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2097 }
2098
2099 float GameCommand_MapVote(string cmd)
2100 {
2101         if(!intermission_running)
2102                 return FALSE;
2103
2104         if(cmd == "mv_getpic")
2105         {
2106                 MapVote_SendPicture(stof(argv(1)));
2107                 return TRUE;
2108         }
2109
2110         return FALSE;
2111 }
2112
2113 float MapVote_GetMapMask()
2114 {
2115         float mask, i, power;
2116         mask = 0;
2117         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2118                 if(mapvote_maps[i] != "")
2119                         mask |= power;
2120         return mask;
2121 }
2122
2123 entity mapvote_ent;
2124 float MapVote_SendEntity(entity to, float sf)
2125 {
2126         string mapfile, pakfile;
2127         float i, o;
2128
2129         if(sf & 1)
2130                 sf &~= 2; // if we send 1, we don't need to also send 2
2131
2132         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2133         WriteByte(MSG_ENTITY, sf);
2134
2135         if(sf & 1)
2136         {
2137                 // flag 1 == initialization
2138                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2139                 WriteByte(MSG_ENTITY, mapvote_count);
2140                 WriteByte(MSG_ENTITY, mapvote_abstain);
2141                 WriteByte(MSG_ENTITY, mapvote_detail);
2142                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2143                 if(mapvote_count <= 8)
2144                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2145                 else
2146                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2147                 for(i = 0; i < mapvote_count; ++i)
2148                         if(mapvote_maps[i] != "")
2149                         {
2150                                 if(mapvote_abstain && i == mapvote_count - 1)
2151                                 {
2152                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2153                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2154                                 }
2155                                 else
2156                                 {
2157                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2158                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2159                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2160                                         if(pakfile == "")
2161                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2162                                         if(pakfile == "")
2163                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2164                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2165                                                 pakfile = substring(pakfile, o, 999);
2166                                         WriteString(MSG_ENTITY, pakfile);
2167                                 }
2168                         }
2169         }
2170
2171         if(sf & 2)
2172         {
2173                 // flag 2 == update of mask
2174                 if(mapvote_count <= 8)
2175                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2176                 else
2177                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2178         }
2179
2180         if(sf & 4)
2181         {
2182                 if(mapvote_detail)
2183                         for(i = 0; i < mapvote_count; ++i)
2184                                 if(mapvote_maps[i] != "")
2185                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2186
2187                 WriteByte(MSG_ENTITY, to.mapvote);
2188         }
2189
2190         return TRUE;
2191 }
2192
2193 void MapVote_Spawn()
2194 {
2195         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2196 }
2197
2198 void MapVote_TouchMask()
2199 {
2200         mapvote_ent.SendFlags |= 2;
2201 }
2202
2203 void MapVote_TouchVotes(entity voter)
2204 {
2205         mapvote_ent.SendFlags |= 4;
2206 }
2207
2208 float MapVote_Finished(float mappos)
2209 {
2210         string result;
2211         float i;
2212         float didntvote;
2213
2214         if(cvar("sv_eventlog"))
2215         {
2216                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2217                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2218                 didntvote = mapvote_voters;
2219                 for(i = 0; i < mapvote_count; ++i)
2220                         if(mapvote_maps[i] != "")
2221                         {
2222                                 didntvote -= mapvote_votes[i];
2223                                 if(i != mappos)
2224                                 {
2225                                         result = strcat(result, ":", mapvote_maps[i]);
2226                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2227                                 }
2228                         }
2229                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2230
2231                 GameLogEcho(result);
2232                 if(mapvote_maps_suggested[mappos])
2233                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2234         }
2235
2236         FOR_EACH_REALCLIENT(other)
2237                 FixClientCvars(other);
2238
2239         Map_Goto_SetStr(mapvote_maps[mappos]);
2240         Map_Goto();
2241         alreadychangedlevel = TRUE;
2242         return TRUE;
2243 }
2244 void MapVote_CheckRules_1()
2245 {
2246         float i;
2247
2248         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2249         {
2250                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2251                 mapvote_votes[i] = 0;
2252         }
2253
2254         mapvote_voters = 0;
2255         FOR_EACH_REALCLIENT(other)
2256         {
2257                 ++mapvote_voters;
2258                 if(other.mapvote)
2259                 {
2260                         i = other.mapvote - 1;
2261                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2262                         mapvote_votes[i] = mapvote_votes[i] + 1;
2263                 }
2264         }
2265 }
2266
2267 float MapVote_CheckRules_2()
2268 {
2269         float i;
2270         float firstPlace, secondPlace;
2271         float firstPlaceVotes, secondPlaceVotes;
2272         float mapvote_voters_real;
2273         string result;
2274
2275         if(mapvote_count_real == 1)
2276                 return MapVote_Finished(0);
2277
2278         mapvote_voters_real = mapvote_voters;
2279         if(mapvote_abstain)
2280                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2281
2282         RandomSelection_Init();
2283         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2284                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2285         firstPlace = RandomSelection_chosen_float;
2286         firstPlaceVotes = RandomSelection_best_priority;
2287         //dprint("First place: ", ftos(firstPlace), "\n");
2288         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2289
2290         RandomSelection_Init();
2291         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2292                 if(i != firstPlace)
2293                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2294         secondPlace = RandomSelection_chosen_float;
2295         secondPlaceVotes = RandomSelection_best_priority;
2296         //dprint("Second place: ", ftos(secondPlace), "\n");
2297         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2298
2299         if(firstPlace == -1)
2300                 error("No first place in map vote... WTF?");
2301
2302         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2303                 return MapVote_Finished(firstPlace);
2304
2305         if(mapvote_keeptwotime)
2306                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2307                 {
2308                         float didntvote;
2309                         MapVote_TouchMask();
2310                         mapvote_message = "Now decide between the TOP TWO!";
2311                         mapvote_keeptwotime = 0;
2312                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2313                         result = strcat(result, ":", ftos(firstPlaceVotes));
2314                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2315                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2316                         didntvote = mapvote_voters;
2317                         for(i = 0; i < mapvote_count; ++i)
2318                                 if(mapvote_maps[i] != "")
2319                                 {
2320                                         didntvote -= mapvote_votes[i];
2321                                         if(i != firstPlace)
2322                                                 if(i != secondPlace)
2323                                                 {
2324                                                         result = strcat(result, ":", mapvote_maps[i]);
2325                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2326                                                         if(i < mapvote_count_real)
2327                                                         {
2328                                                                 strunzone(mapvote_maps[i]);
2329                                                                 mapvote_maps[i] = "";
2330                                                         }
2331                                                 }
2332                                 }
2333                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2334                         if(cvar("sv_eventlog"))
2335                                 GameLogEcho(result);
2336                 }
2337
2338         return FALSE;
2339 }
2340 void MapVote_Tick()
2341 {
2342         float keeptwo;
2343         float totalvotes;
2344
2345         keeptwo = mapvote_keeptwotime;
2346         MapVote_CheckRules_1(); // count
2347         if(MapVote_CheckRules_2()) // decide
2348                 return;
2349
2350         totalvotes = 0;
2351         FOR_EACH_REALCLIENT(other)
2352         {
2353                 // hide scoreboard again
2354                 if(other.health != 2342)
2355                 {
2356                         other.health = 2342;
2357                         other.impulse = 0;
2358                         if(clienttype(other) == CLIENTTYPE_REAL)
2359                         {
2360                                 msg_entity = other;
2361                                 WriteByte(MSG_ONE, SVC_FINALE);
2362                                 WriteString(MSG_ONE, "");
2363                         }
2364                 }
2365
2366                 // clear possibly invalid votes
2367                 if(mapvote_maps[other.mapvote - 1] == "")
2368                         other.mapvote = 0;
2369                 // use impulses as new vote
2370                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2371                         if(mapvote_maps[other.impulse - 1] != "")
2372                         {
2373                                 other.mapvote = other.impulse;
2374                                 MapVote_TouchVotes(other);
2375                         }
2376                 other.impulse = 0;
2377
2378                 if(other.mapvote)
2379                         ++totalvotes;
2380         }
2381
2382         MapVote_CheckRules_1(); // just count
2383 }
2384 void MapVote_Start()
2385 {
2386         if(mapvote_run)
2387                 return;
2388
2389         MapInfo_Enumerate();
2390         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2391                 mapvote_run = TRUE;
2392 }
2393 void MapVote_Think()
2394 {
2395         if(!mapvote_run)
2396                 return;
2397
2398         if(alreadychangedlevel)
2399                 return;
2400
2401         if(time < mapvote_nextthink)
2402                 return;
2403         //dprint("tick\n");
2404
2405         mapvote_nextthink = time + 0.5;
2406
2407         if(!mapvote_initialized)
2408         {
2409                 mapvote_initialized = TRUE;
2410                 if(DoNextMapOverride())
2411                         return;
2412                 if(!cvar("g_maplist_votable") || player_count <= 0)
2413                 {
2414                         GotoNextMap();
2415                         return;
2416                 }
2417                 MapVote_Init();
2418         }
2419
2420         MapVote_Tick();
2421 };
2422
2423 string GotoMap(string m)
2424 {
2425         if(!MapInfo_CheckMap(m))
2426                 return "The map you chose is not available on this server.";
2427         cvar_set("nextmap", m);
2428         cvar_set("timelimit", "-1");
2429         if(mapvote_initialized || alreadychangedlevel)
2430         {
2431                 if(DoNextMapOverride())
2432                         return "Map switch initiated.";
2433                 else
2434                         return "Hm... no. For some reason I like THIS map more.";
2435         }
2436         else
2437                 return "Map switch will happen after scoreboard.";
2438 }
2439
2440
2441 void EndFrame()
2442 {
2443         FOR_EACH_REALCLIENT(self)
2444         {
2445                 if(self.classname == "spectator")
2446                 {
2447                         if(self.enemy.typehitsound)
2448                                 play2(self, "misc/typehit.wav");
2449                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2450                                 play2(self, "misc/hit.wav");
2451                 }
2452                 else
2453                 {
2454                         if(self.typehitsound)
2455                                 play2(self, "misc/typehit.wav");
2456                         else if(self.hitsound && self.cvar_cl_hitsound)
2457                                 play2(self, "misc/hit.wav");
2458                 }
2459         }
2460         FOR_EACH_CLIENT(self)
2461         {
2462                 self.hitsound = FALSE;
2463                 self.typehitsound = FALSE;
2464         }
2465 }
2466
2467
2468 /*
2469  * RedirectionThink:
2470  * returns TRUE if redirecting
2471  */
2472 float redirection_timeout;
2473 float redirection_nextthink;
2474 float RedirectionThink()
2475 {
2476         float clients_found;
2477
2478         if(redirection_target == "")
2479                 return FALSE;
2480
2481         if(!redirection_timeout)
2482         {
2483                 cvar_set("sv_public", "-2");
2484                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2485                 if(redirection_target == "self")
2486                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2487                 else
2488                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2489         }
2490
2491         if(time < redirection_nextthink)
2492                 return TRUE;
2493
2494         redirection_nextthink = time + 1;
2495
2496         clients_found = 0;
2497         FOR_EACH_REALCLIENT(self)
2498         {
2499                 print("Redirecting: sending connect command to ", self.netname, "\n");
2500                 if(redirection_target == "self")
2501                         stuffcmd(self, "\ndisconnect; reconnect\n");
2502                 else
2503                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2504                 ++clients_found;
2505         }
2506
2507         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2508
2509         if(time > redirection_timeout || clients_found == 0)
2510                 localcmd("\nwait; wait; wait; quit\n");
2511
2512         return TRUE;
2513 }
2514
2515 void RestoreGame()
2516 {
2517         // Loaded from a save game
2518         // some things then break, so let's work around them...
2519
2520         // Progs DB (capture records)
2521         if(sv_cheats)
2522                 ServerProgsDB = db_create();
2523         else
2524                 ServerProgsDB = db_load("server.db");
2525
2526         // Mapinfo
2527         MapInfo_Shutdown();
2528         MapInfo_Enumerate();
2529         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2530 }
2531
2532 void SV_Shutdown()
2533 {
2534         if(world_initialized > 0)
2535         {
2536                 world_initialized = 0;
2537                 print("Saving persistent data...\n");
2538                 Ban_SaveBans();
2539                 if(!sv_cheats)
2540                         db_save(ServerProgsDB, "server.db");
2541                 if(cvar("developer"))
2542                         db_save(TemporaryDB, "server-temp.db");
2543                 db_close(ServerProgsDB);
2544                 db_close(TemporaryDB);
2545                 print("done!\n");
2546                 // tell the bot system the game is ending now
2547                 bot_endgame();
2548
2549                 MapInfo_Shutdown();
2550         }
2551         else if(world_initialized == 0)
2552         {
2553                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2554         }
2555 }