data/qcsrc/server/g_hook.qc

   1 /*============================================
   2
   3       Wazat's Nexuiz Grappling Hook
   4
   5         Contact: Wazat1@gmail.com
   6
   7
   8 Installation instructions:
   9 --------------------------
  10
  11 1. Place hook.c in your gamec source directory with the other source files.
  12
  13 2. Add this line to the bottom of progs.src:
  14
  15 gamec/hook.c
  16
  17 3. Open defs.h and add these lines to the very bottom:
  18
  19 // Wazat's grappling hook
  20 .entity         hook;
  21 void GrapplingHookFrame();
  22 void RemoveGrapplingHook(entity pl);
  23 void SetGrappleHookBindings();
  24 // hook impulses
  25 float GRAPHOOK_FIRE             = 20;
  26 float GRAPHOOK_RELEASE          = 21;
  27 // (note: you can change the hook impulse #'s to whatever you please)
  28
  29 4. Open client.c and add this to the top of PutClientInServer():
  30
  31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
  32
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  34
  35         // Wazat's grappling hook
  36         SetGrappleHookBindings();
  37
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  39
  40         GrapplingHookFrame();
  41
  42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  43 bind ctrl "+hook"
  44
  45 And you should be done!
  46
  47
  48 ============================================*/
  49
  50 .string aiment_classname;
  51 .float aiment_deadflag;
  52 void SetMovetypeFollow(entity ent, entity e)
  53 {
  54         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
  55         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid
  56         ent.aiment = e; // make the hole follow bmodel
  57         ent.punchangle = e.angles; // the original angles of bmodel
  58         ent.view_ofs = ent.origin - e.origin; // relative origin
  59         ent.v_angle = ent.angles - e.angles; // relative angles
  60         ent.aiment_classname = strzone(e.classname);
  61         ent.aiment_deadflag = e.deadflag;
  62 }
  63 void UnsetMovetypeFollow(entity ent)
  64 {
  65         ent.movetype = MOVETYPE_FLY;
  66         ent.solid = SOLID_BBOX;
  67         ent.aiment = world;
  68 }
  69 float LostMovetypeFollow(entity ent)
  70 {
  71         if(ent.aiment)
  72         {
  73                 if(ent.aiment.classname != ent.aiment_classname)
  74                         return 1;
  75                 if(ent.aiment.deadflag != ent.aiment_deadflag)
  76                         return 1;
  77         }
  78         return 0;
  79 }
  80
  81 .float rope_length;
  82 .float button6_pressed_before;
  83
  84 void RemoveGrapplingHook(entity pl)
  85 {
  86         if(pl.hook == world)
  87                 return;
  88         remove(pl.hook);
  89         pl.hook = world;
  90         if(pl.movetype == MOVETYPE_FLY)
  91                 pl.movetype = MOVETYPE_WALK;
  92
  93         pl.hook_time = time + 0.0;
  94
  95         //pl.disableclientprediction = FALSE;
  96 }
  97
  98 void GrapplingHookThink();
  99 void GrapplingHook_Stop()
 100 {
 101         pointparticles(particleeffectnum("grapple_impact"), self.origin, '0 0 0', 1);
 102         sound (self, CHAN_PROJECTILE, "weapons/hook_impact.wav", VOL_BASE, ATTN_NORM);
 103
 104         self.state = 1;
 105         self.think = GrapplingHookThink;
 106         self.nextthink = time;
 107         self.touch = SUB_Null;
 108         self.velocity = '0 0 0';
 109         self.movetype = MOVETYPE_NONE;
 110         self.rope_length = -1;
 111 }
 112
 113 void GrapplingHookThink()
 114 {
 115         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
 116         vector dir, org, end, v0, dv;
 117         if(self.owner.health <= 0 || self.owner.hook != self)   // how did that happen?
 118         {                                                                                                               // well, better fix it anyway
 119                 remove(self);
 120                 return;
 121         }
 122         if(LostMovetypeFollow(self))
 123         {
 124                 RemoveGrapplingHook(self.owner);
 125                 return;
 126         }
 127
 128         self.nextthink = time;
 129
 130         makevectors(self.owner.v_angle);
 131         org = self.owner.origin + self.owner.view_ofs + v_forward * 8 - v_right * 8 + v_up * -12;
 132
 133         tracebox(org, self.mins, self.maxs, self.origin, MOVE_NOMONSTERS, self.owner);
 134         // do not hit players with this, as they tend to get in the way just too often
 135         // NOTE: this assumes sky brushes cannot get in the way
 136         // if they can, assume the map is broken! :P
 137         if(trace_fraction < 1 && (!self.aiment || trace_ent != self.aiment))
 138         {
 139                 // 0. stop it
 140                 if(self.state != 1)
 141                         GrapplingHook_Stop();
 142
 143                 // 1. detach the hook
 144                 if(self.aiment)
 145                         UnsetMovetypeFollow(self);
 146
 147                 // 2. cut it off
 148                 self.origin = trace_endpos;
 149
 150                 // 3. reattach the hook
 151                 if(trace_ent)
 152                         if(trace_ent.movetype != MOVETYPE_NONE)
 153                                 SetMovetypeFollow(self, trace_ent);
 154         }
 155
 156         if(self.rope_length < 0)
 157                 self.rope_length = vlen(org - self.origin);
 158
 159         if(self.state == 1)
 160         {
 161                 pullspeed = cvar("g_balance_grapplehook_speed_pull");//2000;
 162                 // speed the rope is pulled with
 163
 164                 rubberforce = cvar("g_balance_grapplehook_force_rubber");//2000;
 165                 // force the rope will use if it is stretched
 166
 167                 rubberforce_overstretch = cvar("g_balance_grapplehook_force_rubber_overstretch");//1000;
 168                 // force the rope will use if it is stretched
 169
 170                 minlength = cvar("g_balance_grapplehook_length_min");//100;
 171                 // minimal rope length
 172                 // if the rope goes below this length, it isn't pulled any more
 173
 174                 ropestretch = cvar("g_balance_grapplehook_stretch");//400;
 175                 // if the rope is stretched by more than this amount, more rope is
 176                 // given to you again
 177
 178                 ropeairfriction = cvar("g_balance_grapplehook_airfriction");//0.2
 179                 // while hanging on the rope, this friction component will help you a
 180                 // bit to control the rope
 181
 182                 dir = self.origin - org;
 183                 dist = vlen(dir);
 184                 dir = normalize(dir);
 185
 186                 if(cvar("g_grappling_hook_tarzan"))
 187                 {
 188                         newlength = self.rope_length;
 189                         v0 = self.owner.velocity;
 190
 191                         // first pull the rope...
 192                         newlength = max(newlength - pullspeed * frametime, minlength);
 193
 194                         if(newlength < dist - ropestretch) // overstretched?
 195                         {
 196                                 newlength = dist - ropestretch;
 197                                 if(self.owner.velocity * dir < 0) // only if not already moving in hook direction
 198                                         self.owner.velocity = self.owner.velocity + frametime * dir * rubberforce_overstretch;
 199                         }
 200
 201                         if(!self.owner.BUTTON_CROUCH) // crouch key = don't pull
 202                                 self.rope_length = newlength;
 203
 204                         // then pull the player
 205                         spd = bound(0, (dist - self.rope_length) / ropestretch, 1);
 206                         self.owner.velocity = self.owner.velocity * (1 - frametime * ropeairfriction);
 207                         self.owner.velocity = self.owner.velocity + frametime * dir * spd * rubberforce;
 208
 209                         dv = ((self.owner.velocity - v0) * dir) * dir;
 210                         if(cvar("g_grappling_hook_tarzan") >= 2)
 211                         {
 212                                 if(self.aiment.movetype == MOVETYPE_WALK || self.aiment.movetype == MOVETYPE_TOSS)
 213                                 {
 214                                         self.owner.velocity = self.owner.velocity - dv * 0.5;
 215                                         self.aiment.velocity = self.aiment.velocity - dv * 0.5;
 216                                         self.aiment.flags = self.aiment.flags - (self.aiment.flags & FL_ONGROUND);
 217                                         self.aiment.pusher = self.owner;
 218                                         self.aiment.pushltime = time + cvar("g_maxpushtime");
 219                                 }
 220                         }
 221                 }
 222                 else
 223                 {
 224                         end = self.origin - dir*50;
 225                         dist = vlen(end - org);
 226                         if(dist < 200)
 227                                 spd = dist * (pullspeed / 200);
 228                         else
 229                                 spd = pullspeed;
 230                         if(spd < 50)
 231                                 spd = 0;
 232                         self.owner.velocity = dir*spd;
 233                         self.owner.movetype = MOVETYPE_FLY;
 234                 }
 235
 236                 self.owner.flags = self.owner.flags - (self.owner.flags & FL_ONGROUND);
 237
 238                 org = org + dir*50; // get the beam out of the player's eyes
 239         }
 240
 241         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 242         te_beam(self.owner, self.origin + v_forward * (-9), org);
 243 }
 244
 245 void GrapplingHookTouch (void)
 246 {
 247         if (other == self.owner)
 248                 return;
 249         // altered for Nexuiz
 250         //else if (pointcontents (self.origin) == CONTENT_SKY)
 251         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 252         {
 253                 RemoveGrapplingHook(self.owner);
 254                 return;
 255         }
 256
 257         if(other == world)
 258         {
 259                 vector tic;
 260                 tic = self.velocity * sys_ticrate;
 261                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
 262                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
 263                 if(trace_fraction >= 1)
 264                 {
 265                         dprint("Odd... did not hit...?\n");
 266                 }
 267                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 268                 {
 269                         dprint("Detected and prevented the sky-grapple bug.\n");
 270                         RemoveGrapplingHook(self.owner);
 271                         return;
 272                 }
 273         }
 274
 275         if(other)
 276                 if(other.movetype != MOVETYPE_NONE)
 277                         SetMovetypeFollow(self, other);
 278
 279         GrapplingHook_Stop();
 280         //self.owner.disableclientprediction = TRUE;
 281 }
 282
 283 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 284 {
 285         if(self.health > 0)
 286         {
 287                 self.health = self.health - damage;
 288                 if (self.health <= 0)
 289                 {
 290                         if(attacker != self.owner)
 291                         {
 292                                 self.owner.pusher = attacker;
 293                                 self.owner.pushltime = time + cvar("g_maxpushtime");
 294                         }
 295                         RemoveGrapplingHook(self.owner);
 296                 }
 297         }
 298 }
 299
 300 void FireGrapplingHook (void)
 301 {
 302         local entity missile;
 303         local vector org;
 304
 305         if((arena_roundbased && time < warmup) || (time < restart_countdown))
 306                 return;
 307
 308         makevectors(self.v_angle);
 309
 310         sound (self, CHAN_WEAPON, "weapons/hook_fire.wav", VOL_BASE, ATTN_NORM);
 311         org = self.origin + self.view_ofs + v_forward * 8 - v_right * 8 + '0 0 -12';
 312         pointparticles(particleeffectnum("grapple_muzzleflash"), org, '0 0 0', 1);
 313
 314         missile = spawn ();
 315         missile.owner = self;
 316         self.hook = missile;
 317         missile.classname = "grapplinghook";
 318
 319         missile.movetype = MOVETYPE_FLY;
 320         missile.solid = SOLID_BBOX;
 321
 322         setmodel (missile, "models/hook.md3"); // precision set below
 323         setsize (missile, '-3 -3 -3', '3 3 3');
 324         setorigin (missile, org);
 325
 326         missile.state = 0; // not latched onto anything
 327
 328         missile.velocity = v_forward * cvar("g_balance_grapplehook_speed_fly");
 329         W_SetupProjectileVelocity(missile);
 330
 331         missile.angles = vectoangles (missile.velocity);
 332         //missile.glow_color = 250; // 244, 250
 333         //missile.glow_size = 120;
 334         missile.touch = GrapplingHookTouch;
 335         missile.think = GrapplingHookThink;
 336         missile.nextthink = time + 0.1;
 337
 338         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
 339
 340         missile.health = cvar("g_balance_grapplehook_health");//120
 341         missile.event_damage = GrapplingHook_Damage;
 342         missile.takedamage = DAMAGE_AIM;
 343         missile.damageforcescale = 0;
 344 }
 345
 346 void GrapplingHookFrame()
 347 {
 348         // this function has been modified for Nexuiz
 349         if (self.BUTTON_HOOK && g_grappling_hook)
 350         {
 351                 if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
 352                         if (timeoutStatus != 2) //only allow the player to fire the grappling hook if the game is not paused (timeout)
 353                                 FireGrapplingHook();
 354         }
 355         else
 356         {
 357                 if (self.hook)
 358                         RemoveGrapplingHook(self);
 359         }
 360         self.button6_pressed_before = self.BUTTON_HOOK;
 361         /*
 362         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 363         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 364         {
 365                 self.movetype = MOVETYPE_WALK;
 366         }
 367         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && g_grappling_hook)
 368         {
 369                 // fire hook
 370                 FireGrapplingHook();
 371                 return;
 372         }
 373         else if(self.hookimpulse == GRAPHOOK_RELEASE)
 374         {
 375                 // remove hook, reset movement type
 376                 RemoveGrapplingHook(self);
 377                 return;
 378         }
 379         */
 380         /*else // make sure the player's movetype is correct
 381         {
 382                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
 383                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 384                 {
 385                         self.movetype = MOVETYPE_WALK;
 386                 }
 387         }*/
 388         // note: The hook entity does the actual pulling
 389 }
 390
 391 void SetGrappleHookBindings()
 392 {
 393         // this function has been modified for Nexuiz
 394         // don't remove these lines! old server or demos coud overwrite the new aliases
 395         stuffcmd(self, "alias +hook +button6\n");
 396         stuffcmd(self, "alias -hook -button6\n");
 397 }