data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_cts");
 255                 BADCVAR("g_runematch");
 256                 BADCVAR("g_tdm");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("teamplay");
 259
 260                 // long
 261                 BADCVAR("hostname");
 262                 BADCVAR("g_maplist");
 263                 BADCVAR("g_maplist_mostrecent");
 264                 BADCVAR("sv_motd");
 265 #undef BADPREFIX
 266 #undef BADCVAR
 267
 268                 v = cvar_string(k);
 269                 d = cvar_defstring(k);
 270                 if(v != d)
 271                 {
 272                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 273                         if(strlen(cvar_changes) > 16384)
 274                         {
 275                                 cvar_changes = "// too many settings have been changed to show them here\n";
 276                                 break;
 277                         }
 278                 }
 279         }
 280         buf_del(h);
 281         if(cvar_changes == "")
 282                 cvar_changes = "// this server runs at default settings\n";
 283         else
 284                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 285         cvar_changes = strzone(cvar_changes);
 286 }
 287
 288 void detect_maptype()
 289 {
 290 #if 0
 291         vector o, v;
 292         float i;
 293
 294         for(;;)
 295         {
 296                 o = world.mins;
 297                 o_x += random() * (world.maxs_x - world.mins_x);
 298                 o_y += random() * (world.maxs_y - world.mins_y);
 299                 o_z += random() * (world.maxs_z - world.mins_z);
 300
 301                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 302                 if(trace_fraction == 1)
 303                         continue;
 304
 305                 v = trace_endpos;
 306
 307                 for(i = 0; i < 64; i += 4)
 308                 {
 309                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 310         if(trace_fraction == 1)
 311                 continue;
 312                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 313                 }
 314
 315                 break;
 316         }
 317 #endif
 318 }
 319
 320 entity randomseed;
 321 float RandomSeed_Send(entity to, float sf)
 322 {
 323         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 324         WriteShort(MSG_ENTITY, self.cnt);
 325         return TRUE;
 326 }
 327 void RandomSeed_Think()
 328 {
 329         self.cnt = bound(0, floor(random() * 65536), 65535);
 330         self.nextthink = time + 5;
 331
 332         self.SendFlags |= 1;
 333 }
 334 void RandomSeed_Spawn()
 335 {
 336         randomseed = spawn();
 337         randomseed.think = RandomSeed_Think;
 338         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 339
 340         entity oldself;
 341         oldself = self;
 342         self = randomseed;
 343         self.think(); // sets random seed and nextthink
 344         self = oldself;
 345 }
 346
 347 void spawnfunc___init_dedicated_server(void)
 348 {
 349         // handler for _init/_init map (only for dedicated server initialization)
 350
 351         world_initialized = -1; // don't complain
 352         cvar = cvar_builtin;
 353         cvar_string = cvar_string_builtin;
 354         cvar_set = cvar_set_builtin;
 355         dprint_load(); // load dprint status from cvar
 356
 357         remove = remove_unsafely;
 358
 359         entity e;
 360         e = spawn();
 361         e.think = GotoFirstMap;
 362         e.nextthink = time; // this is usually 1 at this point
 363
 364         e = spawn();
 365         e.classname = "info_player_deathmatch"; // safeguard against player joining
 366
 367         self.classname = "worldspawn"; // safeguard against various stuff ;)
 368
 369         MapInfo_Enumerate();
 370         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 371 }
 372
 373 void Map_MarkAsRecent(string m);
 374 float world_already_spawned;
 375 void RegisterWeapons();
 376 void Nagger_Init();
 377 void ClientInit_Spawn();
 378 void spawnfunc_worldspawn (void)
 379 {
 380         float fd, l, i, j, n;
 381         string s, col;
 382
 383         cvar = cvar_builtin;
 384         cvar_string = cvar_string_builtin;
 385         cvar_set = cvar_set_builtin;
 386         dprint_load(); // load dprint status from cvar
 387
 388         if(world_already_spawned)
 389                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 390         world_already_spawned = TRUE;
 391
 392         remove = remove_safely; // during spawning, watch what you remove!
 393
 394         check_unacceptable_compiler_bugs();
 395
 396         if(cvar_string("cvar_check_default") != "bypass")
 397         {
 398                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 399                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 400
 401                 if(cvar_string("cvar_check_balance") != CVAR_CHECK_BALANCE)
 402                         error("Config file mismatch! Please update balance*.cfg to match the QuakeC code, and restart the engine!");
 403         }
 404
 405         compressShortVector_init();
 406
 407         local entity head;
 408         head = nextent(world);
 409         maxclients = 0;
 410         while(head)
 411         {
 412                 ++maxclients;
 413                 head = nextent(head);
 414         }
 415
 416         // needs to be done so early as they would still spawn
 417         RegisterWeapons();
 418
 419         if(sv_cheats)
 420                 ServerProgsDB = db_create();
 421         else
 422                 ServerProgsDB = db_load("server.db");
 423
 424         TemporaryDB = db_create();
 425
 426         /*
 427         TODO sound pack system
 428         // initialize sound pack system
 429         soundpack = cvar_string("g_soundpack");
 430         if(soundpack != "")
 431                 soundpack = strcat(soundpack, "/");
 432         soundpack = strzone(soundpack);
 433         */
 434
 435         // 0 normal
 436         lightstyle(0, "m");
 437
 438         // 1 FLICKER (first variety)
 439         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 440
 441         // 2 SLOW STRONG PULSE
 442         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 443
 444         // 3 CANDLE (first variety)
 445         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 446
 447         // 4 FAST STROBE
 448         lightstyle(4, "mamamamamama");
 449
 450         // 5 GENTLE PULSE 1
 451         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 452
 453         // 6 FLICKER (second variety)
 454         lightstyle(6, "nmonqnmomnmomomno");
 455
 456         // 7 CANDLE (second variety)
 457         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 458
 459         // 8 CANDLE (third variety)
 460         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 461
 462         // 9 SLOW STROBE (fourth variety)
 463         lightstyle(9, "aaaaaaaazzzzzzzz");
 464
 465         // 10 FLUORESCENT FLICKER
 466         lightstyle(10, "mmamammmmammamamaaamammma");
 467
 468         // 11 SLOW PULSE NOT FADE TO BLACK
 469         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 470
 471         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 472
 473         // 63 testing
 474         lightstyle(63, "a");
 475
 476         if(cvar("g_campaign"))
 477                 CampaignPreInit();
 478
 479         Map_MarkAsRecent(mapname);
 480
 481         precache_model ("null"); // we need this one before InitGameplayMode
 482         InitGameplayMode();
 483         readlevelcvars();
 484         GrappleHookInit();
 485
 486         player_count = 0;
 487         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 488         if(bot_waypoints_for_items == 1)
 489                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 490                         bot_waypoints_for_items = 0;
 491
 492         // for setting by mapinfo
 493         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 494         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 495
 496         precache();
 497
 498         WaypointSprite_Init();
 499
 500         //if (g_domination)
 501         //      dom_init();
 502
 503         GameLogInit(); // prepare everything
 504         if(cvar("sv_eventlog"))
 505         {
 506                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 507                 s = strcat(s, ftos(random()));
 508                 matchid = strzone(s);
 509
 510                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 511                 s = ":gameinfo:mutators:LIST";
 512                 if(cvar("g_grappling_hook"))
 513                         s = strcat(s, ":grappling_hook");
 514                 if(!cvar("g_use_ammunition"))
 515                         s = strcat(s, ":no_use_ammunition");
 516                 if(!cvar("g_pickup_items"))
 517                         s = strcat(s, ":no_pickup_items");
 518                 if(cvar("g_instagib"))
 519                         s = strcat(s, ":instagib");
 520                 if(cvar_string("g_weaponarena") != "0")
 521                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 522                 if(cvar("g_nixnex"))
 523                         s = strcat(s, ":nixnex");
 524                 if(cvar("g_vampire"))
 525                         s = strcat(s, ":vampire");
 526                 if(cvar("g_laserguided_missile"))
 527                         s = strcat(s, ":laserguided_missile");
 528                 if(cvar("g_norecoil"))
 529                         s = strcat(s, ":norecoil");
 530                 if(cvar("g_midair"))
 531                         s = strcat(s, ":midair");
 532                 if(cvar("g_minstagib"))
 533                         s = strcat(s, ":minstagib");
 534                 GameLogEcho(s);
 535                 GameLogEcho(":gameinfo:end");
 536         }
 537         else
 538                 matchid = strzone(ftos(random()));
 539
 540         cvar_set("nextmap", "");
 541
 542         SetDefaultAlpha();
 543
 544         if(cvar("g_campaign"))
 545                 CampaignPostInit();
 546
 547         fteqcc_testbugs();
 548
 549         Ban_LoadBans();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 553
 554         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 555         {
 556                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 557                 if(fd != -1)
 558                 {
 559                         while((s = fgets(fd)))
 560                         {
 561                                 l = tokenize_console(s);
 562                                 if(l < 2)
 563                                         continue;
 564                                 if(argv(0) == "cd")
 565                                 {
 566                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 567                                         print("  cdtrack ", argv(2), "\n");
 568                                 }
 569                                 else if(argv(0) == "fog")
 570                                 {
 571                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 572                                         print("  \"fog\" \"", s, "\"\n");
 573                                 }
 574                                 else if(argv(0) == "set")
 575                                 {
 576                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 577                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 578                                 }
 579                                 else if(argv(0) != "//")
 580                                 {
 581                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 582                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 583                                 }
 584                         }
 585                         fclose(fd);
 586                 }
 587         }
 588
 589         addstat(STAT_WEAPONS, AS_INT, weapons);
 590         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 591         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 592         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 593         Nagger_Init();
 594
 595         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 596         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 597         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 598         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 599         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 600         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 601         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 602         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 603         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 604
 605         next_pingtime = time + 5;
 606         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 607
 608         detect_maptype();
 609
 610         lsmaps_reply = "^7Maps available: ";
 611         for(i = 0, j = 0; i < MapInfo_count; ++i)
 612         {
 613                 if(MapInfo_Get_ByID(i))
 614                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 615                         {
 616                                 if(mod(i, 2))
 617                                         col = "^2";
 618                                 else
 619                                         col = "^3";
 620                                 ++j;
 621                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 622                         }
 623         }
 624         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 625
 626         maplist_reply = "^7Maps in list: ";
 627         n = tokenize_console(cvar_string("g_maplist"));
 628         for(i = 0, j = 0; i < n; ++i)
 629         {
 630                 if(MapInfo_CheckMap(argv(i)))
 631                 {
 632                         if(mod(j, 2))
 633                                 col = "^2";
 634                         else
 635                                 col = "^3";
 636                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 637                         ++j;
 638                 }
 639         }
 640         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 641         MapInfo_ClearTemps();
 642
 643         records_reply = strzone(getrecords());
 644
 645         ClientInit_Spawn();
 646         RandomSeed_Spawn();
 647
 648         localcmd("\n_sv_hook_gamestart ", GetGametype(), ";");
 649
 650         world_initialized = 1;
 651 }
 652
 653 void spawnfunc_light (void)
 654 {
 655         //makestatic (self); // Who the f___ did that?
 656         remove(self);
 657 }
 658
 659 float TryFile( string pFilename )
 660 {
 661         local float lHandle;
 662         dprint("TryFile(\"", pFilename, "\")\n");
 663         lHandle = fopen( pFilename, FILE_READ );
 664         if( lHandle != -1 ) {
 665                 fclose( lHandle );
 666                 return TRUE;
 667         } else {
 668                 return FALSE;
 669         }
 670 };
 671
 672 string GetGametype()
 673 {
 674         return GametypeNameFromType(game);
 675 }
 676
 677 string getmapname_stored;
 678 string GetMapname()
 679 {
 680         return mapname;
 681 }
 682
 683 float Map_Count, Map_Current;
 684 string Map_Current_Name;
 685
 686 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 687 float GetMaplistPosition()
 688 {
 689         float pos, idx;
 690         string map;
 691
 692         map = GetMapname();
 693         idx = cvar("g_maplist_index");
 694
 695         if(idx >= 0)
 696                 if(idx < Map_Count)
 697                         if(map == argv(idx))
 698                                 return idx;
 699
 700         for(pos = 0; pos < Map_Count; ++pos)
 701                 if(map == argv(pos))
 702                         return pos;
 703
 704         // resume normal maplist rotation if current map is not in g_maplist
 705         return idx;
 706 }
 707
 708 float MapHasRightSize(string map)
 709 {
 710         float fh;
 711         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 712         if(cvar("g_maplist_check_waypoints"))
 713         {
 714                 dprint("checkwp "); dprint(map);
 715                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 716                 if(fh < 0)
 717                 {
 718                         dprint(": no waypoints\n");
 719                         return FALSE;
 720                 }
 721                 dprint(": has waypoints\n");
 722                 fclose(fh);
 723         }
 724
 725         // open map size restriction file
 726         dprint("opensize "); dprint(map);
 727         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 728         if(fh >= 0)
 729         {
 730                 float mapmin, mapmax;
 731                 dprint(": ok, ");
 732                 mapmin = stof(fgets(fh));
 733                 mapmax = stof(fgets(fh));
 734                 fclose(fh);
 735                 if(player_count < mapmin)
 736                 {
 737                         dprint("not enough\n");
 738                         return FALSE;
 739                 }
 740                 if(player_count > mapmax)
 741                 {
 742                         dprint("too many\n");
 743                         return FALSE;
 744                 }
 745                 dprint("right size\n");
 746                 return TRUE;
 747         }
 748         dprint(": not found\n");
 749         return TRUE;
 750 }
 751
 752 string Map_Filename(float position)
 753 {
 754         return strcat("maps/", argv(position), ".bsp");
 755 }
 756
 757 string strwords(string s, float w)
 758 {
 759         float endpos;
 760         for(endpos = 0; w && endpos >= 0; --w)
 761                 endpos = strstrofs(s, " ", endpos + 1);
 762         if(endpos < 0)
 763                 return s;
 764         else
 765                 return substring(s, 0, endpos);
 766 }
 767
 768 float strhasword(string s, string w)
 769 {
 770         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 771 }
 772
 773 void Map_MarkAsRecent(string m)
 774 {
 775         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 776 }
 777
 778 float Map_IsRecent(string m)
 779 {
 780         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 781 }
 782
 783 float Map_Check(float position, float pass)
 784 {
 785         string filename;
 786         string map_next;
 787         map_next = argv(position);
 788         if(pass <= 1)
 789         {
 790                 if(Map_IsRecent(map_next))
 791                         return 0;
 792         }
 793         filename = Map_Filename(position);
 794         if(MapInfo_CheckMap(map_next))
 795         {
 796                 if(pass == 2)
 797                         return 1;
 798                 if(MapHasRightSize(map_next))
 799                         return 1;
 800                 return 0;
 801         }
 802         else
 803                 dprint( "Couldn't select '", filename, "'..\n" );
 804
 805         return 0;
 806 }
 807
 808 void Map_Goto_SetStr(string nextmapname)
 809 {
 810         if(getmapname_stored != "")
 811                 strunzone(getmapname_stored);
 812         if(nextmapname == "")
 813                 getmapname_stored = "";
 814         else
 815                 getmapname_stored = strzone(nextmapname);
 816 }
 817
 818 void Map_Goto_SetFloat(float position)
 819 {
 820         cvar_set("g_maplist_index", ftos(position));
 821         Map_Goto_SetStr(argv(position));
 822 }
 823
 824 void GameResetCfg()
 825 {
 826         // settings persist, except...
 827         localcmd("\nsettemp_restore\n");
 828 };
 829
 830 void Map_Goto()
 831 {
 832         GameResetCfg();
 833         MapInfo_LoadMap(getmapname_stored);
 834 }
 835
 836 // return codes of map selectors:
 837 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 838 //   -2 = permanent failure
 839 float() MaplistMethod_Iterate = // usual method
 840 {
 841         float pass, i;
 842
 843         for(pass = 1; pass <= 2; ++pass)
 844         {
 845                 for(i = 1; i < Map_Count; ++i)
 846                 {
 847                         float mapindex;
 848                         mapindex = mod(i + Map_Current, Map_Count);
 849                         if(Map_Check(mapindex, pass))
 850                                 return mapindex;
 851                 }
 852         }
 853         return -1;
 854 }
 855
 856 float() MaplistMethod_Repeat = // fallback method
 857 {
 858         if(Map_Check(Map_Current, 2))
 859                 return Map_Current;
 860         return -2;
 861 }
 862
 863 float() MaplistMethod_Random = // random map selection
 864 {
 865         float i, imax;
 866
 867         imax = 42;
 868
 869         for(i = 0; i <= imax; ++i)
 870         {
 871                 float mapindex;
 872                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 873                 if(Map_Check(mapindex, 1))
 874                         return mapindex;
 875         }
 876         return -1;
 877 }
 878
 879 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 880 // the exponent sets a bias on the map selection:
 881 // the higher the exponent, the less likely "shortly repeated" same maps are
 882 {
 883         float i, j, imax, insertpos;
 884
 885         imax = 42;
 886
 887         for(i = 0; i <= imax; ++i)
 888         {
 889                 string newlist;
 890
 891                 // now reinsert this at another position
 892                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 893                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 894                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 895                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 896
 897                 // insert the current map there
 898                 newlist = "";
 899                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 900                         newlist = strcat(newlist, " ", argv(j));
 901                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 902                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 903                         newlist = strcat(newlist, " ", argv(j));
 904                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 905                 cvar_set("g_maplist", newlist);
 906                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 907
 908                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 909                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 910                 if(Map_Check(Map_Current, 1))
 911                         return Map_Current;
 912         }
 913         return -1;
 914 }
 915
 916 void Maplist_Init()
 917 {
 918         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 919         if(Map_Count == 0)
 920         {
 921                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 922                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 923                 if(cvar("g_maplist_shuffle"))
 924                         ShuffleMaplist();
 925                 localcmd("\nmenu_cmd sync\n");
 926                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 927         }
 928         if(Map_Count == 0)
 929                 error("empty maplist, cannot select a new map");
 930         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 931
 932         if(Map_Current_Name)
 933                 strunzone(Map_Current_Name);
 934         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 935         // this may or may not be correct, but who cares, in the worst case a map
 936         // isn't chosen in the first pass that should have been
 937 }
 938
 939 string GetNextMap()
 940 {
 941         float nextMap;
 942
 943         Maplist_Init();
 944         nextMap = -1;
 945
 946         if(nextMap == -1)
 947                 if(cvar("g_maplist_shuffle") > 0)
 948                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 949
 950         if(nextMap == -1)
 951                 if(cvar("g_maplist_selectrandom"))
 952                         nextMap = MaplistMethod_Random();
 953
 954         if(nextMap == -1)
 955                 nextMap = MaplistMethod_Iterate();
 956
 957         if(nextMap == -1)
 958                 nextMap = MaplistMethod_Repeat();
 959
 960         if(nextMap >= 0)
 961         {
 962                 Map_Goto_SetFloat(nextMap);
 963                 return getmapname_stored;
 964         }
 965
 966         return "";
 967 };
 968
 969 float DoNextMapOverride()
 970 {
 971         if(cvar("g_campaign"))
 972         {
 973                 CampaignPostIntermission();
 974                 alreadychangedlevel = TRUE;
 975                 return TRUE;
 976         }
 977         if(cvar("quit_when_empty"))
 978         {
 979                 if(player_count <= currentbots)
 980                 {
 981                         localcmd("quit\n");
 982                         alreadychangedlevel = TRUE;
 983                         return TRUE;
 984                 }
 985         }
 986         if(cvar_string("quit_and_redirect") != "")
 987         {
 988                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 989                 alreadychangedlevel = TRUE;
 990                 return TRUE;
 991         }
 992         if (cvar("samelevel")) // if samelevel is set, stay on same level
 993         {
 994                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 995                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 996                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 997                 localcmd("restart\n");
 998                 //changelevel (mapname);
 999                 alreadychangedlevel = TRUE;
1000                 return TRUE;
1001         }
1002         if(cvar_string("nextmap") != "")
1003                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1004                 {
1005                         Map_Goto_SetStr(cvar_string("nextmap"));
1006                         Map_Goto();
1007                         alreadychangedlevel = TRUE;
1008                         return TRUE;
1009                 }
1010         if(cvar("lastlevel"))
1011         {
1012                 GameResetCfg();
1013                 localcmd("set lastlevel 0\ntogglemenu\n");
1014                 alreadychangedlevel = TRUE;
1015                 return TRUE;
1016         }
1017         return FALSE;
1018 };
1019
1020 void GotoNextMap()
1021 {
1022         //local string nextmap;
1023         //local float n, nummaps;
1024         //local string s;
1025         if (alreadychangedlevel)
1026                 return;
1027         alreadychangedlevel = TRUE;
1028
1029         {
1030                 string nextMap;
1031                 float allowReset;
1032
1033                 for(allowReset = 1; allowReset >= 0; --allowReset)
1034                 {
1035                         nextMap = GetNextMap();
1036                         if(nextMap != "")
1037                                 break;
1038
1039                         if(allowReset)
1040                         {
1041                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1042                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1043                                 if(cvar("g_maplist_shuffle"))
1044                                         ShuffleMaplist();
1045                                 localcmd("\nmenu_cmd sync\n");
1046                         }
1047                         else
1048                         {
1049                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1050                         }
1051                 }
1052                 Map_Goto();
1053         }
1054 };
1055
1056
1057 /*
1058 ============
1059 IntermissionThink
1060
1061 When the player presses attack or jump, change to the next level
1062 ============
1063 */
1064 .float autoscreenshot;
1065 void() MapVote_Start;
1066 void() MapVote_Think;
1067 float mapvote_initialized;
1068 void IntermissionThink()
1069 {
1070         FixIntermissionClient(self);
1071
1072         if(cvar("sv_autoscreenshot"))
1073         if(self.autoscreenshot > 0)
1074         if(time > self.autoscreenshot)
1075         {
1076                 self.autoscreenshot = -1;
1077                 if(clienttype(self) == CLIENTTYPE_REAL)
1078                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1079                 return;
1080         }
1081
1082         if (time < intermission_exittime)
1083                 return;
1084
1085         if(!mapvote_initialized)
1086                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1087                         return;
1088
1089         MapVote_Start();
1090 };
1091
1092 /*
1093 ============
1094 FindIntermission
1095
1096 Returns the entity to view from
1097 ============
1098 */
1099 /*
1100 entity FindIntermission()
1101 {
1102         local   entity spot;
1103         local   float cyc;
1104
1105 // look for info_intermission first
1106         spot = find (world, classname, "info_intermission");
1107         if (spot)
1108         {       // pick a random one
1109                 cyc = random() * 4;
1110                 while (cyc > 1)
1111                 {
1112                         spot = find (spot, classname, "info_intermission");
1113                         if (!spot)
1114                                 spot = find (spot, classname, "info_intermission");
1115                         cyc = cyc - 1;
1116                 }
1117                 return spot;
1118         }
1119
1120 // then look for the start position
1121         spot = find (world, classname, "info_player_start");
1122         if (spot)
1123                 return spot;
1124
1125 // testinfo_player_start is only found in regioned levels
1126         spot = find (world, classname, "testplayerstart");
1127         if (spot)
1128                 return spot;
1129
1130 // then look for the start position
1131         spot = find (world, classname, "info_player_deathmatch");
1132         if (spot)
1133                 return spot;
1134
1135         //objerror ("FindIntermission: no spot");
1136         return world;
1137 };
1138 */
1139
1140 /*
1141 ===============================================================================
1142
1143 RULES
1144
1145 ===============================================================================
1146 */
1147
1148 void DumpStats(float final)
1149 {
1150         local float file;
1151         local string s;
1152         local float to_console;
1153         local float to_eventlog;
1154         local float to_file;
1155         local float i;
1156
1157         to_console = cvar("sv_logscores_console");
1158         to_eventlog = cvar("sv_eventlog");
1159         to_file = cvar("sv_logscores_file");
1160
1161         if(!final)
1162         {
1163                 to_console = TRUE; // always print printstats replies
1164                 to_eventlog = FALSE; // but never print them to the event log
1165         }
1166
1167         if(to_eventlog)
1168                 if(cvar("sv_eventlog_console"))
1169                         to_console = FALSE; // otherwise we get the output twice
1170
1171         if(final)
1172                 s = ":scores:";
1173         else
1174                 s = ":status:";
1175         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1176
1177         if(to_console)
1178                 print(s, "\n");
1179         if(to_eventlog)
1180                 GameLogEcho(s);
1181         if(to_file)
1182         {
1183                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1184                 if(file == -1)
1185                         to_file = FALSE;
1186                 else
1187                         fputs(file, strcat(s, "\n"));
1188         }
1189
1190         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1191         if(to_console)
1192                 print(s, "\n");
1193         if(to_eventlog)
1194                 GameLogEcho(s);
1195         if(to_file)
1196                 fputs(file, strcat(s, "\n"));
1197
1198         FOR_EACH_CLIENT(other)
1199         {
1200                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1201                 {
1202                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1203                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1204                         if(other.classname == "player" || g_arena || g_lms)
1205                                 s = strcat(s, ftos(other.team), ":");
1206                         else
1207                                 s = strcat(s, "spectator:");
1208
1209                         if(to_console)
1210                                 print(s, other.netname, "\n");
1211                         if(to_eventlog)
1212                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1213                         if(to_file)
1214                                 fputs(file, strcat(s, other.netname, "\n"));
1215                 }
1216         }
1217
1218         if(teams_matter)
1219         {
1220                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1221                 if(to_console)
1222                         print(s, "\n");
1223                 if(to_eventlog)
1224                         GameLogEcho(s);
1225                 if(to_file)
1226                         fputs(file, strcat(s, "\n"));
1227
1228                 for(i = 1; i < 16; ++i)
1229                 {
1230                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1231                         s = strcat(s, ":", ftos(i));
1232                         if(to_console)
1233                                 print(s, "\n");
1234                         if(to_eventlog)
1235                                 GameLogEcho(s);
1236                         if(to_file)
1237                                 fputs(file, strcat(s, "\n"));
1238                 }
1239         }
1240
1241         if(to_console)
1242                 print(":end\n");
1243         if(to_eventlog)
1244                 GameLogEcho(":end");
1245         if(to_file)
1246         {
1247                 fputs(file, ":end\n");
1248                 fclose(file);
1249         }
1250 }
1251
1252 void FixIntermissionClient(entity e)
1253 {
1254         string s;
1255         if(!e.autoscreenshot) // initial call
1256         {
1257                 e.angles = e.v_angle;
1258                 e.angles_x = -e.angles_x;
1259                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1260                 e.health = -2342;
1261                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1262                 e.solid = SOLID_NOT;
1263                 e.movetype = MOVETYPE_NONE;
1264                 e.takedamage = DAMAGE_NO;
1265                 if(e.weaponentity)
1266                 {
1267                         e.weaponentity.effects = EF_NODRAW;
1268                         if (e.weaponentity.weaponentity)
1269                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1270                 }
1271                 if(clienttype(e) == CLIENTTYPE_REAL)
1272                 {
1273                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1274                         s = cvar_string("sv_intermission_cdtrack");
1275                         if(s != "")
1276                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1277                         msg_entity = e;
1278                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1279                 }
1280         }
1281
1282         //e.velocity = '0 0 0';
1283         //e.fixangle = TRUE;
1284
1285         // TODO halt weapon animation
1286 }
1287
1288
1289 /*
1290 go to the next level for deathmatch
1291 only called if a time or frag limit has expired
1292 */
1293 void NextLevel()
1294 {
1295         float minTotalFrags;
1296         float maxTotalFrags;
1297         float score;
1298         float f;
1299
1300         gameover = TRUE;
1301
1302         intermission_running = 1;
1303
1304 // enforce a wait time before allowing changelevel
1305         if(player_count > 0)
1306                 intermission_exittime = time + cvar("sv_mapchange_delay");
1307         else
1308                 intermission_exittime = -1;
1309
1310         /*
1311         WriteByte (MSG_ALL, SVC_CDTRACK);
1312         WriteByte (MSG_ALL, 3);
1313         WriteByte (MSG_ALL, 3);
1314         // done in FixIntermission
1315         */
1316
1317         //pos = FindIntermission ();
1318
1319         VoteReset();
1320
1321         DumpStats(TRUE);
1322
1323         if(cvar("sv_eventlog"))
1324                 GameLogEcho(":gameover");
1325
1326         GameLogClose();
1327
1328         FOR_EACH_CLIENT(other)
1329         {
1330                 FixIntermissionClient(other);
1331
1332                 if(other.winning)
1333                         bprint(other.netname, " ^7wins.\n");
1334         }
1335
1336         minTotalFrags = 0;
1337         maxTotalFrags = 0;
1338         FOR_EACH_PLAYER(other)
1339         {
1340                 if(maxTotalFrags < other.totalfrags)
1341                         maxTotalFrags = other.totalfrags;
1342                 if(minTotalFrags > other.totalfrags)
1343                         minTotalFrags = other.totalfrags;
1344         }
1345
1346         if(!currentbots)
1347         {
1348                 FOR_EACH_PLAYER(other)
1349                 {
1350                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1351                         f = bound(0, other.play_time / max(time, 1), 1);
1352                         // store some statistics?
1353                 }
1354         }
1355
1356         if(cvar("g_campaign"))
1357                 CampaignPreIntermission();
1358
1359         localcmd("\nsv_hook_gameend;");
1360
1361         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1362 };
1363
1364 /*
1365 ============
1366 CheckRules_Player
1367
1368 Exit deathmatch games upon conditions
1369 ============
1370 */
1371 void CheckRules_Player()
1372 {
1373         if (gameover)   // someone else quit the game already
1374                 return;
1375
1376         if(self.deadflag == DEAD_NO)
1377                 self.play_time += frametime;
1378
1379         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1380         //   (div0: and that in CheckRules_World please)
1381 };
1382
1383 float checkrules_equality;
1384 float checkrules_suddendeathwarning;
1385 float checkrules_suddendeathend;
1386 float checkrules_overtimesadded; //how many overtimes have been already added
1387
1388 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1389 float WINNING_YES = 1; // winner found
1390 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1391 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1392
1393 void InitiateOvertime()
1394 {
1395         // Check first whether normal overtimes could be added before initiating suddendeath mode
1396         // - for this timelimit_overtime needs to be >0 of course
1397         // - also check the winning condition calculated in the previous frame and only add normal overtime
1398         //   again, if at the point at which timelimit would be extended again, still no winner was found
1399         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1400         {
1401                 ++checkrules_overtimesadded;
1402                 //add one more overtime by simply extending the timelimit
1403                 float tl;
1404                 tl = cvar("timelimit");
1405                 tl += cvar("timelimit_overtime");
1406                 cvar_set("timelimit", ftos(tl));
1407                 string minutesPlural;
1408                 if (cvar("timelimit_overtime") == 1)
1409                         minutesPlural = " ^3minute";
1410                 else
1411                         minutesPlural = " ^3minutes";
1412
1413                 bcenterprint(
1414                         strcat(
1415                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1416                                 ftos(cvar("timelimit_overtime")),
1417                                 minutesPlural,
1418                                 " to the game!"
1419                         )
1420                 );
1421         }
1422         else
1423         {
1424                 if(!checkrules_suddendeathend)
1425                 {
1426                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1427                         if(g_race && !g_race_qualifying)
1428                                 race_StartCompleting();
1429                 }
1430         }
1431 }
1432
1433 float GetWinningCode(float fraglimitreached, float equality)
1434 {
1435         if(equality)
1436                 if(fraglimitreached)
1437                         return WINNING_STARTSUDDENDEATHOVERTIME;
1438                 else
1439                         return WINNING_NEVER;
1440         else
1441                 if(fraglimitreached)
1442                         return WINNING_YES;
1443                 else
1444                         return WINNING_NO;
1445 }
1446
1447 // set the .winning flag for exactly those players with a given field value
1448 void SetWinners(.float field, float value)
1449 {
1450         entity head;
1451         FOR_EACH_PLAYER(head)
1452                 head.winning = (head.field == value);
1453 }
1454
1455 // set the .winning flag for those players with a given field value
1456 void AddWinners(.float field, float value)
1457 {
1458         entity head;
1459         FOR_EACH_PLAYER(head)
1460                 if(head.field == value)
1461                         head.winning = 1;
1462 }
1463
1464 // clear the .winning flags
1465 void ClearWinners(void)
1466 {
1467         entity head;
1468         FOR_EACH_PLAYER(head)
1469                 head.winning = 0;
1470 }
1471
1472 // Onslaught winning condition:
1473 // game terminates if only one team has a working generator (or none)
1474 float WinningCondition_Onslaught()
1475 {
1476         entity head;
1477         local float t1, t2, t3, t4;
1478
1479         WinningConditionHelper(); // set worldstatus
1480
1481         if(inWarmupStage)
1482                 return WINNING_NO;
1483
1484         // first check if the game has ended
1485         t1 = t2 = t3 = t4 = 0;
1486         head = find(world, classname, "onslaught_generator");
1487         while (head)
1488         {
1489                 if (head.health > 0)
1490                 {
1491                         if (head.team == COLOR_TEAM1) t1 = 1;
1492                         if (head.team == COLOR_TEAM2) t2 = 1;
1493                         if (head.team == COLOR_TEAM3) t3 = 1;
1494                         if (head.team == COLOR_TEAM4) t4 = 1;
1495                 }
1496                 head = find(head, classname, "onslaught_generator");
1497         }
1498         if (t1 + t2 + t3 + t4 < 2)
1499         {
1500                 // game over, only one team remains (or none)
1501                 ClearWinners();
1502                 if (t1) SetWinners(team, COLOR_TEAM1);
1503                 if (t2) SetWinners(team, COLOR_TEAM2);
1504                 if (t3) SetWinners(team, COLOR_TEAM3);
1505                 if (t4) SetWinners(team, COLOR_TEAM4);
1506                 dprint("Have a winner, ending game.\n");
1507                 return WINNING_YES;
1508         }
1509
1510         // Two or more teams remain
1511         return WINNING_NO;
1512 }
1513
1514 float LMS_NewPlayerLives()
1515 {
1516         float fl;
1517         fl = cvar("fraglimit");
1518         if(fl == 0)
1519                 fl = 999;
1520
1521         // first player has left the game for dying too much? Nobody else can get in.
1522         if(lms_lowest_lives < 1)
1523                 return 0;
1524
1525         if(!cvar("g_lms_join_anytime"))
1526                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1527                         return 0;
1528
1529         return bound(1, lms_lowest_lives, fl);
1530 }
1531
1532 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1533 // they win. Otherwise the defending team wins once the timelimit passes.
1534 void assault_new_round();
1535 float WinningCondition_Assault()
1536 {
1537         local float status;
1538
1539         WinningConditionHelper(); // set worldstatus
1540
1541         status = WINNING_NO;
1542         // as the timelimit has not yet passed just assume the defending team will win
1543         if(assault_attacker_team == COLOR_TEAM1)
1544         {
1545                 SetWinners(team, COLOR_TEAM2);
1546         }
1547         else
1548         {
1549                 SetWinners(team, COLOR_TEAM1);
1550         }
1551
1552         local entity ent;
1553         ent = find(world, classname, "target_assault_roundend");
1554         if(ent)
1555         {
1556                 if(ent.winning) // round end has been triggered by attacking team
1557                 {
1558                         bprint("ASSAULT: round completed...\n");
1559                         SetWinners(team, assault_attacker_team);
1560
1561                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1562
1563                         if(ent.cnt == 1) // this was the second round
1564                         {
1565                                 status = WINNING_YES;
1566                         }
1567                         else
1568                         {
1569                                 local entity oldself;
1570                                 oldself = self;
1571                                 self = ent;
1572                                 assault_new_round();
1573                                 self = oldself;
1574                         }
1575                 }
1576         }
1577
1578         return status;
1579 }
1580
1581 // LMS winning condition: game terminates if and only if there's at most one
1582 // one player who's living lives. Top two scores being equal cancels the time
1583 // limit.
1584 float WinningCondition_LMS()
1585 {
1586         entity head, head2;
1587         float have_player;
1588         float have_players;
1589         float l;
1590
1591         have_player = FALSE;
1592         have_players = FALSE;
1593         l = LMS_NewPlayerLives();
1594
1595         head = find(world, classname, "player");
1596         if(head)
1597                 have_player = TRUE;
1598         head2 = find(head, classname, "player");
1599         if(head2)
1600                 have_players = TRUE;
1601
1602         if(have_player)
1603         {
1604                 // we have at least one player
1605                 if(have_players)
1606                 {
1607                         // two or more active players - continue with the game
1608                 }
1609                 else
1610                 {
1611                         // exactly one player?
1612
1613                         ClearWinners();
1614                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1615
1616                         if(l)
1617                         {
1618                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1619                                 return WINNING_NO;
1620                         }
1621                         else
1622                         {
1623                                 // a winner!
1624                                 // and assign him his first place
1625                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1626                                 return WINNING_YES;
1627                         }
1628                 }
1629         }
1630         else
1631         {
1632                 // nobody is playing at all...
1633                 if(l)
1634                 {
1635                         // wait for players...
1636                 }
1637                 else
1638                 {
1639                         // SNAFU (maybe a draw game?)
1640                         ClearWinners();
1641                         dprint("No players, ending game.\n");
1642                         return WINNING_YES;
1643                 }
1644         }
1645
1646         // When we get here, we have at least two players who are actually LIVING,
1647         // now check if the top two players have equal score.
1648         WinningConditionHelper();
1649
1650         ClearWinners();
1651         if(WinningConditionHelper_winner)
1652                 WinningConditionHelper_winner.winning = TRUE;
1653         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1654                 return WINNING_NEVER;
1655
1656         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1657         return WINNING_NO;
1658 }
1659
1660 void ShuffleMaplist()
1661 {
1662         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1663 }
1664
1665 float leaderfrags;
1666 float WinningCondition_Scores(float limit, float leadlimit)
1667 {
1668         // TODO make everything use THIS winning condition (except LMS)
1669         WinningConditionHelper();
1670
1671         if(teams_matter)
1672         {
1673                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1674                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1675                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1676                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1677         }
1678
1679         ClearWinners();
1680         if(WinningConditionHelper_winner)
1681                 WinningConditionHelper_winner.winning = 1;
1682         if(WinningConditionHelper_winnerteam >= 0)
1683                 SetWinners(team, WinningConditionHelper_winnerteam);
1684
1685         if(WinningConditionHelper_lowerisbetter)
1686         {
1687                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1688                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1689                 limit = -limit;
1690         }
1691
1692         if(WinningConditionHelper_zeroisworst)
1693                 leadlimit = 0; // not supported in this mode
1694
1695         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1696         // these modes always score in increments of 1, thus this makes sense
1697         {
1698                 if(leaderfrags != WinningConditionHelper_topscore)
1699                 {
1700                         leaderfrags = WinningConditionHelper_topscore;
1701
1702                         if (limit)
1703                         if (leaderfrags == limit - 1)
1704                                 play2all("announcer/robotic/1fragleft.wav");
1705                         else if (leaderfrags == limit - 2)
1706                                 play2all("announcer/robotic/2fragsleft.wav");
1707                         else if (leaderfrags == limit - 3)
1708                                 play2all("announcer/robotic/3fragsleft.wav");
1709                 }
1710         }
1711
1712         return GetWinningCode(
1713                 WinningConditionHelper_topscore &&
1714                 (
1715                         (limit && (WinningConditionHelper_topscore >= limit))
1716                         ||
1717                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1718                 ),
1719                 WinningConditionHelper_equality
1720         );
1721 }
1722
1723 float WinningCondition_Race(float fraglimit)
1724 {
1725         float wc;
1726         entity p;
1727         float n, c;
1728
1729         n = 0;
1730         c = 0;
1731         FOR_EACH_PLAYER(p)
1732         {
1733                 ++n;
1734                 if(p.race_completed)
1735                         ++c;
1736         }
1737         if(n && (n == c))
1738                 return WINNING_YES;
1739         wc = WinningCondition_Scores(fraglimit, 0);
1740
1741         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1742         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1743         // do NOT support equality when the laps are all raced!
1744                 return WINNING_STARTSUDDENDEATHOVERTIME;
1745         else
1746                 return WINNING_NEVER;
1747         return wc;
1748 }
1749
1750 void ReadyRestart();
1751 float WinningCondition_QualifyingThenRace(float limit)
1752 {
1753         float wc;
1754         wc = WinningCondition_Scores(limit, 0);
1755
1756         // NEVER initiate overtime
1757         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1758         {
1759                 return WINNING_YES;
1760         }
1761
1762         return wc;
1763 }
1764
1765 float WinningCondition_RanOutOfSpawns()
1766 {
1767         entity head;
1768
1769         if(!have_team_spawns)
1770                 return WINNING_NO;
1771
1772         if(!some_spawn_has_been_used)
1773                 return WINNING_NO;
1774
1775         team1_score = team2_score = team3_score = team4_score = 0;
1776
1777         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1778         {
1779                 if(head.team == COLOR_TEAM1)
1780                         team1_score = 1;
1781                 else if(head.team == COLOR_TEAM2)
1782                         team2_score = 1;
1783                 else if(head.team == COLOR_TEAM3)
1784                         team3_score = 1;
1785                 else if(head.team == COLOR_TEAM4)
1786                         team4_score = 1;
1787         }
1788
1789         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1790         {
1791                 if(head.team == COLOR_TEAM1)
1792                         team1_score = 1;
1793                 else if(head.team == COLOR_TEAM2)
1794                         team2_score = 1;
1795                 else if(head.team == COLOR_TEAM3)
1796                         team3_score = 1;
1797                 else if(head.team == COLOR_TEAM4)
1798                         team4_score = 1;
1799         }
1800
1801         ClearWinners();
1802         if(team1_score + team2_score + team3_score + team4_score == 0)
1803         {
1804                 checkrules_equality = TRUE;
1805                 return WINNING_YES;
1806         }
1807         else if(team1_score + team2_score + team3_score + team4_score == 1)
1808         {
1809                 float t, i;
1810                 if(team1_score) t = COLOR_TEAM1;
1811                 if(team2_score) t = COLOR_TEAM2;
1812                 if(team3_score) t = COLOR_TEAM3;
1813                 if(team4_score) t = COLOR_TEAM4;
1814                 CheckAllowedTeams(world);
1815                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1816                 {
1817                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1818                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1819                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1820                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1821                 }
1822
1823                 AddWinners(team, t);
1824                 return WINNING_YES;
1825         }
1826         else
1827                 return WINNING_NO;
1828 }
1829
1830 /*
1831 ============
1832 CheckRules_World
1833
1834 Exit deathmatch games upon conditions
1835 ============
1836 */
1837 void CheckRules_World()
1838 {
1839         float timelimit;
1840         float fraglimit;
1841         float leadlimit;
1842
1843         VoteThink();
1844         MapVote_Think();
1845
1846         SetDefaultAlpha();
1847
1848         /*
1849         MapVote_Think should now do that part
1850         if (intermission_running)
1851                 if (time >= intermission_exittime + 60)
1852                 {
1853                         if(!DoNextMapOverride())
1854                                 GotoNextMap();
1855                         return;
1856                 }
1857         */
1858
1859         if (gameover)   // someone else quit the game already
1860         {
1861                 if(player_count == 0) // Nobody there? Then let's go to the next map
1862                         MapVote_Start();
1863                         // this will actually check the player count in the next frame
1864                         // again, but this shouldn't hurt
1865                 return;
1866         }
1867
1868         timelimit = cvar("timelimit") * 60;
1869         fraglimit = cvar("fraglimit");
1870         leadlimit = cvar("leadlimit");
1871
1872         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1873         {
1874                 if(timelimit > 0)
1875                         timelimit = 0; // timelimit is not made for warmup
1876                 if(fraglimit > 0)
1877                         fraglimit = 0; // no fraglimit for now
1878                 leadlimit = 0; // no leadlimit for now
1879         }
1880
1881         if(g_onslaught)
1882                 timelimit = 0; // ONS has its own overtime rule
1883
1884         if(timelimit > 0)
1885         {
1886                 timelimit += game_starttime;
1887         }
1888         else if (timelimit < 0)
1889         {
1890                 // endmatch
1891                 NextLevel();
1892                 return;
1893         }
1894
1895         if(checkrules_suddendeathend)
1896         {
1897                 if(!checkrules_suddendeathwarning)
1898                 {
1899                         checkrules_suddendeathwarning = TRUE;
1900                         if(g_race && !g_race_qualifying)
1901                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1902                         else
1903                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1904                 }
1905         }
1906         else
1907         {
1908                 if (timelimit && time >= timelimit)
1909                 {
1910                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1911                         {
1912                                 float totalplayers;
1913                                 float playerswithlaps;
1914                                 float readyplayers;
1915                                 entity head;
1916                                 totalplayers = playerswithlaps = readyplayers = 0;
1917                                 FOR_EACH_PLAYER(head)
1918                                 {
1919                                         ++totalplayers;
1920                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1921                                                 ++playerswithlaps;
1922                                         if(head.ready)
1923                                                 ++readyplayers;
1924                                 }
1925
1926                                 // at least 2 of the players have completed a lap: start the RACE
1927                                 // otherwise, the players should end the qualifying on their own
1928                                 if(readyplayers || playerswithlaps >= 2)
1929                                 {
1930                                         checkrules_suddendeathend = 0;
1931                                         ReadyRestart(); // go to race
1932                                         return;
1933                                 }
1934                                 else
1935                                         InitiateOvertime();
1936                         }
1937                         else
1938                                 InitiateOvertime();
1939                 }
1940         }
1941
1942         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1943         {
1944                 NextLevel();
1945                 return;
1946         }
1947
1948         float checkrules_status;
1949         checkrules_status = WinningCondition_RanOutOfSpawns();
1950         if(checkrules_status == WINNING_YES)
1951         {
1952                 bprint("Hey! Someone ran out of spawns!\n");
1953         }
1954         else if(g_race && !g_race_qualifying && timelimit >= 0)
1955         {
1956                 checkrules_status = WinningCondition_Race(fraglimit);
1957                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
1958         }
1959         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1960         {
1961                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1962                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
1963         }
1964         else if(g_assault)
1965         {
1966                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1967         }
1968         else if(g_lms)
1969         {
1970                 checkrules_status = WinningCondition_LMS();
1971         }
1972         else if (g_onslaught)
1973         {
1974                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1975         }
1976         else
1977         {
1978                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1979                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
1980         }
1981
1982         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1983         {
1984                 checkrules_status = WINNING_NEVER;
1985                 checkrules_overtimesadded = -1;
1986                 InitiateOvertime();
1987         }
1988
1989         if(checkrules_status == WINNING_NEVER)
1990                 // equality cases! Nobody wins if the overtime ends in a draw.
1991                 ClearWinners();
1992
1993         if(checkrules_suddendeathend)
1994                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1995                         checkrules_status = WINNING_YES;
1996
1997         if(checkrules_status == WINNING_YES)
1998         {
1999                 //print("WINNING\n");
2000                 NextLevel();
2001         }
2002 };
2003
2004 float mapvote_nextthink;
2005 float mapvote_initialized;
2006 float mapvote_keeptwotime;
2007 float mapvote_timeout;
2008 string mapvote_message;
2009 string mapvote_screenshot_dir;
2010
2011 float mapvote_count;
2012 float mapvote_count_real;
2013 string mapvote_maps[MAPVOTE_COUNT];
2014 float mapvote_maps_suggested[MAPVOTE_COUNT];
2015 string mapvote_suggestions[MAPVOTE_COUNT];
2016 float mapvote_suggestion_ptr;
2017 float mapvote_maxlen;
2018 float mapvote_voters;
2019 float mapvote_votes[MAPVOTE_COUNT];
2020 float mapvote_run;
2021 float mapvote_detail;
2022 float mapvote_abstain;
2023 .float mapvote;
2024
2025 void MapVote_ClearAllVotes()
2026 {
2027         FOR_EACH_CLIENT(other)
2028                 other.mapvote = 0;
2029 }
2030
2031 string MapVote_Suggest(string m)
2032 {
2033         float i;
2034         if(m == "")
2035                 return "That's not how to use this command.";
2036         if(!cvar("g_maplist_votable_suggestions"))
2037                 return "Suggestions are not accepted on this server.";
2038         if(mapvote_initialized)
2039                 return "Can't suggest - voting is already in progress!";
2040         m = MapInfo_FixName(m);
2041         if(!m)
2042                 return "The map you suggested is not available on this server.";
2043         if(!cvar("g_maplist_votable_override_mostrecent"))
2044                 if(Map_IsRecent(m))
2045                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2046
2047         if(!MapInfo_CheckMap(m))
2048                 return "The map you suggested does not support the current game mode.";
2049         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2050                 if(mapvote_suggestions[i] == m)
2051                         return "This map was already suggested.";
2052         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2053         {
2054                 i = floor(random() * mapvote_suggestion_ptr);
2055         }
2056         else
2057         {
2058                 i = mapvote_suggestion_ptr;
2059                 mapvote_suggestion_ptr += 1;
2060         }
2061         if(mapvote_suggestions[i] != "")
2062                 strunzone(mapvote_suggestions[i]);
2063         mapvote_suggestions[i] = strzone(m);
2064         if(cvar("sv_eventlog"))
2065                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2066         return strcat("Suggestion of ", m, " accepted.");
2067 }
2068
2069 void MapVote_AddVotable(string nextMap, float isSuggestion)
2070 {
2071         float j;
2072         if(nextMap == "")
2073                 return;
2074         for(j = 0; j < mapvote_count; ++j)
2075                 if(mapvote_maps[j] == nextMap)
2076                         return;
2077         if(strlen(nextMap) > mapvote_maxlen)
2078                 mapvote_maxlen = strlen(nextMap);
2079         mapvote_maps[mapvote_count] = strzone(nextMap);
2080         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2081         mapvote_count += 1;
2082 }
2083
2084 void MapVote_Spawn();
2085 void MapVote_Init()
2086 {
2087         float i;
2088         float nmax, smax;
2089
2090         MapVote_ClearAllVotes();
2091
2092         mapvote_count = 0;
2093         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2094         mapvote_abstain = cvar("g_maplist_votable_abstain");
2095
2096         if(mapvote_abstain)
2097                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2098         else
2099                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2100         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2101
2102         if(mapvote_suggestion_ptr)
2103                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2104                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2105
2106         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2107                 MapVote_AddVotable(GetNextMap(), FALSE);
2108
2109         if(mapvote_count == 0)
2110         {
2111                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2112                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2113                 if(cvar("g_maplist_shuffle"))
2114                         ShuffleMaplist();
2115                 localcmd("\nmenu_cmd sync\n");
2116                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2117                         MapVote_AddVotable(GetNextMap(), FALSE);
2118         }
2119
2120         mapvote_count_real = mapvote_count;
2121         if(mapvote_abstain)
2122                 MapVote_AddVotable("don't care", 0);
2123
2124         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2125
2126         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2127         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2128         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2129                 mapvote_keeptwotime = 0;
2130         mapvote_message = "Choose a map and press its key!";
2131
2132         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2133         if(mapvote_screenshot_dir == "")
2134                 mapvote_screenshot_dir = "maps";
2135         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2136
2137         MapVote_Spawn();
2138 }
2139
2140 void MapVote_SendPicture(float id)
2141 {
2142         msg_entity = self;
2143         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2144         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2145         WriteByte(MSG_ONE, id);
2146         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2147 }
2148
2149 float GameCommand_MapVote(string cmd)
2150 {
2151         if(!intermission_running)
2152                 return FALSE;
2153
2154         if(cmd == "mv_getpic")
2155         {
2156                 MapVote_SendPicture(stof(argv(1)));
2157                 return TRUE;
2158         }
2159
2160         return FALSE;
2161 }
2162
2163 float MapVote_GetMapMask()
2164 {
2165         float mask, i, power;
2166         mask = 0;
2167         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2168                 if(mapvote_maps[i] != "")
2169                         mask |= power;
2170         return mask;
2171 }
2172
2173 entity mapvote_ent;
2174 float MapVote_SendEntity(entity to, float sf)
2175 {
2176         string mapfile, pakfile;
2177         float i, o;
2178
2179         if(sf & 1)
2180                 sf &~= 2; // if we send 1, we don't need to also send 2
2181
2182         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2183         WriteByte(MSG_ENTITY, sf);
2184
2185         if(sf & 1)
2186         {
2187                 // flag 1 == initialization
2188                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2189                 WriteByte(MSG_ENTITY, mapvote_count);
2190                 WriteByte(MSG_ENTITY, mapvote_abstain);
2191                 WriteByte(MSG_ENTITY, mapvote_detail);
2192                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2193                 if(mapvote_count <= 8)
2194                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2195                 else
2196                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2197                 for(i = 0; i < mapvote_count; ++i)
2198                         if(mapvote_maps[i] != "")
2199                         {
2200                                 if(mapvote_abstain && i == mapvote_count - 1)
2201                                 {
2202                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2203                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2204                                 }
2205                                 else
2206                                 {
2207                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2208                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2209                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2210                                         if(pakfile == "")
2211                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2212                                         if(pakfile == "")
2213                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2214                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2215                                                 pakfile = substring(pakfile, o, 999);
2216                                         WriteString(MSG_ENTITY, pakfile);
2217                                 }
2218                         }
2219         }
2220
2221         if(sf & 2)
2222         {
2223                 // flag 2 == update of mask
2224                 if(mapvote_count <= 8)
2225                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2226                 else
2227                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2228         }
2229
2230         if(sf & 4)
2231         {
2232                 if(mapvote_detail)
2233                         for(i = 0; i < mapvote_count; ++i)
2234                                 if(mapvote_maps[i] != "")
2235                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2236
2237                 WriteByte(MSG_ENTITY, to.mapvote);
2238         }
2239
2240         return TRUE;
2241 }
2242
2243 void MapVote_Spawn()
2244 {
2245         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2246 }
2247
2248 void MapVote_TouchMask()
2249 {
2250         mapvote_ent.SendFlags |= 2;
2251 }
2252
2253 void MapVote_TouchVotes(entity voter)
2254 {
2255         mapvote_ent.SendFlags |= 4;
2256 }
2257
2258 float MapVote_Finished(float mappos)
2259 {
2260         string result;
2261         float i;
2262         float didntvote;
2263
2264         if(cvar("sv_eventlog"))
2265         {
2266                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2267                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2268                 didntvote = mapvote_voters;
2269                 for(i = 0; i < mapvote_count; ++i)
2270                         if(mapvote_maps[i] != "")
2271                         {
2272                                 didntvote -= mapvote_votes[i];
2273                                 if(i != mappos)
2274                                 {
2275                                         result = strcat(result, ":", mapvote_maps[i]);
2276                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2277                                 }
2278                         }
2279                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2280
2281                 GameLogEcho(result);
2282                 if(mapvote_maps_suggested[mappos])
2283                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2284         }
2285
2286         FOR_EACH_REALCLIENT(other)
2287                 FixClientCvars(other);
2288
2289         Map_Goto_SetStr(mapvote_maps[mappos]);
2290         Map_Goto();
2291         alreadychangedlevel = TRUE;
2292         return TRUE;
2293 }
2294 void MapVote_CheckRules_1()
2295 {
2296         float i;
2297
2298         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2299         {
2300                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2301                 mapvote_votes[i] = 0;
2302         }
2303
2304         mapvote_voters = 0;
2305         FOR_EACH_REALCLIENT(other)
2306         {
2307                 ++mapvote_voters;
2308                 if(other.mapvote)
2309                 {
2310                         i = other.mapvote - 1;
2311                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2312                         mapvote_votes[i] = mapvote_votes[i] + 1;
2313                 }
2314         }
2315 }
2316
2317 float MapVote_CheckRules_2()
2318 {
2319         float i;
2320         float firstPlace, secondPlace;
2321         float firstPlaceVotes, secondPlaceVotes;
2322         float mapvote_voters_real;
2323         string result;
2324
2325         if(mapvote_count_real == 1)
2326                 return MapVote_Finished(0);
2327
2328         mapvote_voters_real = mapvote_voters;
2329         if(mapvote_abstain)
2330                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2331
2332         RandomSelection_Init();
2333         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2334                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2335         firstPlace = RandomSelection_chosen_float;
2336         firstPlaceVotes = RandomSelection_best_priority;
2337         //dprint("First place: ", ftos(firstPlace), "\n");
2338         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2339
2340         RandomSelection_Init();
2341         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2342                 if(i != firstPlace)
2343                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2344         secondPlace = RandomSelection_chosen_float;
2345         secondPlaceVotes = RandomSelection_best_priority;
2346         //dprint("Second place: ", ftos(secondPlace), "\n");
2347         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2348
2349         if(firstPlace == -1)
2350                 error("No first place in map vote... WTF?");
2351
2352         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2353                 return MapVote_Finished(firstPlace);
2354
2355         if(mapvote_keeptwotime)
2356                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2357                 {
2358                         float didntvote;
2359                         MapVote_TouchMask();
2360                         mapvote_message = "Now decide between the TOP TWO!";
2361                         mapvote_keeptwotime = 0;
2362                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2363                         result = strcat(result, ":", ftos(firstPlaceVotes));
2364                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2365                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2366                         didntvote = mapvote_voters;
2367                         for(i = 0; i < mapvote_count; ++i)
2368                                 if(mapvote_maps[i] != "")
2369                                 {
2370                                         didntvote -= mapvote_votes[i];
2371                                         if(i != firstPlace)
2372                                                 if(i != secondPlace)
2373                                                 {
2374                                                         result = strcat(result, ":", mapvote_maps[i]);
2375                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2376                                                         if(i < mapvote_count_real)
2377                                                         {
2378                                                                 strunzone(mapvote_maps[i]);
2379                                                                 mapvote_maps[i] = "";
2380                                                         }
2381                                                 }
2382                                 }
2383                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2384                         if(cvar("sv_eventlog"))
2385                                 GameLogEcho(result);
2386                 }
2387
2388         return FALSE;
2389 }
2390 void MapVote_Tick()
2391 {
2392         float keeptwo;
2393         float totalvotes;
2394
2395         keeptwo = mapvote_keeptwotime;
2396         MapVote_CheckRules_1(); // count
2397         if(MapVote_CheckRules_2()) // decide
2398                 return;
2399
2400         totalvotes = 0;
2401         FOR_EACH_REALCLIENT(other)
2402         {
2403                 // hide scoreboard again
2404                 if(other.health != 2342)
2405                 {
2406                         other.health = 2342;
2407                         other.impulse = 0;
2408                         if(clienttype(other) == CLIENTTYPE_REAL)
2409                         {
2410                                 msg_entity = other;
2411                                 WriteByte(MSG_ONE, SVC_FINALE);
2412                                 WriteString(MSG_ONE, "");
2413                         }
2414                 }
2415
2416                 // clear possibly invalid votes
2417                 if(mapvote_maps[other.mapvote - 1] == "")
2418                         other.mapvote = 0;
2419                 // use impulses as new vote
2420                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2421                         if(mapvote_maps[other.impulse - 1] != "")
2422                         {
2423                                 other.mapvote = other.impulse;
2424                                 MapVote_TouchVotes(other);
2425                         }
2426                 other.impulse = 0;
2427
2428                 if(other.mapvote)
2429                         ++totalvotes;
2430         }
2431
2432         MapVote_CheckRules_1(); // just count
2433 }
2434 void MapVote_Start()
2435 {
2436         if(mapvote_run)
2437                 return;
2438
2439         MapInfo_Enumerate();
2440         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2441                 mapvote_run = TRUE;
2442 }
2443 void MapVote_Think()
2444 {
2445         if(!mapvote_run)
2446                 return;
2447
2448         if(alreadychangedlevel)
2449                 return;
2450
2451         if(time < mapvote_nextthink)
2452                 return;
2453         //dprint("tick\n");
2454
2455         mapvote_nextthink = time + 0.5;
2456
2457         if(!mapvote_initialized)
2458         {
2459                 mapvote_initialized = TRUE;
2460                 if(DoNextMapOverride())
2461                         return;
2462                 if(!cvar("g_maplist_votable") || player_count <= 0)
2463                 {
2464                         GotoNextMap();
2465                         return;
2466                 }
2467                 MapVote_Init();
2468         }
2469
2470         MapVote_Tick();
2471 };
2472
2473 string GotoMap(string m)
2474 {
2475         if(!MapInfo_CheckMap(m))
2476                 return "The map you chose is not available on this server.";
2477         cvar_set("nextmap", m);
2478         cvar_set("timelimit", "-1");
2479         if(mapvote_initialized || alreadychangedlevel)
2480         {
2481                 if(DoNextMapOverride())
2482                         return "Map switch initiated.";
2483                 else
2484                         return "Hm... no. For some reason I like THIS map more.";
2485         }
2486         else
2487                 return "Map switch will happen after scoreboard.";
2488 }
2489
2490
2491 void EndFrame()
2492 {
2493         float altime;
2494         FOR_EACH_REALCLIENT(self)
2495         {
2496                 if(self.classname == "spectator")
2497                 {
2498                         if(self.enemy.typehitsound)
2499                                 play2(self, "misc/typehit.wav");
2500                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2501                                 play2(self, "misc/hit.wav");
2502                 }
2503                 else
2504                 {
2505                         if(self.typehitsound)
2506                                 play2(self, "misc/typehit.wav");
2507                         else if(self.hitsound && self.cvar_cl_hitsound)
2508                                 play2(self, "misc/hit.wav");
2509                 }
2510         }
2511         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2512         // add 1 frametime because after this, engine SV_Physics
2513         // increases time by a frametime and then networks the frame
2514         // add another frametime because client shows everything with
2515         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2516         // needed!
2517         FOR_EACH_CLIENT(self)
2518         {
2519                 self.hitsound = FALSE;
2520                 self.typehitsound = FALSE;
2521                 antilag_record(self, altime);
2522         }
2523 }
2524
2525
2526 /*
2527  * RedirectionThink:
2528  * returns TRUE if redirecting
2529  */
2530 float redirection_timeout;
2531 float redirection_nextthink;
2532 float RedirectionThink()
2533 {
2534         float clients_found;
2535
2536         if(redirection_target == "")
2537                 return FALSE;
2538
2539         if(!redirection_timeout)
2540         {
2541                 cvar_set("sv_public", "-2");
2542                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2543                 if(redirection_target == "self")
2544                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2545                 else
2546                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2547         }
2548
2549         if(time < redirection_nextthink)
2550                 return TRUE;
2551
2552         redirection_nextthink = time + 1;
2553
2554         clients_found = 0;
2555         FOR_EACH_REALCLIENT(self)
2556         {
2557                 print("Redirecting: sending connect command to ", self.netname, "\n");
2558                 if(redirection_target == "self")
2559                         stuffcmd(self, "\ndisconnect; reconnect\n");
2560                 else
2561                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2562                 ++clients_found;
2563         }
2564
2565         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2566
2567         if(time > redirection_timeout || clients_found == 0)
2568                 localcmd("\nwait; wait; wait; quit\n");
2569
2570         return TRUE;
2571 }
2572
2573 void RestoreGame()
2574 {
2575         // Loaded from a save game
2576         // some things then break, so let's work around them...
2577
2578         // Progs DB (capture records)
2579         if(sv_cheats)
2580                 ServerProgsDB = db_create();
2581         else
2582                 ServerProgsDB = db_load("server.db");
2583
2584         // Mapinfo
2585         MapInfo_Shutdown();
2586         MapInfo_Enumerate();
2587         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2588 }
2589
2590 void SV_Shutdown()
2591 {
2592         if(gameover > 1) // shutting down already?
2593                 return;
2594
2595         gameover = 2; // 2 = server shutting down
2596
2597         if(world_initialized > 0)
2598         {
2599                 world_initialized = 0;
2600                 print("Saving persistent data...\n");
2601                 Ban_SaveBans();
2602                 if(!sv_cheats)
2603                         db_save(ServerProgsDB, "server.db");
2604                 if(cvar("developer"))
2605                         db_save(TemporaryDB, "server-temp.db");
2606                 db_close(ServerProgsDB);
2607                 db_close(TemporaryDB);
2608                 print("done!\n");
2609                 // tell the bot system the game is ending now
2610                 bot_endgame();
2611
2612                 MapInfo_Shutdown();
2613         }
2614         else if(world_initialized == 0)
2615         {
2616                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2617         }
2618 }