centerprints now are managed independently per line
[divverent/nexuiz.git] / data / qcsrc / server / g_hook.qc
1 /*============================================
2
3       Wazat's Nexuiz Grappling Hook
4
5         Contact: Wazat1@gmail.com
6
7
8 Installation instructions:
9 --------------------------
10
11 1. Place hook.c in your gamec source directory with the other source files.
12
13 2. Add this line to the bottom of progs.src:
14
15 gamec/hook.c
16
17 3. Open defs.h and add these lines to the very bottom:
18
19 // Wazat's grappling hook
20 .entity         hook;
21 void GrapplingHookFrame();
22 void RemoveGrapplingHook(entity pl);
23 void SetGrappleHookBindings();
24 // hook impulses
25 float GRAPHOOK_FIRE             = 20;
26 float GRAPHOOK_RELEASE          = 21;
27 // (note: you can change the hook impulse #'s to whatever you please)
28
29 4. Open client.c and add this to the top of PutClientInServer():
30
31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
32
33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
34
35         // Wazat's grappling hook
36         SetGrappleHookBindings();
37
38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
39
40         GrapplingHookFrame();
41
42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
43 bind ctrl "+hook"
44
45 And you should be done!
46
47
48 ============================================*/
49
50 .float rope_length;
51 .float button6_pressed_before;
52
53 void RemoveGrapplingHook(entity pl)
54 {
55         if(pl.hook == world)
56                 return;
57         remove(pl.hook);
58         pl.hook = world;
59         if(pl.movetype == MOVETYPE_FLY)
60                 pl.movetype = MOVETYPE_WALK;
61
62         pl.hook_time = time + 0.0;
63 }
64
65 void GrapplingHookThink()
66 {
67         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
68         vector dir, org, end;
69         if(self.owner.health <= 0 || self.owner.hook != self)   // how did that happen?
70         {                                                                                                               // well, better fix it anyway
71                 remove(self);
72                 return;
73         }
74
75         self.nextthink = time + 0.1;
76
77         makevectors(self.owner.v_angle);
78         org = self.owner.origin + self.owner.view_ofs + v_forward * 15 - v_right * 5 + v_up * -12;
79
80         if(self.rope_length < 0)
81                 self.rope_length = vlen(org - self.origin);
82
83         if(self.state == 1)
84         {
85                 pullspeed = cvar("g_balance_grapplehook_speed_pull");//2000;
86                 // speed the rope is pulled with
87
88                 rubberforce = cvar("g_balance_grapplehook_force_rubber");//2000;
89                 // force the rope will use if it is stretched
90
91                 rubberforce_overstretch = cvar("g_balance_grapplehook_force_rubber_overstretch");//1000;
92                 // force the rope will use if it is stretched
93
94                 minlength = cvar("g_balance_grapplehook_length_min");//100;
95                 // minimal rope length
96                 // if the rope goes below this length, it isn't pulled any more
97
98                 ropestretch = cvar("g_balance_grapplehook_stretch");//400;
99                 // if the rope is stretched by more than this amount, more rope is
100                 // given to you again
101
102                 ropeairfriction = cvar("g_balance_grapplehook_airfriction");//0.2
103                 // while hanging on the rope, this friction component will help you a
104                 // bit to control the rope
105
106                 dir = self.origin - org;
107                 dist = vlen(dir);
108                 dir = normalize(dir);
109
110                 if(cvar("g_grappling_hook_tarzan"))
111                 {
112                         newlength = self.rope_length;
113
114                         // first pull the rope...
115                         newlength = max(newlength - pullspeed * 0.1, minlength);
116
117                         if(newlength < dist - ropestretch) // overstretched?
118                         {
119                                 newlength = dist - ropestretch;
120                                 if(self.owner.velocity * dir < 0) // only if not already moving in hook direction
121                                         self.owner.velocity = self.owner.velocity + 0.1 * dir * rubberforce_overstretch;
122                         }
123
124                         if(!self.owner.button5) // crouch key = don't pull
125                                 self.rope_length = newlength;
126
127                         // then pull the player
128                         spd = bound(0, (dist - self.rope_length) / ropestretch, 1);
129                         self.owner.velocity = self.owner.velocity * (1 - 0.1 * ropeairfriction);
130                         self.owner.velocity = self.owner.velocity + 0.1 * dir * spd * rubberforce;
131                 }
132                 else
133                 {
134                         end = self.origin - dir*50;
135                         dist = vlen(end - org);
136                         if(dist < 200)
137                                 spd = dist * (pullspeed / 200);
138                         else
139                                 spd = pullspeed;
140                         if(spd < 50)
141                                 spd = 0;
142                         self.owner.velocity = dir*spd;
143                         self.owner.movetype = MOVETYPE_FLY;
144                 }
145
146                 self.owner.flags = self.owner.flags - (self.owner.flags & FL_ONGROUND);
147
148                 org = org + dir*50; // get the beam out of the player's eyes
149         }
150
151         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
152         WriteByte (MSG_BROADCAST, TE_BEAM);
153         WriteEntity (MSG_BROADCAST, self);
154         WriteCoord (MSG_BROADCAST, self.origin_x);
155         WriteCoord (MSG_BROADCAST, self.origin_y);
156         WriteCoord (MSG_BROADCAST, self.origin_z);
157         WriteCoord (MSG_BROADCAST, org_x);
158         WriteCoord (MSG_BROADCAST, org_y);
159         WriteCoord (MSG_BROADCAST, org_z);
160 }
161
162 void GrapplingHookTouch (void)
163 {
164         if (other == self.owner)
165                 return;
166         // altered for Nexuiz
167         //else if (pointcontents (self.origin) == CONTENT_SKY)
168         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
169         {
170                 RemoveGrapplingHook(self.owner);
171                 return;
172         }
173
174         sound (self, CHAN_BODY, "weapons/hook_impact.ogg", 1, ATTN_NORM);
175
176         self.state = 1;
177         self.think = GrapplingHookThink;
178         self.nextthink = time + 0.1;
179         self.touch = SUB_Null;
180         self.velocity = '0 0 0';
181         self.movetype = MOVETYPE_NONE;
182         self.rope_length = -1;
183 }
184
185 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
186 {
187         if(self.health > 0)
188         {
189                 self.health = self.health - damage;
190                 if (self.health <= 0)
191                 {
192                         if(attacker != self.owner)
193                         {
194                                 self.owner.pusher = attacker;
195                                 self.owner.pushltime = time + cvar("g_maxpushtime");
196                         }
197                         RemoveGrapplingHook(self.owner);
198                 }
199         }
200 }
201
202 void FireGrapplingHook (void)
203 {
204         local entity missile;
205         local vector org;
206
207         if(arena_roundbased)
208         if(time < warmup)
209                 return;
210
211         makevectors(self.v_angle);
212
213         sound (self, CHAN_WEAPON, "weapons/hook_fire.ogg", 1, ATTN_NORM);
214         org = self.origin + self.view_ofs + v_forward * 15 - v_right * 5 + v_up * -12;
215         te_customflash(org, 160, 0.2, '1 0 0');
216
217         missile = spawn ();
218         missile.owner = self;
219         self.hook = missile;
220         missile.classname = "grapplinghook";
221
222         missile.movetype = MOVETYPE_FLY;
223         missile.solid = SOLID_BBOX;
224
225         setmodel (missile, "models/ebomb.mdl"); // replace by something CENTERED!
226         setsize (missile, '-3 -3 -3', '3 3 3');
227         setorigin (missile, org);
228
229         missile.state = 0; // not latched onto anything
230
231         missile.velocity = v_forward * cvar("g_balance_grapplehook_speed_fly");
232         missile.angles = vectoangles (missile.velocity);
233         //missile.glow_color = 250; // 244, 250
234         //missile.glow_size = 120;
235         missile.touch = GrapplingHookTouch;
236         missile.think = GrapplingHookThink;
237         missile.nextthink = time + 0.1;
238
239         missile.effects = EF_FULLBRIGHT | EF_ADDITIVE | EF_LOWPRECISION;
240
241         missile.health = cvar("g_balance_grapplehook_health");//120
242         missile.event_damage = GrapplingHook_Damage;
243         missile.takedamage = DAMAGE_AIM;
244         missile.damageforcescale = 0;
245 }
246
247 void GrapplingHookFrame()
248 {
249         // this function has been modified for Nexuiz
250         if (self.button6 && cvar("g_grappling_hook"))
251         {
252                 if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
253                         FireGrapplingHook();
254         }
255         else
256         {
257                 if (self.hook)
258                         RemoveGrapplingHook(self);
259         }
260         self.button6_pressed_before = self.button6;
261         /*
262         // if I have no hook or it's not pulling yet, make sure I'm not flying!
263         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
264         {
265                 self.movetype = MOVETYPE_WALK;
266         }
267         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && cvar("g_grappling_hook"))
268         {
269                 // fire hook
270                 FireGrapplingHook();
271                 return;
272         }
273         else if(self.hookimpulse == GRAPHOOK_RELEASE)
274         {
275                 // remove hook, reset movement type
276                 RemoveGrapplingHook(self);
277                 return;
278         }
279         */
280         /*else // make sure the player's movetype is correct
281         {
282                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
283                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
284                 {
285                         self.movetype = MOVETYPE_WALK;
286                 }
287         }*/
288         // note: The hook entity does the actual pulling
289 }
290
291 void SetGrappleHookBindings()
292 {
293         // this function has been modified for Nexuiz
294         // don't remove these lines! old server or demos coud overwrite the new aliases
295         stuffcmd(self, "alias +hook +button6\n");
296         stuffcmd(self, "alias -hook -button6\n");
297 }