data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         dprint_load(); // load dprint status from cvar
 345         world_initialized = -1; // don't complain
 346         remove = remove_unsafely;
 347
 348         entity e;
 349         e = spawn();
 350         e.think = GotoFirstMap;
 351         e.nextthink = time; // this is usually 1 at this point
 352
 353         e = spawn();
 354         e.classname = "info_player_deathmatch"; // safeguard against player joining
 355
 356         self.classname = "worldspawn"; // safeguard against various stuff ;)
 357
 358         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 359         MapInfo_Enumerate();
 360         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 361 }
 362
 363 void Map_MarkAsRecent(string m);
 364 float world_already_spawned;
 365 void RegisterWeapons();
 366 void Nagger_Init();
 367 void ClientInit_Spawn();
 368 void spawnfunc_worldspawn (void)
 369 {
 370         float fd, l, i, j, n;
 371         string s, col;
 372
 373         dprint_load(); // load dprint status from cvar
 374
 375         if(world_already_spawned)
 376                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 377         world_already_spawned = TRUE;
 378
 379         remove = remove_safely; // during spawning, watch what you remove!
 380
 381         if(cvar_string("cvar_check_default") != "bypass")
 382         {
 383                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 384                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 385
 386                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 387                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 388         }
 389
 390         compressShortVector_init();
 391
 392         local entity head;
 393         head = nextent(world);
 394         maxclients = 0;
 395         while(head)
 396         {
 397                 ++maxclients;
 398                 head = nextent(head);
 399         }
 400
 401         // needs to be done so early as they would still spawn
 402         RegisterWeapons();
 403
 404         if(sv_cheats)
 405                 ServerProgsDB = db_create();
 406         else
 407                 ServerProgsDB = db_load("server.db");
 408
 409         TemporaryDB = db_create();
 410
 411         /*
 412         TODO sound pack system
 413         // initialize sound pack system
 414         soundpack = cvar_string("g_soundpack");
 415         if(soundpack != "")
 416                 soundpack = strcat(soundpack, "/");
 417         soundpack = strzone(soundpack);
 418         */
 419
 420         // 0 normal
 421         lightstyle(0, "m");
 422
 423         // 1 FLICKER (first variety)
 424         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 425
 426         // 2 SLOW STRONG PULSE
 427         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 428
 429         // 3 CANDLE (first variety)
 430         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 431
 432         // 4 FAST STROBE
 433         lightstyle(4, "mamamamamama");
 434
 435         // 5 GENTLE PULSE 1
 436         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 437
 438         // 6 FLICKER (second variety)
 439         lightstyle(6, "nmonqnmomnmomomno");
 440
 441         // 7 CANDLE (second variety)
 442         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 443
 444         // 8 CANDLE (third variety)
 445         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 446
 447         // 9 SLOW STROBE (fourth variety)
 448         lightstyle(9, "aaaaaaaazzzzzzzz");
 449
 450         // 10 FLUORESCENT FLICKER
 451         lightstyle(10, "mmamammmmammamamaaamammma");
 452
 453         // 11 SLOW PULSE NOT FADE TO BLACK
 454         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 455
 456         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 457
 458         // 63 testing
 459         lightstyle(63, "a");
 460
 461         if(cvar("g_campaign"))
 462                 CampaignPreInit();
 463
 464         Map_MarkAsRecent(mapname);
 465
 466         precache_model ("null"); // we need this one before InitGameplayMode
 467         InitGameplayMode();
 468         readlevelcvars();
 469         GrappleHookInit();
 470
 471         player_count = 0;
 472         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 473         if(bot_waypoints_for_items == 1)
 474                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 475                         bot_waypoints_for_items = 0;
 476
 477         // for setting by mapinfo
 478         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 479         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 480
 481         precache();
 482
 483         WaypointSprite_Init();
 484
 485         //if (g_domination)
 486         //      dom_init();
 487
 488         GameLogInit(); // prepare everything
 489         if(cvar("sv_eventlog"))
 490         {
 491                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 492                 s = strcat(s, ftos(random()));
 493                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 494                 s = ":gameinfo:mutators:LIST";
 495                 if(cvar("g_grappling_hook"))
 496                         s = strcat(s, ":grappling_hook");
 497                 if(!cvar("g_use_ammunition"))
 498                         s = strcat(s, ":no_use_ammunition");
 499                 if(!cvar("g_pickup_items"))
 500                         s = strcat(s, ":no_pickup_items");
 501                 if(cvar("g_instagib"))
 502                         s = strcat(s, ":instagib");
 503                 if(cvar_string("g_weaponarena") != "0")
 504                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 505                 if(cvar("g_nixnex"))
 506                         s = strcat(s, ":nixnex");
 507                 if(cvar("g_vampire"))
 508                         s = strcat(s, ":vampire");
 509                 if(cvar("g_laserguided_missile"))
 510                         s = strcat(s, ":laserguided_missile");
 511                 if(cvar("g_norecoil"))
 512                         s = strcat(s, ":norecoil");
 513                 if(cvar("g_midair"))
 514                         s = strcat(s, ":midair");
 515                 if(cvar("g_minstagib"))
 516                         s = strcat(s, ":minstagib");
 517                 GameLogEcho(s);
 518                 GameLogEcho(":gameinfo:end");
 519         }
 520
 521         cvar_set("nextmap", "");
 522
 523         SetDefaultAlpha();
 524
 525         if(cvar("g_campaign"))
 526                 CampaignPostInit();
 527
 528         fteqcc_testbugs();
 529
 530         Ban_LoadBans();
 531
 532         //initialise globals related to sv_timeout
 533         sys_ticrate = cvar("sys_ticrate");
 534         orig_slowmo = cvar("slowmo");
 535
 536         MapInfo_Enumerate();
 537         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 538
 539         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 540         {
 541                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 542                 if(fd != -1)
 543                 {
 544                         while((s = fgets(fd)))
 545                         {
 546                                 l = tokenize_sane(s);
 547                                 if(l < 2)
 548                                         continue;
 549                                 if(argv(0) == "cd")
 550                                 {
 551                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 552                                         print("  cdtrack ", argv(2), "\n");
 553                                 }
 554                                 else if(argv(0) == "fog")
 555                                 {
 556                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 557                                         print("  \"fog\" \"", s, "\"\n");
 558                                 }
 559                                 else if(argv(0) == "set")
 560                                 {
 561                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 562                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 563                                 }
 564                                 else if(argv(0) != "//")
 565                                 {
 566                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 567                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 568                                 }
 569                         }
 570                         fclose(fd);
 571                 }
 572         }
 573
 574         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 575         addstat(STAT_WEAPONS, AS_INT, weapons);
 576         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 577         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 578         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 579         Nagger_Init();
 580
 581         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 582         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 583
 584         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 585
 586         next_pingtime = time + 5;
 587         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 588
 589         detect_maptype();
 590
 591         lsmaps_reply = "^7Maps available: ";
 592         for(i = 0, j = 0; i < MapInfo_count; ++i)
 593         {
 594                 if(MapInfo_Get_ByID(i))
 595                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 596                         {
 597                                 if(mod(i, 2))
 598                                         col = "^2";
 599                                 else
 600                                         col = "^3";
 601                                 ++j;
 602                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 603                         }
 604         }
 605         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 606
 607         maplist_reply = "^7Maps in list: ";
 608         n = tokenize_sane(cvar_string("g_maplist"));
 609         for(i = 0, j = 0; i < n; ++i)
 610         {
 611                 if(MapInfo_CheckMap(argv(i)))
 612                 {
 613                         if(mod(j, 2))
 614                                 col = "^2";
 615                         else
 616                                 col = "^3";
 617                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 618                         ++j;
 619                 }
 620         }
 621         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 622         MapInfo_ClearTemps();
 623
 624         records_reply = strzone(getrecords());
 625
 626         ClientInit_Spawn();
 627         RandomSeed_Spawn();
 628
 629         world_initialized = 1;
 630 }
 631
 632 void spawnfunc_light (void)
 633 {
 634         //makestatic (self); // Who the f___ did that?
 635         remove(self);
 636 }
 637
 638 float TryFile( string pFilename )
 639 {
 640         local float lHandle;
 641         dprint("TryFile(\"", pFilename, "\")\n");
 642         lHandle = fopen( pFilename, FILE_READ );
 643         if( lHandle != -1 ) {
 644                 fclose( lHandle );
 645                 return TRUE;
 646         } else {
 647                 return FALSE;
 648         }
 649 };
 650
 651 string GetGametype()
 652 {
 653         return GametypeNameFromType(game);
 654 }
 655
 656 string getmapname_stored;
 657 string GetMapname()
 658 {
 659         return mapname;
 660 }
 661
 662 float Map_Count, Map_Current;
 663 string Map_Current_Name;
 664
 665 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 666 float GetMaplistPosition()
 667 {
 668         float pos, idx;
 669         string map;
 670
 671         map = GetMapname();
 672         idx = cvar("g_maplist_index");
 673
 674         if(idx >= 0)
 675                 if(idx < Map_Count)
 676                         if(map == argv(idx))
 677                                 return idx;
 678
 679         for(pos = 0; pos < Map_Count; ++pos)
 680                 if(map == argv(pos))
 681                         return pos;
 682
 683         // resume normal maplist rotation if current map is not in g_maplist
 684         return idx;
 685 }
 686
 687 float MapHasRightSize(string map)
 688 {
 689         float fh;
 690         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 691         if(cvar("g_maplist_check_waypoints"))
 692         {
 693                 dprint("checkwp "); dprint(map);
 694                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 695                 if(fh < 0)
 696                 {
 697                         dprint(": no waypoints\n");
 698                         return FALSE;
 699                 }
 700                 dprint(": has waypoints\n");
 701                 fclose(fh);
 702         }
 703
 704         // open map size restriction file
 705         dprint("opensize "); dprint(map);
 706         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 707         if(fh >= 0)
 708         {
 709                 float mapmin, mapmax;
 710                 dprint(": ok, ");
 711                 mapmin = stof(fgets(fh));
 712                 mapmax = stof(fgets(fh));
 713                 fclose(fh);
 714                 if(player_count < mapmin)
 715                 {
 716                         dprint("not enough\n");
 717                         return FALSE;
 718                 }
 719                 if(player_count > mapmax)
 720                 {
 721                         dprint("too many\n");
 722                         return FALSE;
 723                 }
 724                 dprint("right size\n");
 725                 return TRUE;
 726         }
 727         dprint(": not found\n");
 728         return TRUE;
 729 }
 730
 731 string Map_Filename(float position)
 732 {
 733         return strcat("maps/", argv(position), ".bsp");
 734 }
 735
 736 string strwords(string s, float w)
 737 {
 738         float endpos;
 739         for(endpos = 0; w && endpos >= 0; --w)
 740                 endpos = strstrofs(s, " ", endpos + 1);
 741         if(endpos < 0)
 742                 return s;
 743         else
 744                 return substring(s, 0, endpos);
 745 }
 746
 747 float strhasword(string s, string w)
 748 {
 749         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 750 }
 751
 752 void Map_MarkAsRecent(string m)
 753 {
 754         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 755 }
 756
 757 float Map_IsRecent(string m)
 758 {
 759         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 760 }
 761
 762 float Map_Check(float position, float pass)
 763 {
 764         string filename;
 765         string map_next;
 766         map_next = argv(position);
 767         if(pass <= 1)
 768         {
 769                 if(Map_IsRecent(map_next))
 770                         return 0;
 771         }
 772         filename = Map_Filename(position);
 773         if(MapInfo_CheckMap(map_next))
 774         {
 775                 if(pass == 2)
 776                         return 1;
 777                 if(MapHasRightSize(map_next))
 778                         return 1;
 779                 return 0;
 780         }
 781         else
 782                 dprint( "Couldn't select '", filename, "'..\n" );
 783
 784         return 0;
 785 }
 786
 787 void Map_Goto_SetStr(string nextmapname)
 788 {
 789         if(getmapname_stored != "")
 790                 strunzone(getmapname_stored);
 791         if(nextmapname == "")
 792                 getmapname_stored = "";
 793         else
 794                 getmapname_stored = strzone(nextmapname);
 795 }
 796
 797 void Map_Goto_SetFloat(float position)
 798 {
 799         cvar_set("g_maplist_index", ftos(position));
 800         Map_Goto_SetStr(argv(position));
 801 }
 802
 803 void GameResetCfg()
 804 {
 805         // settings persist, except...
 806         if(cvar("g_campaign"))
 807                 localcmd("\nexec mutator_reset.cfg\n");
 808         localcmd("\nsettemp_restore\n");
 809 };
 810
 811 void Map_Goto()
 812 {
 813         GameResetCfg();
 814         MapInfo_LoadMap(getmapname_stored);
 815 }
 816
 817 // return codes of map selectors:
 818 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 819 //   -2 = permanent failure
 820 float() MaplistMethod_Iterate = // usual method
 821 {
 822         float pass, i;
 823
 824         for(pass = 1; pass <= 2; ++pass)
 825         {
 826                 for(i = 1; i < Map_Count; ++i)
 827                 {
 828                         float mapindex;
 829                         mapindex = mod(i + Map_Current, Map_Count);
 830                         if(Map_Check(mapindex, pass))
 831                                 return mapindex;
 832                 }
 833         }
 834         return -1;
 835 }
 836
 837 float() MaplistMethod_Repeat = // fallback method
 838 {
 839         if(Map_Check(Map_Current, 2))
 840                 return Map_Current;
 841         return -2;
 842 }
 843
 844 float() MaplistMethod_Random = // random map selection
 845 {
 846         float i, imax;
 847
 848         imax = 42;
 849
 850         for(i = 0; i <= imax; ++i)
 851         {
 852                 float mapindex;
 853                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 854                 if(Map_Check(mapindex, 1))
 855                         return mapindex;
 856         }
 857         return -1;
 858 }
 859
 860 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 861 // the exponent sets a bias on the map selection:
 862 // the higher the exponent, the less likely "shortly repeated" same maps are
 863 {
 864         float i, j, imax, insertpos;
 865
 866         imax = 42;
 867
 868         for(i = 0; i <= imax; ++i)
 869         {
 870                 string newlist;
 871
 872                 // now reinsert this at another position
 873                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 874                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 875                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 876                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 877
 878                 // insert the current map there
 879                 newlist = "";
 880                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 881                         newlist = strcat(newlist, " ", argv(j));
 882                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 883                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 884                         newlist = strcat(newlist, " ", argv(j));
 885                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 886                 cvar_set("g_maplist", newlist);
 887                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 888
 889                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 890                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 891                 if(Map_Check(Map_Current, 1))
 892                         return Map_Current;
 893         }
 894         return -1;
 895 }
 896
 897 void Maplist_Init()
 898 {
 899         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 900         if(Map_Count == 0)
 901         {
 902                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 903                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 904                 if(cvar("g_maplist_shuffle"))
 905                         ShuffleMaplist();
 906                 localcmd("\nmenu_cmd sync\n");
 907                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 908         }
 909         if(Map_Count == 0)
 910                 error("empty maplist, cannot select a new map");
 911         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 912
 913         if(Map_Current_Name)
 914                 strunzone(Map_Current_Name);
 915         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 916         // this may or may not be correct, but who cares, in the worst case a map
 917         // isn't chosen in the first pass that should have been
 918 }
 919
 920 string GetNextMap()
 921 {
 922         float nextMap;
 923
 924         Maplist_Init();
 925         nextMap = -1;
 926
 927         if(nextMap == -1)
 928                 if(cvar("g_maplist_shuffle") > 0)
 929                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 930
 931         if(nextMap == -1)
 932                 if(cvar("g_maplist_selectrandom"))
 933                         nextMap = MaplistMethod_Random();
 934
 935         if(nextMap == -1)
 936                 nextMap = MaplistMethod_Iterate();
 937
 938         if(nextMap == -1)
 939                 nextMap = MaplistMethod_Repeat();
 940
 941         if(nextMap >= 0)
 942         {
 943                 Map_Goto_SetFloat(nextMap);
 944                 return getmapname_stored;
 945         }
 946
 947         return "";
 948 };
 949
 950 float DoNextMapOverride()
 951 {
 952         if(cvar("g_campaign"))
 953         {
 954                 CampaignPostIntermission();
 955                 alreadychangedlevel = TRUE;
 956                 return TRUE;
 957         }
 958         if(cvar("quit_when_empty"))
 959         {
 960                 if(player_count <= currentbots)
 961                 {
 962                         localcmd("quit\n");
 963                         alreadychangedlevel = TRUE;
 964                         return TRUE;
 965                 }
 966         }
 967         if(cvar_string("quit_and_redirect") != "")
 968         {
 969                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 970                 alreadychangedlevel = TRUE;
 971                 return TRUE;
 972         }
 973         if (cvar("samelevel")) // if samelevel is set, stay on same level
 974         {
 975                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 976                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 977                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 978                 localcmd("restart\n");
 979                 //changelevel (mapname);
 980                 alreadychangedlevel = TRUE;
 981                 return TRUE;
 982         }
 983         if(cvar_string("nextmap") != "")
 984                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 985                 {
 986                         Map_Goto_SetStr(cvar_string("nextmap"));
 987                         Map_Goto();
 988                         alreadychangedlevel = TRUE;
 989                         return TRUE;
 990                 }
 991         if(cvar("lastlevel"))
 992         {
 993                 GameResetCfg();
 994                 localcmd("set lastlevel 0\ntogglemenu\n");
 995                 alreadychangedlevel = TRUE;
 996                 return TRUE;
 997         }
 998         return FALSE;
 999 };
