data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_cts");
 255                 BADCVAR("g_runematch");
 256                 BADCVAR("g_tdm");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("teamplay");
 259
 260                 // long
 261                 BADCVAR("hostname");
 262                 BADCVAR("g_maplist");
 263                 BADCVAR("g_maplist_mostrecent");
 264                 BADCVAR("sv_motd");
 265 #undef BADPREFIX
 266 #undef BADCVAR
 267
 268                 v = cvar_string(k);
 269                 d = cvar_defstring(k);
 270                 if(v != d)
 271                 {
 272                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 273                         if(strlen(cvar_changes) > 16384)
 274                         {
 275                                 cvar_changes = "// too many settings have been changed to show them here\n";
 276                                 break;
 277                         }
 278                 }
 279         }
 280         buf_del(h);
 281         if(cvar_changes == "")
 282                 cvar_changes = "// this server runs at default settings\n";
 283         else
 284                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 285         cvar_changes = strzone(cvar_changes);
 286 }
 287
 288 void detect_maptype()
 289 {
 290 #if 0
 291         vector o, v;
 292         float i;
 293
 294         for(;;)
 295         {
 296                 o = world.mins;
 297                 o_x += random() * (world.maxs_x - world.mins_x);
 298                 o_y += random() * (world.maxs_y - world.mins_y);
 299                 o_z += random() * (world.maxs_z - world.mins_z);
 300
 301                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 302                 if(trace_fraction == 1)
 303                         continue;
 304
 305                 v = trace_endpos;
 306
 307                 for(i = 0; i < 64; i += 4)
 308                 {
 309                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 310         if(trace_fraction == 1)
 311                 continue;
 312                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 313                 }
 314
 315                 break;
 316         }
 317 #endif
 318 }
 319
 320 entity randomseed;
 321 float RandomSeed_Send(entity to, float sf)
 322 {
 323         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 324         WriteShort(MSG_ENTITY, self.cnt);
 325         return TRUE;
 326 }
 327 void RandomSeed_Think()
 328 {
 329         self.cnt = bound(0, floor(random() * 65536), 65535);
 330         self.nextthink = time + 5;
 331
 332         self.SendFlags |= 1;
 333 }
 334 void RandomSeed_Spawn()
 335 {
 336         randomseed = spawn();
 337         randomseed.think = RandomSeed_Think;
 338         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 339
 340         entity oldself;
 341         oldself = self;
 342         self = randomseed;
 343         self.think(); // sets random seed and nextthink
 344         self = oldself;
 345 }
 346
 347 void spawnfunc___init_dedicated_server(void)
 348 {
 349         // handler for _init/_init map (only for dedicated server initialization)
 350
 351         world_initialized = -1; // don't complain
 352         cvar = cvar_builtin;
 353         cvar_string = cvar_string_builtin;
 354         cvar_set = cvar_set_builtin;
 355         dprint_load(); // load dprint status from cvar
 356
 357         remove = remove_unsafely;
 358
 359         entity e;
 360         e = spawn();
 361         e.think = GotoFirstMap;
 362         e.nextthink = time; // this is usually 1 at this point
 363
 364         e = spawn();
 365         e.classname = "info_player_deathmatch"; // safeguard against player joining
 366
 367         self.classname = "worldspawn"; // safeguard against various stuff ;)
 368
 369         MapInfo_Enumerate();
 370         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 371 }
 372
 373 void Map_MarkAsRecent(string m);
 374 float world_already_spawned;
 375 void RegisterWeapons();
 376 void Nagger_Init();
 377 void ClientInit_Spawn();
 378 void WeaponStats_Init();
 379 void WeaponStats_Shutdown();
 380 void spawnfunc_worldspawn (void)
 381 {
 382         float fd, l, i, j, n;
 383         string s, col;
 384
 385         cvar = cvar_builtin;
 386         cvar_string = cvar_string_builtin;
 387         cvar_set = cvar_set_builtin;
 388         dprint_load(); // load dprint status from cvar
 389
 390         if(world_already_spawned)
 391                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 392         world_already_spawned = TRUE;
 393
 394         remove = remove_safely; // during spawning, watch what you remove!
 395
 396         check_unacceptable_compiler_bugs();
 397
 398         if(cvar_string("cvar_check_default") != "bypass")
 399         {
 400                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 401                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 402
 403                 if(cvar_string("cvar_check_balance") != CVAR_CHECK_BALANCE)
 404                         error("Config file mismatch! Please update balance*.cfg to match the QuakeC code, and restart the engine!");
 405         }
 406
 407         compressShortVector_init();
 408
 409         local entity head;
 410         head = nextent(world);
 411         maxclients = 0;
 412         while(head)
 413         {
 414                 ++maxclients;
 415                 head = nextent(head);
 416         }
 417
 418         // needs to be done so early as they would still spawn
 419         RegisterWeapons();
 420
 421         if(sv_cheats)
 422                 ServerProgsDB = db_create();
 423         else
 424                 ServerProgsDB = db_load("server.db");
 425
 426         TemporaryDB = db_create();
 427
 428         /*
 429         TODO sound pack system
 430         // initialize sound pack system
 431         soundpack = cvar_string("g_soundpack");
 432         if(soundpack != "")
 433                 soundpack = strcat(soundpack, "/");
 434         soundpack = strzone(soundpack);
 435         */
 436
 437         // 0 normal
 438         lightstyle(0, "m");
 439
 440         // 1 FLICKER (first variety)
 441         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 442
 443         // 2 SLOW STRONG PULSE
 444         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 445
 446         // 3 CANDLE (first variety)
 447         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 448
 449         // 4 FAST STROBE
 450         lightstyle(4, "mamamamamama");
 451
 452         // 5 GENTLE PULSE 1
 453         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 454
 455         // 6 FLICKER (second variety)
 456         lightstyle(6, "nmonqnmomnmomomno");
 457
 458         // 7 CANDLE (second variety)
 459         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 460
 461         // 8 CANDLE (third variety)
 462         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 463
 464         // 9 SLOW STROBE (fourth variety)
 465         lightstyle(9, "aaaaaaaazzzzzzzz");
 466
 467         // 10 FLUORESCENT FLICKER
 468         lightstyle(10, "mmamammmmammamamaaamammma");
 469
 470         // 11 SLOW PULSE NOT FADE TO BLACK
 471         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 472
 473         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 474
 475         // 63 testing
 476         lightstyle(63, "a");
 477
 478         if(cvar("g_campaign"))
 479                 CampaignPreInit();
 480
 481         Map_MarkAsRecent(mapname);
 482
 483         precache_model ("null"); // we need this one before InitGameplayMode
 484         InitGameplayMode();
 485         readlevelcvars();
 486         GrappleHookInit();
 487
 488         player_count = 0;
 489         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 490         if(bot_waypoints_for_items == 1)
 491                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 492                         bot_waypoints_for_items = 0;
 493
 494         // for setting by mapinfo
 495         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 496         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 497
 498         precache();
 499
 500         WaypointSprite_Init();
 501
 502         //if (g_domination)
 503         //      dom_init();
 504
 505         GameLogInit(); // prepare everything
 506         if(cvar("sv_eventlog"))
 507         {
 508                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 509                 s = strcat(s, ftos(random()));
 510                 matchid = strzone(s);
 511
 512                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 513                 s = ":gameinfo:mutators:LIST";
 514                 if(cvar("g_grappling_hook"))
 515                         s = strcat(s, ":grappling_hook");
 516                 if(!cvar("g_use_ammunition"))
 517                         s = strcat(s, ":no_use_ammunition");
 518                 if(!cvar("g_pickup_items"))
 519                         s = strcat(s, ":no_pickup_items");
 520                 if(cvar("g_instagib"))
 521                         s = strcat(s, ":instagib");
 522                 if(cvar_string("g_weaponarena") != "0")
 523                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 524                 if(cvar("g_nixnex"))
 525                         s = strcat(s, ":nixnex");
 526                 if(cvar("g_vampire"))
 527                         s = strcat(s, ":vampire");
 528                 if(cvar("g_laserguided_missile"))
 529                         s = strcat(s, ":laserguided_missile");
 530                 if(cvar("g_norecoil"))
 531                         s = strcat(s, ":norecoil");
 532                 if(cvar("g_midair"))
 533                         s = strcat(s, ":midair");
 534                 if(cvar("g_minstagib"))
 535                         s = strcat(s, ":minstagib");
 536                 GameLogEcho(s);
 537                 GameLogEcho(":gameinfo:end");
 538         }
 539         else
 540                 matchid = strzone(ftos(random()));
 541
 542         cvar_set("nextmap", "");
 543
 544         SetDefaultAlpha();
 545
 546         if(cvar("g_campaign"))
 547                 CampaignPostInit();
 548
 549         fteqcc_testbugs();
 550
 551         Ban_LoadBans();
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 555
 556         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 557         {
 558                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 559                 if(fd != -1)
 560                 {
 561                         while((s = fgets(fd)))
 562                         {
 563                                 l = tokenize_console(s);
 564                                 if(l < 2)
 565                                         continue;
 566                                 if(argv(0) == "cd")
 567                                 {
 568                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 569                                         print("  cdtrack ", argv(2), "\n");
 570                                 }
 571                                 else if(argv(0) == "fog")
 572                                 {
 573                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 574                                         print("  \"fog\" \"", s, "\"\n");
 575                                 }
 576                                 else if(argv(0) == "set")
 577                                 {
 578                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 579                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 580                                 }
 581                                 else if(argv(0) != "//")
 582                                 {
 583                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 584                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 585                                 }
 586                         }
 587                         fclose(fd);
 588                 }
 589         }
 590
 591         WeaponStats_Init();
 592
 593         addstat(STAT_WEAPONS, AS_INT, weapons);
 594         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 595         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 596         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 597         Nagger_Init();
 598
 599         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 600         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 601         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 602         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 603         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 604         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 605         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 606         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 607         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 608
 609         next_pingtime = time + 5;
 610         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 611
 612         detect_maptype();
 613
 614         lsmaps_reply = "^7Maps available: ";
 615         for(i = 0, j = 0; i < MapInfo_count; ++i)
 616         {
 617                 if(MapInfo_Get_ByID(i))
 618                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 619                         {
 620                                 if(mod(i, 2))
 621                                         col = "^2";
 622                                 else
 623                                         col = "^3";
 624                                 ++j;
 625                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 626                         }
 627         }
 628         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 629
 630         maplist_reply = "^7Maps in list: ";
 631         n = tokenize_console(cvar_string("g_maplist"));
 632         for(i = 0, j = 0; i < n; ++i)
 633         {
 634                 if(MapInfo_CheckMap(argv(i)))
 635                 {
 636                         if(mod(j, 2))
 637                                 col = "^2";
 638                         else
 639                                 col = "^3";
 640                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 641                         ++j;
 642                 }
 643         }
 644         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 645         MapInfo_ClearTemps();
 646
 647         records_reply = strzone(getrecords());
 648
 649         ClientInit_Spawn();
 650         RandomSeed_Spawn();
 651
 652         localcmd("\n_sv_hook_gamestart ", GetGametype(), ";");
 653
 654         world_initialized = 1;
 655 }
 656
 657 void spawnfunc_light (void)
 658 {
 659         //makestatic (self); // Who the f___ did that?
 660         remove(self);
 661 }
 662
 663 float TryFile( string pFilename )
 664 {
 665         local float lHandle;
 666         dprint("TryFile(\"", pFilename, "\")\n");
 667         lHandle = fopen( pFilename, FILE_READ );
 668         if( lHandle != -1 ) {
 669                 fclose( lHandle );
 670                 return TRUE;
 671         } else {
 672                 return FALSE;
 673         }
 674 };
 675
 676 string GetGametype()
 677 {
 678         return GametypeNameFromType(game);
 679 }
 680
 681 string getmapname_stored;
 682 string GetMapname()
 683 {
 684         return mapname;
 685 }
 686
 687 float Map_Count, Map_Current;
 688 string Map_Current_Name;
 689
 690 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 691 float GetMaplistPosition()
 692 {
 693         float pos, idx;
 694         string map;
 695
 696         map = GetMapname();
 697         idx = cvar("g_maplist_index");
 698
 699         if(idx >= 0)
 700                 if(idx < Map_Count)
 701                         if(map == argv(idx))
 702                                 return idx;
 703
 704         for(pos = 0; pos < Map_Count; ++pos)
 705                 if(map == argv(pos))
 706                         return pos;
 707
 708         // resume normal maplist rotation if current map is not in g_maplist
 709         return idx;
 710 }
 711
 712 float MapHasRightSize(string map)
 713 {
 714         float fh;
 715         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 716         if(cvar("g_maplist_check_waypoints"))
 717         {
 718                 dprint("checkwp "); dprint(map);
 719                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 720                 if(fh < 0)
 721                 {
 722                         dprint(": no waypoints\n");
 723                         return FALSE;
 724                 }
 725                 dprint(": has waypoints\n");
 726                 fclose(fh);
 727         }
 728
 729         // open map size restriction file
 730         dprint("opensize "); dprint(map);
 731         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 732         if(fh >= 0)
 733         {
 734                 float mapmin, mapmax;
 735                 dprint(": ok, ");
 736                 mapmin = stof(fgets(fh));
 737                 mapmax = stof(fgets(fh));
 738                 fclose(fh);
 739                 if(player_count < mapmin)
 740                 {
 741                         dprint("not enough\n");
 742                         return FALSE;
 743                 }
 744                 if(player_count > mapmax)
 745                 {
 746                         dprint("too many\n");
 747                         return FALSE;
 748                 }
 749                 dprint("right size\n");
 750                 return TRUE;
 751         }
 752         dprint(": not found\n");
 753         return TRUE;
 754 }
 755
 756 string Map_Filename(float position)
 757 {
 758         return strcat("maps/", argv(position), ".bsp");
 759 }
 760
 761 string strwords(string s, float w)
 762 {
 763         float endpos;
 764         for(endpos = 0; w && endpos >= 0; --w)
 765                 endpos = strstrofs(s, " ", endpos + 1);
 766         if(endpos < 0)
 767                 return s;
 768         else
 769                 return substring(s, 0, endpos);
 770 }
 771
 772 float strhasword(string s, string w)
 773 {
 774         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 775 }
 776
 777 void Map_MarkAsRecent(string m)
 778 {
 779         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 780 }
 781
 782 float Map_IsRecent(string m)
 783 {
 784         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 785 }
 786
 787 float Map_Check(float position, float pass)
 788 {
 789         string filename;
 790         string map_next;
 791         map_next = argv(position);
 792         if(pass <= 1)
 793         {
 794                 if(Map_IsRecent(map_next))
 795                         return 0;
 796         }
 797         filename = Map_Filename(position);
 798         if(MapInfo_CheckMap(map_next))
 799         {
 800                 if(pass == 2)
 801                         return 1;
 802                 if(MapHasRightSize(map_next))
 803                         return 1;
 804                 return 0;
 805         }
 806         else
 807                 dprint( "Couldn't select '", filename, "'..\n" );
 808
 809         return 0;
 810 }
 811
 812 void Map_Goto_SetStr(string nextmapname)
 813 {
 814         if(getmapname_stored != "")
 815                 strunzone(getmapname_stored);
 816         if(nextmapname == "")
 817                 getmapname_stored = "";
 818         else
 819                 getmapname_stored = strzone(nextmapname);
 820 }
 821
 822 void Map_Goto_SetFloat(float position)
 823 {
 824         cvar_set("g_maplist_index", ftos(position));
 825         Map_Goto_SetStr(argv(position));
 826 }
 827
 828 void GameResetCfg()
 829 {
 830         // settings persist, except...
 831         localcmd("\nsettemp_restore\n");
 832 };
 833
 834 void Map_Goto()
 835 {
 836         GameResetCfg();
 837         MapInfo_LoadMap(getmapname_stored);
 838 }
 839
 840 // return codes of map selectors:
 841 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 842 //   -2 = permanent failure
 843 float() MaplistMethod_Iterate = // usual method
 844 {
 845         float pass, i;
 846
 847         for(pass = 1; pass <= 2; ++pass)
 848         {
 849                 for(i = 1; i < Map_Count; ++i)
 850                 {
 851                         float mapindex;
 852                         mapindex = mod(i + Map_Current, Map_Count);
 853                         if(Map_Check(mapindex, pass))
 854                                 return mapindex;
 855                 }
 856         }
 857         return -1;
 858 }
 859
 860 float() MaplistMethod_Repeat = // fallback method
 861 {
 862         if(Map_Check(Map_Current, 2))
 863                 return Map_Current;
 864         return -2;
 865 }
 866
 867 float() MaplistMethod_Random = // random map selection
 868 {
 869         float i, imax;
 870
 871         imax = 42;
 872
 873         for(i = 0; i <= imax; ++i)
 874         {
 875                 float mapindex;
 876                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 877                 if(Map_Check(mapindex, 1))
 878                         return mapindex;
 879         }
 880         return -1;
 881 }
 882
 883 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 884 // the exponent sets a bias on the map selection:
 885 // the higher the exponent, the less likely "shortly repeated" same maps are
 886 {
 887         float i, j, imax, insertpos;
 888
 889         imax = 42;
 890
 891         for(i = 0; i <= imax; ++i)
 892         {
 893                 string newlist;
 894
 895                 // now reinsert this at another position
 896                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 897                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 898                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 899                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 900
 901                 // insert the current map there
 902                 newlist = "";
 903                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 904                         newlist = strcat(newlist, " ", argv(j));
 905                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 906                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 907                         newlist = strcat(newlist, " ", argv(j));
 908                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 909                 cvar_set("g_maplist", newlist);
 910                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 911
 912                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 913                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 914                 if(Map_Check(Map_Current, 1))
 915                         return Map_Current;
 916         }
 917         return -1;
 918 }
 919
 920 void Maplist_Init()
 921 {
 922         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 923         if(Map_Count == 0)
 924         {
 925                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 926                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 927                 if(cvar("g_maplist_shuffle"))
 928                         ShuffleMaplist();
 929                 localcmd("\nmenu_cmd sync\n");
 930                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 931         }
 932         if(Map_Count == 0)
 933                 error("empty maplist, cannot select a new map");
 934         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 935
 936         if(Map_Current_Name)
 937                 strunzone(Map_Current_Name);
 938         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 939         // this may or may not be correct, but who cares, in the worst case a map
 940         // isn't chosen in the first pass that should have been
 941 }
 942
 943 string GetNextMap()
 944 {
 945         float nextMap;
 946
 947         Maplist_Init();
 948         nextMap = -1;
 949
 950         if(nextMap == -1)
 951                 if(cvar("g_maplist_shuffle") > 0)
 952                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 953
 954         if(nextMap == -1)
 955                 if(cvar("g_maplist_selectrandom"))
 956                         nextMap = MaplistMethod_Random();
 957
 958         if(nextMap == -1)
 959                 nextMap = MaplistMethod_Iterate();
 960
 961         if(nextMap == -1)
 962                 nextMap = MaplistMethod_Repeat();
 963
 964         if(nextMap >= 0)
 965         {
 966                 Map_Goto_SetFloat(nextMap);
 967                 return getmapname_stored;
 968         }
 969
 970         return "";
 971 };
 972
 973 float DoNextMapOverride()
 974 {
 975         if(cvar("g_campaign"))
 976         {
 977                 CampaignPostIntermission();
 978                 alreadychangedlevel = TRUE;
 979                 return TRUE;
 980         }
 981         if(cvar("quit_when_empty"))
 982         {
 983                 if(player_count <= currentbots)
 984                 {
 985                         localcmd("quit\n");
 986                         alreadychangedlevel = TRUE;
 987                         return TRUE;
 988                 }
 989         }
 990         if(cvar_string("quit_and_redirect") != "")
 991         {
 992                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 993                 alreadychangedlevel = TRUE;
 994                 return TRUE;
 995         }
 996         if (cvar("samelevel")) // if samelevel is set, stay on same level
 997         {
 998                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 999                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1000                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1001                 localcmd("restart\n");
1002                 //changelevel (mapname);
1003                 alreadychangedlevel = TRUE;
1004                 return TRUE;
1005         }
1006         if(cvar_string("nextmap") != "")
1007                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1008                 {
1009                         Map_Goto_SetStr(cvar_string("nextmap"));
1010                         Map_Goto();
1011                         alreadychangedlevel = TRUE;
1012                         return TRUE;
1013                 }
1014         if(cvar("lastlevel"))
1015         {
1016                 GameResetCfg();
1017                 localcmd("set lastlevel 0\ntogglemenu\n");
1018                 alreadychangedlevel = TRUE;
1019                 return TRUE;
1020         }
1021         return FALSE;
1022 };
1023
1024 void GotoNextMap()
1025 {
1026         //local string nextmap;
1027         //local float n, nummaps;
1028         //local string s;
1029         if (alreadychangedlevel)
1030                 return;
1031         alreadychangedlevel = TRUE;
1032
1033         {
1034                 string nextMap;
1035                 float allowReset;
1036
1037                 for(allowReset = 1; allowReset >= 0; --allowReset)
1038                 {
1039                         nextMap = GetNextMap();
1040                         if(nextMap != "")
1041                                 break;
1042
1043                         if(allowReset)
1044                         {
1045                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1046                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1047                                 if(cvar("g_maplist_shuffle"))
1048                                         ShuffleMaplist();
1049                                 localcmd("\nmenu_cmd sync\n");
1050                         }
1051                         else
1052                         {
1053                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1054                         }
1055                 }
1056                 Map_Goto();
1057         }
1058 };
1059
1060
1061 /*
1062 ============
1063 IntermissionThink
1064
1065 When the player presses attack or jump, change to the next level
1066 ============
1067 */
1068 .float autoscreenshot;
1069 void() MapVote_Start;
1070 void() MapVote_Think;
1071 float mapvote_initialized;
1072 void IntermissionThink()
1073 {
1074         FixIntermissionClient(self);
1075
1076         if(cvar("sv_autoscreenshot"))
1077         if(self.autoscreenshot > 0)
1078         if(time > self.autoscreenshot)
1079         {
1080                 self.autoscreenshot = -1;
1081                 if(clienttype(self) == CLIENTTYPE_REAL)
1082                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1083                 return;
1084         }
1085
1086         if (time < intermission_exittime)
1087                 return;
1088
1089         if(!mapvote_initialized)
1090                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1091                         return;
1092
1093         MapVote_Start();
1094 };
1095
1096 /*
1097 ============
1098 FindIntermission
1099
1100 Returns the entity to view from
1101 ============
1102 */
1103 /*
1104 entity FindIntermission()
1105 {
1106         local   entity spot;
1107         local   float cyc;
1108
1109 // look for info_intermission first
1110         spot = find (world, classname, "info_intermission");
1111         if (spot)
1112         {       // pick a random one
1113                 cyc = random() * 4;
1114                 while (cyc > 1)
1115                 {
1116                         spot = find (spot, classname, "info_intermission");
1117                         if (!spot)
1118                                 spot = find (spot, classname, "info_intermission");
1119                         cyc = cyc - 1;
1120                 }
1121                 return spot;
1122         }
1123
1124 // then look for the start position
1125         spot = find (world, classname, "info_player_start");
1126         if (spot)
1127                 return spot;
1128
1129 // testinfo_player_start is only found in regioned levels
1130         spot = find (world, classname, "testplayerstart");
1131         if (spot)
1132                 return spot;
1133
1134 // then look for the start position
1135         spot = find (world, classname, "info_player_deathmatch");
1136         if (spot)
1137                 return spot;
1138
1139         //objerror ("FindIntermission: no spot");
1140         return world;
1141 };
1142 */
1143
1144 /*
1145 ===============================================================================
1146
1147 RULES
1148
1149 ===============================================================================
1150 */
1151
1152 void DumpStats(float final)
1153 {
1154         local float file;
1155         local string s;
1156         local float to_console;
1157         local float to_eventlog;
1158         local float to_file;
1159         local float i;
1160
1161         to_console = cvar("sv_logscores_console");
1162         to_eventlog = cvar("sv_eventlog");
1163         to_file = cvar("sv_logscores_file");
1164
1165         if(!final)
1166         {
1167                 to_console = TRUE; // always print printstats replies
1168                 to_eventlog = FALSE; // but never print them to the event log
1169         }
1170
1171         if(to_eventlog)
1172                 if(cvar("sv_eventlog_console"))
1173                         to_console = FALSE; // otherwise we get the output twice
1174
1175         if(final)
1176                 s = ":scores:";
1177         else
1178                 s = ":status:";
1179         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1180
1181         if(to_console)
1182                 print(s, "\n");
1183         if(to_eventlog)
1184                 GameLogEcho(s);
1185         if(to_file)
1186         {
1187                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1188                 if(file == -1)
1189                         to_file = FALSE;
1190                 else
1191                         fputs(file, strcat(s, "\n"));
1192         }
1193
1194         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1195         if(to_console)
1196                 print(s, "\n");
1197         if(to_eventlog)
1198                 GameLogEcho(s);
1199         if(to_file)
1200                 fputs(file, strcat(s, "\n"));
1201
1202         FOR_EACH_CLIENT(other)
1203         {
1204                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1205                 {
1206                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1207                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1208                         if(other.classname == "player" || g_arena || g_lms)
1209                                 s = strcat(s, ftos(other.team), ":");
1210                         else
1211                                 s = strcat(s, "spectator:");
1212
1213                         if(to_console)
1214                                 print(s, other.netname, "\n");
1215                         if(to_eventlog)
1216                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1217                         if(to_file)
1218                                 fputs(file, strcat(s, other.netname, "\n"));
1219                 }
1220         }
1221
1222         if(teams_matter)
1223         {
1224                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1225                 if(to_console)
1226                         print(s, "\n");
1227                 if(to_eventlog)
1228                         GameLogEcho(s);
1229                 if(to_file)
1230                         fputs(file, strcat(s, "\n"));
1231
1232                 for(i = 1; i < 16; ++i)
1233                 {
1234                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1235                         s = strcat(s, ":", ftos(i));
1236                         if(to_console)
1237                                 print(s, "\n");
1238                         if(to_eventlog)
1239                                 GameLogEcho(s);
1240                         if(to_file)
1241                                 fputs(file, strcat(s, "\n"));
1242                 }
1243         }
1244
1245         if(to_console)
1246                 print(":end\n");
1247         if(to_eventlog)
1248                 GameLogEcho(":end");
1249         if(to_file)
1250         {
1251                 fputs(file, ":end\n");
1252                 fclose(file);
1253         }
1254 }
1255
1256 void FixIntermissionClient(entity e)
1257 {
1258         string s;
1259         if(!e.autoscreenshot) // initial call
1260         {
1261                 e.angles = e.v_angle;
1262                 e.angles_x = -e.angles_x;
1263                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1264                 e.health = -2342;
1265                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1266                 e.solid = SOLID_NOT;
1267                 e.movetype = MOVETYPE_NONE;
1268                 e.takedamage = DAMAGE_NO;
1269                 if(e.weaponentity)
1270                 {
1271                         e.weaponentity.effects = EF_NODRAW;
1272                         if (e.weaponentity.weaponentity)
1273                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1274                 }
1275                 if(clienttype(e) == CLIENTTYPE_REAL)
1276                 {
1277                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1278                         s = cvar_string("sv_intermission_cdtrack");
1279                         if(s != "")
1280                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1281                         msg_entity = e;
1282                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1283                 }
1284         }
1285
1286         //e.velocity = '0 0 0';
1287         //e.fixangle = TRUE;
1288
1289         // TODO halt weapon animation
1290 }
1291
1292
1293 /*
1294 go to the next level for deathmatch
1295 only called if a time or frag limit has expired
1296 */
1297 void NextLevel()
1298 {
1299         float minTotalFrags;
1300         float maxTotalFrags;
1301         float score;
1302         float f;
1303
1304         gameover = TRUE;
1305
1306         intermission_running = 1;
1307
1308 // enforce a wait time before allowing changelevel
1309         if(player_count > 0)
1310                 intermission_exittime = time + cvar("sv_mapchange_delay");
1311         else
1312                 intermission_exittime = -1;
1313
1314         /*
1315         WriteByte (MSG_ALL, SVC_CDTRACK);
1316         WriteByte (MSG_ALL, 3);
1317         WriteByte (MSG_ALL, 3);
1318         // done in FixIntermission
1319         */
1320
1321         //pos = FindIntermission ();
1322
1323         VoteReset();
1324
1325         DumpStats(TRUE);
1326
1327         if(cvar("sv_eventlog"))
1328                 GameLogEcho(":gameover");
1329
1330         GameLogClose();
1331
1332         FOR_EACH_CLIENT(other)
1333         {
1334                 FixIntermissionClient(other);
1335
1336                 if(other.winning)
1337                         bprint(other.netname, " ^7wins.\n");
1338         }
1339
1340         minTotalFrags = 0;
1341         maxTotalFrags = 0;
1342         FOR_EACH_PLAYER(other)
1343         {
1344                 if(maxTotalFrags < other.totalfrags)
1345                         maxTotalFrags = other.totalfrags;
1346                 if(minTotalFrags > other.totalfrags)
1347                         minTotalFrags = other.totalfrags;
1348         }
1349
1350         if(!currentbots)
1351         {
1352                 FOR_EACH_PLAYER(other)
1353                 {
1354                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1355                         f = bound(0, other.play_time / max(time, 1), 1);
1356                         // store some statistics?
1357                 }
1358         }
1359
1360         if(cvar("g_campaign"))
1361                 CampaignPreIntermission();
1362
1363         localcmd("\nsv_hook_gameend;");
1364
1365         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1366 };
1367
1368 /*
1369 ============
1370 CheckRules_Player
1371
1372 Exit deathmatch games upon conditions
1373 ============
1374 */
1375 void CheckRules_Player()
1376 {
1377         if (gameover)   // someone else quit the game already
1378                 return;
1379
1380         if(self.deadflag == DEAD_NO)
1381                 self.play_time += frametime;
1382
1383         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1384         //   (div0: and that in CheckRules_World please)
1385 };
1386
1387 float checkrules_equality;
1388 float checkrules_suddendeathwarning;
1389 float checkrules_suddendeathend;
1390 float checkrules_overtimesadded; //how many overtimes have been already added
1391
1392 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1393 float WINNING_YES = 1; // winner found
1394 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1395 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1396
1397 float InitiateSuddenDeath()
1398 {
1399         // Check first whether normal overtimes could be added before initiating suddendeath mode
1400         // - for this timelimit_overtime needs to be >0 of course
1401         // - also check the winning condition calculated in the previous frame and only add normal overtime
1402         //   again, if at the point at which timelimit would be extended again, still no winner was found
1403         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1404         {
1405                 return 1; // need to call InitiateOvertime later
1406         }
1407         else
1408         {
1409                 if(!checkrules_suddendeathend)
1410                 {
1411                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1412                         if(g_race && !g_race_qualifying)
1413                                 race_StartCompleting();
1414                 }
1415                 return 0;
1416         }
1417 }
1418
1419 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1420 {
1421         ++checkrules_overtimesadded;
1422         //add one more overtime by simply extending the timelimit
1423         float tl;
1424         tl = cvar("timelimit");
1425         tl += cvar("timelimit_overtime");
1426         cvar_set("timelimit", ftos(tl));
1427         string minutesPlural;
1428         if (cvar("timelimit_overtime") == 1)
1429                 minutesPlural = " ^3minute";
1430         else
1431                 minutesPlural = " ^3minutes";
1432
1433         bcenterprint(
1434                 strcat(
1435                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1436                         ftos(cvar("timelimit_overtime")),
1437                         minutesPlural,
1438                         " to the game!"
1439                 )
1440         );
1441 }
1442
1443 float GetWinningCode(float fraglimitreached, float equality)
1444 {
1445         if(equality)
1446                 if(fraglimitreached)
1447                         return WINNING_STARTSUDDENDEATHOVERTIME;
1448                 else
1449                         return WINNING_NEVER;
1450         else
1451                 if(fraglimitreached)
1452                         return WINNING_YES;
1453                 else
1454                         return WINNING_NO;
1455 }
1456
1457 // set the .winning flag for exactly those players with a given field value
1458 void SetWinners(.float field, float value)
1459 {
1460         entity head;
1461         FOR_EACH_PLAYER(head)
1462                 head.winning = (head.field == value);
1463 }
1464
1465 // set the .winning flag for those players with a given field value
1466 void AddWinners(.float field, float value)
1467 {
1468         entity head;
1469         FOR_EACH_PLAYER(head)
1470                 if(head.field == value)
1471                         head.winning = 1;
1472 }
1473
1474 // clear the .winning flags
1475 void ClearWinners(void)
1476 {
1477         entity head;
1478         FOR_EACH_PLAYER(head)
1479                 head.winning = 0;
1480 }
1481
1482 // Onslaught winning condition:
1483 // game terminates if only one team has a working generator (or none)
1484 float WinningCondition_Onslaught()
1485 {
1486         entity head;
1487         local float t1, t2, t3, t4;
1488
1489         WinningConditionHelper(); // set worldstatus
1490
1491         if(inWarmupStage)
1492                 return WINNING_NO;
1493
1494         // first check if the game has ended
1495         t1 = t2 = t3 = t4 = 0;
1496         head = find(world, classname, "onslaught_generator");
1497         while (head)
1498         {
1499                 if (head.health > 0)
1500                 {
1501                         if (head.team == COLOR_TEAM1) t1 = 1;
1502                         if (head.team == COLOR_TEAM2) t2 = 1;
1503                         if (head.team == COLOR_TEAM3) t3 = 1;
1504                         if (head.team == COLOR_TEAM4) t4 = 1;
1505                 }
1506                 head = find(head, classname, "onslaught_generator");
1507         }
1508         if (t1 + t2 + t3 + t4 < 2)
1509         {
1510                 // game over, only one team remains (or none)
1511                 ClearWinners();
1512                 if (t1) SetWinners(team, COLOR_TEAM1);
1513                 if (t2) SetWinners(team, COLOR_TEAM2);
1514                 if (t3) SetWinners(team, COLOR_TEAM3);
1515                 if (t4) SetWinners(team, COLOR_TEAM4);
1516                 dprint("Have a winner, ending game.\n");
1517                 return WINNING_YES;
1518         }
1519
1520         // Two or more teams remain
1521         return WINNING_NO;
1522 }
1523
1524 float LMS_NewPlayerLives()
1525 {
1526         float fl;
1527         fl = cvar("fraglimit");
1528         if(fl == 0)
1529                 fl = 999;
1530
1531         // first player has left the game for dying too much? Nobody else can get in.
1532         if(lms_lowest_lives < 1)
1533                 return 0;
1534
1535         if(!cvar("g_lms_join_anytime"))
1536                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1537                         return 0;
1538
1539         return bound(1, lms_lowest_lives, fl);
1540 }
1541
1542 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1543 // they win. Otherwise the defending team wins once the timelimit passes.
1544 void assault_new_round();
1545 float WinningCondition_Assault()
1546 {
1547         local float status;
1548
1549         WinningConditionHelper(); // set worldstatus
1550
1551         status = WINNING_NO;
1552         // as the timelimit has not yet passed just assume the defending team will win
1553         if(assault_attacker_team == COLOR_TEAM1)
1554         {
1555                 SetWinners(team, COLOR_TEAM2);
1556         }
1557         else
1558         {
1559                 SetWinners(team, COLOR_TEAM1);
1560         }
1561
1562         local entity ent;
1563         ent = find(world, classname, "target_assault_roundend");
1564         if(ent)
1565         {
1566                 if(ent.winning) // round end has been triggered by attacking team
1567                 {
1568                         bprint("ASSAULT: round completed...\n");
1569                         SetWinners(team, assault_attacker_team);
1570
1571                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1572
1573                         if(ent.cnt == 1) // this was the second round
1574                         {
1575                                 status = WINNING_YES;
1576                         }
1577                         else
1578                         {
1579                                 local entity oldself;
1580                                 oldself = self;
1581                                 self = ent;
1582                                 assault_new_round();
1583                                 self = oldself;
1584                         }
1585                 }
1586         }
1587
1588         return status;
1589 }
1590
1591 // LMS winning condition: game terminates if and only if there's at most one
1592 // one player who's living lives. Top two scores being equal cancels the time
1593 // limit.
1594 float WinningCondition_LMS()
1595 {
1596         entity head, head2;
1597         float have_player;
1598         float have_players;
1599         float l;
1600
1601         have_player = FALSE;
1602         have_players = FALSE;
1603         l = LMS_NewPlayerLives();
1604
1605         head = find(world, classname, "player");
1606         if(head)
1607                 have_player = TRUE;
1608         head2 = find(head, classname, "player");
1609         if(head2)
1610                 have_players = TRUE;
1611
1612         if(have_player)
1613         {
1614                 // we have at least one player
1615                 if(have_players)
1616                 {
1617                         // two or more active players - continue with the game
1618                 }
1619                 else
1620                 {
1621                         // exactly one player?
1622
1623                         ClearWinners();
1624                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1625
1626                         if(l)
1627                         {
1628                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1629                                 return WINNING_NO;
1630                         }
1631                         else
1632                         {
1633                                 // a winner!
1634                                 // and assign him his first place
1635                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1636                                 return WINNING_YES;
1637                         }
1638                 }
1639         }
1640         else
1641         {
1642                 // nobody is playing at all...
1643                 if(l)
1644                 {
1645                         // wait for players...
1646                 }
1647                 else
1648                 {
1649                         // SNAFU (maybe a draw game?)
1650                         ClearWinners();
1651                         dprint("No players, ending game.\n");
1652                         return WINNING_YES;
1653                 }
1654         }
1655
1656         // When we get here, we have at least two players who are actually LIVING,
1657         // now check if the top two players have equal score.
1658         WinningConditionHelper();
1659
1660         ClearWinners();
1661         if(WinningConditionHelper_winner)
1662                 WinningConditionHelper_winner.winning = TRUE;
1663         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1664                 return WINNING_NEVER;
1665
1666         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1667         return WINNING_NO;
1668 }
1669
1670 void ShuffleMaplist()
1671 {
1672         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1673 }
1674
1675 float leaderfrags;
1676 float WinningCondition_Scores(float limit, float leadlimit)
1677 {
1678         // TODO make everything use THIS winning condition (except LMS)
1679         WinningConditionHelper();
1680
1681         if(teams_matter)
1682         {
1683                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1684                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1685                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1686                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1687         }
1688
1689         ClearWinners();
1690         if(WinningConditionHelper_winner)
1691                 WinningConditionHelper_winner.winning = 1;
1692         if(WinningConditionHelper_winnerteam >= 0)
1693                 SetWinners(team, WinningConditionHelper_winnerteam);
1694
1695         if(WinningConditionHelper_lowerisbetter)
1696         {
1697                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1698                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1699                 limit = -limit;
1700         }
1701
1702         if(WinningConditionHelper_zeroisworst)
1703                 leadlimit = 0; // not supported in this mode
1704
1705         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1706         // these modes always score in increments of 1, thus this makes sense
1707         {
1708                 if(leaderfrags != WinningConditionHelper_topscore)
1709                 {
1710                         leaderfrags = WinningConditionHelper_topscore;
1711
1712                         if (limit)
1713                         if (leaderfrags == limit - 1)
1714                                 play2all("announcer/robotic/1fragleft.wav");
1715                         else if (leaderfrags == limit - 2)
1716                                 play2all("announcer/robotic/2fragsleft.wav");
1717                         else if (leaderfrags == limit - 3)
1718                                 play2all("announcer/robotic/3fragsleft.wav");
1719                 }
1720         }
1721
1722         return GetWinningCode(
1723                 WinningConditionHelper_topscore &&
1724                 (
1725                         (limit && (WinningConditionHelper_topscore >= limit))
1726                         ||
1727                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1728                 ),
1729                 WinningConditionHelper_equality
1730         );
1731 }
1732
1733 float WinningCondition_Race(float fraglimit)
1734 {
1735         float wc;
1736         entity p;
1737         float n, c;
1738
1739         n = 0;
1740         c = 0;
1741         FOR_EACH_PLAYER(p)
1742         {
1743                 ++n;
1744                 if(p.race_completed)
1745                         ++c;
1746         }
1747         if(n && (n == c))
1748                 return WINNING_YES;
1749         wc = WinningCondition_Scores(fraglimit, 0);
1750
1751         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1752         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1753         // do NOT support equality when the laps are all raced!
1754                 return WINNING_STARTSUDDENDEATHOVERTIME;
1755         else
1756                 return WINNING_NEVER;
1757         return wc;
1758 }
1759
1760 void ReadyRestart();
1761 float WinningCondition_QualifyingThenRace(float limit)
1762 {
1763         float wc;
1764         wc = WinningCondition_Scores(limit, 0);
1765
1766         // NEVER initiate overtime
1767         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1768         {
1769                 return WINNING_YES;
1770         }
1771
1772         return wc;
1773 }
1774
1775 float WinningCondition_RanOutOfSpawns()
1776 {
1777         entity head;
1778
1779         if(!have_team_spawns)
1780                 return WINNING_NO;
1781
1782         if(!some_spawn_has_been_used)
1783                 return WINNING_NO;
1784
1785         team1_score = team2_score = team3_score = team4_score = 0;
1786
1787         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1788         {
1789                 if(head.team == COLOR_TEAM1)
1790                         team1_score = 1;
1791                 else if(head.team == COLOR_TEAM2)
1792                         team2_score = 1;
1793                 else if(head.team == COLOR_TEAM3)
1794                         team3_score = 1;
1795                 else if(head.team == COLOR_TEAM4)
1796                         team4_score = 1;
1797         }
1798
1799         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1800         {
1801                 if(head.team == COLOR_TEAM1)
1802                         team1_score = 1;
1803                 else if(head.team == COLOR_TEAM2)
1804                         team2_score = 1;
1805                 else if(head.team == COLOR_TEAM3)
1806                         team3_score = 1;
1807                 else if(head.team == COLOR_TEAM4)
1808                         team4_score = 1;
1809         }
1810
1811         ClearWinners();
1812         if(team1_score + team2_score + team3_score + team4_score == 0)
1813         {
1814                 checkrules_equality = TRUE;
1815                 return WINNING_YES;
1816         }
1817         else if(team1_score + team2_score + team3_score + team4_score == 1)
1818         {
1819                 float t, i;
1820                 if(team1_score) t = COLOR_TEAM1;
1821                 if(team2_score) t = COLOR_TEAM2;
1822                 if(team3_score) t = COLOR_TEAM3;
1823                 if(team4_score) t = COLOR_TEAM4;
1824                 CheckAllowedTeams(world);
1825                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1826                 {
1827                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1828                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1829                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1830                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1831                 }
1832
1833                 AddWinners(team, t);
1834                 return WINNING_YES;
1835         }
1836         else
1837                 return WINNING_NO;
1838 }
1839
1840 /*
1841 ============
1842 CheckRules_World
1843
1844 Exit deathmatch games upon conditions
1845 ============
1846 */
1847 void CheckRules_World()
1848 {
1849         float timelimit;
1850         float fraglimit;
1851         float leadlimit;
1852
1853         VoteThink();
1854         MapVote_Think();
1855
1856         SetDefaultAlpha();
1857
1858         /*
1859         MapVote_Think should now do that part
1860         if (intermission_running)
1861                 if (time >= intermission_exittime + 60)
1862                 {
1863                         if(!DoNextMapOverride())
1864                                 GotoNextMap();
1865                         return;
1866                 }
1867         */
1868
1869         if (gameover)   // someone else quit the game already
1870         {
1871                 if(player_count == 0) // Nobody there? Then let's go to the next map
1872                         MapVote_Start();
1873                         // this will actually check the player count in the next frame
1874                         // again, but this shouldn't hurt
1875                 return;
1876         }
1877
1878         timelimit = cvar("timelimit") * 60;
1879         fraglimit = cvar("fraglimit");
1880         leadlimit = cvar("leadlimit");
1881
1882         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1883         {
1884                 if(timelimit > 0)
1885                         timelimit = 0; // timelimit is not made for warmup
1886                 if(fraglimit > 0)
1887                         fraglimit = 0; // no fraglimit for now
1888                 leadlimit = 0; // no leadlimit for now
1889         }
1890
1891         if(g_onslaught)
1892                 timelimit = 0; // ONS has its own overtime rule
1893
1894         if(timelimit > 0)
1895         {
1896                 timelimit += game_starttime;
1897         }
1898         else if (timelimit < 0)
1899         {
1900                 // endmatch
1901                 NextLevel();
1902                 return;
1903         }
1904
1905         float wantovertime;
1906         wantovertime = 0;
1907
1908         if(checkrules_suddendeathend)
1909         {
1910                 if(!checkrules_suddendeathwarning)
1911                 {
1912                         checkrules_suddendeathwarning = TRUE;
1913                         if(g_race && !g_race_qualifying)
1914                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1915                         else
1916                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1917                 }
1918         }
1919         else
1920         {
1921                 if (timelimit && time >= timelimit)
1922                 {
1923                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1924                         {
1925                                 float totalplayers;
1926                                 float playerswithlaps;
1927                                 float readyplayers;
1928                                 entity head;
1929                                 totalplayers = playerswithlaps = readyplayers = 0;
1930                                 FOR_EACH_PLAYER(head)
1931                                 {
1932                                         ++totalplayers;
1933                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1934                                                 ++playerswithlaps;
1935                                         if(head.ready)
1936                                                 ++readyplayers;
1937                                 }
1938
1939                                 // at least 2 of the players have completed a lap: start the RACE
1940                                 // otherwise, the players should end the qualifying on their own
1941                                 if(readyplayers || playerswithlaps >= 2)
1942                                 {
1943                                         checkrules_suddendeathend = 0;
1944                                         ReadyRestart(); // go to race
1945                                         return;
1946                                 }
1947                                 else
1948                                         wantovertime |= InitiateSuddenDeath();
1949                         }
1950                         else
1951                                 wantovertime |= InitiateSuddenDeath();
1952                 }
1953         }
1954
1955         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1956         {
1957                 NextLevel();
1958                 return;
1959         }
1960
1961         float checkrules_status;
1962         checkrules_status = WinningCondition_RanOutOfSpawns();
1963         if(checkrules_status == WINNING_YES)
1964         {
1965                 bprint("Hey! Someone ran out of spawns!\n");
1966         }
1967         else if(g_race && !g_race_qualifying && timelimit >= 0)
1968         {
1969                 checkrules_status = WinningCondition_Race(fraglimit);
1970                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
1971         }
1972         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1973         {
1974                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1975                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
1976         }
1977         else if(g_assault)
1978         {
1979                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1980         }
1981         else if(g_lms)
1982         {
1983                 checkrules_status = WinningCondition_LMS();
1984         }
1985         else if (g_onslaught)
1986         {
1987                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1988         }
1989         else
1990         {
1991                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1992                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
1993         }
1994
1995         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1996         {
1997                 checkrules_status = WINNING_NEVER;
1998                 checkrules_overtimesadded = -1;
1999                 wantovertime |= InitiateSuddenDeath();
2000         }
2001
2002         if(checkrules_status == WINNING_NEVER)
2003                 // equality cases! Nobody wins if the overtime ends in a draw.
2004                 ClearWinners();
2005
2006         if(wantovertime)
2007         {
2008                 if(checkrules_status == WINNING_NEVER)
2009                         InitiateOvertime();
2010                 else
2011                         checkrules_status = WINNING_YES;
2012         }
2013
2014         if(checkrules_suddendeathend)
2015                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2016                         checkrules_status = WINNING_YES;
2017
2018         if(checkrules_status == WINNING_YES)
2019         {
2020                 //print("WINNING\n");
2021                 NextLevel();
2022         }
2023 };
2024
2025 float mapvote_nextthink;
2026 float mapvote_initialized;
2027 float mapvote_keeptwotime;
2028 float mapvote_timeout;
2029 string mapvote_message;
2030 string mapvote_screenshot_dir;
2031
2032 float mapvote_count;
2033 float mapvote_count_real;
2034 string mapvote_maps[MAPVOTE_COUNT];
2035 float mapvote_maps_suggested[MAPVOTE_COUNT];
2036 string mapvote_suggestions[MAPVOTE_COUNT];
2037 float mapvote_suggestion_ptr;
2038 float mapvote_maxlen;
2039 float mapvote_voters;
2040 float mapvote_votes[MAPVOTE_COUNT];
2041 float mapvote_run;
2042 float mapvote_detail;
2043 float mapvote_abstain;
2044 .float mapvote;
2045
2046 void MapVote_ClearAllVotes()
2047 {
2048         FOR_EACH_CLIENT(other)
2049                 other.mapvote = 0;
2050 }
2051
2052 string MapVote_Suggest(string m)
2053 {
2054         float i;
2055         if(m == "")
2056                 return "That's not how to use this command.";
2057         if(!cvar("g_maplist_votable_suggestions"))
2058                 return "Suggestions are not accepted on this server.";
2059         if(mapvote_initialized)
2060                 return "Can't suggest - voting is already in progress!";
2061         m = MapInfo_FixName(m);
2062         if(!m)
2063                 return "The map you suggested is not available on this server.";
2064         if(!cvar("g_maplist_votable_override_mostrecent"))
2065                 if(Map_IsRecent(m))
2066                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2067
2068         if(!MapInfo_CheckMap(m))
2069                 return "The map you suggested does not support the current game mode.";
2070         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2071                 if(mapvote_suggestions[i] == m)
2072                         return "This map was already suggested.";
2073         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2074         {
2075                 i = floor(random() * mapvote_suggestion_ptr);
2076         }
2077         else
2078         {
2079                 i = mapvote_suggestion_ptr;
2080                 mapvote_suggestion_ptr += 1;
2081         }
2082         if(mapvote_suggestions[i] != "")
2083                 strunzone(mapvote_suggestions[i]);
2084         mapvote_suggestions[i] = strzone(m);
2085         if(cvar("sv_eventlog"))
2086                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2087         return strcat("Suggestion of ", m, " accepted.");
2088 }
2089
2090 void MapVote_AddVotable(string nextMap, float isSuggestion)
2091 {
2092         float j;
2093         if(nextMap == "")
2094                 return;
2095         for(j = 0; j < mapvote_count; ++j)
2096                 if(mapvote_maps[j] == nextMap)
2097                         return;
2098         if(strlen(nextMap) > mapvote_maxlen)
2099                 mapvote_maxlen = strlen(nextMap);
2100         mapvote_maps[mapvote_count] = strzone(nextMap);
2101         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2102         mapvote_count += 1;
2103 }
2104
2105 void MapVote_Spawn();
2106 void MapVote_Init()
2107 {
2108         float i;
2109         float nmax, smax;
2110
2111         MapVote_ClearAllVotes();
2112
2113         mapvote_count = 0;
2114         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2115         mapvote_abstain = cvar("g_maplist_votable_abstain");
2116
2117         if(mapvote_abstain)
2118                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2119         else
2120                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2121         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2122
2123         if(mapvote_suggestion_ptr)
2124                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2125                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2126
2127         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2128                 MapVote_AddVotable(GetNextMap(), FALSE);
2129
2130         if(mapvote_count == 0)
2131         {
2132                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2133                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2134                 if(cvar("g_maplist_shuffle"))
2135                         ShuffleMaplist();
2136                 localcmd("\nmenu_cmd sync\n");
2137                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2138                         MapVote_AddVotable(GetNextMap(), FALSE);
2139         }
2140
2141         mapvote_count_real = mapvote_count;
2142         if(mapvote_abstain)
2143                 MapVote_AddVotable("don't care", 0);
2144
2145         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2146
2147         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2148         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2149         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2150                 mapvote_keeptwotime = 0;
2151         mapvote_message = "Choose a map and press its key!";
2152
2153         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2154         if(mapvote_screenshot_dir == "")
2155                 mapvote_screenshot_dir = "maps";
2156         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2157
2158         MapVote_Spawn();
2159 }
2160
2161 void MapVote_SendPicture(float id)
2162 {
2163         msg_entity = self;
2164         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2165         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2166         WriteByte(MSG_ONE, id);
2167         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2168 }
2169
2170 float GameCommand_MapVote(string cmd)
2171 {
2172         if(!intermission_running)
2173                 return FALSE;
2174
2175         if(cmd == "mv_getpic")
2176         {
2177                 MapVote_SendPicture(stof(argv(1)));
2178                 return TRUE;
2179         }
2180
2181         return FALSE;
2182 }
2183
2184 float MapVote_GetMapMask()
2185 {
2186         float mask, i, power;
2187         mask = 0;
2188         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2189                 if(mapvote_maps[i] != "")
2190                         mask |= power;
2191         return mask;
2192 }
2193
2194 entity mapvote_ent;
2195 float MapVote_SendEntity(entity to, float sf)
2196 {
2197         string mapfile, pakfile;
2198         float i, o;
2199
2200         if(sf & 1)
2201                 sf &~= 2; // if we send 1, we don't need to also send 2
2202
2203         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2204         WriteByte(MSG_ENTITY, sf);
2205
2206         if(sf & 1)
2207         {
2208                 // flag 1 == initialization
2209                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2210                 WriteByte(MSG_ENTITY, mapvote_count);
2211                 WriteByte(MSG_ENTITY, mapvote_abstain);
2212                 WriteByte(MSG_ENTITY, mapvote_detail);
2213                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2214                 if(mapvote_count <= 8)
2215                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2216                 else
2217                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2218                 for(i = 0; i < mapvote_count; ++i)
2219                         if(mapvote_maps[i] != "")
2220                         {
2221                                 if(mapvote_abstain && i == mapvote_count - 1)
2222                                 {
2223                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2224                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2225                                 }
2226                                 else
2227                                 {
2228                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2229                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2230                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2231                                         if(pakfile == "")
2232                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2233                                         if(pakfile == "")
2234                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2235                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2236                                                 pakfile = substring(pakfile, o, 999);
2237                                         WriteString(MSG_ENTITY, pakfile);
2238                                 }
2239                         }
2240         }
2241
2242         if(sf & 2)
2243         {
2244                 // flag 2 == update of mask
2245                 if(mapvote_count <= 8)
2246                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2247                 else
2248                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2249         }
2250
2251         if(sf & 4)
2252         {
2253                 if(mapvote_detail)
2254                         for(i = 0; i < mapvote_count; ++i)
2255                                 if(mapvote_maps[i] != "")
2256                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2257
2258                 WriteByte(MSG_ENTITY, to.mapvote);
2259         }
2260
2261         return TRUE;
2262 }
2263
2264 void MapVote_Spawn()
2265 {
2266         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2267 }
2268
2269 void MapVote_TouchMask()
2270 {
2271         mapvote_ent.SendFlags |= 2;
2272 }
2273
2274 void MapVote_TouchVotes(entity voter)
2275 {
2276         mapvote_ent.SendFlags |= 4;
2277 }
2278
2279 float MapVote_Finished(float mappos)
2280 {
2281         string result;
2282         float i;
2283         float didntvote;
2284
2285         if(cvar("sv_eventlog"))
2286         {
2287                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2288                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2289                 didntvote = mapvote_voters;
2290                 for(i = 0; i < mapvote_count; ++i)
2291                         if(mapvote_maps[i] != "")
2292                         {
2293                                 didntvote -= mapvote_votes[i];
2294                                 if(i != mappos)
2295                                 {
2296                                         result = strcat(result, ":", mapvote_maps[i]);
2297                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2298                                 }
2299                         }
2300                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2301
2302                 GameLogEcho(result);
2303                 if(mapvote_maps_suggested[mappos])
2304                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2305         }
2306
2307         FOR_EACH_REALCLIENT(other)
2308                 FixClientCvars(other);
2309
2310         Map_Goto_SetStr(mapvote_maps[mappos]);
2311         Map_Goto();
2312         alreadychangedlevel = TRUE;
2313         return TRUE;
2314 }
2315 void MapVote_CheckRules_1()
2316 {
2317         float i;
2318
2319         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2320         {
2321                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2322                 mapvote_votes[i] = 0;
2323         }
2324
2325         mapvote_voters = 0;
2326         FOR_EACH_REALCLIENT(other)
2327         {
2328                 ++mapvote_voters;
2329                 if(other.mapvote)
2330                 {
2331                         i = other.mapvote - 1;
2332                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2333                         mapvote_votes[i] = mapvote_votes[i] + 1;
2334                 }
2335         }
2336 }
2337
2338 float MapVote_CheckRules_2()
2339 {
2340         float i;
2341         float firstPlace, secondPlace;
2342         float firstPlaceVotes, secondPlaceVotes;
2343         float mapvote_voters_real;
2344         string result;
2345
2346         if(mapvote_count_real == 1)
2347                 return MapVote_Finished(0);
2348
2349         mapvote_voters_real = mapvote_voters;
2350         if(mapvote_abstain)
2351                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2352
2353         RandomSelection_Init();
2354         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2355                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2356         firstPlace = RandomSelection_chosen_float;
2357         firstPlaceVotes = RandomSelection_best_priority;
2358         //dprint("First place: ", ftos(firstPlace), "\n");
2359         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2360
2361         RandomSelection_Init();
2362         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2363                 if(i != firstPlace)
2364                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2365         secondPlace = RandomSelection_chosen_float;
2366         secondPlaceVotes = RandomSelection_best_priority;
2367         //dprint("Second place: ", ftos(secondPlace), "\n");
2368         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2369
2370         if(firstPlace == -1)
2371                 error("No first place in map vote... WTF?");
2372
2373         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2374                 return MapVote_Finished(firstPlace);
2375
2376         if(mapvote_keeptwotime)
2377                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2378                 {
2379                         float didntvote;
2380                         MapVote_TouchMask();
2381                         mapvote_message = "Now decide between the TOP TWO!";
2382                         mapvote_keeptwotime = 0;
2383                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2384                         result = strcat(result, ":", ftos(firstPlaceVotes));
2385                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2386                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2387                         didntvote = mapvote_voters;
2388                         for(i = 0; i < mapvote_count; ++i)
2389                                 if(mapvote_maps[i] != "")
2390                                 {
2391                                         didntvote -= mapvote_votes[i];
2392                                         if(i != firstPlace)
2393                                                 if(i != secondPlace)
2394                                                 {
2395                                                         result = strcat(result, ":", mapvote_maps[i]);
2396                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2397                                                         if(i < mapvote_count_real)
2398                                                         {
2399                                                                 strunzone(mapvote_maps[i]);
2400                                                                 mapvote_maps[i] = "";
2401                                                         }
2402                                                 }
2403                                 }
2404                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2405                         if(cvar("sv_eventlog"))
2406                                 GameLogEcho(result);
2407                 }
2408
2409         return FALSE;
2410 }
2411 void MapVote_Tick()
2412 {
2413         float keeptwo;
2414         float totalvotes;
2415
2416         keeptwo = mapvote_keeptwotime;
2417         MapVote_CheckRules_1(); // count
2418         if(MapVote_CheckRules_2()) // decide
2419                 return;
2420
2421         totalvotes = 0;
2422         FOR_EACH_REALCLIENT(other)
2423         {
2424                 // hide scoreboard again
2425                 if(other.health != 2342)
2426                 {
2427                         other.health = 2342;
2428                         other.impulse = 0;
2429                         if(clienttype(other) == CLIENTTYPE_REAL)
2430                         {
2431                                 msg_entity = other;
2432                                 WriteByte(MSG_ONE, SVC_FINALE);
2433                                 WriteString(MSG_ONE, "");
2434                         }
2435                 }
2436
2437                 // clear possibly invalid votes
2438                 if(mapvote_maps[other.mapvote - 1] == "")
2439                         other.mapvote = 0;
2440                 // use impulses as new vote
2441                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2442                         if(mapvote_maps[other.impulse - 1] != "")
2443                         {
2444                                 other.mapvote = other.impulse;
2445                                 MapVote_TouchVotes(other);
2446                         }
2447                 other.impulse = 0;
2448
2449                 if(other.mapvote)
2450                         ++totalvotes;
2451         }
2452
2453         MapVote_CheckRules_1(); // just count
2454 }
2455 void MapVote_Start()
2456 {
2457         if(mapvote_run)
2458                 return;
2459
2460         MapInfo_Enumerate();
2461         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2462                 mapvote_run = TRUE;
2463 }
2464 void MapVote_Think()
2465 {
2466         if(!mapvote_run)
2467                 return;
2468
2469         if(alreadychangedlevel)
2470                 return;
2471
2472         if(time < mapvote_nextthink)
2473                 return;
2474         //dprint("tick\n");
2475
2476         mapvote_nextthink = time + 0.5;
2477
2478         if(!mapvote_initialized)
2479         {
2480                 if(cvar("rescan_pending") == 1)
2481                 {
2482                         cvar_set("rescan_pending", "2");
2483                         localcmd("fs_rescan\nrescan_pending 3\n");
2484                         return;
2485                 }
2486                 else if(cvar("rescan_pending") == 2)
2487                 {
2488                         return;
2489                 }
2490                 else if(cvar("rescan_pending") == 3)
2491                 {
2492                         // now build missing mapinfo files
2493                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2494                                 return;
2495
2496                         // we're done, start the timer
2497                         cvar_set("rescan_pending", "0");
2498                 }
2499
2500                 mapvote_initialized = TRUE;
2501                 if(DoNextMapOverride())
2502                         return;
2503                 if(!cvar("g_maplist_votable") || player_count <= 0)
2504                 {
2505                         GotoNextMap();
2506                         return;
2507                 }
2508                 MapVote_Init();
2509         }
2510
2511         MapVote_Tick();
2512 };
2513
2514 string GotoMap(string m)
2515 {
2516         if(!MapInfo_CheckMap(m))
2517                 return "The map you chose is not available on this server.";
2518         cvar_set("nextmap", m);
2519         cvar_set("timelimit", "-1");
2520         if(mapvote_initialized || alreadychangedlevel)
2521         {
2522                 if(DoNextMapOverride())
2523                         return "Map switch initiated.";
2524                 else
2525                         return "Hm... no. For some reason I like THIS map more.";
2526         }
2527         else
2528                 return "Map switch will happen after scoreboard.";
2529 }
2530
2531
2532 void EndFrame()
2533 {
2534         float altime;
2535         FOR_EACH_REALCLIENT(self)
2536         {
2537                 if(self.classname == "spectator")
2538                 {
2539                         if(self.enemy.typehitsound)
2540                                 play2(self, "misc/typehit.wav");
2541                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2542                                 play2(self, "misc/hit.wav");
2543                 }
2544                 else
2545                 {
2546                         if(self.typehitsound)
2547                                 play2(self, "misc/typehit.wav");
2548                         else if(self.hitsound && self.cvar_cl_hitsound)
2549                                 play2(self, "misc/hit.wav");
2550                 }
2551         }
2552         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2553         // add 1 frametime because after this, engine SV_Physics
2554         // increases time by a frametime and then networks the frame
2555         // add another frametime because client shows everything with
2556         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2557         // needed!
2558         FOR_EACH_CLIENT(self)
2559         {
2560                 self.hitsound = FALSE;
2561                 self.typehitsound = FALSE;
2562                 antilag_record(self, altime);
2563         }
2564 }
2565
2566
2567 /*
2568  * RedirectionThink:
2569  * returns TRUE if redirecting
2570  */
2571 float redirection_timeout;
2572 float redirection_nextthink;
2573 float RedirectionThink()
2574 {
2575         float clients_found;
2576
2577         if(redirection_target == "")
2578                 return FALSE;
2579
2580         if(!redirection_timeout)
2581         {
2582                 cvar_set("sv_public", "-2");
2583                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2584                 if(redirection_target == "self")
2585                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2586                 else
2587                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2588         }
2589
2590         if(time < redirection_nextthink)
2591                 return TRUE;
2592
2593         redirection_nextthink = time + 1;
2594
2595         clients_found = 0;
2596         FOR_EACH_REALCLIENT(self)
2597         {
2598                 print("Redirecting: sending connect command to ", self.netname, "\n");
2599                 if(redirection_target == "self")
2600                         stuffcmd(self, "\ndisconnect; reconnect\n");
2601                 else
2602                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2603                 ++clients_found;
2604         }
2605
2606         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2607
2608         if(time > redirection_timeout || clients_found == 0)
2609                 localcmd("\nwait; wait; wait; quit\n");
2610
2611         return TRUE;
2612 }
2613
2614 void RestoreGame()
2615 {
2616         // Loaded from a save game
2617         // some things then break, so let's work around them...
2618
2619         // Progs DB (capture records)
2620         if(sv_cheats)
2621                 ServerProgsDB = db_create();
2622         else
2623                 ServerProgsDB = db_load("server.db");
2624
2625         // Mapinfo
2626         MapInfo_Shutdown();
2627         MapInfo_Enumerate();
2628         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2629         WeaponStats_Init();
2630 }
2631
2632 void SV_Shutdown()
2633 {
2634         if(gameover > 1) // shutting down already?
2635                 return;
2636
2637         gameover = 2; // 2 = server shutting down
2638
2639         if(world_initialized > 0)
2640         {
2641                 world_initialized = 0;
2642                 print("Saving persistent data...\n");
2643                 Ban_SaveBans();
2644                 if(!sv_cheats)
2645                         db_save(ServerProgsDB, "server.db");
2646                 if(cvar("developer"))
2647                         db_save(TemporaryDB, "server-temp.db");
2648                 db_close(ServerProgsDB);
2649                 db_close(TemporaryDB);
2650                 print("done!\n");
2651                 // tell the bot system the game is ending now
2652                 bot_endgame();
2653
2654                 WeaponStats_Shutdown();
2655                 MapInfo_Shutdown();
2656         }
2657         else if(world_initialized == 0)
2658         {
2659                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2660         }
2661 }