data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha <= 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float fh;
 160         string s, k, v, d;
 161         float n;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166         fh = fopen("cvars.txt", FILE_READ);
 167         if(fh < 0)
 168                 return;
 169         while((s = fgets(fh)))
 170         {
 171                 n = tokenize_sane(s);
 172                 if(n < 1)
 173                         continue;
 174                 if(argv(0) == "//")
 175                         continue;
 176                 k = argv(0);
 177                 v = cvar_string(k);
 178                 d = cvar_defstring(k);
 179                 if(v != d)
 180                 {
 181                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 182                         if(strlen(cvar_changes) > 16384)
 183                         {
 184                                 cvar_changes = "// too many settings have been changed to show them here\n";
 185                                 break;
 186                         }
 187                 }
 188         }
 189         fclose(fh);
 190         if(cvar_changes == "")
 191                 cvar_changes = "// this server runs at default settings\n";
 192         else
 193                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 194         cvar_changes = strzone(cvar_changes);
 195 }
 196
 197 float world_already_spawned;
 198 void RegisterWeapons();
 199 void Nagger_Init();
 200 void spawnfunc_worldspawn (void)
 201 {
 202         float fd, l;
 203         string s;
 204
 205         dprint_load(); // load dprint status from cvar
 206
 207         if(world_already_spawned)
 208                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 209         world_already_spawned = TRUE;
 210
 211         remove = remove_safely; // during spawning, watch what you remove!
 212
 213         compressShortVector_init();
 214
 215         local entity head;
 216         head = nextent(world);
 217         maxclients = 0;
 218         while(head)
 219         {
 220                 ++maxclients;
 221                 head = nextent(head);
 222         }
 223
 224         // needs to be done so early as they would still spawn
 225         RegisterWeapons();
 226
 227         if(GotoFirstMap())
 228         {
 229                 world_initialized = -1; // don't complain
 230                 return;
 231         }
 232
 233         if(sv_cheats)
 234                 ServerProgsDB = db_create();
 235         else
 236                 ServerProgsDB = db_load("server.db");
 237
 238         TemporaryDB = db_create();
 239
 240         /*
 241         TODO sound pack system
 242         // initialize sound pack system
 243         soundpack = cvar_string("g_soundpack");
 244         if(soundpack != "")
 245                 soundpack = strcat(soundpack, "/");
 246         soundpack = strzone(soundpack);
 247         */
 248
 249         // 0 normal
 250         lightstyle(0, "m");
 251
 252         // 1 FLICKER (first variety)
 253         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 254
 255         // 2 SLOW STRONG PULSE
 256         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 257
 258         // 3 CANDLE (first variety)
 259         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 260
 261         // 4 FAST STROBE
 262         lightstyle(4, "mamamamamama");
 263
 264         // 5 GENTLE PULSE 1
 265         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 266
 267         // 6 FLICKER (second variety)
 268         lightstyle(6, "nmonqnmomnmomomno");
 269
 270         // 7 CANDLE (second variety)
 271         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 272
 273         // 8 CANDLE (third variety)
 274         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 275
 276         // 9 SLOW STROBE (fourth variety)
 277         lightstyle(9, "aaaaaaaazzzzzzzz");
 278
 279         // 10 FLUORESCENT FLICKER
 280         lightstyle(10, "mmamammmmammamamaaamammma");
 281
 282         // 11 SLOW PULSE NOT FADE TO BLACK
 283         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 284
 285         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 286
 287         // 63 testing
 288         lightstyle(63, "a");
 289
 290         if(cvar("g_campaign"))
 291                 CampaignPreInit();
 292
 293         InitGameplayMode();
 294         readlevelcvars();
 295         GrappleHookInit();
 296
 297         player_count = 0;
 298         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 299         if(bot_waypoints_for_items == 1)
 300                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 301                         bot_waypoints_for_items = 0;
 302
 303         // for setting by mapinfo
 304         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 305         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 306
 307         precache();
 308
 309         WaypointSprite_Init();
 310
 311         //if (g_domination)
 312         //      dom_init();
 313
 314         GameLogInit(); // prepare everything
 315         if(cvar("sv_eventlog"))
 316         {
 317                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 318                 s = strcat(s, ftos(random()));
 319                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 320                 s = ":gameinfo:mutators:LIST";
 321                 if(cvar("g_grappling_hook"))
 322                         s = strcat(s, ":grappling_hook");
 323                 if(!cvar("g_use_ammunition"))
 324                         s = strcat(s, ":no_use_ammunition");
 325                 if(!cvar("g_pickup_items"))
 326                         s = strcat(s, ":no_pickup_items");
 327                 if(cvar("g_instagib"))
 328                         s = strcat(s, ":instagib");
 329                 if(cvar_string("g_weaponarena") != "0")
 330                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 331                 if(cvar("g_nixnex"))
 332                         s = strcat(s, ":nixnex");
 333                 if(cvar("g_vampire"))
 334                         s = strcat(s, ":vampire");
 335                 if(cvar("g_laserguided_missile"))
 336                         s = strcat(s, ":laserguided_missile");
 337                 if(cvar("g_norecoil"))
 338                         s = strcat(s, ":norecoil");
 339                 if(cvar("g_midair"))
 340                         s = strcat(s, ":midair");
 341                 if(cvar("g_minstagib"))
 342                         s = strcat(s, ":minstagib");
 343                 GameLogEcho(s);
 344                 GameLogEcho(":gameinfo:end");
 345         }
 346
 347         cvar_set("nextmap", "");
 348
 349         SetDefaultAlpha();
 350
 351         if(cvar("g_campaign"))
 352                 CampaignPostInit();
 353
 354         fteqcc_testbugs();
 355
 356         Ban_LoadBans();
 357
 358         //initialise globals related to sv_timeout
 359         sys_ticrate = cvar("sys_ticrate");
 360         orig_slowmo = cvar("slowmo");
 361
 362         MapInfo_Enumerate();
 363         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 364
 365         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 366         {
 367                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 368                 if(fd != -1)
 369                 {
 370                         while((s = fgets(fd)))
 371                         {
 372                                 l = tokenize_sane(s);
 373                                 if(l < 2)
 374                                         continue;
 375                                 if(argv(0) == "cd")
 376                                 {
 377                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 378                                         print("  cdtrack ", argv(2), "\n");
 379                                 }
 380                                 else if(argv(0) == "fog")
 381                                 {
 382                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 383                                         print("  \"fog\" \"", s, "\"\n");
 384                                 }
 385                                 else if(argv(0) == "set")
 386                                 {
 387                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 388                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 389                                 }
 390                                 else if(argv(0) != "//")
 391                                 {
 392                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 393                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 394                                 }
 395                         }
 396                         fclose(fd);
 397                 }
 398         }
 399
 400         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 401         addstat(STAT_WEAPONS, AS_INT, weapons);
 402         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 403         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 404         Nagger_Init();
 405
 406         next_pingtime = time + 5;
 407         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 408
 409         world_initialized = 1;
 410 }
 411
 412 void spawnfunc_light (void)
 413 {
 414         //makestatic (self); // Who the f___ did that?
 415         remove(self);
 416 }
 417
 418 float TryFile( string pFilename )
 419 {
 420         local float lHandle;
 421         dprint("TryFile(\"", pFilename, "\")\n");
 422         lHandle = fopen( pFilename, FILE_READ );
 423         if( lHandle != -1 ) {
 424                 fclose( lHandle );
 425                 return TRUE;
 426         } else {
 427                 return FALSE;
 428         }
 429 };
 430
 431 string GetGametype()
 432 {
 433         return GametypeNameFromType(game);
 434 }
 435
 436 string getmapname_stored;
 437 string GetMapname()
 438 {
 439         return mapname;
 440 }
 441
 442 float Map_Count, Map_Current;
 443 string Map_Current_Name;
 444
 445 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 446 float GetMaplistPosition()
 447 {
 448         float pos, idx;
 449         string map;
 450
 451         map = GetMapname();
 452         idx = cvar("g_maplist_index");
 453
 454         if(idx >= 0)
 455                 if(idx < Map_Count)
 456                         if(map == argv(idx))
 457                                 return idx;
 458
 459         for(pos = 0; pos < Map_Count; ++pos)
 460                 if(map == argv(pos))
 461                         return pos;
 462
 463         // resume normal maplist rotation if current map is not in g_maplist
 464         return idx;
 465 }
 466
 467 float MapHasRightSize(string map)
 468 {
 469         float fh;
 470         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 471         if(cvar("g_maplist_check_waypoints"))
 472         {
 473                 dprint("checkwp "); dprint(map);
 474                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 475                 if(fh < 0)
 476                 {
 477                         dprint(": no waypoints\n");
 478                         return FALSE;
 479                 }
 480                 dprint(": has waypoints\n");
 481                 fclose(fh);
 482         }
 483
 484         // open map size restriction file
 485         dprint("opensize "); dprint(map);
 486         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 487         if(fh >= 0)
 488         {
 489                 float mapmin, mapmax;
 490                 dprint(": ok, ");
 491                 mapmin = stof(fgets(fh));
 492                 mapmax = stof(fgets(fh));
 493                 fclose(fh);
 494                 if(player_count < mapmin)
 495                 {
 496                         dprint("not enough\n");
 497                         return FALSE;
 498                 }
 499                 if(player_count > mapmax)
 500                 {
 501                         dprint("too many\n");
 502                         return FALSE;
 503                 }
 504                 dprint("right size\n");
 505                 return TRUE;
 506         }
 507         dprint(": not found\n");
 508         return TRUE;
 509 }
 510
 511 string Map_Filename(float position)
 512 {
 513         return strcat("maps/", argv(position), ".bsp");
 514 }
 515
 516 string strwords(string s, float w)
 517 {
 518         float endpos;
 519         for(endpos = 0; w && endpos >= 0; --w)
 520                 endpos = strstrofs(s, " ", endpos + 1);
 521         if(endpos < 0)
 522                 return s;
 523         else
 524                 return substring(s, 0, endpos);
 525 }
 526
 527 float strhasword(string s, string w)
 528 {
 529         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 530 }
 531
 532 void Map_MarkAsRecent(string m)
 533 {
 534         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 535 }
 536
 537 float Map_IsRecent(string m)
 538 {
 539         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 540 }
 541
 542 float Map_Check(float position, float pass)
 543 {
 544         string filename;
 545         string map_next;
 546         map_next = argv(position);
 547         if(pass <= 1)
 548         {
 549                 if(map_next == Map_Current_Name) // same map again in first pass?
 550                         return 0;
 551                 if(Map_IsRecent(map_next))
 552                         return 0;
 553         }
 554         filename = Map_Filename(position);
 555         if(MapInfo_CheckMap(map_next))
 556         {
 557                 if(pass == 2)
 558                         return 1;
 559                 if(MapHasRightSize(map_next))
 560                         return 1;
 561                 return 0;
 562         }
 563         else
 564                 dprint( "Couldn't select '", filename, "'..\n" );
 565
 566         return 0;
 567 }
 568
 569 void Map_Goto_SetStr(string nextmapname)
 570 {
 571         if(getmapname_stored != "")
 572                 strunzone(getmapname_stored);
 573         if(nextmapname == "")
 574                 getmapname_stored = "";
 575         else
 576                 getmapname_stored = strzone(nextmapname);
 577 }
 578
 579 void Map_Goto_SetFloat(float position)
 580 {
 581         cvar_set("g_maplist_index", ftos(position));
 582         Map_Goto_SetStr(argv(position));
 583 }
 584
 585 void GameResetCfg()
 586 {
 587         // settings persist, except...
 588         if(cvar("g_campaign"))
 589                 localcmd("\nexec mutator_reset.cfg\n");
 590         localcmd("\nsettemp_restore\n");
 591 };
 592
 593 void Map_Goto()
 594 {
 595         Map_MarkAsRecent(getmapname_stored);
 596         GameResetCfg();
 597         MapInfo_LoadMap(getmapname_stored);
 598 }
 599
 600 // return codes of map selectors:
 601 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 602 //   -2 = permanent failure
 603 float() MaplistMethod_Iterate = // usual method
 604 {
 605         float pass, i;
 606
 607         for(pass = 1; pass <= 2; ++pass)
 608         {
 609                 for(i = 1; i < Map_Count; ++i)
 610                 {
 611                         float mapindex;
 612                         mapindex = mod(i + Map_Current, Map_Count);
 613                         if(Map_Check(mapindex, pass))
 614                                 return mapindex;
 615                 }
 616         }
 617         return -1;
 618 }
 619
 620 float() MaplistMethod_Repeat = // fallback method
 621 {
 622         if(Map_Check(Map_Current, 2))
 623                 return Map_Current;
 624         return -2;
 625 }
 626
 627 float() MaplistMethod_Random = // random map selection
 628 {
 629         float i, imax;
 630
 631         imax = 42;
 632
 633         for(i = 0; i <= imax; ++i)
 634         {
 635                 float mapindex;
 636                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 637                 if(Map_Check(mapindex, 1))
 638                         return mapindex;
 639         }
 640         return -1;
 641 }
 642
 643 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 644 // the exponent sets a bias on the map selection:
 645 // the higher the exponent, the less likely "shortly repeated" same maps are
 646 {
 647         float i, j, imax, insertpos;
 648
 649         imax = 42;
 650
 651         for(i = 0; i <= imax; ++i)
 652         {
 653                 string newlist;
 654
 655                 // now reinsert this at another position
 656                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 657                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 658                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 659                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 660
 661                 // insert the current map there
 662                 newlist = "";
 663                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 664                         newlist = strcat(newlist, " ", argv(j));
 665                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 666                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 667                         newlist = strcat(newlist, " ", argv(j));
 668                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 669                 cvar_set("g_maplist", newlist);
 670                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 671
 672                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 673                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 674                 if(Map_Check(Map_Current, 1))
 675                         return Map_Current;
 676         }
 677         return -1;
 678 }
 679
 680 void Maplist_Init()
 681 {
 682         string temp;
 683         temp = cvar_string("g_maplist");
 684         Map_Count = tokenizebyseparator(temp, " ");
 685         if(Map_Count == 0)
 686         {
 687                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 688                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 689                 localcmd("\nmenu_cmd sync\n");
 690                 Map_Count = tokenizebyseparator(temp, " ");
 691         }
 692         if(Map_Count == 0)
 693                 error("empty maplist, cannot select a new map");
 694         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 695
 696         if(Map_Current_Name)
 697                 strunzone(Map_Current_Name);
 698         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 699         // this may or may not be correct, but who cares, in the worst case a map
 700         // isn't chosen in the first pass that should have been
 701 }
 702
 703 string GetNextMap()
 704 {
 705         float nextMap;
 706
 707         Maplist_Init();
 708         nextMap = -1;
 709
 710         if(nextMap == -1)
 711                 if(cvar("g_maplist_shuffle") > 0)
 712                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 713
 714         if(nextMap == -1)
 715                 if(cvar("g_maplist_selectrandom"))
 716                         nextMap = MaplistMethod_Random();
 717
 718         if(nextMap == -1)
 719                 nextMap = MaplistMethod_Iterate();
 720
 721         if(nextMap == -1)
 722                 nextMap = MaplistMethod_Repeat();
 723
 724         if(nextMap >= 0)
 725         {
 726                 Map_Goto_SetFloat(nextMap);
 727                 return getmapname_stored;
 728         }
 729
 730         return "";
 731 };
 732
 733 float DoNextMapOverride()
 734 {
 735         if(cvar("g_campaign"))
 736         {
 737                 CampaignPostIntermission();
 738                 alreadychangedlevel = TRUE;
 739                 return TRUE;
 740         }
 741         if(cvar("quit_when_empty"))
 742         {
 743                 if(player_count <= currentbots)
 744                 {
 745                         localcmd("quit\n");
 746                         alreadychangedlevel = TRUE;
 747                         return TRUE;
 748                 }
 749         }
 750         if(cvar_string("quit_and_redirect") != "")
 751         {
 752                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 753                 alreadychangedlevel = TRUE;
 754                 return TRUE;
 755         }
 756         if (cvar("samelevel")) // if samelevel is set, stay on same level
 757         {
 758                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 759                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 760                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 761                 localcmd("restart\n");
 762                 //changelevel (mapname);
 763                 alreadychangedlevel = TRUE;
 764                 return TRUE;
 765         }
 766         if(cvar_string("nextmap") != "")
 767                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 768                 {
 769                         Map_Goto_SetStr(cvar_string("nextmap"));
 770                         Map_Goto();
 771                         alreadychangedlevel = TRUE;
 772                         return TRUE;
 773                 }
 774         if(cvar("lastlevel"))
 775         {
 776                 GameResetCfg();
 777                 localcmd("set lastlevel 0\ntogglemenu\n");
 778                 alreadychangedlevel = TRUE;
 779                 return TRUE;
 780         }
 781         return FALSE;
 782 };
 783
 784 void GotoNextMap()
 785 {
 786         //local string nextmap;
 787         //local float n, nummaps;
 788         //local string s;
 789         if (alreadychangedlevel)
 790                 return;
 791         alreadychangedlevel = TRUE;
 792
 793         {
 794                 string nextMap;
 795                 float allowReset;
 796
 797                 for(allowReset = 1; allowReset >= 0; --allowReset)
 798                 {
 799                         nextMap = GetNextMap();
 800                         if(nextMap != "")
 801                                 break;
 802
 803                         if(allowReset)
 804                         {
 805                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 806                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 807                                 localcmd("\nmenu_cmd sync\n");
 808                         }
 809                         else
 810                         {
 811                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 812                         }
 813                 }
 814                 Map_Goto();
 815         }
 816 };
 817
 818
 819 /*
 820 ============
 821 IntermissionThink
 822
 823 When the player presses attack or jump, change to the next level
 824 ============
 825 */
 826 .float autoscreenshot;
 827 void() MapVote_Start;
 828 void() MapVote_Think;
 829 float mapvote_initialized;
 830 void IntermissionThink()
 831 {
 832         FixIntermissionClient(self);
 833
 834         if(cvar("sv_autoscreenshot"))
 835         if(self.autoscreenshot > 0)
 836         if(time > self.autoscreenshot)
 837         {
 838                 self.autoscreenshot = -1;
 839                 if(clienttype(self) == CLIENTTYPE_REAL)
 840                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 841                 return;
 842         }
 843
 844         if (time < intermission_exittime)
 845                 return;
 846
 847         if(!mapvote_initialized)
 848                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 849                         return;
 850
 851         MapVote_Start();
 852 };
 853
 854 /*
 855 ============
 856 FindIntermission
 857
 858 Returns the entity to view from
 859 ============
 860 */
 861 /*
 862 entity FindIntermission()
 863 {
 864         local   entity spot;
 865         local   float cyc;
 866
 867 // look for info_intermission first
 868         spot = find (world, classname, "info_intermission");
 869         if (spot)
 870         {       // pick a random one
 871                 cyc = random() * 4;
 872                 while (cyc > 1)
 873                 {
 874                         spot = find (spot, classname, "info_intermission");
 875                         if (!spot)
 876                                 spot = find (spot, classname, "info_intermission");
 877                         cyc = cyc - 1;
 878                 }
 879                 return spot;
 880         }
 881
 882 // then look for the start position
 883         spot = find (world, classname, "info_player_start");
 884         if (spot)
 885                 return spot;
 886
 887 // testinfo_player_start is only found in regioned levels
 888         spot = find (world, classname, "testplayerstart");
 889         if (spot)
 890                 return spot;
 891
 892 // then look for the start position
 893         spot = find (world, classname, "info_player_deathmatch");
 894         if (spot)
 895                 return spot;
 896
 897         //objerror ("FindIntermission: no spot");
 898         return world;
 899 };
 900 */
 901
 902 /*
 903 ===============================================================================
 904
 905 RULES
 906
 907 ===============================================================================
 908 */
 909
 910 void DumpStats(float final)
 911 {
 912         local float file;
 913         local string s;
 914         local float to_console;
 915         local float to_eventlog;
 916         local float to_file;
 917         local float i;
 918
 919         to_console = cvar("sv_logscores_console");
 920         to_eventlog = cvar("sv_eventlog");
 921         to_file = cvar("sv_logscores_file");
 922
 923         if(!final)
 924         {
 925                 to_console = TRUE; // always print printstats replies
 926                 to_eventlog = FALSE; // but never print them to the event log
 927         }
 928
 929         if(to_eventlog)
 930                 if(cvar("sv_eventlog_console"))
 931                         to_console = FALSE; // otherwise we get the output twice
 932
 933         if(final)
 934                 s = ":scores:";
 935         else
 936                 s = ":status:";
 937         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 938
 939         if(to_console)
 940                 print(s, "\n");
 941         if(to_eventlog)
 942                 GameLogEcho(s);
 943         if(to_file)
 944         {
 945                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 946                 if(file == -1)
 947                         to_file = FALSE;
 948                 else
 949                         fputs(file, strcat(s, "\n"));
 950         }
 951
 952         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
 953         if(to_console)
 954                 print(s, "\n");
 955         if(to_eventlog)
 956                 GameLogEcho(s);
 957         if(to_file)
 958                 fputs(file, strcat(s, "\n"));
 959
 960         FOR_EACH_CLIENT(other)
 961         {
 962                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 963                 {
 964                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
 965                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 966                         if(other.classname == "player" || g_arena || g_lms)
 967                                 s = strcat(s, ftos(other.team), ":");
 968                         else
 969                                 s = strcat(s, "spectator:");
 970
 971                         if(to_console)
 972                                 print(s, other.netname, "\n");
 973                         if(to_eventlog)
 974                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
 975                         if(to_file)
 976                                 fputs(file, strcat(s, other.netname, "\n"));
 977                 }
 978         }
 979
 980         if(teamplay)
 981         {
 982                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
 983                 if(to_console)
 984                         print(s, "\n");
 985                 if(to_eventlog)
 986                         GameLogEcho(s);
 987                 if(to_file)
 988                         fputs(file, strcat(s, "\n"));
 989
 990                 for(i = 1; i < 16; ++i)
 991                 {
 992                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
 993                         s = strcat(s, ":", ftos(i));
 994                         if(to_console)
 995                                 print(s, "\n");
 996                         if(to_eventlog)
 997                                 GameLogEcho(s);
 998                         if(to_file)
 999                                 fputs(file, strcat(s, "\n"));
1000                 }
1001         }
1002
1003         if(to_console)
1004                 print(":end\n");
1005         if(to_eventlog)
1006                 GameLogEcho(":end");
1007         if(to_file)
1008         {
1009                 fputs(file, ":end\n");
1010                 fclose(file);
1011         }
1012 }
1013
1014 void FixIntermissionClient(entity e)
1015 {
1016         string s;
1017         if(!e.autoscreenshot) // initial call
1018         {
1019                 e.angles = e.v_angle;
1020                 e.angles_x = -e.angles_x;
1021                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1022                 e.health = -2342;
1023                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1024                 e.solid = SOLID_NOT;
1025                 e.movetype = MOVETYPE_NONE;
1026                 e.takedamage = DAMAGE_NO;
1027                 if(e.weaponentity)
1028                         e.weaponentity.effects = EF_NODRAW;
1029                 if(clienttype(e) == CLIENTTYPE_REAL)
1030                 {
1031                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1032                         s = cvar_string("sv_intermission_cdtrack");
1033                         if(s != "")
1034                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1035                         msg_entity = e;
1036                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1037                 }
1038         }
1039
1040         //e.velocity = '0 0 0';
1041         //e.fixangle = TRUE;
1042
1043         // TODO halt weapon animation
1044 }
1045
1046
1047 /*
1048 go to the next level for deathmatch
1049 only called if a time or frag limit has expired
1050 */
1051 void NextLevel()
1052 {
1053         float minTotalFrags;
1054         float maxTotalFrags;
1055         float score;
1056         float f;
1057
1058         gameover = TRUE;
1059
1060         intermission_running = 1;
1061
1062 // enforce a wait time before allowing changelevel
1063         if(player_count > 0)
1064                 intermission_exittime = time + cvar("sv_mapchange_delay");
1065         else
1066                 intermission_exittime = -1;
1067
1068         /*
1069         WriteByte (MSG_ALL, SVC_CDTRACK);
1070         WriteByte (MSG_ALL, 3);
1071         WriteByte (MSG_ALL, 3);
1072         // done in FixIntermission
1073         */
1074
1075         //pos = FindIntermission ();
1076
1077         VoteReset();
1078
1079         DumpStats(TRUE);
1080
1081         if(cvar("sv_eventlog"))
1082                 GameLogEcho(":gameover");
1083
1084         GameLogClose();
1085
1086         FOR_EACH_CLIENT(other)
1087         {
1088                 FixIntermissionClient(other);
1089
1090                 if(other.winning)
1091                         bprint(other.netname, " ^7wins.\n");
1092         }
1093
1094         minTotalFrags = 0;
1095         maxTotalFrags = 0;
1096         FOR_EACH_PLAYER(other)
1097         {
1098                 if(maxTotalFrags < other.totalfrags)
1099                         maxTotalFrags = other.totalfrags;
1100                 if(minTotalFrags > other.totalfrags)
1101                         minTotalFrags = other.totalfrags;
1102         }
1103
1104         if(!currentbots)
1105         {
1106                 FOR_EACH_PLAYER(other)
1107                 {
1108                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1109                         f = bound(0, other.play_time / max(time, 1), 1);
1110                         // store some statistics?
1111                 }
1112         }
1113
1114         if(cvar("g_campaign"))
1115                 CampaignPreIntermission();
1116
1117         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1118 };
1119
1120 /*
1121 ============
1122 CheckRules_Player
1123
1124 Exit deathmatch games upon conditions
1125 ============
1126 */
1127 void CheckRules_Player()
1128 {
1129         if (gameover)   // someone else quit the game already
1130                 return;
1131
1132         if(self.deadflag == DEAD_NO)
1133                 self.play_time += frametime;
1134
1135         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1136         //   (div0: and that in CheckRules_World please)
1137 };
1138
1139 float checkrules_oneminutewarning;
1140
1141 float checkrules_equality;
1142 float checkrules_overtimewarning;
1143 float checkrules_overtimeend;
1144
1145 void InitiateOvertime()
1146 {
1147         if(!checkrules_overtimeend)
1148                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1149 }
1150
1151 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1152 float WINNING_YES = 1; // winner found
1153 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1154 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1155
1156 float GetWinningCode(float fraglimitreached, float equality)
1157 {
1158         if(equality)
1159                 if(fraglimitreached)
1160                         return WINNING_STARTOVERTIME;
1161                 else
1162                         return WINNING_NEVER;
1163         else
1164                 if(fraglimitreached)
1165                         return WINNING_YES;
1166                 else
1167                         return WINNING_NO;
1168 }
1169
1170 // set the .winning flag for exactly those players with a given field value
1171 void SetWinners(.float field, float value)
1172 {
1173         entity head;
1174         FOR_EACH_PLAYER(head)
1175                 head.winning = (head.field == value);
1176 }
1177
1178 // set the .winning flag for those players with a given field value
1179 void AddWinners(.float field, float value)
1180 {
1181         entity head;
1182         FOR_EACH_PLAYER(head)
1183                 if(head.field == value)
1184                         head.winning = 1;
1185 }
1186
1187 // clear the .winning flags
1188 void ClearWinners(void)
1189 {
1190         entity head;
1191         FOR_EACH_PLAYER(head)
1192                 head.winning = 0;
1193 }
1194
1195 // Onslaught winning condition:
1196 // game terminates if only one team has a working generator (or none)
1197 float WinningCondition_Onslaught()
1198 {
1199         entity head;
1200         local float t1, t2, t3, t4;
1201         // first check if the game has ended
1202         t1 = t2 = t3 = t4 = 0;
1203         head = find(world, classname, "onslaught_generator");
1204         while (head)
1205         {
1206                 if (head.health > 0)
1207                 {
1208                         if (head.team == COLOR_TEAM1) t1 = 1;
1209                         if (head.team == COLOR_TEAM2) t2 = 1;
1210                         if (head.team == COLOR_TEAM3) t3 = 1;
1211                         if (head.team == COLOR_TEAM4) t4 = 1;
1212                 }
1213                 head = find(head, classname, "onslaught_generator");
1214         }
1215         if (t1 + t2 + t3 + t4 < 2)
1216         {
1217                 // game over, only one team remains (or none)
1218                 ClearWinners();
1219                 if (t1) SetWinners(team, COLOR_TEAM1);
1220                 if (t2) SetWinners(team, COLOR_TEAM2);
1221                 if (t3) SetWinners(team, COLOR_TEAM3);
1222                 if (t4) SetWinners(team, COLOR_TEAM4);
1223                 dprint("Have a winner, ending game.\n");
1224                 return WINNING_YES;
1225         }
1226
1227         // Two or more teams remain
1228         return WINNING_NO;
1229 }
1230
1231 float LMS_NewPlayerLives()
1232 {
1233         float fl;
1234         fl = cvar("fraglimit");
1235         if(fl == 0)
1236                 fl = 999;
1237
1238         // first player has left the game for dying too much? Nobody else can get in.
1239         if(lms_lowest_lives < 1)
1240                 return 0;
1241
1242         if(!cvar("g_lms_join_anytime"))
1243                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1244                         return 0;
1245
1246         return bound(1, lms_lowest_lives, fl);
1247 }
1248
1249 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1250 // they win. Otherwise the defending team wins once the timelimit passes.
1251 void assault_new_round();
1252 float WinningCondition_Assault()
1253 {
1254         local float status;
1255         status = WINNING_NO;
1256
1257         // as the timelimit has not yet passed just assume the defending team will win
1258         if(assault_attacker_team == COLOR_TEAM1)
1259         {
1260                 SetWinners(team, COLOR_TEAM2);
1261         }
1262         else
1263         {
1264                 SetWinners(team, COLOR_TEAM1);
1265         }
1266
1267         local entity ent;
1268         ent = find(world, classname, "target_assault_roundend");
1269         if(ent)
1270         {
1271                 if(ent.winning) // round end has been triggered by attacking team
1272                 {
1273                         bprint("ASSAULT: round completed...\n");
1274                         SetWinners(team, assault_attacker_team);
1275
1276                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1277
1278                         if(ent.cnt == 1) // this was the second round
1279                         {
1280                                 status = WINNING_YES;
1281                         }
1282                         else
1283                         {
1284                                 local entity oldself;
1285                                 oldself = self;
1286                                 self = ent;
1287                                 assault_new_round();
1288                                 self = oldself;
1289                         }
1290                 }
1291         }
1292
1293         return status;
1294 }
1295
1296 // LMS winning condition: game terminates if and only if there's at most one
1297 // one player who's living lives. Top two scores being equal cancels the time
1298 // limit.
1299 float WinningCondition_LMS()
1300 {
1301         entity head, head2;
1302         float have_player;
1303         float have_players;
1304         float l;
1305
1306         have_player = FALSE;
1307         have_players = FALSE;
1308         l = LMS_NewPlayerLives();
1309
1310         head = find(world, classname, "player");
1311         if(head)
1312                 have_player = TRUE;
1313         head2 = find(head, classname, "player");
1314         if(head2)
1315                 have_players = TRUE;
1316
1317         if(have_player)
1318         {
1319                 // we have at least one player
1320                 if(have_players)
1321                 {
1322                         // two or more active players - continue with the game
1323                 }
1324                 else
1325                 {
1326                         // exactly one player?
1327
1328                         ClearWinners();
1329                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1330
1331                         if(l)
1332                         {
1333                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1334                                 return WINNING_NO;
1335                         }
1336                         else
1337                         {
1338                                 // a winner!
1339                                 // and assign him his first place
1340                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1341                                 return WINNING_YES;
1342                         }
1343                 }
1344         }
1345         else
1346         {
1347                 // nobody is playing at all...
1348                 if(l)
1349                 {
1350                         // wait for players...
1351                 }
1352                 else
1353                 {
1354                         // SNAFU (maybe a draw game?)
1355                         ClearWinners();
1356                         dprint("No players, ending game.\n");
1357                         return WINNING_YES;
1358                 }
1359         }
1360
1361         // When we get here, we have at least two players who are actually LIVING,
1362         // now check if the top two players have equal score.
1363         WinningConditionHelper();
1364
1365         ClearWinners();
1366         if(WinningConditionHelper_winner)
1367                 WinningConditionHelper_winner.winning = TRUE;
1368         if(WinningConditionHelper_equality)
1369                 return WINNING_NEVER;
1370
1371         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1372         return WINNING_NO;
1373 }
1374
1375 void print_to(entity e, string s)
1376 {
1377         if(e)
1378                 sprint(e, strcat(s, "\n"));
1379         else
1380                 print(s, "\n");
1381 }
1382
1383 void ShuffleMaplist()
1384 {
1385         string result;
1386         float start;
1387         float litems;
1388         float selected;
1389         float i;
1390
1391         result = cvar_string("g_maplist");
1392         litems = tokenizebyseparator(result, " ");
1393
1394         for(start = 0; start < litems - 1; ++start)
1395         {
1396                 result = "";
1397
1398                 // select a random item
1399                 selected = floor(random() * (litems - start) + start);
1400
1401                 // shift this item to the place start
1402                 for(i = 0; i < start; ++i)
1403                         result = strcat(result, " ", argv(i));
1404                 result = strcat(result, " ", argv(selected));
1405                 for(i = start; i < litems; ++i)
1406                         if(i != selected)
1407                                 result = strcat(result, " ", argv(i));
1408                 result = substring(result, 1, strlen(result) - 1);
1409
1410                 litems = tokenizebyseparator(result, " ");
1411
1412                 //dprint(result, "\n");
1413         }
1414
1415         cvar_set("g_maplist", result);
1416 }
1417
1418 float WinningCondition_Scores(float limit)
1419 {
1420         // TODO make everything use THIS winning condition (except LMS)
1421         WinningConditionHelper();
1422
1423         if(teams_matter)
1424         {
1425                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1426                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1427                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1428                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1429         }
1430
1431         ClearWinners();
1432         if(WinningConditionHelper_winner)
1433                 WinningConditionHelper_winner.winning = 1;
1434         if(WinningConditionHelper_winnerteam >= 0)
1435                 SetWinners(team, WinningConditionHelper_winnerteam);
1436
1437         if(WinningConditionHelper_lowerisbetter)
1438         {
1439                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1440                 limit = -limit;
1441         }
1442
1443         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1444 }
1445
1446 float WinningCondition_Race(float fraglimit)
1447 {
1448         float wc;
1449         entity p;
1450         wc = WinningCondition_Scores(fraglimit);
1451
1452         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1453         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1454         // do NOT support equality when the laps are all raced!
1455         {
1456                 FOR_EACH_PLAYER(p)
1457                         if not(p.race_completed)
1458                                 return WINNING_STARTOVERTIME;
1459                 return WINNING_YES;
1460         }
1461         return wc;
1462 }
1463
1464 void ReadyRestart();
1465 float WinningCondition_QualifyingThenRace(float limit)
1466 {
1467         float wc;
1468         wc = WinningCondition_Scores(limit);
1469
1470         // NEVER initiate overtime
1471         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1472         {
1473                 return WINNING_YES;
1474         }
1475
1476         return wc;
1477 }
1478
1479 float WinningCondition_RanOutOfSpawns()
1480 {
1481         entity head;
1482
1483         if(!have_team_spawns)
1484                 return WINNING_NO;
1485
1486         if(!some_spawn_has_been_used)
1487                 return WINNING_NO;
1488
1489         team1_score = team2_score = team3_score = team4_score = 0;
1490
1491         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1492         {
1493                 if(head.team == COLOR_TEAM1)
1494                         team1_score = 1;
1495                 else if(head.team == COLOR_TEAM2)
1496                         team2_score = 1;
1497                 else if(head.team == COLOR_TEAM3)
1498                         team3_score = 1;
1499                 else if(head.team == COLOR_TEAM4)
1500                         team4_score = 1;
1501         }
1502
1503         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1504         {
1505                 if(head.team == COLOR_TEAM1)
1506                         team1_score = 1;
1507                 else if(head.team == COLOR_TEAM2)
1508                         team2_score = 1;
1509                 else if(head.team == COLOR_TEAM3)
1510                         team3_score = 1;
1511                 else if(head.team == COLOR_TEAM4)
1512                         team4_score = 1;
1513         }
1514
1515         ClearWinners();
1516         if(team1_score + team2_score + team3_score + team4_score == 0)
1517         {
1518                 checkrules_equality = TRUE;
1519                 return WINNING_YES;
1520         }
1521         else if(team1_score + team2_score + team3_score + team4_score == 1)
1522         {
1523                 float t, i;
1524                 if(team1_score) t = COLOR_TEAM1;
1525                 if(team2_score) t = COLOR_TEAM2;
1526                 if(team3_score) t = COLOR_TEAM3;
1527                 if(team4_score) t = COLOR_TEAM4;
1528                 CheckAllowedTeams(world);
1529                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1530                 {
1531                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1532                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1533                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1534                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1535                 }
1536
1537                 AddWinners(team, t);
1538                 return WINNING_YES;
1539         }
1540         else
1541                 return WINNING_NO;
1542 }
1543
1544 /*
1545 ============
1546 CheckRules_World
1547
1548 Exit deathmatch games upon conditions
1549 ============
1550 */
1551 void CheckRules_World()
1552 {
1553         local float status;
1554         local float timelimit;
1555         local float fraglimit;
1556
1557         VoteThink();
1558         MapVote_Think();
1559
1560         SetDefaultAlpha();
1561
1562         /*
1563         MapVote_Think should now do that part
1564         if (intermission_running)
1565                 if (time >= intermission_exittime + 60)
1566                 {
1567                         if(!DoNextMapOverride())
1568                                 GotoNextMap();
1569                         return;
1570                 }
1571         */
1572
1573         if (gameover)   // someone else quit the game already
1574         {
1575                 if(player_count == 0) // Nobody there? Then let's go to the next map
1576                         MapVote_Start();
1577                         // this will actually check the player count in the next frame
1578                         // again, but this shouldn't hurt
1579                 return;
1580         }
1581
1582         timelimit = cvar("timelimit") * 60;
1583         fraglimit = cvar("fraglimit");
1584
1585         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1586         {
1587                 if(timelimit > 0)
1588                         timelimit = 0; // timelimit is not made for warmup
1589                 if(fraglimit > 0)
1590                         fraglimit = 0; // no fraglimit for now
1591         }
1592
1593         if(timelimit > 0)
1594                 timelimit += game_starttime;
1595
1596         if(checkrules_overtimeend)
1597         {
1598                 if(!checkrules_overtimewarning)
1599                 {
1600                         checkrules_overtimewarning = TRUE;
1601                         //announceall("announcer/robotic/1minuteremains.wav");
1602                         if(g_race && !g_race_qualifying)
1603                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1604                         else
1605                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1606                 }
1607         }
1608         else
1609         {
1610                 if (timelimit && time >= timelimit)
1611                 {
1612                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1613                         {
1614                                 float totalplayers;
1615                                 float playerswithlaps;
1616                                 float readyplayers;
1617                                 entity head;
1618                                 totalplayers = playerswithlaps = readyplayers = 0;
1619                                 FOR_EACH_PLAYER(head)
1620                                 {
1621                                         ++totalplayers;
1622                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1623                                                 ++playerswithlaps;
1624                                         if(head.ready)
1625                                                 ++readyplayers;
1626                                 }
1627
1628                                 // at least 2/3 of the players have completed a lap: start the RACE
1629                                 // otherwise, the players should end the qualifying on their own
1630                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1631                                 {
1632                                         checkrules_overtimeend = 0;
1633                                         ReadyRestart(); // go to race
1634                                 }
1635                                 else
1636                                         InitiateOvertime();
1637                         }
1638                         else
1639                                 InitiateOvertime();
1640                 }
1641         }
1642
1643         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1644         {
1645                 NextLevel();
1646                 return;
1647         }
1648
1649         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1650         {
1651                 checkrules_oneminutewarning = TRUE;
1652                 play2all("announcer/robotic/1minuteremains.wav");
1653         }
1654
1655         status = WinningCondition_RanOutOfSpawns();
1656         if(status == WINNING_YES)
1657         {
1658                 bprint("Hey! Someone ran out of spawns!\n");
1659         }
1660         else if(g_race && !g_race_qualifying && timelimit >= 0)
1661         {
1662                 status = WinningCondition_Race(fraglimit);
1663         }
1664         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1665         {
1666                 status = WinningCondition_QualifyingThenRace(fraglimit);
1667         }
1668         else if(g_assault)
1669         {
1670                 status = WinningCondition_Assault(); // TODO remove this?
1671         }
1672         else if(g_lms)
1673         {
1674                 status = WinningCondition_LMS();
1675         }
1676         else if (g_onslaught)
1677         {
1678                 status = WinningCondition_Onslaught(); // TODO remove this?
1679         }
1680         else
1681         {
1682                 status = WinningCondition_Scores(fraglimit);
1683         }
1684
1685         if(status == WINNING_STARTOVERTIME)
1686         {
1687                 status = WINNING_NEVER;
1688                 InitiateOvertime();
1689         }
1690
1691         if(status == WINNING_NEVER)
1692                 // equality cases! Nobody wins if the overtime ends in a draw.
1693                 ClearWinners();
1694
1695         if(checkrules_overtimeend)
1696                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1697                         status = WINNING_YES;
1698
1699         if(status == WINNING_YES)
1700                 NextLevel();
1701 };
1702
1703 float mapvote_nextthink;
1704 float mapvote_initialized;
1705 float mapvote_keeptwotime;
1706 float mapvote_timeout;
1707 string mapvote_message;
1708 string mapvote_screenshot_dir;
1709
1710 float mapvote_count;
1711 float mapvote_count_real;
1712 string mapvote_maps[MAPVOTE_COUNT];
1713 float mapvote_maps_suggested[MAPVOTE_COUNT];
1714 string mapvote_suggestions[MAPVOTE_COUNT];
1715 float mapvote_suggestion_ptr;
1716 float mapvote_maxlen;
1717 float mapvote_voters;
1718 float mapvote_votes[MAPVOTE_COUNT];
1719 float mapvote_run;
1720 float mapvote_detail;
1721 float mapvote_abstain;
1722 float mapvote_dirty;
1723 .float mapvote;
1724
1725 void MapVote_ClearAllVotes()
1726 {
1727         FOR_EACH_CLIENT(other)
1728                 other.mapvote = 0;
1729 }
1730
1731 string MapVote_Suggest(string m)
1732 {
1733         float i;
1734         if(m == "")
1735                 return "That's not how to use this command.";
1736         if(!cvar("g_maplist_votable_suggestions"))
1737                 return "Suggestions are not accepted on this server.";
1738         if(mapvote_initialized)
1739                 return "Can't suggest - voting is already in progress!";
1740         m = MapInfo_FixName(m);
1741         if(!m)
1742                 return "The map you suggested is not available on this server.";
1743         if(!cvar("g_maplist_votable_override_mostrecent"))
1744                 if(Map_IsRecent(m))
1745                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1746
1747         if(!MapInfo_CheckMap(m))
1748                 return "The map you suggested does not support the current game mode.";
1749         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1750                 if(mapvote_suggestions[i] == m)
1751                         return "This map was already suggested.";
1752         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1753         {
1754                 i = floor(random() * mapvote_suggestion_ptr);
1755         }
1756         else
1757         {
1758                 i = mapvote_suggestion_ptr;
1759                 mapvote_suggestion_ptr += 1;
1760         }
1761         if(mapvote_suggestions[i] != "")
1762                 strunzone(mapvote_suggestions[i]);
1763         mapvote_suggestions[i] = strzone(m);
1764         if(cvar("sv_eventlog"))
1765                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
1766         return strcat("Suggestion of ", m, " accepted.");
1767 }
1768
1769 void MapVote_AddVotable(string nextMap, float isSuggestion)
1770 {
1771         float j;
1772         if(nextMap == "")
1773                 return;
1774         for(j = 0; j < mapvote_count; ++j)
1775                 if(mapvote_maps[j] == nextMap)
1776                         return;
1777         if(strlen(nextMap) > mapvote_maxlen)
1778                 mapvote_maxlen = strlen(nextMap);
1779         mapvote_maps[mapvote_count] = strzone(nextMap);
1780         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1781         mapvote_count += 1;
1782 }
1783
1784 void MapVote_SendData(float target);
1785 void MapVote_Init()
1786 {
1787         float i;
1788         float nmax, smax;
1789
1790         MapVote_ClearAllVotes();
1791
1792         mapvote_count = 0;
1793         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1794         mapvote_abstain = cvar("g_maplist_votable_abstain");
1795
1796         if(mapvote_abstain)
1797                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1798         else
1799                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1800         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1801
1802         if(mapvote_suggestion_ptr)
1803                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1804                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
1805
1806         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1807                 MapVote_AddVotable(GetNextMap(), FALSE);
1808
1809         if(mapvote_count == 0)
1810         {
1811                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1812                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1813                 localcmd("\nmenu_cmd sync\n");
1814                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1815                         MapVote_AddVotable(GetNextMap(), FALSE);
1816         }
1817
1818         mapvote_count_real = mapvote_count;
1819         if(mapvote_abstain)
1820                 MapVote_AddVotable("don't care", 0);
1821
1822         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1823
1824         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1825         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1826         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1827                 mapvote_keeptwotime = 0;
1828         mapvote_message = "Choose a map and press its key!";
1829
1830         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1831         if(mapvote_screenshot_dir == "")
1832                 mapvote_screenshot_dir = "maps";
1833         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1834
1835         if(!cvar("g_maplist_textonly"))
1836                 MapVote_SendData(MSG_ALL);
1837 }
1838
1839 void MapVote_SendPicture(float id)
1840 {
1841         msg_entity = self;
1842         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1843         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1844         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1845         WriteByte(MSG_ONE, id);
1846         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
1847 }
1848
1849 float GameCommand_MapVote(string cmd)
1850 {
1851         if(!intermission_running)
1852                 return FALSE;
1853         if(!cvar("g_maplist_textonly"))
1854         {
1855                 if(cmd == "mv_getpic")
1856                 {
1857                         MapVote_SendPicture(stof(argv(1)));
1858                         return TRUE;
1859                 }
1860         }
1861
1862         return FALSE;
1863 }
1864
1865 float MapVote_GetMapMask()
1866 {
1867         float mask, i, power;
1868         mask = 0;
1869         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1870                 if(mapvote_maps[i] != "")
1871                         mask |= power;
1872         return mask;
1873 }
1874
1875 void MapVote_SendData(float targ)
1876 {
1877         string mapfile, pakfile;
1878         float i, o;
1879         WriteByte(targ, SVC_TEMPENTITY);
1880         WriteByte(targ, TE_CSQC_CONFIG);
1881         WriteString(targ, "mv_screenshot_dir");
1882         WriteString(targ, mapvote_screenshot_dir);
1883
1884         WriteByte(targ, SVC_TEMPENTITY);
1885         WriteByte(targ, TE_CSQC_MAPVOTE);
1886         WriteByte(targ, MAPVOTE_NET_INIT);
1887
1888         WriteByte(targ, mapvote_count);
1889         WriteByte(targ, mapvote_abstain);
1890         WriteByte(targ, mapvote_detail);
1891         WriteCoord(targ, mapvote_timeout);
1892         if(mapvote_count <= 8)
1893                 WriteByte(targ, MapVote_GetMapMask());
1894         else
1895                 WriteShort(targ, MapVote_GetMapMask());
1896         for(i = 0; i < mapvote_count; ++i)
1897                 if(mapvote_maps[i] != "")
1898                 {
1899                         WriteString(targ, mapvote_maps[i]);
1900                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1901                         pakfile = whichpack(strcat(mapfile, ".tga"));
1902                         if(pakfile == "")
1903                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1904                         if(pakfile == "")
1905                                 pakfile = whichpack(strcat(mapfile, ".png"));
1906                         print("pakfile is ", pakfile, "\n");
1907                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
1908                                 pakfile = substring(pakfile, o, 999);
1909                         WriteString(targ, pakfile);
1910                 }
1911 }
1912
1913 void MapVote_UpdateData(float targ)
1914 {
1915         float i;
1916         WriteByte(targ, SVC_TEMPENTITY);
1917         WriteByte(targ, TE_CSQC_MAPVOTE);
1918         WriteByte(targ, MAPVOTE_NET_UPDATE);
1919         if(mapvote_count <= 8)
1920                 WriteByte(targ, MapVote_GetMapMask());
1921         else
1922                 WriteShort(targ, MapVote_GetMapMask());
1923         if(mapvote_detail)
1924                 for(i = 0; i < mapvote_count; ++i)
1925                         if(mapvote_maps[i] != "")
1926                                 WriteByte(targ, mapvote_votes[i]);
1927 }
1928
1929 void MapVote_TellVote(float targ, float vote)
1930 {
1931         WriteByte(targ, SVC_TEMPENTITY);
1932         WriteByte(targ, TE_CSQC_MAPVOTE);
1933         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
1934         WriteByte(targ, vote);
1935 }
1936
1937 float MapVote_Finished(float mappos)
1938 {
1939         string result;
1940         float i;
1941         float didntvote;
1942
1943         if(cvar("sv_eventlog"))
1944         {
1945                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
1946                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1947                 didntvote = mapvote_voters;
1948                 for(i = 0; i < mapvote_count; ++i)
1949                         if(mapvote_maps[i] != "")
1950                         {
1951                                 didntvote -= mapvote_votes[i];
1952                                 if(i != mappos)
1953                                 {
1954                                         result = strcat(result, ":", mapvote_maps[i]);
1955                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1956                                 }
1957                         }
1958                 result = strcat(result, ":didn't vote:", ftos(didntvote));
1959
1960                 GameLogEcho(result);
1961                 if(mapvote_maps_suggested[mappos])
1962                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
1963         }
1964
1965         FOR_EACH_REALCLIENT(other)
1966                 FixClientCvars(other);
1967
1968         Map_Goto_SetStr(mapvote_maps[mappos]);
1969         Map_Goto();
1970         alreadychangedlevel = TRUE;
1971         return TRUE;
1972 }
1973 void MapVote_CheckRules_1()
1974 {
1975         float i;
1976
1977         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1978         {
1979                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1980                 mapvote_votes[i] = 0;
1981         }
1982
1983         mapvote_voters = 0;
1984         FOR_EACH_REALCLIENT(other)
1985         {
1986                 ++mapvote_voters;
1987                 if(other.mapvote)
1988                 {
1989                         i = other.mapvote - 1;
1990                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1991                         mapvote_votes[i] = mapvote_votes[i] + 1;
1992                 }
1993         }
1994 }
1995
1996 float MapVote_CheckRules_2()
1997 {
1998         float i;
1999         float firstPlace, secondPlace;
2000         float firstPlaceVotes, secondPlaceVotes;
2001         float mapvote_voters_real;
2002         string result;
2003
2004         mapvote_voters_real = mapvote_voters;
2005         if(mapvote_abstain)
2006                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2007
2008         RandomSelection_Init();
2009         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2010                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2011         firstPlace = RandomSelection_chosen_float;
2012         firstPlaceVotes = RandomSelection_best_priority;
2013         //dprint("First place: ", ftos(firstPlace), "\n");
2014         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2015
2016         RandomSelection_Init();
2017         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2018                 if(i != firstPlace)
2019                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2020         secondPlace = RandomSelection_chosen_float;
2021         secondPlaceVotes = RandomSelection_best_priority;
2022         //dprint("Second place: ", ftos(secondPlace), "\n");
2023         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2024
2025         if(firstPlace == -1)
2026                 error("No first place in map vote... WTF?");
2027
2028         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2029                 return MapVote_Finished(firstPlace);
2030
2031         if(mapvote_keeptwotime)
2032                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2033                 {
2034                         float didntvote;
2035                         mapvote_dirty = TRUE;
2036                         mapvote_message = "Now decide between the TOP TWO!";
2037                         mapvote_keeptwotime = 0;
2038                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2039                         result = strcat(result, ":", ftos(firstPlaceVotes));
2040                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2041                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2042                         didntvote = mapvote_voters;
2043                         for(i = 0; i < mapvote_count; ++i)
2044                                 if(mapvote_maps[i] != "")
2045                                 {
2046                                         didntvote -= mapvote_votes[i];
2047                                         if(i != firstPlace)
2048                                                 if(i != secondPlace)
2049                                                 {
2050                                                         result = strcat(result, ":", mapvote_maps[i]);
2051                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2052                                                         if(i < mapvote_count_real)
2053                                                         {
2054                                                                 strunzone(mapvote_maps[i]);
2055                                                                 mapvote_maps[i] = "";
2056                                                         }
2057                                                 }
2058                                 }
2059                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2060                         if(cvar("sv_eventlog"))
2061                                 GameLogEcho(result);
2062                 }
2063
2064         return FALSE;
2065 }
2066 void MapVote_Tick()
2067 {
2068         string msgstr;
2069         string tmp;
2070         float i;
2071         float keeptwo;
2072         float totalvotes;
2073
2074         keeptwo = mapvote_keeptwotime;
2075         MapVote_CheckRules_1(); // count
2076         if(MapVote_CheckRules_2()) // decide
2077                 return;
2078
2079         totalvotes = 0;
2080         FOR_EACH_REALCLIENT(other)
2081         {
2082                 // hide scoreboard again
2083                 if(other.health != 2342)
2084                 {
2085                         other.health = 2342;
2086                         other.impulse = 0;
2087                         if(clienttype(other) == CLIENTTYPE_REAL)
2088                         {
2089                                 if(cvar("g_maplist_textonly"))
2090                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2091
2092                                 msg_entity = other;
2093                                 WriteByte(MSG_ONE, SVC_FINALE);
2094                                 WriteString(MSG_ONE, "");
2095                         }
2096                 }
2097
2098                 // notify about keep-two
2099                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2100                         play2(other, "misc/invshot.wav");
2101
2102                 // clear possibly invalid votes
2103                 if(mapvote_maps[other.mapvote - 1] == "")
2104                         other.mapvote = 0;
2105                 // use impulses as new vote
2106                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2107                         if(mapvote_maps[other.impulse - 1] != "")
2108                         {
2109                                 other.mapvote = other.impulse;
2110                                 if(mapvote_detail)
2111                                         mapvote_dirty = TRUE;
2112
2113                                 msg_entity = other;
2114                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2115                         }
2116                 other.impulse = 0;
2117
2118                 if(other.mapvote)
2119                         ++totalvotes;
2120         }
2121
2122         MapVote_CheckRules_1(); // just count
2123
2124         if(!cvar("g_maplist_textonly"))
2125         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2126         {
2127                 MapVote_UpdateData(MSG_BROADCAST);
2128                 mapvote_dirty = FALSE;
2129         }
2130
2131         if(cvar("g_maplist_textonly"))
2132         {
2133                 FOR_EACH_REALCLIENT(other)
2134                 {
2135                         // display voting screen
2136                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2137                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2138                         if(mapvote_abstain)
2139                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2140                         msgstr = strcat(msgstr, mapvote_message);
2141                         msgstr = strcat(msgstr, "\n\n");
2142                         for(i = 0; i < mapvote_count; ++i)
2143                                 if(mapvote_maps[i] == "")
2144                                         msgstr = strcat(msgstr, "\n");
2145                                 else
2146                                 {
2147                                         tmp = mapvote_maps[i];
2148                                         tmp = strpad(mapvote_maxlen, tmp);
2149                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2150                                         if(mapvote_detail)
2151                                         {
2152                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2153                                                 if(mapvote_votes[i] != 1)
2154                                                         tmp = strcat(tmp, "s");
2155                                                 tmp = strcat(tmp, ")");
2156                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2157                                         }
2158                                         if(mapvote_abstain)
2159                                                 if(i == mapvote_count - 1)
2160                                                         msgstr = strcat(msgstr, "\n");
2161                                         if(other.mapvote == i + 1)
2162                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2163                                         else
2164                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2165                                 }
2166
2167                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2168                         if(totalvotes != 1)
2169                                 msgstr = strcat(msgstr, "s");
2170                         msgstr = strcat(msgstr, " cast");
2171                         i = ceil(mapvote_timeout - time);
2172                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2173                         if(i != 1)
2174                                 msgstr = strcat(msgstr, "s");
2175                         msgstr = strcat(msgstr, " left");
2176
2177                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2178                 }
2179         }
2180 }
2181 void MapVote_Start()
2182 {
2183         if(mapvote_run)
2184                 return;
2185
2186         MapInfo_Enumerate();
2187         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2188                 mapvote_run = TRUE;
2189 }
2190 void MapVote_Think()
2191 {
2192         if(!mapvote_run)
2193                 return;
2194
2195         if(alreadychangedlevel)
2196                 return;
2197
2198         if(time < mapvote_nextthink)
2199                 return;
2200         //dprint("tick\n");
2201
2202         mapvote_nextthink = time + 0.5;
2203
2204         if(!mapvote_initialized)
2205         {
2206                 mapvote_initialized = TRUE;
2207                 if(DoNextMapOverride())
2208                         return;
2209                 if(!cvar("g_maplist_votable") || player_count <= 0)
2210                 {
2211                         GotoNextMap();
2212                         return;
2213                 }
2214                 MapVote_Init();
2215         }
2216
2217         MapVote_Tick();
2218 };
2219
2220 string GotoMap(string m)
2221 {
2222         if(!MapInfo_CheckMap(m))
2223                 return "The map you chose is not available on this server.";
2224         cvar_set("nextmap", m);
2225         cvar_set("timelimit", "-1");
2226         if(mapvote_initialized || alreadychangedlevel)
2227         {
2228                 if(DoNextMapOverride())
2229                         return "Map switch initiated.";
2230                 else
2231                         return "Hm... no. For some reason I like THIS map more.";
2232         }
2233         else
2234                 return "Map switch will happen after scoreboard.";
2235 }
2236
2237
2238 void EndFrame()
2239 {
2240         FOR_EACH_REALCLIENT(self)
2241         {
2242                 if(self.classname == "spectator")
2243                 {
2244                         if(self.enemy.typehitsound)
2245                                 play2(self, "misc/typehit.wav");
2246                         else if(self.enemy.hitsound)
2247                                 play2(self, "misc/hit.wav");
2248                 }
2249                 else
2250                 {
2251                         if(self.typehitsound)
2252                                 play2(self, "misc/typehit.wav");
2253                         else if(self.hitsound)
2254                                 play2(self, "misc/hit.wav");
2255                 }
2256         }
2257         FOR_EACH_CLIENT(self)
2258         {
2259                 self.hitsound = FALSE;
2260                 self.typehitsound = FALSE;
2261         }
2262 }
2263
2264
2265 /*
2266  * RedirectionThink:
2267  * returns TRUE if redirecting
2268  */
2269 float redirection_timeout;
2270 float redirection_nextthink;
2271 float RedirectionThink()
2272 {
2273         float clients_found;
2274
2275         if(redirection_target == "")
2276                 return FALSE;
2277
2278         if(!redirection_timeout)
2279         {
2280                 cvar_set("sv_public", "-2");
2281                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2282                 if(redirection_target == "self")
2283                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2284                 else
2285                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2286         }
2287
2288         if(time < redirection_nextthink)
2289                 return TRUE;
2290
2291         redirection_nextthink = time + 1;
2292
2293         clients_found = 0;
2294         FOR_EACH_REALCLIENT(self)
2295         {
2296                 print("Redirecting: sending connect command to ", self.netname, "\n");
2297                 if(redirection_target == "self")
2298                         stuffcmd(self, "\ndisconnect; reconnect\n");
2299                 else
2300                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2301                 ++clients_found;
2302         }
2303
2304         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2305
2306         if(time > redirection_timeout || clients_found == 0)
2307                 localcmd("\nwait; wait; wait; quit\n");
2308
2309         return TRUE;
2310 }
2311
2312 void RestoreGame()
2313 {
2314         // Loaded from a save game
2315         // some things then break, so let's work around them...
2316
2317         // Progs DB (capture records)
2318         if(sv_cheats)
2319                 ServerProgsDB = db_create();
2320         else
2321                 ServerProgsDB = db_load("server.db");
2322
2323         // Mapinfo
2324         MapInfo_Shutdown();
2325         MapInfo_Enumerate();
2326         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2327 }
2328
2329 void SV_Shutdown()
2330 {
2331         if(world_initialized > 0)
2332         {
2333                 world_initialized = 0;
2334                 print("Saving persistent data...\n");
2335                 Ban_SaveBans();
2336                 if(!sv_cheats)
2337                         db_save(ServerProgsDB, "server.db");
2338                 if(cvar("developer"))
2339                         db_save(TemporaryDB, "server-temp.db");
2340                 db_close(ServerProgsDB);
2341                 db_close(TemporaryDB);
2342                 print("done!\n");
2343                 // tell the bot system the game is ending now
2344                 bot_endgame();
2345
2346                 MapInfo_Shutdown();
2347         }
2348         else if(world_initialized == 0)
2349         {
2350                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2351         }
2352 }