data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 // cvar_set("_sv_init", "0");
 139                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 140                 // to this "init" map on a dedicated server will cause no permanent
 141                 // harm
 142                 if(cvar("g_maplist_shuffle"))
 143                         ShuffleMaplist();
 144                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 145
 146                 cvar_set("nextmap", argv(0));
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         dprint_load(); // load dprint status from cvar
 345         world_initialized = -1; // don't complain
 346         remove = remove_unsafely;
 347
 348         entity e;
 349         e = spawn();
 350         e.think = GotoFirstMap;
 351         e.nextthink = time; // this is usually 1 at this point
 352
 353         e = spawn();
 354         e.classname = "info_player_deathmatch"; // safeguard against player joining
 355
 356         self.classname = "worldspawn"; // safeguard against various stuff ;)
 357 }
 358
 359 void Map_MarkAsRecent(string m);
 360 float world_already_spawned;
 361 void RegisterWeapons();
 362 void Nagger_Init();
 363 void ClientInit_Spawn();
 364 void spawnfunc_worldspawn (void)
 365 {
 366         float fd, l, i, j, n;
 367         string s, col;
 368
 369         dprint_load(); // load dprint status from cvar
 370
 371         if(world_already_spawned)
 372                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 373         world_already_spawned = TRUE;
 374
 375         remove = remove_safely; // during spawning, watch what you remove!
 376
 377         if(cvar_string("cvar_check_default") != "bypass")
 378         {
 379                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 380                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 381
 382                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 383                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 384         }
 385
 386         compressShortVector_init();
 387
 388         local entity head;
 389         head = nextent(world);
 390         maxclients = 0;
 391         while(head)
 392         {
 393                 ++maxclients;
 394                 head = nextent(head);
 395         }
 396
 397         // needs to be done so early as they would still spawn
 398         RegisterWeapons();
 399
 400         if(sv_cheats)
 401                 ServerProgsDB = db_create();
 402         else
 403                 ServerProgsDB = db_load("server.db");
 404
 405         TemporaryDB = db_create();
 406
 407         /*
 408         TODO sound pack system
 409         // initialize sound pack system
 410         soundpack = cvar_string("g_soundpack");
 411         if(soundpack != "")
 412                 soundpack = strcat(soundpack, "/");
 413         soundpack = strzone(soundpack);
 414         */
 415
 416         // 0 normal
 417         lightstyle(0, "m");
 418
 419         // 1 FLICKER (first variety)
 420         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 421
 422         // 2 SLOW STRONG PULSE
 423         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 424
 425         // 3 CANDLE (first variety)
 426         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 427
 428         // 4 FAST STROBE
 429         lightstyle(4, "mamamamamama");
 430
 431         // 5 GENTLE PULSE 1
 432         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 433
 434         // 6 FLICKER (second variety)
 435         lightstyle(6, "nmonqnmomnmomomno");
 436
 437         // 7 CANDLE (second variety)
 438         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 439
 440         // 8 CANDLE (third variety)
 441         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 442
 443         // 9 SLOW STROBE (fourth variety)
 444         lightstyle(9, "aaaaaaaazzzzzzzz");
 445
 446         // 10 FLUORESCENT FLICKER
 447         lightstyle(10, "mmamammmmammamamaaamammma");
 448
 449         // 11 SLOW PULSE NOT FADE TO BLACK
 450         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 451
 452         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 453
 454         // 63 testing
 455         lightstyle(63, "a");
 456
 457         if(cvar("g_campaign"))
 458                 CampaignPreInit();
 459
 460         Map_MarkAsRecent(mapname);
 461
 462         precache_model ("null"); // we need this one before InitGameplayMode
 463         InitGameplayMode();
 464         readlevelcvars();
 465         GrappleHookInit();
 466
 467         player_count = 0;
 468         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 469         if(bot_waypoints_for_items == 1)
 470                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 471                         bot_waypoints_for_items = 0;
 472
 473         // for setting by mapinfo
 474         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 475         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 476
 477         precache();
 478
 479         WaypointSprite_Init();
 480
 481         //if (g_domination)
 482         //      dom_init();
 483
 484         GameLogInit(); // prepare everything
 485         if(cvar("sv_eventlog"))
 486         {
 487                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 488                 s = strcat(s, ftos(random()));
 489                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 490                 s = ":gameinfo:mutators:LIST";
 491                 if(cvar("g_grappling_hook"))
 492                         s = strcat(s, ":grappling_hook");
 493                 if(!cvar("g_use_ammunition"))
 494                         s = strcat(s, ":no_use_ammunition");
 495                 if(!cvar("g_pickup_items"))
 496                         s = strcat(s, ":no_pickup_items");
 497                 if(cvar("g_instagib"))
 498                         s = strcat(s, ":instagib");
 499                 if(cvar_string("g_weaponarena") != "0")
 500                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 501                 if(cvar("g_nixnex"))
 502                         s = strcat(s, ":nixnex");
 503                 if(cvar("g_vampire"))
 504                         s = strcat(s, ":vampire");
 505                 if(cvar("g_laserguided_missile"))
 506                         s = strcat(s, ":laserguided_missile");
 507                 if(cvar("g_norecoil"))
 508                         s = strcat(s, ":norecoil");
 509                 if(cvar("g_midair"))
 510                         s = strcat(s, ":midair");
 511                 if(cvar("g_minstagib"))
 512                         s = strcat(s, ":minstagib");
 513                 GameLogEcho(s);
 514                 GameLogEcho(":gameinfo:end");
 515         }
 516
 517         cvar_set("nextmap", "");
 518
 519         SetDefaultAlpha();
 520
 521         if(cvar("g_campaign"))
 522                 CampaignPostInit();
 523
 524         fteqcc_testbugs();
 525
 526         Ban_LoadBans();
 527
 528         //initialise globals related to sv_timeout
 529         sys_ticrate = cvar("sys_ticrate");
 530         orig_slowmo = cvar("slowmo");
 531
 532         MapInfo_Enumerate();
 533         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 534
 535         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 536         {
 537                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 538                 if(fd != -1)
 539                 {
 540                         while((s = fgets(fd)))
 541                         {
 542                                 l = tokenize_sane(s);
 543                                 if(l < 2)
 544                                         continue;
 545                                 if(argv(0) == "cd")
 546                                 {
 547                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 548                                         print("  cdtrack ", argv(2), "\n");
 549                                 }
 550                                 else if(argv(0) == "fog")
 551                                 {
 552                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 553                                         print("  \"fog\" \"", s, "\"\n");
 554                                 }
 555                                 else if(argv(0) == "set")
 556                                 {
 557                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 558                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 559                                 }
 560                                 else if(argv(0) != "//")
 561                                 {
 562                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 563                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 564                                 }
 565                         }
 566                         fclose(fd);
 567                 }
 568         }
 569
 570         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 571         addstat(STAT_WEAPONS, AS_INT, weapons);
 572         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 573         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 574         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 575         Nagger_Init();
 576
 577         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 578         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 579
 580         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 581
 582         next_pingtime = time + 5;
 583         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 584
 585         detect_maptype();
 586
 587         lsmaps_reply = "^7Maps available: ";
 588         for(i = 0, j = 0; i < MapInfo_count; ++i)
 589         {
 590                 if(MapInfo_Get_ByID(i))
 591                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 592                         {
 593                                 if(mod(i, 2))
 594                                         col = "^2";
 595                                 else
 596                                         col = "^3";
 597                                 ++j;
 598                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 599                         }
 600         }
 601         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 602
 603         maplist_reply = "^7Maps in list: ";
 604         n = tokenize_sane(cvar_string("g_maplist"));
 605         for(i = 0, j = 0; i < n; ++i)
 606         {
 607                 if(MapInfo_CheckMap(argv(i)))
 608                 {
 609                         if(mod(j, 2))
 610                                 col = "^2";
 611                         else
 612                                 col = "^3";
 613                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 614                         ++j;
 615                 }
 616         }
 617         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 618
 619         records_reply = strzone(getrecords());
 620
 621         ClientInit_Spawn();
 622         RandomSeed_Spawn();
 623
 624         world_initialized = 1;
 625 }
 626
 627 void spawnfunc_light (void)
 628 {
 629         //makestatic (self); // Who the f___ did that?
 630         remove(self);
 631 }
 632
 633 float TryFile( string pFilename )
 634 {
 635         local float lHandle;
 636         dprint("TryFile(\"", pFilename, "\")\n");
 637         lHandle = fopen( pFilename, FILE_READ );
 638         if( lHandle != -1 ) {
 639                 fclose( lHandle );
 640                 return TRUE;
 641         } else {
 642                 return FALSE;
 643         }
 644 };
 645
 646 string GetGametype()
 647 {
 648         return GametypeNameFromType(game);
 649 }
 650
 651 string getmapname_stored;
 652 string GetMapname()
 653 {
 654         return mapname;
 655 }
 656
 657 float Map_Count, Map_Current;
 658 string Map_Current_Name;
 659
 660 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 661 float GetMaplistPosition()
 662 {
 663         float pos, idx;
 664         string map;
 665
 666         map = GetMapname();
 667         idx = cvar("g_maplist_index");
 668
 669         if(idx >= 0)
 670                 if(idx < Map_Count)
 671                         if(map == argv(idx))
 672                                 return idx;
 673
 674         for(pos = 0; pos < Map_Count; ++pos)
 675                 if(map == argv(pos))
 676                         return pos;
 677
 678         // resume normal maplist rotation if current map is not in g_maplist
 679         return idx;
 680 }
 681
 682 float MapHasRightSize(string map)
 683 {
 684         float fh;
 685         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 686         if(cvar("g_maplist_check_waypoints"))
 687         {
 688                 dprint("checkwp "); dprint(map);
 689                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 690                 if(fh < 0)
 691                 {
 692                         dprint(": no waypoints\n");
 693                         return FALSE;
 694                 }
 695                 dprint(": has waypoints\n");
 696                 fclose(fh);
 697         }
 698
 699         // open map size restriction file
 700         dprint("opensize "); dprint(map);
 701         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 702         if(fh >= 0)
 703         {
 704                 float mapmin, mapmax;
 705                 dprint(": ok, ");
 706                 mapmin = stof(fgets(fh));
 707                 mapmax = stof(fgets(fh));
 708                 fclose(fh);
 709                 if(player_count < mapmin)
 710                 {
 711                         dprint("not enough\n");
 712                         return FALSE;
 713                 }
 714                 if(player_count > mapmax)
 715                 {
 716                         dprint("too many\n");
 717                         return FALSE;
 718                 }
 719                 dprint("right size\n");
 720                 return TRUE;
 721         }
 722         dprint(": not found\n");
 723         return TRUE;
 724 }
 725
 726 string Map_Filename(float position)
 727 {
 728         return strcat("maps/", argv(position), ".bsp");
 729 }
 730
 731 string strwords(string s, float w)
 732 {
 733         float endpos;
 734         for(endpos = 0; w && endpos >= 0; --w)
 735                 endpos = strstrofs(s, " ", endpos + 1);
 736         if(endpos < 0)
 737                 return s;
 738         else
 739                 return substring(s, 0, endpos);
 740 }
 741
 742 float strhasword(string s, string w)
 743 {
 744         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 745 }
 746
 747 void Map_MarkAsRecent(string m)
 748 {
 749         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 750 }
 751
 752 float Map_IsRecent(string m)
 753 {
 754         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 755 }
 756
 757 float Map_Check(float position, float pass)
 758 {
 759         string filename;
 760         string map_next;
 761         map_next = argv(position);
 762         if(pass <= 1)
 763         {
 764                 if(Map_IsRecent(map_next))
 765                         return 0;
 766         }
 767         filename = Map_Filename(position);
 768         if(MapInfo_CheckMap(map_next))
 769         {
 770                 if(pass == 2)
 771                         return 1;
 772                 if(MapHasRightSize(map_next))
 773                         return 1;
 774                 return 0;
 775         }
 776         else
 777                 dprint( "Couldn't select '", filename, "'..\n" );
 778
 779         return 0;
 780 }
 781
 782 void Map_Goto_SetStr(string nextmapname)
 783 {
 784         if(getmapname_stored != "")
 785                 strunzone(getmapname_stored);
 786         if(nextmapname == "")
 787                 getmapname_stored = "";
 788         else
 789                 getmapname_stored = strzone(nextmapname);
 790 }
 791
 792 void Map_Goto_SetFloat(float position)
 793 {
 794         cvar_set("g_maplist_index", ftos(position));
 795         Map_Goto_SetStr(argv(position));
 796 }
 797
 798 void GameResetCfg()
 799 {
 800         // settings persist, except...
 801         if(cvar("g_campaign"))
 802                 localcmd("\nexec mutator_reset.cfg\n");
 803         localcmd("\nsettemp_restore\n");
 804 };
 805
 806 void Map_Goto()
 807 {
 808         GameResetCfg();
 809         MapInfo_LoadMap(getmapname_stored);
 810 }
 811
 812 // return codes of map selectors:
 813 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 814 //   -2 = permanent failure
 815 float() MaplistMethod_Iterate = // usual method
 816 {
 817         float pass, i;
 818
 819         for(pass = 1; pass <= 2; ++pass)
 820         {
 821                 for(i = 1; i < Map_Count; ++i)
 822                 {
 823                         float mapindex;
 824                         mapindex = mod(i + Map_Current, Map_Count);
 825                         if(Map_Check(mapindex, pass))
 826                                 return mapindex;
 827                 }
 828         }
 829         return -1;
 830 }
 831
 832 float() MaplistMethod_Repeat = // fallback method
 833 {
 834         if(Map_Check(Map_Current, 2))
 835                 return Map_Current;
 836         return -2;
 837 }
 838
 839 float() MaplistMethod_Random = // random map selection
 840 {
 841         float i, imax;
 842
 843         imax = 42;
 844
 845         for(i = 0; i <= imax; ++i)
 846         {
 847                 float mapindex;
 848                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 849                 if(Map_Check(mapindex, 1))
 850                         return mapindex;
 851         }
 852         return -1;
 853 }
 854
 855 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 856 // the exponent sets a bias on the map selection:
 857 // the higher the exponent, the less likely "shortly repeated" same maps are
 858 {
 859         float i, j, imax, insertpos;
 860
 861         imax = 42;
 862
 863         for(i = 0; i <= imax; ++i)
 864         {
 865                 string newlist;
 866
 867                 // now reinsert this at another position
 868                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 869                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 870                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 871                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 872
 873                 // insert the current map there
 874                 newlist = "";
 875                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 876                         newlist = strcat(newlist, " ", argv(j));
 877                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 878                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 879                         newlist = strcat(newlist, " ", argv(j));
 880                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 881                 cvar_set("g_maplist", newlist);
 882                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 883
 884                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 885                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 886                 if(Map_Check(Map_Current, 1))
 887                         return Map_Current;
 888         }
 889         return -1;
 890 }
 891
 892 void Maplist_Init()
 893 {
 894         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 895         if(Map_Count == 0)
 896         {
 897                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 898                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 899                 if(cvar("g_maplist_shuffle"))
 900                         ShuffleMaplist();
 901                 localcmd("\nmenu_cmd sync\n");
 902                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 903         }
 904         if(Map_Count == 0)
 905                 error("empty maplist, cannot select a new map");
 906         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 907
 908         if(Map_Current_Name)
 909                 strunzone(Map_Current_Name);
 910         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 911         // this may or may not be correct, but who cares, in the worst case a map
 912         // isn't chosen in the first pass that should have been
 913 }
 914
 915 string GetNextMap()
 916 {
 917         float nextMap;
 918
 919         Maplist_Init();
 920         nextMap = -1;
 921
 922         if(nextMap == -1)
 923                 if(cvar("g_maplist_shuffle") > 0)
 924                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 925
 926         if(nextMap == -1)
 927                 if(cvar("g_maplist_selectrandom"))
 928                         nextMap = MaplistMethod_Random();
 929
 930         if(nextMap == -1)
 931                 nextMap = MaplistMethod_Iterate();
 932
 933         if(nextMap == -1)
 934                 nextMap = MaplistMethod_Repeat();
 935
 936         if(nextMap >= 0)
 937         {
 938                 Map_Goto_SetFloat(nextMap);
 939                 return getmapname_stored;
 940         }
 941
 942         return "";
 943 };
 944
 945 float DoNextMapOverride()
 946 {
 947         if(cvar("g_campaign"))
 948         {
 949                 CampaignPostIntermission();
 950                 alreadychangedlevel = TRUE;
 951                 return TRUE;
 952         }
 953         if(cvar("quit_when_empty"))
 954         {
 955                 if(player_count <= currentbots)
 956                 {
 957                         localcmd("quit\n");
 958                         alreadychangedlevel = TRUE;
 959                         return TRUE;
 960                 }
 961         }
 962         if(cvar_string("quit_and_redirect") != "")
 963         {
 964                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 965                 alreadychangedlevel = TRUE;
 966                 return TRUE;
 967         }
 968         if (cvar("samelevel")) // if samelevel is set, stay on same level
 969         {
 970                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 971                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 972                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 973                 localcmd("restart\n");
 974                 //changelevel (mapname);
 975                 alreadychangedlevel = TRUE;
 976                 return TRUE;
 977         }
 978         if(cvar_string("nextmap") != "")
 979                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 980                 {
 981                         Map_Goto_SetStr(cvar_string("nextmap"));
 982                         Map_Goto();
 983                         alreadychangedlevel = TRUE;
 984                         return TRUE;
 985                 }
 986         if(cvar("lastlevel"))
 987         {
 988                 GameResetCfg();
 989                 localcmd("set lastlevel 0\ntogglemenu\n");
 990                 alreadychangedlevel = TRUE;
 991                 return TRUE;
 992         }
 993         return FALSE;
 994 };
 995
 996 void GotoNextMap()
 997 {
 998         //local string nextmap;
 999         //local float n, nummaps;
1000         //local string s;
1001         if (alreadychangedlevel)
1002                 return;
1003         alreadychangedlevel = TRUE;
1004
1005         {
1006                 string nextMap;
1007                 float allowReset;
1008
1009                 for(allowReset = 1; allowReset >= 0; --allowReset)
1010                 {
1011                         nextMap = GetNextMap();
1012                         if(nextMap != "")
1013                                 break;
1014
1015                         if(allowReset)
1016                         {
1017                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1018                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1019                                 if(cvar("g_maplist_shuffle"))
1020                                         ShuffleMaplist();
1021                                 localcmd("\nmenu_cmd sync\n");
1022                         }
1023                         else
1024                         {
1025                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1026                         }
1027                 }
1028                 Map_Goto();
1029         }
1030 };
1031
1032
1033 /*
1034 ============
1035 IntermissionThink
1036
1037 When the player presses attack or jump, change to the next level
1038 ============
1039 */
1040 .float autoscreenshot;
1041 void() MapVote_Start;
1042 void() MapVote_Think;
1043 float mapvote_initialized;
1044 void IntermissionThink()
1045 {
1046         FixIntermissionClient(self);
1047
1048         if(cvar("sv_autoscreenshot"))
1049         if(self.autoscreenshot > 0)
1050         if(time > self.autoscreenshot)
1051         {
1052                 self.autoscreenshot = -1;
1053                 if(clienttype(self) == CLIENTTYPE_REAL)
1054                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1055                 return;
1056         }
1057
1058         if (time < intermission_exittime)
1059                 return;
1060
1061         if(!mapvote_initialized)
1062                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1063                         return;
1064
1065         MapVote_Start();
1066 };
1067
1068 /*
1069 ============
1070 FindIntermission
1071
1072 Returns the entity to view from
1073 ============
1074 */
1075 /*
1076 entity FindIntermission()
1077 {
1078         local   entity spot;
1079         local   float cyc;
1080
1081 // look for info_intermission first
1082         spot = find (world, classname, "info_intermission");
1083         if (spot)
1084         {       // pick a random one
1085                 cyc = random() * 4;
1086                 while (cyc > 1)
1087                 {
1088                         spot = find (spot, classname, "info_intermission");
1089                         if (!spot)
1090                                 spot = find (spot, classname, "info_intermission");
1091                         cyc = cyc - 1;
1092                 }
1093                 return spot;
1094         }
1095
1096 // then look for the start position
1097         spot = find (world, classname, "info_player_start");
1098         if (spot)
1099                 return spot;
1100
1101 // testinfo_player_start is only found in regioned levels
1102         spot = find (world, classname, "testplayerstart");
1103         if (spot)
1104                 return spot;
1105
1106 // then look for the start position
1107         spot = find (world, classname, "info_player_deathmatch");
1108         if (spot)
1109                 return spot;
1110
1111         //objerror ("FindIntermission: no spot");
1112         return world;
1113 };
1114 */
1115
1116 /*
1117 ===============================================================================
1118
1119 RULES
1120
1121 ===============================================================================
1122 */
1123
1124 void DumpStats(float final)
1125 {
1126         local float file;
1127         local string s;
1128         local float to_console;
1129         local float to_eventlog;
1130         local float to_file;
1131         local float i;
1132
1133         to_console = cvar("sv_logscores_console");
1134         to_eventlog = cvar("sv_eventlog");
1135         to_file = cvar("sv_logscores_file");
1136
1137         if(!final)
1138         {
1139                 to_console = TRUE; // always print printstats replies
1140                 to_eventlog = FALSE; // but never print them to the event log
1141         }
1142
1143         if(to_eventlog)
1144                 if(cvar("sv_eventlog_console"))
1145                         to_console = FALSE; // otherwise we get the output twice
1146
1147         if(final)
1148                 s = ":scores:";
1149         else
1150                 s = ":status:";
1151         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1152
1153         if(to_console)
1154                 print(s, "\n");
1155         if(to_eventlog)
1156                 GameLogEcho(s);
1157         if(to_file)
1158         {
1159                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1160                 if(file == -1)
1161                         to_file = FALSE;
1162                 else
1163                         fputs(file, strcat(s, "\n"));
1164         }
1165
1166         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1167         if(to_console)
1168                 print(s, "\n");
1169         if(to_eventlog)
1170                 GameLogEcho(s);
1171         if(to_file)
1172                 fputs(file, strcat(s, "\n"));
1173
1174         FOR_EACH_CLIENT(other)
1175         {
1176                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1177                 {
1178                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1179                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1180                         if(other.classname == "player" || g_arena || g_lms)
1181                                 s = strcat(s, ftos(other.team), ":");
1182                         else
1183                                 s = strcat(s, "spectator:");
1184
1185                         if(to_console)
1186                                 print(s, other.netname, "\n");
1187                         if(to_eventlog)
1188                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1189                         if(to_file)
1190                                 fputs(file, strcat(s, other.netname, "\n"));
1191                 }
1192         }
1193
1194         if(teams_matter)
1195         {
1196                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1197                 if(to_console)
1198                         print(s, "\n");
1199                 if(to_eventlog)
1200                         GameLogEcho(s);
1201                 if(to_file)
1202                         fputs(file, strcat(s, "\n"));
1203
1204                 for(i = 1; i < 16; ++i)
1205                 {
1206                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1207                         s = strcat(s, ":", ftos(i));
1208                         if(to_console)
1209                                 print(s, "\n");
1210                         if(to_eventlog)
1211                                 GameLogEcho(s);
1212                         if(to_file)
1213                                 fputs(file, strcat(s, "\n"));
1214                 }
1215         }
1216
1217         if(to_console)
1218                 print(":end\n");
1219         if(to_eventlog)
1220                 GameLogEcho(":end");
1221         if(to_file)
1222         {
1223                 fputs(file, ":end\n");
1224                 fclose(file);
1225         }
1226 }
1227
1228 void FixIntermissionClient(entity e)
1229 {
1230         string s;
1231         if(!e.autoscreenshot) // initial call
1232         {
1233                 e.angles = e.v_angle;
1234                 e.angles_x = -e.angles_x;
1235                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1236                 e.health = -2342;
1237                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1238                 e.solid = SOLID_NOT;
1239                 e.movetype = MOVETYPE_NONE;
1240                 e.takedamage = DAMAGE_NO;
1241                 if(e.weaponentity)
1242                         e.weaponentity.effects = EF_NODRAW;
1243                 if(clienttype(e) == CLIENTTYPE_REAL)
1244                 {
1245                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1246                         s = cvar_string("sv_intermission_cdtrack");
1247                         if(s != "")
1248                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1249                         msg_entity = e;
1250                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1251                 }
1252         }
1253
1254         //e.velocity = '0 0 0';
1255         //e.fixangle = TRUE;
1256
1257         // TODO halt weapon animation
1258 }
1259
1260
1261 /*
1262 go to the next level for deathmatch
1263 only called if a time or frag limit has expired
1264 */
1265 void NextLevel()
1266 {
1267         float minTotalFrags;
1268         float maxTotalFrags;
1269         float score;
1270         float f;
1271
1272         gameover = TRUE;
1273
1274         intermission_running = 1;
1275
1276 // enforce a wait time before allowing changelevel
1277         if(player_count > 0)
1278                 intermission_exittime = time + cvar("sv_mapchange_delay");
1279         else
1280                 intermission_exittime = -1;
1281
1282         /*
1283         WriteByte (MSG_ALL, SVC_CDTRACK);
1284         WriteByte (MSG_ALL, 3);
1285         WriteByte (MSG_ALL, 3);
1286         // done in FixIntermission
1287         */
1288
1289         //pos = FindIntermission ();
1290
1291         VoteReset();
1292
1293         DumpStats(TRUE);
1294
1295         if(cvar("sv_eventlog"))
1296                 GameLogEcho(":gameover");
1297
1298         GameLogClose();
1299
1300         FOR_EACH_CLIENT(other)
1301         {
1302                 FixIntermissionClient(other);
1303
1304                 if(other.winning)
1305                         bprint(other.netname, " ^7wins.\n");
1306         }
1307
1308         minTotalFrags = 0;
1309         maxTotalFrags = 0;
1310         FOR_EACH_PLAYER(other)
1311         {
1312                 if(maxTotalFrags < other.totalfrags)
1313                         maxTotalFrags = other.totalfrags;
1314                 if(minTotalFrags > other.totalfrags)
1315                         minTotalFrags = other.totalfrags;
1316         }
1317
1318         if(!currentbots)
1319         {
1320                 FOR_EACH_PLAYER(other)
1321                 {
1322                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1323                         f = bound(0, other.play_time / max(time, 1), 1);
1324                         // store some statistics?
1325                 }
1326         }
1327
1328         if(cvar("g_campaign"))
1329                 CampaignPreIntermission();
1330
1331         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1332 };
1333
1334 /*
1335 ============
1336 CheckRules_Player
1337
1338 Exit deathmatch games upon conditions
1339 ============
1340 */
1341 void CheckRules_Player()
1342 {
1343         if (gameover)   // someone else quit the game already
1344                 return;
1345
1346         if(self.deadflag == DEAD_NO)
1347                 self.play_time += frametime;
1348
1349         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1350         //   (div0: and that in CheckRules_World please)
1351 };
1352
1353 float checkrules_oneminutewarning;
1354
1355 float checkrules_equality;
1356 float checkrules_suddendeathwarning;
1357 float checkrules_suddendeathend;
1358 float checkrules_overtimesadded; //how many overtimes have been already added
1359 float checkrules_status;
1360
1361 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1362 float WINNING_YES = 1; // winner found
1363 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1364 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1365
1366 void InitiateOvertime()
1367 {
1368         // Check first whether normal overtimes could be added before initiating suddendeath mode
1369         // - for this timelimit_overtime needs to be >0 of course
1370         // - also check the winning condition calculated in the previous frame and only add normal overtime
1371         //   again, if at the point at which timelimit would be extended again, still no winner was found
1372         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1373         {
1374                 ++checkrules_overtimesadded;
1375                 //add one more overtime by simply extending the timelimit
1376                 float tl;
1377                 tl = cvar("timelimit");
1378                 tl += cvar("timelimit_overtime");
1379                 cvar_set("timelimit", ftos(tl));
1380                 string minutesPlural;
1381                 if (cvar("timelimit_overtime") == 1)
1382                         minutesPlural = " ^3minute";
1383                 else
1384                         minutesPlural = " ^3minutes";
1385
1386                 bcenterprint(
1387                         strcat(
1388                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1389                                 ftos(cvar("timelimit_overtime")),
1390                                 minutesPlural,
1391                                 " to the game!"
1392                         )
1393                 );
1394         }
1395         else
1396         {
1397                 if(!checkrules_suddendeathend)
1398                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1399         }
1400 }
1401
1402 float GetWinningCode(float fraglimitreached, float equality)
1403 {
1404         if(equality)
1405                 if(fraglimitreached)
1406                         return WINNING_STARTSUDDENDEATHOVERTIME;
1407                 else
1408                         return WINNING_NEVER;
1409         else
1410                 if(fraglimitreached)
1411                         return WINNING_YES;
1412                 else
1413                         return WINNING_NO;
1414 }
1415
1416 // set the .winning flag for exactly those players with a given field value
1417 void SetWinners(.float field, float value)
1418 {
1419         entity head;
1420         FOR_EACH_PLAYER(head)
1421                 head.winning = (head.field == value);
1422 }
1423
1424 // set the .winning flag for those players with a given field value
1425 void AddWinners(.float field, float value)
1426 {
1427         entity head;
1428         FOR_EACH_PLAYER(head)
1429                 if(head.field == value)
1430                         head.winning = 1;
1431 }
1432
1433 // clear the .winning flags
1434 void ClearWinners(void)
1435 {
1436         entity head;
1437         FOR_EACH_PLAYER(head)
1438                 head.winning = 0;
1439 }
1440
1441 // Onslaught winning condition:
1442 // game terminates if only one team has a working generator (or none)
1443 float WinningCondition_Onslaught()
1444 {
1445         entity head;
1446         local float t1, t2, t3, t4;
1447
1448         WinningConditionHelper(); // set worldstatus
1449
1450         // first check if the game has ended
1451         t1 = t2 = t3 = t4 = 0;
1452         head = find(world, classname, "onslaught_generator");
1453         while (head)
1454         {
1455                 if (head.health > 0)
1456                 {
1457                         if (head.team == COLOR_TEAM1) t1 = 1;
1458                         if (head.team == COLOR_TEAM2) t2 = 1;
1459                         if (head.team == COLOR_TEAM3) t3 = 1;
1460                         if (head.team == COLOR_TEAM4) t4 = 1;
1461                 }
1462                 head = find(head, classname, "onslaught_generator");
1463         }
1464         if (t1 + t2 + t3 + t4 < 2)
1465         {
1466                 // game over, only one team remains (or none)
1467                 ClearWinners();
1468                 if (t1) SetWinners(team, COLOR_TEAM1);
1469                 if (t2) SetWinners(team, COLOR_TEAM2);
1470                 if (t3) SetWinners(team, COLOR_TEAM3);
1471                 if (t4) SetWinners(team, COLOR_TEAM4);
1472                 dprint("Have a winner, ending game.\n");
1473                 return WINNING_YES;
1474         }
1475
1476         // Two or more teams remain
1477         return WINNING_NO;
1478 }
1479
1480 float LMS_NewPlayerLives()
1481 {
1482         float fl;
1483         fl = cvar("fraglimit");
1484         if(fl == 0)
1485                 fl = 999;
1486
1487         // first player has left the game for dying too much? Nobody else can get in.
1488         if(lms_lowest_lives < 1)
1489                 return 0;
1490
1491         if(!cvar("g_lms_join_anytime"))
1492                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1493                         return 0;
1494
1495         return bound(1, lms_lowest_lives, fl);
1496 }
1497
1498 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1499 // they win. Otherwise the defending team wins once the timelimit passes.
1500 void assault_new_round();
1501 float WinningCondition_Assault()
1502 {
1503         local float status;
1504
1505         WinningConditionHelper(); // set worldstatus
1506
1507         status = WINNING_NO;
1508         // as the timelimit has not yet passed just assume the defending team will win
1509         if(assault_attacker_team == COLOR_TEAM1)
1510         {
1511                 SetWinners(team, COLOR_TEAM2);
1512         }
1513         else
1514         {
1515                 SetWinners(team, COLOR_TEAM1);
1516         }
1517
1518         local entity ent;
1519         ent = find(world, classname, "target_assault_roundend");
1520         if(ent)
1521         {
1522                 if(ent.winning) // round end has been triggered by attacking team
1523                 {
1524                         bprint("ASSAULT: round completed...\n");
1525                         SetWinners(team, assault_attacker_team);
1526
1527                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1528
1529                         if(ent.cnt == 1) // this was the second round
1530                         {
1531                                 status = WINNING_YES;
1532                         }
1533                         else
1534                         {
1535                                 local entity oldself;
1536                                 oldself = self;
1537                                 self = ent;
1538                                 assault_new_round();
1539                                 self = oldself;
1540                         }
1541                 }
1542         }
1543
1544         return status;
1545 }
1546
1547 // LMS winning condition: game terminates if and only if there's at most one
1548 // one player who's living lives. Top two scores being equal cancels the time
1549 // limit.
1550 float WinningCondition_LMS()
1551 {
1552         entity head, head2;
1553         float have_player;
1554         float have_players;
1555         float l;
1556
1557         have_player = FALSE;
1558         have_players = FALSE;
1559         l = LMS_NewPlayerLives();
1560
1561         head = find(world, classname, "player");
1562         if(head)
1563                 have_player = TRUE;
1564         head2 = find(head, classname, "player");
1565         if(head2)
1566                 have_players = TRUE;
1567
1568         if(have_player)
1569         {
1570                 // we have at least one player
1571                 if(have_players)
1572                 {
1573                         // two or more active players - continue with the game
1574                 }
1575                 else
1576                 {
1577                         // exactly one player?
1578
1579                         ClearWinners();
1580                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1581
1582                         if(l)
1583                         {
1584                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1585                                 return WINNING_NO;
1586                         }
1587                         else
1588                         {
1589                                 // a winner!
1590                                 // and assign him his first place
1591                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1592                                 return WINNING_YES;
1593                         }
1594                 }
1595         }
1596         else
1597         {
1598                 // nobody is playing at all...
1599                 if(l)
1600                 {
1601                         // wait for players...
1602                 }
1603                 else
1604                 {
1605                         // SNAFU (maybe a draw game?)
1606                         ClearWinners();
1607                         dprint("No players, ending game.\n");
1608                         return WINNING_YES;
1609                 }
1610         }
1611
1612         // When we get here, we have at least two players who are actually LIVING,
1613         // now check if the top two players have equal score.
1614         WinningConditionHelper();
1615
1616         ClearWinners();
1617         if(WinningConditionHelper_winner)
1618                 WinningConditionHelper_winner.winning = TRUE;
1619         if(WinningConditionHelper_equality)
1620                 return WINNING_NEVER;
1621
1622         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1623         return WINNING_NO;
1624 }
1625
1626 void ShuffleMaplist()
1627 {
1628         float n, i;
1629         string s, s2;
1630
1631         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
1632         shufflearray_build(n);
1633         s2 = "";
1634         for(i = 0; i < n; ++i)
1635                 s2 = strcat(s2, " ", argv(shufflearray[i]));
1636         s = substring(s2, 1, strlen(s2) - 1);
1637         cvar_set("g_maplist", s);
1638 }
1639
1640 float leaderfrags;
1641 float WinningCondition_Scores(float limit)
1642 {
1643         // TODO make everything use THIS winning condition (except LMS)
1644         WinningConditionHelper();
1645
1646         if(teams_matter)
1647         {
1648                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1649                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1650                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1651                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1652         }
1653
1654         ClearWinners();
1655         if(WinningConditionHelper_winner)
1656                 WinningConditionHelper_winner.winning = 1;
1657         if(WinningConditionHelper_winnerteam >= 0)
1658                 SetWinners(team, WinningConditionHelper_winnerteam);
1659
1660         if(WinningConditionHelper_lowerisbetter)
1661         {
1662                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1663                 limit = -limit;
1664         }
1665
1666         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1667         // these modes always score in increments of 1, thus this makes sense
1668         {
1669                 if(leaderfrags != WinningConditionHelper_topscore)
1670                 {
1671                         leaderfrags = WinningConditionHelper_topscore;
1672
1673                         if (limit)
1674                         if (leaderfrags == limit - 1)
1675                                 play2all("announcer/robotic/1fragleft.wav");
1676                         else if (leaderfrags == limit - 2)
1677                                 play2all("announcer/robotic/2fragsleft.wav");
1678                         else if (leaderfrags == limit - 3)
1679                                 play2all("announcer/robotic/3fragsleft.wav");
1680                 }
1681         }
1682
1683         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1684 }
1685
1686 float WinningCondition_Race(float fraglimit)
1687 {
1688         float wc;
1689         entity p;
1690         wc = WinningCondition_Scores(fraglimit);
1691
1692         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1693         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1694         // do NOT support equality when the laps are all raced!
1695         {
1696                 FOR_EACH_PLAYER(p)
1697                         if not(p.race_completed)
1698                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1699                 return WINNING_YES;
1700         }
1701         return wc;
1702 }
1703
1704 void ReadyRestart();
1705 float WinningCondition_QualifyingThenRace(float limit)
1706 {
1707         float wc;
1708         wc = WinningCondition_Scores(limit);
1709
1710         // NEVER initiate overtime
1711         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1712         {
1713                 return WINNING_YES;
1714         }
1715
1716         return wc;
1717 }
1718
1719 float WinningCondition_RanOutOfSpawns()
1720 {
1721         entity head;
1722
1723         if(!have_team_spawns)
1724                 return WINNING_NO;
1725
1726         if(!some_spawn_has_been_used)
1727                 return WINNING_NO;
1728
1729         team1_score = team2_score = team3_score = team4_score = 0;
1730
1731         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1732         {
1733                 if(head.team == COLOR_TEAM1)
1734                         team1_score = 1;
1735                 else if(head.team == COLOR_TEAM2)
1736                         team2_score = 1;
1737                 else if(head.team == COLOR_TEAM3)
1738                         team3_score = 1;
1739                 else if(head.team == COLOR_TEAM4)
1740                         team4_score = 1;
1741         }
1742
1743         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1744         {
1745                 if(head.team == COLOR_TEAM1)
1746                         team1_score = 1;
1747                 else if(head.team == COLOR_TEAM2)
1748                         team2_score = 1;
1749                 else if(head.team == COLOR_TEAM3)
1750                         team3_score = 1;
1751                 else if(head.team == COLOR_TEAM4)
1752                         team4_score = 1;
1753         }
1754
1755         ClearWinners();
1756         if(team1_score + team2_score + team3_score + team4_score == 0)
1757         {
1758                 checkrules_equality = TRUE;
1759                 return WINNING_YES;
1760         }
1761         else if(team1_score + team2_score + team3_score + team4_score == 1)
1762         {
1763                 float t, i;
1764                 if(team1_score) t = COLOR_TEAM1;
1765                 if(team2_score) t = COLOR_TEAM2;
1766                 if(team3_score) t = COLOR_TEAM3;
1767                 if(team4_score) t = COLOR_TEAM4;
1768                 CheckAllowedTeams(world);
1769                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1770                 {
1771                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1772                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1773                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1774                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1775                 }
1776
1777                 AddWinners(team, t);
1778                 return WINNING_YES;
1779         }
1780         else
1781                 return WINNING_NO;
1782 }
1783
1784 /*
1785 ============
1786 CheckRules_World
1787
1788 Exit deathmatch games upon conditions
1789 ============
1790 */
1791 void CheckRules_World()
1792 {
1793         local float timelimit;
1794         local float fraglimit;
1795
1796         VoteThink();
1797         MapVote_Think();
1798
1799         SetDefaultAlpha();
1800
1801         /*
1802         MapVote_Think should now do that part
1803         if (intermission_running)
1804                 if (time >= intermission_exittime + 60)
1805                 {
1806                         if(!DoNextMapOverride())
1807                                 GotoNextMap();
1808                         return;
1809                 }
1810         */
1811
1812         if (gameover)   // someone else quit the game already
1813         {
1814                 if(player_count == 0) // Nobody there? Then let's go to the next map
1815                         MapVote_Start();
1816                         // this will actually check the player count in the next frame
1817                         // again, but this shouldn't hurt
1818                 return;
1819         }
1820
1821         timelimit = cvar("timelimit") * 60;
1822         fraglimit = cvar("fraglimit");
1823
1824         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1825         {
1826                 if(timelimit > 0)
1827                         timelimit = 0; // timelimit is not made for warmup
1828                 if(fraglimit > 0)
1829                         fraglimit = 0; // no fraglimit for now
1830         }
1831
1832         if(timelimit > 0)
1833         {
1834                 timelimit += game_starttime;
1835         }
1836         else if (timelimit < 0)
1837         {
1838                 // endmatch
1839                 NextLevel();
1840                 return;
1841         }
1842
1843         if(checkrules_suddendeathend)
1844         {
1845                 if(!checkrules_suddendeathwarning)
1846                 {
1847                         checkrules_suddendeathwarning = TRUE;
1848                         if(g_race && !g_race_qualifying)
1849                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1850                         else
1851                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1852                 }
1853         }
1854         else
1855         {
1856                 if (timelimit && time >= timelimit)
1857                 {
1858                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1859                         {
1860                                 float totalplayers;
1861                                 float playerswithlaps;
1862                                 float readyplayers;
1863                                 entity head;
1864                                 totalplayers = playerswithlaps = readyplayers = 0;
1865                                 FOR_EACH_PLAYER(head)
1866                                 {
1867                                         ++totalplayers;
1868                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1869                                                 ++playerswithlaps;
1870                                         if(head.ready)
1871                                                 ++readyplayers;
1872                                 }
1873
1874                                 // at least 2/3 of the players have completed a lap: start the RACE
1875                                 // otherwise, the players should end the qualifying on their own
1876                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1877                                 {
1878                                         checkrules_suddendeathend = 0;
1879                                         ReadyRestart(); // go to race
1880                                 }
1881                                 else
1882                                         InitiateOvertime();
1883                         }
1884                         else
1885                                 InitiateOvertime();
1886                 }
1887         }
1888
1889         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1890         {
1891                 NextLevel();
1892                 return;
1893         }
1894
1895         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1896         {
1897                 checkrules_oneminutewarning = TRUE;
1898                 play2all("announcer/robotic/1minuteremains.wav");
1899         }
1900
1901         checkrules_status = WinningCondition_RanOutOfSpawns();
1902         if(checkrules_status == WINNING_YES)
1903         {
1904                 bprint("Hey! Someone ran out of spawns!\n");
1905         }
1906         else if(g_race && !g_race_qualifying && timelimit >= 0)
1907         {
1908                 checkrules_status = WinningCondition_Race(fraglimit);
1909         }
1910         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1911         {
1912                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1913         }
1914         else if(g_assault)
1915         {
1916                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1917         }
1918         else if(g_lms)
1919         {
1920                 checkrules_status = WinningCondition_LMS();
1921         }
1922         else if (g_onslaught)
1923         {
1924                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1925         }
1926         else
1927         {
1928                 checkrules_status = WinningCondition_Scores(fraglimit);
1929         }
1930
1931         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1932         {
1933                 checkrules_status = WINNING_NEVER;
1934                 InitiateOvertime();
1935         }
1936
1937         if(checkrules_status == WINNING_NEVER)
1938                 // equality cases! Nobody wins if the overtime ends in a draw.
1939                 ClearWinners();
1940
1941         if(checkrules_suddendeathend)
1942                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1943                         checkrules_status = WINNING_YES;
1944
1945         if(checkrules_status == WINNING_YES)
1946                 NextLevel();
1947 };
1948
1949 float mapvote_nextthink;
1950 float mapvote_initialized;
1951 float mapvote_keeptwotime;
1952 float mapvote_timeout;
1953 string mapvote_message;
1954 string mapvote_screenshot_dir;
1955
1956 float mapvote_count;
1957 float mapvote_count_real;
1958 string mapvote_maps[MAPVOTE_COUNT];
1959 float mapvote_maps_suggested[MAPVOTE_COUNT];
1960 string mapvote_suggestions[MAPVOTE_COUNT];
1961 float mapvote_suggestion_ptr;
1962 float mapvote_maxlen;
1963 float mapvote_voters;
1964 float mapvote_votes[MAPVOTE_COUNT];
1965 float mapvote_run;
1966 float mapvote_detail;
1967 float mapvote_abstain;
1968 .float mapvote;
1969
1970 void MapVote_ClearAllVotes()
1971 {
1972         FOR_EACH_CLIENT(other)
1973                 other.mapvote = 0;
1974 }
1975
1976 string MapVote_Suggest(string m)
1977 {
1978         float i;
1979         if(m == "")
1980                 return "That's not how to use this command.";
1981         if(!cvar("g_maplist_votable_suggestions"))
1982                 return "Suggestions are not accepted on this server.";
1983         if(mapvote_initialized)
1984                 return "Can't suggest - voting is already in progress!";
1985         m = MapInfo_FixName(m);
1986         if(!m)
1987                 return "The map you suggested is not available on this server.";
1988         if(!cvar("g_maplist_votable_override_mostrecent"))
1989                 if(Map_IsRecent(m))
1990                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1991
1992         if(!MapInfo_CheckMap(m))
1993                 return "The map you suggested does not support the current game mode.";
1994         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1995                 if(mapvote_suggestions[i] == m)
1996                         return "This map was already suggested.";
1997         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1998         {
1999                 i = floor(random() * mapvote_suggestion_ptr);
2000         }
2001         else
2002         {
2003                 i = mapvote_suggestion_ptr;
2004                 mapvote_suggestion_ptr += 1;
2005         }
2006         if(mapvote_suggestions[i] != "")
2007                 strunzone(mapvote_suggestions[i]);
2008         mapvote_suggestions[i] = strzone(m);
2009         if(cvar("sv_eventlog"))
2010                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2011         return strcat("Suggestion of ", m, " accepted.");
2012 }
2013
2014 void MapVote_AddVotable(string nextMap, float isSuggestion)
2015 {
2016         float j;
2017         if(nextMap == "")
2018                 return;
2019         for(j = 0; j < mapvote_count; ++j)
2020                 if(mapvote_maps[j] == nextMap)
2021                         return;
2022         if(strlen(nextMap) > mapvote_maxlen)
2023                 mapvote_maxlen = strlen(nextMap);
2024         mapvote_maps[mapvote_count] = strzone(nextMap);
2025         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2026         mapvote_count += 1;
2027 }
2028
2029 void MapVote_Spawn();
2030 void MapVote_Init()
2031 {
2032         float i;
2033         float nmax, smax;
2034
2035         MapVote_ClearAllVotes();
2036
2037         mapvote_count = 0;
2038         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2039         mapvote_abstain = cvar("g_maplist_votable_abstain");
2040
2041         if(mapvote_abstain)
2042                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2043         else
2044                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2045         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2046
2047         if(mapvote_suggestion_ptr)
2048                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2049                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2050
2051         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2052                 MapVote_AddVotable(GetNextMap(), FALSE);
2053
2054         if(mapvote_count == 0)
2055         {
2056                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2057                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2058                 if(cvar("g_maplist_shuffle"))
2059                         ShuffleMaplist();
2060                 localcmd("\nmenu_cmd sync\n");
2061                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2062                         MapVote_AddVotable(GetNextMap(), FALSE);
2063         }
2064
2065         mapvote_count_real = mapvote_count;
2066         if(mapvote_abstain)
2067                 MapVote_AddVotable("don't care", 0);
2068
2069         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2070
2071         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2072         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2073         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2074                 mapvote_keeptwotime = 0;
2075         mapvote_message = "Choose a map and press its key!";
2076
2077         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2078         if(mapvote_screenshot_dir == "")
2079                 mapvote_screenshot_dir = "maps";
2080         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2081
2082         MapVote_Spawn();
2083 }
2084
2085 void MapVote_SendPicture(float id)
2086 {
2087         msg_entity = self;
2088         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2089         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2090         WriteByte(MSG_ONE, id);
2091         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2092 }
2093
2094 float GameCommand_MapVote(string cmd)
2095 {
2096         if(!intermission_running)
2097                 return FALSE;
2098
2099         if(cmd == "mv_getpic")
2100         {
2101                 MapVote_SendPicture(stof(argv(1)));
2102                 return TRUE;
2103         }
2104
2105         return FALSE;
2106 }
2107
2108 float MapVote_GetMapMask()
2109 {
2110         float mask, i, power;
2111         mask = 0;
2112         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2113                 if(mapvote_maps[i] != "")
2114                         mask |= power;
2115         return mask;
2116 }
2117
2118 entity mapvote_ent;
2119 float MapVote_SendEntity(entity to, float sf)
2120 {
2121         string mapfile, pakfile;
2122         float i, o;
2123
2124         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2125         WriteByte(MSG_ENTITY, sf);
2126
2127         if(sf & 1)
2128         {
2129                 // flag 1 == initialization
2130                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2131                 WriteByte(MSG_ENTITY, mapvote_count);
2132                 WriteByte(MSG_ENTITY, mapvote_abstain);
2133                 WriteByte(MSG_ENTITY, mapvote_detail);
2134                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2135                 if(mapvote_count <= 8)
2136                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2137                 else
2138                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2139                 for(i = 0; i < mapvote_count; ++i)
2140                         if(mapvote_maps[i] != "")
2141                         {
2142                                 WriteString(MSG_ENTITY, mapvote_maps[i]);
2143                                 mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2144                                 pakfile = whichpack(strcat(mapfile, ".tga"));
2145                                 if(pakfile == "")
2146                                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2147                                 if(pakfile == "")
2148                                         pakfile = whichpack(strcat(mapfile, ".png"));
2149                                 for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2150                                         pakfile = substring(pakfile, o, 999);
2151                                 WriteString(MSG_ENTITY, pakfile);
2152                         }
2153         }
2154
2155         if(sf & 2)
2156         {
2157                 // flag 2 == update of mask
2158                 if(mapvote_count <= 8)
2159                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2160                 else
2161                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2162         }
2163
2164         if(sf & 4)
2165         {
2166                 if(mapvote_detail)
2167                         for(i = 0; i < mapvote_count; ++i)
2168                                 if(mapvote_maps[i] != "")
2169                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2170
2171                 WriteByte(MSG_ENTITY, to.mapvote);
2172         }
2173
2174         return TRUE;
2175 }
2176
2177 void MapVote_Spawn()
2178 {
2179         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2180 }
2181
2182 void MapVote_TouchMask()
2183 {
2184         mapvote_ent.SendFlags |= 2;
2185 }
2186
2187 void MapVote_TouchVotes(entity voter)
2188 {
2189         mapvote_ent.SendFlags |= 4;
2190 }
2191
2192 float MapVote_Finished(float mappos)
2193 {
2194         string result;
2195         float i;
2196         float didntvote;
2197
2198         if(cvar("sv_eventlog"))
2199         {
2200                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2201                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2202                 didntvote = mapvote_voters;
2203                 for(i = 0; i < mapvote_count; ++i)
2204                         if(mapvote_maps[i] != "")
2205                         {
2206                                 didntvote -= mapvote_votes[i];
2207                                 if(i != mappos)
2208                                 {
2209                                         result = strcat(result, ":", mapvote_maps[i]);
2210                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2211                                 }
2212                         }
2213                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2214
2215                 GameLogEcho(result);
2216                 if(mapvote_maps_suggested[mappos])
2217                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2218         }
2219
2220         FOR_EACH_REALCLIENT(other)
2221                 FixClientCvars(other);
2222
2223         Map_Goto_SetStr(mapvote_maps[mappos]);
2224         Map_Goto();
2225         alreadychangedlevel = TRUE;
2226         return TRUE;
2227 }
2228 void MapVote_CheckRules_1()
2229 {
2230         float i;
2231
2232         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2233         {
2234                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2235                 mapvote_votes[i] = 0;
2236         }
2237
2238         mapvote_voters = 0;
2239         FOR_EACH_REALCLIENT(other)
2240         {
2241                 ++mapvote_voters;
2242                 if(other.mapvote)
2243                 {
2244                         i = other.mapvote - 1;
2245                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2246                         mapvote_votes[i] = mapvote_votes[i] + 1;
2247                 }
2248         }
2249 }
2250
2251 float MapVote_CheckRules_2()
2252 {
2253         float i;
2254         float firstPlace, secondPlace;
2255         float firstPlaceVotes, secondPlaceVotes;
2256         float mapvote_voters_real;
2257         string result;
2258
2259         mapvote_voters_real = mapvote_voters;
2260         if(mapvote_abstain)
2261                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2262
2263         RandomSelection_Init();
2264         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2265                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2266         firstPlace = RandomSelection_chosen_float;
2267         firstPlaceVotes = RandomSelection_best_priority;
2268         //dprint("First place: ", ftos(firstPlace), "\n");
2269         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2270
2271         RandomSelection_Init();
2272         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2273                 if(i != firstPlace)
2274                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2275         secondPlace = RandomSelection_chosen_float;
2276         secondPlaceVotes = RandomSelection_best_priority;
2277         //dprint("Second place: ", ftos(secondPlace), "\n");
2278         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2279
2280         if(firstPlace == -1)
2281                 error("No first place in map vote... WTF?");
2282
2283         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2284                 return MapVote_Finished(firstPlace);
2285
2286         if(mapvote_keeptwotime)
2287                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2288                 {
2289                         float didntvote;
2290                         MapVote_TouchMask();
2291                         mapvote_message = "Now decide between the TOP TWO!";
2292                         mapvote_keeptwotime = 0;
2293                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2294                         result = strcat(result, ":", ftos(firstPlaceVotes));
2295                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2296                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2297                         didntvote = mapvote_voters;
2298                         for(i = 0; i < mapvote_count; ++i)
2299                                 if(mapvote_maps[i] != "")
2300                                 {
2301                                         didntvote -= mapvote_votes[i];
2302                                         if(i != firstPlace)
2303                                                 if(i != secondPlace)
2304                                                 {
2305                                                         result = strcat(result, ":", mapvote_maps[i]);
2306                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2307                                                         if(i < mapvote_count_real)
2308                                                         {
2309                                                                 strunzone(mapvote_maps[i]);
2310                                                                 mapvote_maps[i] = "";
2311                                                         }
2312                                                 }
2313                                 }
2314                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2315                         if(cvar("sv_eventlog"))
2316                                 GameLogEcho(result);
2317                 }
2318
2319         return FALSE;
2320 }
2321 void MapVote_Tick()
2322 {
2323         float keeptwo;
2324         float totalvotes;
2325
2326         keeptwo = mapvote_keeptwotime;
2327         MapVote_CheckRules_1(); // count
2328         if(MapVote_CheckRules_2()) // decide
2329                 return;
2330
2331         totalvotes = 0;
2332         FOR_EACH_REALCLIENT(other)
2333         {
2334                 // hide scoreboard again
2335                 if(other.health != 2342)
2336                 {
2337                         other.health = 2342;
2338                         other.impulse = 0;
2339                         if(clienttype(other) == CLIENTTYPE_REAL)
2340                         {
2341                                 msg_entity = other;
2342                                 WriteByte(MSG_ONE, SVC_FINALE);
2343                                 WriteString(MSG_ONE, "");
2344                         }
2345                 }
2346
2347                 // notify about keep-two
2348                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2349                         play2(other, "misc/invshot.wav");
2350
2351                 // clear possibly invalid votes
2352                 if(mapvote_maps[other.mapvote - 1] == "")
2353                         other.mapvote = 0;
2354                 // use impulses as new vote
2355                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2356                         if(mapvote_maps[other.impulse - 1] != "")
2357                         {
2358                                 other.mapvote = other.impulse;
2359                                 MapVote_TouchVotes(other);
2360                         }
2361                 other.impulse = 0;
2362
2363                 if(other.mapvote)
2364                         ++totalvotes;
2365         }
2366
2367         MapVote_CheckRules_1(); // just count
2368 }
2369 void MapVote_Start()
2370 {
2371         if(mapvote_run)
2372                 return;
2373
2374         MapInfo_Enumerate();
2375         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2376                 mapvote_run = TRUE;
2377 }
2378 void MapVote_Think()
2379 {
2380         if(!mapvote_run)
2381                 return;
2382
2383         if(alreadychangedlevel)
2384                 return;
2385
2386         if(time < mapvote_nextthink)
2387                 return;
2388         //dprint("tick\n");
2389
2390         mapvote_nextthink = time + 0.5;
2391
2392         if(!mapvote_initialized)
2393         {
2394                 mapvote_initialized = TRUE;
2395                 if(DoNextMapOverride())
2396                         return;
2397                 if(!cvar("g_maplist_votable") || player_count <= 0)
2398                 {
2399                         GotoNextMap();
2400                         return;
2401                 }
2402                 MapVote_Init();
2403         }
2404
2405         MapVote_Tick();
2406 };
2407
2408 string GotoMap(string m)
2409 {
2410         if(!MapInfo_CheckMap(m))
2411                 return "The map you chose is not available on this server.";
2412         cvar_set("nextmap", m);
2413         cvar_set("timelimit", "-1");
2414         if(mapvote_initialized || alreadychangedlevel)
2415         {
2416                 if(DoNextMapOverride())
2417                         return "Map switch initiated.";
2418                 else
2419                         return "Hm... no. For some reason I like THIS map more.";
2420         }
2421         else
2422                 return "Map switch will happen after scoreboard.";
2423 }
2424
2425
2426 void EndFrame()
2427 {
2428         FOR_EACH_REALCLIENT(self)
2429         {
2430                 if(self.classname == "spectator")
2431                 {
2432                         if(self.enemy.typehitsound)
2433                                 play2(self, "misc/typehit.wav");
2434                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2435                                 play2(self, "misc/hit.wav");
2436                 }
2437                 else
2438                 {
2439                         if(self.typehitsound)
2440                                 play2(self, "misc/typehit.wav");
2441                         else if(self.hitsound && self.cvar_cl_hitsound)
2442                                 play2(self, "misc/hit.wav");
2443                 }
2444         }
2445         FOR_EACH_CLIENT(self)
2446         {
2447                 self.hitsound = FALSE;
2448                 self.typehitsound = FALSE;
2449         }
2450 }
2451
2452
2453 /*
2454  * RedirectionThink:
2455  * returns TRUE if redirecting
2456  */
2457 float redirection_timeout;
2458 float redirection_nextthink;
2459 float RedirectionThink()
2460 {
2461         float clients_found;
2462
2463         if(redirection_target == "")
2464                 return FALSE;
2465
2466         if(!redirection_timeout)
2467         {
2468                 cvar_set("sv_public", "-2");
2469                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2470                 if(redirection_target == "self")
2471                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2472                 else
2473                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2474         }
2475
2476         if(time < redirection_nextthink)
2477                 return TRUE;
2478
2479         redirection_nextthink = time + 1;
2480
2481         clients_found = 0;
2482         FOR_EACH_REALCLIENT(self)
2483         {
2484                 print("Redirecting: sending connect command to ", self.netname, "\n");
2485                 if(redirection_target == "self")
2486                         stuffcmd(self, "\ndisconnect; reconnect\n");
2487                 else
2488                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2489                 ++clients_found;
2490         }
2491
2492         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2493
2494         if(time > redirection_timeout || clients_found == 0)
2495                 localcmd("\nwait; wait; wait; quit\n");
2496
2497         return TRUE;
2498 }
2499
2500 void RestoreGame()
2501 {
2502         // Loaded from a save game
2503         // some things then break, so let's work around them...
2504
2505         // Progs DB (capture records)
2506         if(sv_cheats)
2507                 ServerProgsDB = db_create();
2508         else
2509                 ServerProgsDB = db_load("server.db");
2510
2511         // Mapinfo
2512         MapInfo_Shutdown();
2513         MapInfo_Enumerate();
2514         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2515 }
2516
2517 void SV_Shutdown()
2518 {
2519         if(world_initialized > 0)
2520         {
2521                 world_initialized = 0;
2522                 print("Saving persistent data...\n");
2523                 Ban_SaveBans();
2524                 if(!sv_cheats)
2525                         db_save(ServerProgsDB, "server.db");
2526                 if(cvar("developer"))
2527                         db_save(TemporaryDB, "server-temp.db");
2528                 db_close(ServerProgsDB);
2529                 db_close(TemporaryDB);
2530                 print("done!\n");
2531                 // tell the bot system the game is ending now
2532                 bot_endgame();
2533
2534                 MapInfo_Shutdown();
2535         }
2536         else if(world_initialized == 0)
2537         {
2538                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2539         }
2540 }