data/qcsrc/server/g_tetris.qc

   1 /*
   2
   3 Installation:
   4
   5 in weapons.qc add TetrisImpulses(); to ImpulseCommands
   6
   7 in progs.src add tetris.qc after subs.qc
   8 in cl_client.qc add if (TetrisPreFrame()) return; to  PlayerPreThink
   9 in cl_client.qc add if (TetrisPostFrame()) return; to PlayerPostThink
  10
  11 */
  12
  13 .vector tet_org;
  14
  15 .float tetris_on, tet_time, tet_autodown;
  16 .vector piece_pos;
  17 .float piece_type, next_piece, tet_score, tet_lines;
  18
  19 var float tet_high_score = 0;
  20
  21 float TET_LINES = 20;
  22 float TET_WIDTH = 10;
  23 //character values
  24 float TET_BORDER = 132;
  25 float TET_BLOCKS = 132; // +1 = first color, +2, +3;
  26 float TET_SPACE = 32; // blankness
  27
  28
  29
  30 float TETKEY_UP = 1;
  31 float TETKEY_DOWN = 2;
  32 float TETKEY_LEFT = 4;
  33 float TETKEY_RIGHT = 8;
  34 float TETKEY_ROTLEFT = 16;
  35 float TETKEY_ROTRIGHT = 32;
  36
  37 float PIECES = 7;
  38
  39 .float line1, line2, line3, line4, line5, line6, line7,
  40 line8, line9, line10, line11, line12, line13, line14, line15,
  41 line16, line17, line18, line19, line20;
  42
  43
  44 float   SVC_CENTERPRINTa                = 26;
  45
  46
  47 /*
  48 *********************************
  49
  50 Library Functions
  51
  52 *********************************
  53 */
  54 void (float ln, float vl) SetLine =
  55 {
  56         if (ln == 1)
  57                 self.line1 = vl;
  58         else if (ln == 2)
  59                 self.line2 = vl;
  60         else if (ln == 3)
  61                 self.line3 = vl;
  62         else if (ln == 4)
  63                 self.line4 = vl;
  64         else if (ln == 5)
  65                 self.line5 = vl;
  66         else if (ln == 6)
  67                 self.line6 = vl;
  68         else if (ln == 7)
  69                 self.line7 = vl;
  70         else if (ln == 8)
  71                 self.line8 = vl;
  72         else if (ln == 9)
  73                 self.line9 = vl;
  74         else if (ln == 10)
  75                 self.line10 = vl;
  76         else if (ln == 11)
  77                 self.line11 = vl;
  78         else if (ln == 12)
  79                 self.line12 = vl;
  80         else if (ln == 13)
  81                 self.line13 = vl;
  82         else if (ln == 14)
  83                 self.line14 = vl;
  84         else if (ln == 15)
  85                 self.line15 = vl;
  86         else if (ln == 16)
  87                 self.line16 = vl;
  88         else if (ln == 17)
  89                 self.line17 = vl;
  90         else if (ln == 18)
  91                 self.line18 = vl;
  92         else if (ln == 19)
  93                 self.line19 = vl;
  94         else if (ln == 20)
  95                 self.line20 = vl;
  96 };
  97
  98 float (float ln) GetLine =
  99 {
 100         if (ln == 1)
 101                 return self.line1;
 102         else if (ln == 2)
 103                 return self.line2;
 104         else if (ln == 3)
 105                 return self.line3;
 106         else if (ln == 4)
 107                 return self.line4;
 108         else if (ln == 5)
 109                 return self.line5;
 110         else if (ln == 6)
 111                 return self.line6;
 112         else if (ln == 7)
 113                 return self.line7;
 114         else if (ln == 8)
 115                 return self.line8;
 116         else if (ln == 9)
 117                 return self.line9;
 118         else if (ln == 10)
 119                 return self.line10;
 120         else if (ln == 11)
 121                 return self.line11;
 122         else if (ln == 12)
 123                 return self.line12;
 124         else if (ln == 13)
 125                 return self.line13;
 126         else if (ln == 14)
 127                 return self.line14;
 128         else if (ln == 15)
 129                 return self.line15;
 130         else if (ln == 16)
 131                 return self.line16;
 132         else if (ln == 17)
 133                 return self.line17;
 134         else if (ln == 18)
 135                 return self.line18;
 136         else if (ln == 19)
 137                 return self.line19;
 138         else if (ln == 20)
 139                 return self.line20;
 140         else
 141                 return 0;
 142 };
 143
 144 float(float x, float dat) GetXBlock =
 145 {
 146         if (x == 1)
 147                 return dat & 3;
 148         else if (x == 2)
 149                 return (dat & 12) / 4;
 150         else if (x == 3)
 151                 return (dat & 48) / 16;
 152         else if (x == 4)
 153                 return (dat & 192) / 64;
 154         else if (x == 5)
 155                 return (dat & 768) / 256;
 156         else if (x == 6)
 157                 return (dat & 3072) / 1024;
 158         else if (x == 7)
 159                 return (dat & 12288) / 4096;
 160         else if (x == 8)
 161                 return (dat & 49152) / 16384;
 162         else if (x == 9)
 163                 return (dat & 196608) / 65536;
 164         else if (x == 10)
 165                 return (dat & 786432) / 262144;
 166         else
 167                 return 0;
 168 };
 169
 170 float(float x, float dat, float new) SetXBlock =
 171 {
 172         if (x == 1)
 173                 return (dat - (dat & 3)) | new;
 174         else if (x == 2)
 175                 return (dat - (dat & 12)) | (new*4);
 176         else if (x == 3)
 177                 return (dat - (dat & 48)) | (new*16);
 178         else if (x == 4)
 179                 return (dat - (dat & 192)) | (new*64);
 180         else if (x == 5)
 181                 return (dat - (dat & 768)) | (new*256);
 182         else if (x == 6)
 183                 return (dat - (dat & 3072)) | (new*1024);
 184         else if (x == 7)
 185                 return (dat - (dat & 12288)) | (new*4096);
 186         else if (x == 8)
 187                 return (dat - (dat & 49152)) | (new*16384);
 188         else if (x == 9)
 189                 return (dat - (dat & 196608)) | (new*65536);
 190         else if (x == 10)
 191                 return (dat - (dat & 786432)) | (new*262144);
 192         else
 193                 return dat;
 194 };
 195
 196
 197 float(float x, float y) GetSquare =
 198 {
 199         return GetXBlock(x,  GetLine(y));
 200 };
 201
 202 void (float x, float y, float val) SetSquare =
 203 {
 204         float dat;
 205
 206         dat = GetLine(y);
 207         dat  = SetXBlock(x, dat, val & 3);
 208         SetLine(y, dat);
 209 };
 210
 211
 212
 213 vector(float pc) PieceShape =
 214 {
 215
 216 /*
 217 1 =
 218  ##
 219  ##
 220 */
 221         if (pc == 1)
 222                 return '20 20 0'; // 1 * 4 + 1 * 16
 223 /*
 224 2 =
 225
 226 ####
 227 */
 228         else if (pc == 2)
 229                 return '85 0 0';
 230
 231 /*
 232 3 =
 233
 234 ###
 235 #
 236 */
 237         else if (pc == 3)
 238                 return '21 1 0';
 239 /*
 240 4 =
 241
 242 #
 243 ###
 244 */
 245         else if (pc == 4)
 246                 return '1 21 0';
 247 /*
 248 5 =
 249 ##
 250  ##
 251 */
 252         else if (pc == 5)
 253                 return '5 20 0';
 254
 255 /*
 256 6 =
 257  ##
 258 ##
 259 */
 260         else if (pc == 6)
 261                 return '20 5 0';
 262
 263 /*
 264 7 =
 265  #
 266 ###
 267 */
 268         else if (pc == 7)
 269                 return '4 21 0';
 270
 271
 272         else
 273                 return '0 0 0';
 274
 275 }
 276
 277 // do x 1..4 and y 1..4 in case of rotation
 278 float(float x, float y, float rot, float pc) PieceMetric =
 279 {
 280         float t;
 281         vector piece_dat;
 282
 283         // return bits of a piece
 284         if (rot == 1) // 90 degrees
 285         {
 286                 t = y;
 287                 y = x;
 288                 x = 5 - t;
 289         }
 290         else if (rot == 2)//180
 291         {
 292                 x = 5 - x;
 293                 y = 3 - y;
 294         }
 295         else if (rot == 3) // 270
 296         {
 297                 t = y;
 298                 y = 5 - x;
 299                 x = t;
 300         }
 301         if (x < 1 || y < 1 || x > 4 || y > 2)
 302                 return 0;
 303         piece_dat = PieceShape(pc);
 304         if (y == 1)
 305                 return GetXBlock(x, piece_dat_x); // first row
 306         else if (y == 2)
 307                 return GetXBlock(x, piece_dat_y); // second row
 308         else if (y == 3)
 309                 return GetXBlock(x, piece_dat_z); // third row (doesn't exist)
 310         else
 311                 return 0; // illegal parms
 312 };
 313 /*
 314 *********************************
 315
 316 Draw
 317
 318 *********************************
 319 */
 320
 321
 322 /* some prydon gate functions to make life easier....
 323
 324 somewhat modified because we don't need all the fanciness Prydon Gate is capable of
 325
 326 */
 327
 328 void(float c1, float c2, float c3, float c4, float c5, float c6) p6 =
 329 {
 330         WriteChar(MSG_ONE, c1);
 331         WriteChar(MSG_ONE, c2);
 332         WriteChar(MSG_ONE, c3);
 333         WriteChar(MSG_ONE, c4);
 334         WriteChar(MSG_ONE, c5);
 335         WriteChar(MSG_ONE, c6);
 336 };
 337
 338 float(float num, float dig) pnum =
 339 {
 340         local float f, i;
 341         if (num < 0)
 342         {
 343                 WriteChar(MSG_ONE, 45);
 344                 num = 0 - num;
 345         }
 346         f = floor(num / 10);
 347         num = num - (f * 10);
 348         if (f)
 349                 dig = pnum(f, dig+1);
 350         else
 351         {
 352                 // pad to 6
 353                 for (i = 0; i < (5 - dig); i = i + 1)
 354                         WriteChar(MSG_ONE, TET_SPACE);
 355         }
 356         WriteChar(MSG_ONE, 48 + num);
 357         return dig;
 358 };
 359
 360 void (float ln) DrawLine =
 361 {
 362         float x, d;
 363         WriteChar(MSG_ONE, TET_BORDER);
 364
 365         for (x = 1; x <= TET_WIDTH; x = x + 1)
 366         {
 367                 d = GetSquare(x, ln);
 368                 if (d)
 369                         WriteChar(MSG_ONE, TET_BLOCKS + d);
 370                 else
 371                         WriteChar(MSG_ONE, TET_SPACE);
 372         }
 373         WriteChar(MSG_ONE, TET_BORDER);
 374 }
 375
 376 void (float pc, float ln) DrawPiece =
 377 {
 378         float x, d, piece_ln, color;
 379         vector piece_dat;
 380         color = pc & 3;
 381         if (color == 0) // 4
 382                 color = 1;
 383         WriteChar(MSG_ONE, TET_SPACE); // pad to 6
 384
 385         piece_dat = PieceShape(pc);
 386         if (ln == 1)
 387                 piece_ln = piece_dat_x;
 388         else
 389                 piece_ln = piece_dat_y;
 390         for (x = 1; x <= 4; x = x + 1)
 391         {
 392                 d = GetXBlock(x, piece_ln) * color;
 393                 if (d)
 394                         WriteChar(MSG_ONE, TET_BLOCKS + d);
 395                 else
 396                         WriteChar(MSG_ONE, TET_SPACE);
 397         }
 398         WriteChar(MSG_ONE, TET_SPACE);  // pad to 6
 399 }
 400 void() Draw_Tetris =
 401 {
 402         float i;
 403         msg_entity = self;
 404         WriteChar(MSG_ONE, SVC_CENTERPRINTa);
 405         // decoration
 406         for (i = 1; i <= (TET_WIDTH + 2); i = i + 1)
 407                 WriteChar(MSG_ONE, TET_BORDER);
 408         p6(' ', ' ', ' ', ' ', ' ', ' ');
 409         WriteChar(MSG_ONE, 10);
 410         for (i = 1; i <= TET_LINES; i = i + 1)
 411         {
 412                 DrawLine(i);
 413                 if (i == 1)
 414                         p6(' ', 'N', 'E', 'X', 'T', ' ');
 415                 else if (i == 3)
 416                         DrawPiece(self.next_piece, 1);
 417                 else if (i == 4)
 418                         DrawPiece(self.next_piece, 2);
 419                 else if (i == 6)
 420                         p6(' ', 'L', 'I', 'N', 'E', 'S');
 421                 else if (i == 7)
 422                         pnum(self.tet_lines, 0);
 423                 else if (i == 9)
 424                         p6(' ', 'S', 'C', 'O', 'R', 'E');
 425                 else if (i == 10)
 426                         pnum(self.tet_score, 0);
 427                 else if (i == 12)
 428                         p6(' ', 'H', 'I', 'G', 'H', ' ');
 429                 else if (i == 13)
 430                         p6(' ', 'S', 'C', 'O', 'R', 'E');
 431                 else if (i == 14)
 432                         pnum(tet_high_score, 0);
 433                 else if (i == 16)
 434                         p6(' ', 'L', 'E', 'V', 'E', 'L');
 435                 else if (i == 17)
 436                         pnum(floor(self.tet_lines / 20)+ 1, 0);
 437                 else
 438                         p6(' ', ' ', ' ', ' ', ' ', ' ');
 439                 WriteChar(MSG_ONE, 10);
 440         }
 441         // decoration
 442
 443         for (i = 1; i <= (TET_WIDTH + 2); i = i + 1)
 444                 WriteChar(MSG_ONE, TET_BORDER);
 445         p6(' ', ' ', ' ', ' ', ' ', ' ');
 446         WriteChar(MSG_ONE, 10);
 447         WriteChar(MSG_ONE, 0);
 448 }
 449 /*
 450 *********************************
 451
 452 Game Functions
 453
 454 *********************************
 455 */
 456
 457 // reset the game
 458 void() ResetTetris =
 459 {
 460         float i;
 461
 462         for (i=1; i<=TET_LINES; i = i + 1)
 463                 SetLine(i, 0);
 464         self.piece_pos = '0 0 0';
 465         self.piece_type = 0;
 466         self.next_piece = self.tet_lines = self.tet_score = 0;
 467
 468 };
 469
 470 void () Tet_GameOver =
 471 {
 472         centerprint(self, "Game Over");
 473         self.tetris_on = 0;
 474         ResetTetris();
 475         self.movetype = MOVETYPE_WALK;
 476 };
 477
 478
 479
 480 /*
 481 *********************************
 482
 483 Game Mechanics
 484
 485 *********************************
 486 */
 487 float() RandomPiece =
 488 {
 489         return floor(random() * PIECES) + 1;
 490 };
 491
 492 void(float n) TetAddScore =
 493 {
 494         self.tet_score = self.tet_score + n;
 495         if (self.tet_score > tet_high_score)
 496                 tet_high_score = self.tet_score;
 497 };
 498 float CheckMetrics(float piece, float orgx, float orgy, float rot) =
 499 {
 500         // check to see if the piece, if moved to the locations will overlap
 501
 502         float x, y;
 503         // why did I start counting from 1, damnit
 504         orgx = orgx - 1;
 505         orgy = orgy - 1;
 506
 507         for (y = 1; y < 5; y = y + 1)
 508         {
 509                 for (x = 1; x < 5; x = x + 1)
 510                 {
 511                         if (PieceMetric(x, y, rot, piece))
 512                         {
 513                                 if (GetSquare(x + orgx, y + orgy))
 514                                         return FALSE; // uhoh, gonna hit something.
 515                                 if (x+orgx<1 || x+orgx > TET_WIDTH || y+orgy<1 || y+orgy> TET_LINES)
 516                                         return FALSE; // ouside the level
 517                         }
 518                 }
 519         }
 520         return TRUE;
 521 }
 522
 523 void ClearPiece(float piece, float orgx, float orgy, float rot) =
 524 {
 525
 526         float x, y;
 527         // why did I start counting from 1, damnit
 528         orgx = orgx - 1;
 529         orgy = orgy - 1;
 530
 531         for (y = 1; y < 5; y = y + 1)
 532         {
 533                 for (x = 1; x < 5; x = x + 1)
 534                 {
 535                         if (PieceMetric(x, y, rot, piece))
 536                         {
 537                                 SetSquare(x + orgx, y + orgy, 0);
 538                         }
 539                 }
 540         }
 541 }
 542 void CementPiece(float piece, float orgx, float orgy, float rot) =
 543 {
 544         float color;
 545         float x, y;
 546         // why did I start counting from 1, damnit
 547         orgx = orgx - 1;
 548         orgy = orgy - 1;
 549
 550         color = piece & 3;
 551         if (color == 0) // 4
 552                 color = 1;
 553
 554         for (y = 1; y < 5; y = y + 1)
 555         {
 556                 for (x = 1; x < 5; x = x + 1)
 557                 {
 558                         if (PieceMetric(x, y, rot, piece))
 559                         {
 560                                 SetSquare(x + orgx, y + orgy, color);
 561                         }
 562                 }
 563         }
 564 }
 565
 566 float LINE_LOW = 349525;
 567 float LINE_HIGH = 699050; // above number times 2
 568
 569 void() CompletedLines =
 570 {
 571         float y, cleared, ln;
 572
 573         cleared = 0;
 574         y = TET_LINES;
 575         while(y >= 1)
 576         {
 577                 ln = GetLine(y);
 578                 if (((ln & LINE_LOW) | ((ln & LINE_HIGH)/2)) == LINE_LOW)
 579                         cleared = cleared + 1;
 580                 else
 581                         y = y - 1;
 582                 ln = GetLine(y - cleared);
 583                 SetLine(y, ln);
 584         }
 585         self.tet_lines = self.tet_lines + cleared;
 586         TetAddScore(cleared * cleared * 10);
 587 };
 588
 589 void(float keyss) HandleGame =
 590 {
 591
 592         // first off, we need to see if we need a new piece
 593         vector check_pos;
 594         float brand_new;
 595         brand_new = 0;
 596         if (self.tet_time > time)
 597                 return;
 598         self.tet_time = time + 0.1;
 599
 600
 601         if (self.piece_type == 0)
 602         {
 603                 self.piece_pos = '5 1 0'; // that's about middle top, we count from 1 ARGH
 604                 if (self.next_piece)
 605                         self.piece_type = self.next_piece;
 606                 else
 607                         self.piece_type = RandomPiece();
 608                 self.next_piece =  RandomPiece();
 609                 keyss = 0; // no movement first frame
 610                 self.tet_autodown = time + 0.2;
 611                 brand_new = 1;
 612         }
 613         else
 614                 ClearPiece(self.piece_type, self.piece_pos_x, self.piece_pos_y, self.piece_pos_z);
 615
 616         // next we need to check the piece metrics against what's on the level
 617         // based on the key order
 618
 619         check_pos = self.piece_pos;
 620
 621         if (keyss & TETKEY_RIGHT)
 622                 check_pos_x = check_pos_x + 1;
 623         else if (keyss & TETKEY_LEFT)
 624                 check_pos_x = check_pos_x - 1;
 625         else if (keyss & TETKEY_ROTRIGHT)
 626                 check_pos_z = check_pos_z + 1;
 627         else if (keyss & TETKEY_ROTLEFT)
 628                 check_pos_z = check_pos_z - 1;
 629         // bounds check
 630         if (check_pos_z > 3)
 631                 check_pos_z = 0;
 632         else if (check_pos_z < 0)
 633                 check_pos_z = 3;
 634
 635         // reality check
 636         if (CheckMetrics(self.piece_type, check_pos_x, check_pos_y, check_pos_z))
 637                 self.piece_pos = check_pos;
 638         else if (brand_new)
 639                 Tet_GameOver();
 640         check_pos = self.piece_pos;
 641         if (keyss & TETKEY_DOWN)
 642                 check_pos_y = check_pos_y + 1;
 643         else if (self.tet_autodown < time)
 644         {
 645                 check_pos_y = check_pos_y + 1;
 646                 self.tet_autodown = time + 1 / (floor(self.tet_lines / 20) + 1);
 647         }
 648         if (CheckMetrics(self.piece_type, check_pos_x, check_pos_y, check_pos_z))
 649                 self.piece_pos = check_pos;
 650         else
 651         {
 652                 CementPiece(self.piece_type, self.piece_pos_x, self.piece_pos_y, self.piece_pos_z);
 653                 TetAddScore(1);
 654                 CompletedLines();
 655                 self.piece_type = 0;
 656                 return;
 657         }
 658         CementPiece(self.piece_type, self.piece_pos_x, self.piece_pos_y, self.piece_pos_z);
 659 };
 660
 661 /*
 662 *********************************
 663
 664 Important Linking Into Quake stuff
 665
 666 *********************************
 667 */
 668
 669
 670 void(float imp) TetrisImpulses =
 671 {
 672         if (imp == 200)
 673         {
 674                 self.tetris_on = 1;
 675                 ResetTetris();
 676                 self.tet_org = self.origin;
 677                 self.movetype = MOVETYPE_NOCLIP;
 678                 stuffcmd(self, "cl_bob 0\ncl_rollangle 0\n");
 679         }
 680 };
 681
 682
 683 float() TetrisPreFrame =
 684 {
 685         if (!self.tetris_on)
 686                 return 0;
 687
 688         self.tet_org = self.origin;
 689         if (self.tet_time > time)
 690                 return 1;
 691         Draw_Tetris();
 692         return 1;
 693
 694 };
 695 float(float v) frik_anglemoda =
 696 {
 697         return v - floor(v/360) * 360;
 698 };
 699 float (float y1, float y2) angcompa =
 700 {
 701         y1 = frik_anglemoda(y1);
 702         y2 = frik_anglemoda(y2);
 703
 704         local float answer;
 705         answer = y1 - y2;
 706         if (answer > 180)
 707                 answer = answer - 360;
 708         else if (answer < -180)
 709                 answer = answer + 360;
 710         return answer;
 711 };
 712
 713
 714 float() TetrisPostFrame =
 715 {
 716         vector mov;
 717         float keysa, norm;
 718
 719         keysa = 0;
 720
 721         if (!self.tetris_on)
 722                 return 0;
 723         if (self.origin != self.tet_org)
 724         {
 725                 mov = vectoangles(self.origin - self.tet_org);
 726                 self.origin = self.tet_org;
 727
 728                 norm = angcompa(self.v_angle_y, mov_y);
 729
 730                 if (norm > -80 && norm < 80)
 731                         keysa = keysa | TETKEY_UP;
 732                 if (norm > 10 && norm < 170)
 733                         keysa = keysa | TETKEY_RIGHT;
 734                 if (norm > 100  || norm < -260)
 735                         keysa = keysa | TETKEY_DOWN;
 736                 if (norm > -170 && norm < -10)
 737                         keysa = keysa | TETKEY_LEFT;
 738         }
 739         if (self.button0)
 740                 keysa = keysa | TETKEY_ROTRIGHT;
 741         if (self.button2)
 742                 keysa = keysa | TETKEY_ROTLEFT;
 743         HandleGame(keysa);
 744         return 1;
 745 };
 746