1000
1001 void GotoNextMap()
1002 {
1003         //local string nextmap;
1004         //local float n, nummaps;
1005         //local string s;
1006         if (alreadychangedlevel)
1007                 return;
1008         alreadychangedlevel = TRUE;
1009
1010         {
1011                 string nextMap;
1012                 float allowReset;
1013
1014                 for(allowReset = 1; allowReset >= 0; --allowReset)
1015                 {
1016                         nextMap = GetNextMap();
1017                         if(nextMap != "")
1018                                 break;
1019
1020                         if(allowReset)
1021                         {
1022                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1023                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1024                                 if(cvar("g_maplist_shuffle"))
1025                                         ShuffleMaplist();
1026                                 localcmd("\nmenu_cmd sync\n");
1027                         }
1028                         else
1029                         {
1030                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1031                         }
1032                 }
1033                 Map_Goto();
1034         }
1035 };
1036
1037
1038 /*
1039 ============
1040 IntermissionThink
1041
1042 When the player presses attack or jump, change to the next level
1043 ============
1044 */
1045 .float autoscreenshot;
1046 void() MapVote_Start;
1047 void() MapVote_Think;
1048 float mapvote_initialized;
1049 void IntermissionThink()
1050 {
1051         FixIntermissionClient(self);
1052
1053         if(cvar("sv_autoscreenshot"))
1054         if(self.autoscreenshot > 0)
1055         if(time > self.autoscreenshot)
1056         {
1057                 self.autoscreenshot = -1;
1058                 if(clienttype(self) == CLIENTTYPE_REAL)
1059                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1060                 return;
1061         }
1062
1063         if (time < intermission_exittime)
1064                 return;
1065
1066         if(!mapvote_initialized)
1067                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1068                         return;
1069
1070         MapVote_Start();
1071 };
1072
1073 /*
1074 ============
1075 FindIntermission
1076
1077 Returns the entity to view from
1078 ============
1079 */
1080 /*
1081 entity FindIntermission()
1082 {
1083         local   entity spot;
1084         local   float cyc;
1085
1086 // look for info_intermission first
1087         spot = find (world, classname, "info_intermission");
1088         if (spot)
1089         {       // pick a random one
1090                 cyc = random() * 4;
1091                 while (cyc > 1)
1092                 {
1093                         spot = find (spot, classname, "info_intermission");
1094                         if (!spot)
1095                                 spot = find (spot, classname, "info_intermission");
1096                         cyc = cyc - 1;
1097                 }
1098                 return spot;
1099         }
1100
1101 // then look for the start position
1102         spot = find (world, classname, "info_player_start");
1103         if (spot)
1104                 return spot;
1105
1106 // testinfo_player_start is only found in regioned levels
1107         spot = find (world, classname, "testplayerstart");
1108         if (spot)
1109                 return spot;
1110
1111 // then look for the start position
1112         spot = find (world, classname, "info_player_deathmatch");
1113         if (spot)
1114                 return spot;
1115
1116         //objerror ("FindIntermission: no spot");
1117         return world;
1118 };
1119 */
1120
1121 /*
1122 ===============================================================================
1123
1124 RULES
1125
1126 ===============================================================================
1127 */
1128
1129 void DumpStats(float final)
1130 {
1131         local float file;
1132         local string s;
1133         local float to_console;
1134         local float to_eventlog;
1135         local float to_file;
1136         local float i;
1137
1138         to_console = cvar("sv_logscores_console");
1139         to_eventlog = cvar("sv_eventlog");
1140         to_file = cvar("sv_logscores_file");
1141
1142         if(!final)
1143         {
1144                 to_console = TRUE; // always print printstats replies
1145                 to_eventlog = FALSE; // but never print them to the event log
1146         }
1147
1148         if(to_eventlog)
1149                 if(cvar("sv_eventlog_console"))
1150                         to_console = FALSE; // otherwise we get the output twice
1151
1152         if(final)
1153                 s = ":scores:";
1154         else
1155                 s = ":status:";
1156         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1157
1158         if(to_console)
1159                 print(s, "\n");
1160         if(to_eventlog)
1161                 GameLogEcho(s);
1162         if(to_file)
1163         {
1164                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1165                 if(file == -1)
1166                         to_file = FALSE;
1167                 else
1168                         fputs(file, strcat(s, "\n"));
1169         }
1170
1171         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1172         if(to_console)
1173                 print(s, "\n");
1174         if(to_eventlog)
1175                 GameLogEcho(s);
1176         if(to_file)
1177                 fputs(file, strcat(s, "\n"));
1178
1179         FOR_EACH_CLIENT(other)
1180         {
1181                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1182                 {
1183                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1184                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1185                         if(other.classname == "player" || g_arena || g_lms)
1186                                 s = strcat(s, ftos(other.team), ":");
1187                         else
1188                                 s = strcat(s, "spectator:");
1189
1190                         if(to_console)
1191                                 print(s, other.netname, "\n");
1192                         if(to_eventlog)
1193                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1194                         if(to_file)
1195                                 fputs(file, strcat(s, other.netname, "\n"));
1196                 }
1197         }
1198
1199         if(teams_matter)
1200         {
1201                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1202                 if(to_console)
1203                         print(s, "\n");
1204                 if(to_eventlog)
1205                         GameLogEcho(s);
1206                 if(to_file)
1207                         fputs(file, strcat(s, "\n"));
1208
1209                 for(i = 1; i < 16; ++i)
1210                 {
1211                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1212                         s = strcat(s, ":", ftos(i));
1213                         if(to_console)
1214                                 print(s, "\n");
1215                         if(to_eventlog)
1216                                 GameLogEcho(s);
1217                         if(to_file)
1218                                 fputs(file, strcat(s, "\n"));
1219                 }
1220         }
1221
1222         if(to_console)
1223                 print(":end\n");
1224         if(to_eventlog)
1225                 GameLogEcho(":end");
1226         if(to_file)
1227         {
1228                 fputs(file, ":end\n");
1229                 fclose(file);
1230         }
1231 }
1232
1233 void FixIntermissionClient(entity e)
1234 {
1235         string s;
1236         if(!e.autoscreenshot) // initial call
1237         {
1238                 e.angles = e.v_angle;
1239                 e.angles_x = -e.angles_x;
1240                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1241                 e.health = -2342;
1242                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1243                 e.solid = SOLID_NOT;
1244                 e.movetype = MOVETYPE_NONE;
1245                 e.takedamage = DAMAGE_NO;
1246                 if(e.weaponentity)
1247                 {
1248                         e.weaponentity.effects = EF_NODRAW;
1249                         if (e.weaponentity.weaponentity)
1250                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1251                 }
1252                 if(clienttype(e) == CLIENTTYPE_REAL)
1253                 {
1254                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1255                         s = cvar_string("sv_intermission_cdtrack");
1256                         if(s != "")
1257                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1258                         msg_entity = e;
1259                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1260                 }
1261         }
1262
1263         //e.velocity = '0 0 0';
1264         //e.fixangle = TRUE;
1265
1266         // TODO halt weapon animation
1267 }
1268
1269
1270 /*
1271 go to the next level for deathmatch
1272 only called if a time or frag limit has expired
1273 */
1274 void NextLevel()
1275 {
1276         float minTotalFrags;
1277         float maxTotalFrags;
1278         float score;
1279         float f;
1280
1281         gameover = TRUE;
1282
1283         intermission_running = 1;
1284
1285 // enforce a wait time before allowing changelevel
1286         if(player_count > 0)
1287                 intermission_exittime = time + cvar("sv_mapchange_delay");
1288         else
1289                 intermission_exittime = -1;
1290
1291         /*
1292         WriteByte (MSG_ALL, SVC_CDTRACK);
1293         WriteByte (MSG_ALL, 3);
1294         WriteByte (MSG_ALL, 3);
1295         // done in FixIntermission
1296         */
1297
1298         //pos = FindIntermission ();
1299
1300         VoteReset();
1301
1302         DumpStats(TRUE);
1303
1304         if(cvar("sv_eventlog"))
1305                 GameLogEcho(":gameover");
1306
1307         GameLogClose();
1308
1309         FOR_EACH_CLIENT(other)
1310         {
1311                 FixIntermissionClient(other);
1312
1313                 if(other.winning)
1314                         bprint(other.netname, " ^7wins.\n");
1315         }
1316
1317         minTotalFrags = 0;
1318         maxTotalFrags = 0;
1319         FOR_EACH_PLAYER(other)
1320         {
1321                 if(maxTotalFrags < other.totalfrags)
1322                         maxTotalFrags = other.totalfrags;
1323                 if(minTotalFrags > other.totalfrags)
1324                         minTotalFrags = other.totalfrags;
1325         }
1326
1327         if(!currentbots)
1328         {
1329                 FOR_EACH_PLAYER(other)
1330                 {
1331                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1332                         f = bound(0, other.play_time / max(time, 1), 1);
1333                         // store some statistics?
1334                 }
1335         }
1336
1337         if(cvar("g_campaign"))
1338                 CampaignPreIntermission();
1339
1340         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1341 };
1342
1343 /*
1344 ============
1345 CheckRules_Player
1346
1347 Exit deathmatch games upon conditions
1348 ============
1349 */
1350 void CheckRules_Player()
1351 {
1352         if (gameover)   // someone else quit the game already
1353                 return;
1354
1355         if(self.deadflag == DEAD_NO)
1356                 self.play_time += frametime;
1357
1358         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1359         //   (div0: and that in CheckRules_World please)
1360 };
1361
1362 float checkrules_oneminutewarning;
1363
1364 float checkrules_equality;
1365 float checkrules_suddendeathwarning;
1366 float checkrules_suddendeathend;
1367 float checkrules_overtimesadded; //how many overtimes have been already added
1368 float checkrules_status;
1369
1370 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1371 float WINNING_YES = 1; // winner found
1372 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1373 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1374
1375 void InitiateOvertime()
1376 {
1377         // Check first whether normal overtimes could be added before initiating suddendeath mode
1378         // - for this timelimit_overtime needs to be >0 of course
1379         // - also check the winning condition calculated in the previous frame and only add normal overtime
1380         //   again, if at the point at which timelimit would be extended again, still no winner was found
1381         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1382         {
1383                 ++checkrules_overtimesadded;
1384                 //add one more overtime by simply extending the timelimit
1385                 float tl;
1386                 tl = cvar("timelimit");
1387                 tl += cvar("timelimit_overtime");
1388                 cvar_set("timelimit", ftos(tl));
1389                 string minutesPlural;
1390                 if (cvar("timelimit_overtime") == 1)
1391                         minutesPlural = " ^3minute";
1392                 else
1393                         minutesPlural = " ^3minutes";
1394
1395                 bcenterprint(
1396                         strcat(
1397                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1398                                 ftos(cvar("timelimit_overtime")),
1399                                 minutesPlural,
1400                                 " to the game!"
1401                         )
1402                 );
1403         }
1404         else
1405         {
1406                 if(!checkrules_suddendeathend)
1407                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1408         }
1409 }
1410
1411 float GetWinningCode(float fraglimitreached, float equality)
1412 {
1413         if(equality)
1414                 if(fraglimitreached)
1415                         return WINNING_STARTSUDDENDEATHOVERTIME;
1416                 else
1417                         return WINNING_NEVER;
1418         else
1419                 if(fraglimitreached)
1420                         return WINNING_YES;
1421                 else
1422                         return WINNING_NO;
1423 }
1424
1425 // set the .winning flag for exactly those players with a given field value
1426 void SetWinners(.float field, float value)
1427 {
1428         entity head;
1429         FOR_EACH_PLAYER(head)
1430                 head.winning = (head.field == value);
1431 }
1432
1433 // set the .winning flag for those players with a given field value
1434 void AddWinners(.float field, float value)
1435 {
1436         entity head;
1437         FOR_EACH_PLAYER(head)
1438                 if(head.field == value)
1439                         head.winning = 1;
1440 }
1441
1442 // clear the .winning flags
1443 void ClearWinners(void)
1444 {
1445         entity head;
1446         FOR_EACH_PLAYER(head)
1447                 head.winning = 0;
1448 }
1449
1450 // Onslaught winning condition:
1451 // game terminates if only one team has a working generator (or none)
1452 float WinningCondition_Onslaught()
1453 {
1454         entity head;
1455         local float t1, t2, t3, t4;
1456
1457         WinningConditionHelper(); // set worldstatus
1458
1459         // first check if the game has ended
1460         t1 = t2 = t3 = t4 = 0;
1461         head = find(world, classname, "onslaught_generator");
1462         while (head)
1463         {
1464                 if (head.health > 0)
1465                 {
1466                         if (head.team == COLOR_TEAM1) t1 = 1;
1467                         if (head.team == COLOR_TEAM2) t2 = 1;
1468                         if (head.team == COLOR_TEAM3) t3 = 1;
1469                         if (head.team == COLOR_TEAM4) t4 = 1;
1470                 }
1471                 head = find(head, classname, "onslaught_generator");
1472         }
1473         if (t1 + t2 + t3 + t4 < 2)
1474         {
1475                 // game over, only one team remains (or none)
1476                 ClearWinners();
1477                 if (t1) SetWinners(team, COLOR_TEAM1);
1478                 if (t2) SetWinners(team, COLOR_TEAM2);
1479                 if (t3) SetWinners(team, COLOR_TEAM3);
1480                 if (t4) SetWinners(team, COLOR_TEAM4);
1481                 dprint("Have a winner, ending game.\n");
1482                 return WINNING_YES;
1483         }
1484
1485         // Two or more teams remain
1486         return WINNING_NO;
1487 }
1488
1489 float LMS_NewPlayerLives()
1490 {
1491         float fl;
1492         fl = cvar("fraglimit");
1493         if(fl == 0)
1494                 fl = 999;
1495
1496         // first player has left the game for dying too much? Nobody else can get in.
1497         if(lms_lowest_lives < 1)
1498                 return 0;
1499
1500         if(!cvar("g_lms_join_anytime"))
1501                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1502                         return 0;
1503
1504         return bound(1, lms_lowest_lives, fl);
1505 }
1506
1507 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1508 // they win. Otherwise the defending team wins once the timelimit passes.
1509 void assault_new_round();
1510 float WinningCondition_Assault()
1511 {
1512         local float status;
1513
1514         WinningConditionHelper(); // set worldstatus
1515
1516         status = WINNING_NO;
1517         // as the timelimit has not yet passed just assume the defending team will win
1518         if(assault_attacker_team == COLOR_TEAM1)
1519         {
1520                 SetWinners(team, COLOR_TEAM2);
1521         }
1522         else
1523         {
1524                 SetWinners(team, COLOR_TEAM1);
1525         }
1526
1527         local entity ent;
1528         ent = find(world, classname, "target_assault_roundend");
1529         if(ent)
1530         {
1531                 if(ent.winning) // round end has been triggered by attacking team
1532                 {
1533                         bprint("ASSAULT: round completed...\n");
1534                         SetWinners(team, assault_attacker_team);
1535
1536                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1537
1538                         if(ent.cnt == 1) // this was the second round
1539                         {
1540                                 status = WINNING_YES;
1541                         }
1542                         else
1543                         {
1544                                 local entity oldself;
1545                                 oldself = self;
1546                                 self = ent;
1547                                 assault_new_round();
1548                                 self = oldself;
1549                         }
1550                 }
1551         }
1552
1553         return status;
1554 }
1555
1556 // LMS winning condition: game terminates if and only if there's at most one
1557 // one player who's living lives. Top two scores being equal cancels the time
1558 // limit.
1559 float WinningCondition_LMS()
1560 {
1561         entity head, head2;
1562         float have_player;
1563         float have_players;
1564         float l;
1565
1566         have_player = FALSE;
1567         have_players = FALSE;
1568         l = LMS_NewPlayerLives();
1569
1570         head = find(world, classname, "player");
1571         if(head)
1572                 have_player = TRUE;
1573         head2 = find(head, classname, "player");
1574         if(head2)
1575                 have_players = TRUE;
1576
1577         if(have_player)
1578         {
1579                 // we have at least one player
1580                 if(have_players)
1581                 {
1582                         // two or more active players - continue with the game
1583                 }
1584                 else
1585                 {
1586                         // exactly one player?
1587
1588                         ClearWinners();
1589                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1590
1591                         if(l)
1592                         {
1593                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1594                                 return WINNING_NO;
1595                         }
1596                         else
1597                         {
1598                                 // a winner!
1599                                 // and assign him his first place
1600                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1601                                 return WINNING_YES;
1602                         }
1603                 }
1604         }
1605         else
1606         {
1607                 // nobody is playing at all...
1608                 if(l)
1609                 {
1610                         // wait for players...
1611                 }
1612                 else
1613                 {
1614                         // SNAFU (maybe a draw game?)
1615                         ClearWinners();
1616                         dprint("No players, ending game.\n");
1617                         return WINNING_YES;
1618                 }
1619         }
1620
1621         // When we get here, we have at least two players who are actually LIVING,
1622         // now check if the top two players have equal score.
1623         WinningConditionHelper();
1624
1625         ClearWinners();
1626         if(WinningConditionHelper_winner)
1627                 WinningConditionHelper_winner.winning = TRUE;
1628         if(WinningConditionHelper_equality)
1629                 return WINNING_NEVER;
1630
1631         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1632         return WINNING_NO;
1633 }
1634
1635 void ShuffleMaplist()
1636 {
1637         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1638 }
1639
1640 float leaderfrags;
1641 float WinningCondition_Scores(float limit)
1642 {
1643         // TODO make everything use THIS winning condition (except LMS)
1644         WinningConditionHelper();
1645
1646         if(teams_matter)
1647         {
1648                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1649                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1650                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1651                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1652         }
1653
1654         ClearWinners();
1655         if(WinningConditionHelper_winner)
1656                 WinningConditionHelper_winner.winning = 1;
1657         if(WinningConditionHelper_winnerteam >= 0)
1658                 SetWinners(team, WinningConditionHelper_winnerteam);
1659
1660         if(WinningConditionHelper_lowerisbetter)
1661         {
1662                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1663                 limit = -limit;
1664         }
1665
1666         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1667         // these modes always score in increments of 1, thus this makes sense
1668         {
1669                 if(leaderfrags != WinningConditionHelper_topscore)
1670                 {
1671                         leaderfrags = WinningConditionHelper_topscore;
1672
1673                         if (limit)
1674                         if (leaderfrags == limit - 1)
1675                                 play2all("announcer/robotic/1fragleft.wav");
1676                         else if (leaderfrags == limit - 2)
1677                                 play2all("announcer/robotic/2fragsleft.wav");
1678                         else if (leaderfrags == limit - 3)
1679                                 play2all("announcer/robotic/3fragsleft.wav");
1680                 }
1681         }
1682
1683         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1684 }
1685
1686 float WinningCondition_Race(float fraglimit)
1687 {
1688         float wc;
1689         entity p;
1690         wc = WinningCondition_Scores(fraglimit);
1691
1692         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1693         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1694         // do NOT support equality when the laps are all raced!
1695         {
1696                 FOR_EACH_PLAYER(p)
1697                         if not(p.race_completed)
1698                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1699                 return WINNING_YES;
1700         }
1701         return wc;
1702 }
1703
1704 void ReadyRestart();
1705 float WinningCondition_QualifyingThenRace(float limit)
1706 {
1707         float wc;
1708         wc = WinningCondition_Scores(limit);
1709
1710         // NEVER initiate overtime
1711         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1712         {
1713                 return WINNING_YES;
1714         }
1715
1716         return wc;
1717 }
1718
1719 float WinningCondition_RanOutOfSpawns()
1720 {
1721         entity head;
1722
1723         if(!have_team_spawns)
1724                 return WINNING_NO;
1725
1726         if(!some_spawn_has_been_used)
1727                 return WINNING_NO;
1728
1729         team1_score = team2_score = team3_score = team4_score = 0;
1730
1731         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1732         {
1733                 if(head.team == COLOR_TEAM1)
1734                         team1_score = 1;
1735                 else if(head.team == COLOR_TEAM2)
1736                         team2_score = 1;
1737                 else if(head.team == COLOR_TEAM3)
1738                         team3_score = 1;
1739                 else if(head.team == COLOR_TEAM4)
1740                         team4_score = 1;
1741         }
1742
1743         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1744         {
1745                 if(head.team == COLOR_TEAM1)
1746                         team1_score = 1;
1747                 else if(head.team == COLOR_TEAM2)
1748                         team2_score = 1;
1749                 else if(head.team == COLOR_TEAM3)
1750                         team3_score = 1;
1751                 else if(head.team == COLOR_TEAM4)
1752                         team4_score = 1;
1753         }
1754
1755         ClearWinners();
1756         if(team1_score + team2_score + team3_score + team4_score == 0)
1757         {
1758                 checkrules_equality = TRUE;
1759                 return WINNING_YES;
1760         }
1761         else if(team1_score + team2_score + team3_score + team4_score == 1)
1762         {
1763                 float t, i;
1764                 if(team1_score) t = COLOR_TEAM1;
1765                 if(team2_score) t = COLOR_TEAM2;
1766                 if(team3_score) t = COLOR_TEAM3;
1767                 if(team4_score) t = COLOR_TEAM4;
1768                 CheckAllowedTeams(world);
1769                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1770                 {
1771                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1772                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1773                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1774                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1775                 }
1776
1777                 AddWinners(team, t);
1778                 return WINNING_YES;
1779         }
1780         else
1781                 return WINNING_NO;
1782 }
1783
1784 /*
1785 ============
1786 CheckRules_World
1787
1788 Exit deathmatch games upon conditions
1789 ============
1790 */
1791 void CheckRules_World()
1792 {
1793         local float timelimit;
1794         local float fraglimit;
1795
1796         VoteThink();
1797         MapVote_Think();
1798
1799         SetDefaultAlpha();
1800
1801         /*
1802         MapVote_Think should now do that part
1803         if (intermission_running)
1804                 if (time >= intermission_exittime + 60)
1805                 {
1806                         if(!DoNextMapOverride())
1807                                 GotoNextMap();
1808                         return;
1809                 }
1810         */
1811
1812         if (gameover)   // someone else quit the game already
1813         {
1814                 if(player_count == 0) // Nobody there? Then let's go to the next map
1815                         MapVote_Start();
1816                         // this will actually check the player count in the next frame
1817                         // again, but this shouldn't hurt
1818                 return;
1819         }
1820
1821         timelimit = cvar("timelimit") * 60;
1822         fraglimit = cvar("fraglimit");
1823
1824         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1825         {
1826                 if(timelimit > 0)
1827                         timelimit = 0; // timelimit is not made for warmup
1828                 if(fraglimit > 0)
1829                         fraglimit = 0; // no fraglimit for now
1830         }
1831
1832         if(timelimit > 0)
1833         {
1834                 timelimit += game_starttime;
1835         }
1836         else if (timelimit < 0)
1837         {
1838                 // endmatch
1839                 NextLevel();
1840                 return;
1841         }
1842
1843         if(checkrules_suddendeathend)
1844         {
1845                 if(!checkrules_suddendeathwarning)
1846                 {
1847                         checkrules_suddendeathwarning = TRUE;
1848                         if(g_race && !g_race_qualifying)
1849                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1850                         else
1851                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1852                 }
1853         }
1854         else
1855         {
1856                 if (timelimit && time >= timelimit)
1857                 {
1858                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1859                         {
1860                                 float totalplayers;
1861                                 float playerswithlaps;
1862                                 float readyplayers;
1863                                 entity head;
1864                                 totalplayers = playerswithlaps = readyplayers = 0;
1865                                 FOR_EACH_PLAYER(head)
1866                                 {
1867                                         ++totalplayers;
1868                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1869                                                 ++playerswithlaps;
1870                                         if(head.ready)
1871                                                 ++readyplayers;
1872                                 }
1873
1874                                 // at least 2/3 of the players have completed a lap: start the RACE
1875                                 // otherwise, the players should end the qualifying on their own
1876                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1877                                 {
1878                                         checkrules_suddendeathend = 0;
1879                                         ReadyRestart(); // go to race
1880                                 }
1881                                 else
1882                                         InitiateOvertime();
1883                         }
1884                         else
1885                                 InitiateOvertime();
1886                 }
1887         }
1888
1889         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1890         {
1891                 NextLevel();
1892                 return;
1893         }
1894
1895         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1896         {
1897                 checkrules_oneminutewarning = TRUE;
1898                 play2all("announcer/robotic/1minuteremains.wav");
1899         }
1900
1901         checkrules_status = WinningCondition_RanOutOfSpawns();
1902         if(checkrules_status == WINNING_YES)
1903         {
1904                 bprint("Hey! Someone ran out of spawns!\n");
1905         }
1906         else if(g_race && !g_race_qualifying && timelimit >= 0)
1907         {
1908                 checkrules_status = WinningCondition_Race(fraglimit);
1909         }
1910         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1911         {
1912                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1913         }
1914         else if(g_assault)
1915         {
1916                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1917         }
1918         else if(g_lms)
1919         {
1920                 checkrules_status = WinningCondition_LMS();
1921         }
1922         else if (g_onslaught)
1923         {
1924                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1925         }
1926         else
1927         {
1928                 checkrules_status = WinningCondition_Scores(fraglimit);
1929         }
1930
1931         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1932         {
1933                 checkrules_status = WINNING_NEVER;
1934                 InitiateOvertime();
1935         }
1936
1937         if(checkrules_status == WINNING_NEVER)
1938                 // equality cases! Nobody wins if the overtime ends in a draw.
1939                 ClearWinners();
1940
1941         if(checkrules_suddendeathend)
1942                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1943                         checkrules_status = WINNING_YES;
1944
1945         if(checkrules_status == WINNING_YES)
1946                 NextLevel();
1947 };
1948
1949 float mapvote_nextthink;
1950 float mapvote_initialized;
1951 float mapvote_keeptwotime;
1952 float mapvote_timeout;
1953 string mapvote_message;
1954 string mapvote_screenshot_dir;
1955
1956 float mapvote_count;
1957 float mapvote_count_real;
1958 string mapvote_maps[MAPVOTE_COUNT];
1959 float mapvote_maps_suggested[MAPVOTE_COUNT];
1960 string mapvote_suggestions[MAPVOTE_COUNT];
1961 float mapvote_suggestion_ptr;
1962 float mapvote_maxlen;
1963 float mapvote_voters;
1964 float mapvote_votes[MAPVOTE_COUNT];
1965 float mapvote_run;
1966 float mapvote_detail;
1967 float mapvote_abstain;
1968 .float mapvote;
1969
1970 void MapVote_ClearAllVotes()
1971 {
1972         FOR_EACH_CLIENT(other)
1973                 other.mapvote = 0;
1974 }
1975
1976 string MapVote_Suggest(string m)
1977 {
1978         float i;
1979         if(m == "")
1980                 return "That's not how to use this command.";
1981         if(!cvar("g_maplist_votable_suggestions"))
1982                 return "Suggestions are not accepted on this server.";
1983         if(mapvote_initialized)
1984                 return "Can't suggest - voting is already in progress!";
1985         m = MapInfo_FixName(m);
1986         if(!m)
1987                 return "The map you suggested is not available on this server.";
1988         if(!cvar("g_maplist_votable_override_mostrecent"))
1989                 if(Map_IsRecent(m))
1990                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1991
1992         if(!MapInfo_CheckMap(m))
1993                 return "The map you suggested does not support the current game mode.";
1994         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1995                 if(mapvote_suggestions[i] == m)
1996                         return "This map was already suggested.";
1997         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1998         {
1999                 i = floor(random() * mapvote_suggestion_ptr);
2000         }
2001         else
2002         {
2003                 i = mapvote_suggestion_ptr;
2004                 mapvote_suggestion_ptr += 1;
2005         }
2006         if(mapvote_suggestions[i] != "")
2007                 strunzone(mapvote_suggestions[i]);
2008         mapvote_suggestions[i] = strzone(m);
2009         if(cvar("sv_eventlog"))
2010                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2011         return strcat("Suggestion of ", m, " accepted.");
2012 }
2013
2014 void MapVote_AddVotable(string nextMap, float isSuggestion)
2015 {
2016         float j;
2017         if(nextMap == "")
2018                 return;
2019         for(j = 0; j < mapvote_count; ++j)
2020                 if(mapvote_maps[j] == nextMap)
2021                         return;
2022         if(strlen(nextMap) > mapvote_maxlen)
2023                 mapvote_maxlen = strlen(nextMap);
2024         mapvote_maps[mapvote_count] = strzone(nextMap);
2025         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2026         mapvote_count += 1;
2027 }
2028
2029 void MapVote_Spawn();
2030 void MapVote_Init()
2031 {
2032         float i;
2033         float nmax, smax;
2034
2035         MapVote_ClearAllVotes();
2036
2037         mapvote_count = 0;
2038         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2039         mapvote_abstain = cvar("g_maplist_votable_abstain");
2040
2041         if(mapvote_abstain)
2042                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2043         else
2044                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2045         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2046
2047         if(mapvote_suggestion_ptr)
2048                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2049                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2050
2051         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2052                 MapVote_AddVotable(GetNextMap(), FALSE);
2053
2054         if(mapvote_count == 0)
2055         {
2056                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2057                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2058                 if(cvar("g_maplist_shuffle"))
2059                         ShuffleMaplist();
2060                 localcmd("\nmenu_cmd sync\n");
2061                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2062                         MapVote_AddVotable(GetNextMap(), FALSE);
2063         }
2064
2065         mapvote_count_real = mapvote_count;
2066         if(mapvote_abstain)
2067                 MapVote_AddVotable("don't care", 0);
2068
2069         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2070
2071         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2072         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2073         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2074                 mapvote_keeptwotime = 0;
2075         mapvote_message = "Choose a map and press its key!";
2076
2077         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2078         if(mapvote_screenshot_dir == "")
2079                 mapvote_screenshot_dir = "maps";
2080         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2081
2082         MapVote_Spawn();
2083 }
2084
2085 void MapVote_SendPicture(float id)
2086 {
2087         msg_entity = self;
2088         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2089         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2090         WriteByte(MSG_ONE, id);
2091         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2092 }
2093
2094 float GameCommand_MapVote(string cmd)
2095 {
2096         if(!intermission_running)
2097                 return FALSE;
2098
2099         if(cmd == "mv_getpic")
2100         {
2101                 MapVote_SendPicture(stof(argv(1)));
2102                 return TRUE;
2103         }
2104
2105         return FALSE;
2106 }
2107
2108 float MapVote_GetMapMask()
2109 {
2110         float mask, i, power;
2111         mask = 0;
2112         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2113                 if(mapvote_maps[i] != "")
2114                         mask |= power;
2115         return mask;
2116 }
2117
2118 entity mapvote_ent;
2119 float MapVote_SendEntity(entity to, float sf)
2120 {
2121         string mapfile, pakfile;
2122         float i, o;
2123
2124         if(sf & 1)
2125                 sf &~= 2; // if we send 1, we don't need to also send 2
2126
2127         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2128         WriteByte(MSG_ENTITY, sf);
2129
2130         if(sf & 1)
2131         {
2132                 // flag 1 == initialization
2133                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2134                 WriteByte(MSG_ENTITY, mapvote_count);
2135                 WriteByte(MSG_ENTITY, mapvote_abstain);
2136                 WriteByte(MSG_ENTITY, mapvote_detail);
2137                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2138                 if(mapvote_count <= 8)
2139                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2140                 else
2141                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2142                 for(i = 0; i < mapvote_count; ++i)
2143                         if(mapvote_maps[i] != "")
2144                         {
2145                                 if(mapvote_abstain && i == mapvote_count - 1)
2146                                 {
2147                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2148                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2149                                 }
2150                                 else
2151                                 {
2152                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2153                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2154                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2155                                         if(pakfile == "")
2156                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2157                                         if(pakfile == "")
2158                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2159                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2160                                                 pakfile = substring(pakfile, o, 999);
2161                                         WriteString(MSG_ENTITY, pakfile);
2162                                 }
2163                         }
2164         }
2165
2166         if(sf & 2)
2167         {
2168                 // flag 2 == update of mask
2169                 if(mapvote_count <= 8)
2170                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2171                 else
2172                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2173         }
2174
2175         if(sf & 4)
2176         {
2177                 if(mapvote_detail)
2178                         for(i = 0; i < mapvote_count; ++i)
2179                                 if(mapvote_maps[i] != "")
2180                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2181
2182                 WriteByte(MSG_ENTITY, to.mapvote);
2183         }
2184
2185         return TRUE;
2186 }
2187
2188 void MapVote_Spawn()
2189 {
2190         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2191 }
2192
2193 void MapVote_TouchMask()
2194 {
2195         mapvote_ent.SendFlags |= 2;
2196 }
2197
2198 void MapVote_TouchVotes(entity voter)
2199 {
2200         mapvote_ent.SendFlags |= 4;
2201 }
2202
2203 float MapVote_Finished(float mappos)
2204 {
2205         string result;
2206         float i;
2207         float didntvote;
2208
2209         if(cvar("sv_eventlog"))
2210         {
2211                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2212                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2213                 didntvote = mapvote_voters;
2214                 for(i = 0; i < mapvote_count; ++i)
2215                         if(mapvote_maps[i] != "")
2216                         {
2217                                 didntvote -= mapvote_votes[i];
2218                                 if(i != mappos)
2219                                 {
2220                                         result = strcat(result, ":", mapvote_maps[i]);
2221                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2222                                 }
2223                         }
2224                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2225
2226                 GameLogEcho(result);
2227                 if(mapvote_maps_suggested[mappos])
2228                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2229         }
2230
2231         FOR_EACH_REALCLIENT(other)
2232                 FixClientCvars(other);
2233
2234         Map_Goto_SetStr(mapvote_maps[mappos]);
2235         Map_Goto();
2236         alreadychangedlevel = TRUE;
2237         return TRUE;
2238 }
2239 void MapVote_CheckRules_1()
2240 {
2241         float i;
2242
2243         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2244         {
2245                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2246                 mapvote_votes[i] = 0;
2247         }
2248
2249         mapvote_voters = 0;
2250         FOR_EACH_REALCLIENT(other)
2251         {
2252                 ++mapvote_voters;
2253                 if(other.mapvote)
2254                 {
2255                         i = other.mapvote - 1;
2256                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2257                         mapvote_votes[i] = mapvote_votes[i] + 1;
2258                 }
2259         }
2260 }
2261
2262 float MapVote_CheckRules_2()
2263 {
2264         float i;
2265         float firstPlace, secondPlace;
2266         float firstPlaceVotes, secondPlaceVotes;
2267         float mapvote_voters_real;
2268         string result;
2269
2270         if(mapvote_count_real == 1)
2271                 return MapVote_Finished(0);
2272
2273         mapvote_voters_real = mapvote_voters;
2274         if(mapvote_abstain)
2275                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2276
2277         RandomSelection_Init();
2278         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2279                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2280         firstPlace = RandomSelection_chosen_float;
2281         firstPlaceVotes = RandomSelection_best_priority;
2282         //dprint("First place: ", ftos(firstPlace), "\n");
2283         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2284
2285         RandomSelection_Init();
2286         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2287                 if(i != firstPlace)
2288                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2289         secondPlace = RandomSelection_chosen_float;
2290         secondPlaceVotes = RandomSelection_best_priority;
2291         //dprint("Second place: ", ftos(secondPlace), "\n");
2292         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2293
2294         if(firstPlace == -1)
2295                 error("No first place in map vote... WTF?");
2296
2297         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2298                 return MapVote_Finished(firstPlace);
2299
2300         if(mapvote_keeptwotime)
2301                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2302                 {
2303                         float didntvote;
2304                         MapVote_TouchMask();
2305                         mapvote_message = "Now decide between the TOP TWO!";
2306                         mapvote_keeptwotime = 0;
2307                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2308                         result = strcat(result, ":", ftos(firstPlaceVotes));
2309                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2310                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2311                         didntvote = mapvote_voters;
2312                         for(i = 0; i < mapvote_count; ++i)
2313                                 if(mapvote_maps[i] != "")
2314                                 {
2315                                         didntvote -= mapvote_votes[i];
2316                                         if(i != firstPlace)
2317                                                 if(i != secondPlace)
2318                                                 {
2319                                                         result = strcat(result, ":", mapvote_maps[i]);
2320                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2321                                                         if(i < mapvote_count_real)
2322                                                         {
2323                                                                 strunzone(mapvote_maps[i]);
2324                                                                 mapvote_maps[i] = "";
2325                                                         }
2326                                                 }
2327                                 }
2328                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2329                         if(cvar("sv_eventlog"))
2330                                 GameLogEcho(result);
2331                 }
2332
2333         return FALSE;
2334 }
2335 void MapVote_Tick()
2336 {
2337         float keeptwo;
2338         float totalvotes;
2339
2340         keeptwo = mapvote_keeptwotime;
2341         MapVote_CheckRules_1(); // count
2342         if(MapVote_CheckRules_2()) // decide
2343                 return;
2344
2345         totalvotes = 0;
2346         FOR_EACH_REALCLIENT(other)
2347         {
2348                 // hide scoreboard again
2349                 if(other.health != 2342)
2350                 {
2351                         other.health = 2342;
2352                         other.impulse = 0;
2353                         if(clienttype(other) == CLIENTTYPE_REAL)
2354                         {
2355                                 msg_entity = other;
2356                                 WriteByte(MSG_ONE, SVC_FINALE);
2357                                 WriteString(MSG_ONE, "");
2358                         }
2359                 }
2360
2361                 // clear possibly invalid votes
2362                 if(mapvote_maps[other.mapvote - 1] == "")
2363                         other.mapvote = 0;
2364                 // use impulses as new vote
2365                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2366                         if(mapvote_maps[other.impulse - 1] != "")
2367                         {
2368                                 other.mapvote = other.impulse;
2369                                 MapVote_TouchVotes(other);
2370                         }
2371                 other.impulse = 0;
2372
2373                 if(other.mapvote)
2374                         ++totalvotes;
2375         }
2376
2377         MapVote_CheckRules_1(); // just count
2378 }
2379 void MapVote_Start()
2380 {
2381         if(mapvote_run)
2382                 return;
2383
2384         MapInfo_Enumerate();
2385         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2386                 mapvote_run = TRUE;
2387 }
2388 void MapVote_Think()
2389 {
2390         if(!mapvote_run)
2391                 return;
2392
2393         if(alreadychangedlevel)
2394                 return;
2395
2396         if(time < mapvote_nextthink)
2397                 return;
2398         //dprint("tick\n");
2399
2400         mapvote_nextthink = time + 0.5;
2401
2402         if(!mapvote_initialized)
2403         {
2404                 mapvote_initialized = TRUE;
2405                 if(DoNextMapOverride())
2406                         return;
2407                 if(!cvar("g_maplist_votable") || player_count <= 0)
2408                 {
2409                         GotoNextMap();
2410                         return;
2411                 }
2412                 MapVote_Init();
2413         }
2414
2415         MapVote_Tick();
2416 };
2417
2418 string GotoMap(string m)
2419 {
2420         if(!MapInfo_CheckMap(m))
2421                 return "The map you chose is not available on this server.";
2422         cvar_set("nextmap", m);
2423         cvar_set("timelimit", "-1");
2424         if(mapvote_initialized || alreadychangedlevel)
2425         {
2426                 if(DoNextMapOverride())
2427                         return "Map switch initiated.";
2428                 else
2429                         return "Hm... no. For some reason I like THIS map more.";
2430         }
2431         else
2432                 return "Map switch will happen after scoreboard.";
2433 }
2434
2435
2436 void EndFrame()
2437 {
2438         FOR_EACH_REALCLIENT(self)
2439         {
2440                 if(self.classname == "spectator")
2441                 {
2442                         if(self.enemy.typehitsound)
2443                                 play2(self, "misc/typehit.wav");
2444                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2445                                 play2(self, "misc/hit.wav");
2446                 }
2447                 else
2448                 {
2449                         if(self.typehitsound)
2450                                 play2(self, "misc/typehit.wav");
2451                         else if(self.hitsound && self.cvar_cl_hitsound)
2452                                 play2(self, "misc/hit.wav");
2453                 }
2454         }
2455         FOR_EACH_CLIENT(self)
2456         {
2457                 self.hitsound = FALSE;
2458                 self.typehitsound = FALSE;
2459         }
2460 }
2461
2462
2463 /*
2464  * RedirectionThink:
2465  * returns TRUE if redirecting
2466  */
2467 float redirection_timeout;
2468 float redirection_nextthink;
2469 float RedirectionThink()
2470 {
2471         float clients_found;
2472
2473         if(redirection_target == "")
2474                 return FALSE;
2475
2476         if(!redirection_timeout)
2477         {
2478                 cvar_set("sv_public", "-2");
2479                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2480                 if(redirection_target == "self")
2481                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2482                 else
2483                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2484         }
2485
2486         if(time < redirection_nextthink)
2487                 return TRUE;
2488
2489         redirection_nextthink = time + 1;
2490
2491         clients_found = 0;
2492         FOR_EACH_REALCLIENT(self)
2493         {
2494                 print("Redirecting: sending connect command to ", self.netname, "\n");
2495                 if(redirection_target == "self")
2496                         stuffcmd(self, "\ndisconnect; reconnect\n");
2497                 else
2498                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2499                 ++clients_found;
2500         }
2501
2502         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2503
2504         if(time > redirection_timeout || clients_found == 0)
2505                 localcmd("\nwait; wait; wait; quit\n");
2506
2507         return TRUE;
2508 }
2509
2510 void RestoreGame()
2511 {
2512         // Loaded from a save game
2513         // some things then break, so let's work around them...
2514
2515         // Progs DB (capture records)
2516         if(sv_cheats)
2517                 ServerProgsDB = db_create();
2518         else
2519                 ServerProgsDB = db_load("server.db");
2520
2521         // Mapinfo
2522         MapInfo_Shutdown();
2523         MapInfo_Enumerate();
2524         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2525 }
2526
2527 void SV_Shutdown()
2528 {
2529         if(world_initialized > 0)
2530         {
2531                 world_initialized = 0;
2532                 print("Saving persistent data...\n");
2533                 Ban_SaveBans();
2534                 if(!sv_cheats)
2535                         db_save(ServerProgsDB, "server.db");
2536                 if(cvar("developer"))
2537                         db_save(TemporaryDB, "server-temp.db");
2538                 db_close(ServerProgsDB);
2539                 db_close(TemporaryDB);
2540                 print("done!\n");
2541                 // tell the bot system the game is ending now
2542                 bot_endgame();
2543
2544                 MapInfo_Shutdown();
2545         }
2546         else if(world_initialized == 0)
2547         {
2548                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2549         }
2550 }