hook: apply the hook bomb damage over time (FIXME check if this may cause too much...
[divverent/nexuiz.git] / data / qcsrc / server / g_damage.qc
1 float checkrules_firstblood;
2
3 float yoda;
4 float damage_goodhits;
5 float damage_gooddamage;
6 float headshot;
7
8 .float teamkill_complain;
9 .float teamkill_soundtime;
10 .entity teamkill_soundsource;
11 .entity pusher;
12
13
14 float IsDifferentTeam(entity a, entity b)
15 {
16         if(teams_matter)
17         {
18                 if(a.team == b.team)
19                         return 0;
20         }
21         else
22         {
23                 if(a == b)
24                         return 0;
25         }
26         return 1;
27 }
28
29 float IsFlying(entity a)
30 {
31         if(a.flags & FL_ONGROUND)
32                 return 0;
33         if(a.waterlevel >= 2)
34                 return 0;
35         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
36         if(trace_fraction < 1)
37                 return 0;
38         return 1;
39 }
40
41 void UpdateFrags(entity player, float f)
42 {
43         PlayerTeamScore_AddScore(player, f);
44 }
45
46 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
47 void GiveFrags (entity attacker, entity targ, float f)
48 {
49         // TODO route through PlayerScores instead
50         if(gameover) return;
51
52         if(f < 0)
53         {
54                 if(targ == attacker)
55                 {
56                         // suicide
57                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
58                 }
59                 else
60                 {
61                         // teamkill
62                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
63                 }
64         }
65         else
66         {
67                 // regular frag
68                 PlayerScore_Add(attacker, SP_KILLS, 1);
69         }
70
71         PlayerScore_Add(targ, SP_DEATHS, 1);
72
73         if(g_arena)
74                 if(cvar("g_arena_roundbased"))
75                         return;
76
77         // FIXME fix the mess this is (we have REAL points now!)
78         if(g_runematch)
79         {
80                 f = RunematchHandleFrags(attacker, targ, f);
81         }
82         else if(g_keyhunt)
83         {
84                 f = kh_HandleFrags(attacker, targ, f);
85         }
86         else if(g_lms)
87         {
88                 // remove a life
89                 float tl;
90                 tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
91                 if(tl < lms_lowest_lives)
92                         lms_lowest_lives = tl;
93                 if(tl <= 0)
94                 {
95                         if(!lms_next_place)
96                                 lms_next_place = player_count;
97                         PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
98                         --lms_next_place;
99                 }
100                 f = 0;
101         }
102         else if(g_ctf)
103         {
104                 if(g_ctf_ignore_frags)
105                         f = 0;
106         }
107
108         attacker.totalfrags += f;
109
110         if(f)
111                 UpdateFrags(attacker, f);
112 }
113
114 string AppendItemcodes(string s, entity player)
115 {
116         float w;
117         w = player.weapon;
118         //if(w == 0)
119         //      w = player.switchweapon;
120         if(w == 0)
121                 w = player.cnt; // previous weapon!
122         s = strcat(s, ftos(w));
123         if(time < player.strength_finished)
124                 s = strcat(s, "S");
125         if(time < player.invincible_finished)
126                 s = strcat(s, "I");
127         if(player.flagcarried != world)
128                 s = strcat(s, "F");
129         if(player.BUTTON_CHAT)
130                 s = strcat(s, "T");
131         if(player.kh_next)
132                 s = strcat(s, "K");
133         if(player.runes)
134                 s = strcat(s, "|", ftos(player.runes));
135         return s;
136 }
137
138 void LogDeath(string mode, float deathtype, entity killer, entity killed)
139 {
140         string s;
141         if(!cvar("sv_eventlog"))
142                 return;
143         s = strcat(":kill:", mode);
144         s = strcat(s, ":", ftos(killer.playerid));
145         s = strcat(s, ":", ftos(killed.playerid));
146         s = strcat(s, ":type=", ftos(deathtype));
147         s = strcat(s, ":items=");
148         s = AppendItemcodes(s, killer);
149         if(killed != killer)
150         {
151                 s = strcat(s, ":victimitems=");
152                 s = AppendItemcodes(s, killed);
153         }
154         GameLogEcho(s);
155 }
156
157 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
158 {
159         string  s, a;
160         float p, w;
161
162         if (targ.classname == "player" || targ.classname == "corpse")
163         {
164                 if (targ.classname == "corpse")
165                         s = "A corpse";
166                 else
167                         s = targ.netname;
168                 a = attacker.netname;
169
170                 if (targ == attacker)
171                 {
172                         if (deathtype == DEATH_TEAMCHANGE) {
173                                 centerprint(targ, strcat("You are now on: ", ColoredTeamName(targ.team)));
174                         } else if (deathtype == DEATH_AUTOTEAMCHANGE) {
175                                 centerprint(targ, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(targ.team)));
176                                 return;
177                         } else if (deathtype == DEATH_CAMP) {
178                                 if(sv_gentle)
179                                         centerprint(targ, "^1Reconsider your tactics, camper!\n\n\n");
180                                 else
181                                         centerprint(targ, "^1Die camper!\n\n\n");
182                         } else if (deathtype == DEATH_NOAMMO) {
183                                 if(sv_gentle)
184                                         centerprint(targ, "^1You are reinserted into the game for running out of ammo...\n\n\n");
185                                 else
186                                         centerprint(targ, "^1You were killed for running out of ammo...\n\n\n");
187                         } else if (deathtype == DEATH_ROT) {
188                                 if(sv_gentle)
189                                         centerprint(targ, "^1You need to preserve your health\n\n\n");
190                                 else
191                                         centerprint(targ, "^1You grew too old without taking your medicine\n\n\n");
192                         } else if (deathtype == DEATH_MIRRORDAMAGE) {
193                                 if(sv_gentle)
194                                         centerprint(targ, "^1Don't go against team mates!\n\n\n");
195                                 else
196                                         centerprint(targ, "^1Don't shoot your team mates!\n\n\n");
197                         } else {
198                                 if(sv_gentle)
199                                         centerprint(targ, "^1You need to be more careful!\n\n\n");
200                                 else
201                                         centerprint(targ, "^1You killed your own dumb self!\n\n\n");
202                         }
203
204                         if(sv_gentle) {
205                                 if (deathtype == DEATH_CAMP)
206                                         bprint ("^1",s, "^1 thought he found a nice camping ground\n");
207                                 else if (deathtype == DEATH_MIRRORDAMAGE)
208                                         bprint ("^1",s, "^1 didn't become friends with the Lord of Teamplay\n");
209                                 else
210                                         bprint ("^1",s, "^1 will be reinserted into the game due to his own actions\n");
211
212                                 if(deathtype != DEATH_TEAMCHANGE)
213                                 {
214                                         LogDeath("suicide", deathtype, targ, targ);
215                                         GiveFrags(attacker, targ, -1);
216                                 }
217                                 if (targ.killcount > 2)
218                                         bprint ("^1",s,"^1 ended it all with a ",ftos(targ.killcount)," scoring spree\n");
219                         } else {
220                                 w = DEATH_WEAPONOF(deathtype);
221                                 if(WEP_VALID(w))
222                                 {
223                                         w_deathtypestring = "couldn't resist the urge to self-destruct";
224                                         w_deathtype = deathtype;
225                                         weapon_action(w, WR_SUICIDEMESSAGE);
226                                         bprint("^1", s, "^1 ", w_deathtypestring, "\n");
227                                 }
228                                 else if (deathtype == DEATH_KILL)
229                                         bprint ("^1",s, "^1 couldn't take it anymore\n");
230                                 else if (deathtype == DEATH_ROT)
231                                         bprint ("^1",s, "^1 died\n");
232                                 else if (deathtype == DEATH_NOAMMO)
233                                 {
234                                         bprint ("^7",s, " ^7committed suicide. What's the point of living without ammo?\n");
235                                 }
236                                 else if (deathtype == DEATH_CAMP)
237                                         bprint ("^1",s, "^1 thought he found a nice camping ground\n");
238                                 else if (deathtype == DEATH_MIRRORDAMAGE)
239                                         bprint ("^1",s, "^1 didn't become friends with the Lord of Teamplay\n");
240                                 else if (deathtype != DEATH_TEAMCHANGE)
241                                         bprint ("^1",s, "^1 couldn't resist the urge to self-destruct\n");
242
243                                 if(deathtype != DEATH_TEAMCHANGE)
244                                 {
245                                         LogDeath("suicide", deathtype, targ, targ);
246                                         GiveFrags(attacker, targ, -1);
247                                 }
248                                 if (targ.killcount > 2)
249                                         bprint ("^1",s,"^1 ended it all with a ",ftos(targ.killcount)," kill spree\n");
250                         }
251                 }
252                 else if (attacker.classname == "player" || attacker.classname == "gib")
253                 {
254                         if(teamplay && attacker.team == targ.team)
255                         {
256                                 if(sv_gentle) {
257                                         centerprint(attacker, "^1Moron! You went against a teammate!\n\n\n");
258                                         bprint ("^1", a, "^1 took action against a teammate\n");
259                                 } else {
260                                         centerprint(attacker, "^1Moron! You fragged a teammate!\n\n\n");
261                                         bprint ("^1", a, "^1 mows down a teammate\n");
262                                 }
263                                 GiveFrags(attacker, targ, -1);
264                                 if (targ.killcount > 2) {
265                                         if(sv_gentle)
266                                                 bprint ("^1",s,"'s ^1",ftos(targ.killcount)," scoring spree was ended by a teammate!\n");
267                                         else
268                                                 bprint ("^1",s,"'s ^1",ftos(targ.killcount)," kill spree was ended by a teammate!\n");
269                                 }
270                                 if (attacker.killcount > 2) {
271                                         if(sv_gentle)
272                                                 bprint ("^1",a,"^1 ended a ",ftos(attacker.killcount)," scoring spree by going against a teammate\n");
273                                         else
274                                                 bprint ("^1",a,"^1 ended a ",ftos(attacker.killcount)," kill spree by killing a teammate\n");
275                                 }
276                                 attacker.killcount = 0;
277
278                                 LogDeath("tk", deathtype, attacker, targ);
279                         }
280                         else
281                         {
282                                 if (!checkrules_firstblood)
283                                 {
284                                         checkrules_firstblood = TRUE;
285                                         if(sv_gentle)
286                                                 bprint("^1",a, "^1 was the first to score", "\n");
287                                         else
288                                                 bprint("^1",a, "^1 drew first blood", "\n");
289                                 }
290
291                                 if(sv_gentle > 0) {
292                                         centerprint(attacker, strcat("^4You scored against ^7", s, "\n\n\n"));
293                                         centerprint(targ, strcat(a,"^1 scored against you ^7\n\n\n"));
294                                 } else {
295                                         centerprint(attacker, strcat("^4You fragged ^7", s, "\n\n\n"));
296                                         centerprint(targ, strcat("^1You were fragged by ^7", a, "\n\n\n"));
297                                 }
298
299                                 if(sv_gentle) {
300                                         bprint ("^1",s, "^1 needs a restart thanks to ", a, "\n");
301                                 } else {
302                                         w = DEATH_WEAPONOF(deathtype);
303                                         if(WEP_VALID(w))
304                                         {
305                                                 w_deathtypestring = "was blasted by";
306                                                 w_deathtype = deathtype;
307                                                 weapon_action(w, WR_KILLMESSAGE);
308                                                 p = strstrofs(w_deathtypestring, "#", 0);
309                                                 if(p < 0)
310                                                         bprint("^1", s, "^1 ", w_deathtypestring, " ", a, "\n");
311                                                 else
312                                                         bprint("^1", s, "^1 ", substring(w_deathtypestring, 0, p), a, "^1", substring(w_deathtypestring, p+1, strlen(w_deathtypestring) - (p+1)), "\n");
313                                         }
314                                         else if (deathtype == DEATH_TELEFRAG)
315                                                 bprint ("^1",s, "^1 was telefragged by ", a, "\n");
316                                         else if (deathtype == DEATH_DROWN)
317                                                 bprint ("^1",s, "^1 was drowned by ", a, "\n");
318                                         else if (deathtype == DEATH_SLIME)
319                                                 bprint ("^1",s, "^1 was slimed by ", a, "\n");
320                                         else if (deathtype == DEATH_LAVA)
321                                                 bprint ("^1",s, "^1 was cooked by ", a, "\n");
322                                         else if (deathtype == DEATH_FALL)
323                                                 bprint ("^1",s, "^1 was grounded by ", a, "\n");
324                                         else if (deathtype == DEATH_SHOOTING_STAR)
325                                                 bprint ("^1",s, "^1 was shot into space by ", a, "\n");
326                                         else if (deathtype == DEATH_SWAMP)
327                                                 bprint ("^1",s, "^1 was conserved by ", a, "\n");
328                                         else if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
329                                         {
330                                                 p = strstrofs(inflictor.message2, "#", 0);
331                                                 if(p < 0)
332                                                         bprint("^1", s, "^1 ", inflictor.message2, " ", a, "\n");
333                                                 else
334                                                         bprint("^1", s, "^1 ", substring(inflictor.message2, 0, p), a, "^1", substring(inflictor.message2, p+1, strlen(inflictor.message2) - (p+1)), "\n");
335                                         }
336                     else if(deathtype == DEATH_TURRET)
337                         bprint ("^1",s, "^1 was pushed into the line of fire by ^1", a, "\n");
338                     else if(deathtype == DEATH_TOUCHEXPLODE)
339                         bprint ("^1",s, "^1 was pushed into an accident by ^1", a, "\n");
340                                         else
341                                                 bprint ("^1",s, "^1 was fragged by ", a, "\n");
342                                 }
343                                 if(g_ctf && targ.flagcarried)
344                                 {
345                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
346                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
347                                         GiveFrags(attacker, targ, 0); // for logging
348                                 }
349                                 else
350                                         GiveFrags(attacker, targ, 1);
351                                 if (targ.killcount > 2) {
352                                         if(sv_gentle)
353                                                 bprint ("^1",s,"'s ^1", ftos(targ.killcount), " scoring spree was ended by ", a, "\n");
354                                         else
355                                                 bprint ("^1",s,"'s ^1", ftos(targ.killcount), " kill spree was ended by ", a, "\n");
356                                 }
357                                 attacker.killcount = attacker.killcount + 1;
358                                 if (attacker.killcount > 2) {
359                                         if(sv_gentle)
360                                                 bprint ("^1",a,"^1 made ",ftos(attacker.killcount)," scores in a row\n");
361                                         else
362                                                 bprint ("^1",a,"^1 has ",ftos(attacker.killcount)," frags in a row\n");
363                                 }
364
365                                 LogDeath("frag", deathtype, attacker, targ);
366
367                                 if (attacker.killcount == 3)
368                                 {
369                                         if(sv_gentle) {
370                                                 bprint (a,"^7 made a ^1TRIPLE SCORE\n");
371                                         } else {
372                                                 bprint (a,"^7 made a ^1TRIPLE FRAG\n");
373                                                 announce(attacker, "announcer/male/03kills.wav");
374                                         }
375                                 }
376                                 else if (attacker.killcount == 5)
377                                 {
378                                         if(sv_gentle) {
379                                                 bprint (a,"^7 unleashes ^1SCORING RAGE\n");
380                                         } else {
381                                                 bprint (a,"^7 unleashes ^1RAGE\n");
382                                                 announce(attacker, "announcer/male/05kills.wav");
383                                         }
384                                 }
385                                 else if (attacker.killcount == 10)
386                                 {
387                                         if(sv_gentle) {
388                                                 bprint (a,"^7 made ^1TEN SCORES IN A ROW!\n");
389                                         } else {
390                                                 bprint (a,"^7 starts the ^1MASSACRE!\n");
391                                                 announce(attacker, "announcer/male/10kills.wav");
392                                         }
393                                 }
394                                 else if (attacker.killcount == 15)
395                                 {
396                                         if(sv_gentle) {
397                                                 bprint (a,"^7 made ^1FIFTEEN SCORES IN A ROW!\n");
398                                         } else {
399                                                 bprint (a,"^7 executes ^1MAYHEM!\n");
400                                                 announce(attacker, "announcer/male/15kills.wav");
401                                         }
402                                 }
403                                 else if (attacker.killcount == 20)
404                                 {
405                                         if(sv_gentle) {
406                                                 bprint (a,"^7 made ^1TWENTY SCORES IN A ROW!\n");
407                                         } else {
408                                                 bprint (a,"^7 is a ^1BERSERKER!\n");
409                                                 announce(attacker, "announcer/male/20kills.wav");
410                                         }
411                                 }
412                                 else if (attacker.killcount == 25)
413                                 {
414                                         if(sv_gentle) {
415                                                 bprint (a,"^7 made ^1TWENTY FIFE SCORES IN A ROW!\n");
416                                         } else {
417                                                 bprint (a,"^7 inflicts ^1CARNAGE!\n");
418                                                 announce(attacker, "announcer/male/25kills.wav");
419                                         }
420                                 }
421                                 else if (attacker.killcount == 30)
422                                 {
423                                         if(sv_gentle) {
424                                                 bprint (a,"^7 made ^1THIRTY SCORES IN A ROW!\n");
425                                         } else {
426                                                 bprint (a,"^7 unleashes ^1ARMAGEDDON!\n");
427                                                 announce(attacker, "announcer/male/30kills.wav");
428                                         }
429                                 }
430                         }
431                 }
432                 else
433                 {
434                         centerprint(targ, "^1Watch your step!\n\n\n");
435                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
436                                 bprint ("^1",s, "^1 ", inflictor.message, "\n");
437                         else if (deathtype == DEATH_DROWN)
438                                 if(sv_gentle)
439                                         bprint ("^1",s, "^1 was in the water for too long\n");
440                                 else
441                                         bprint ("^1",s, "^1 drowned\n");
442                         else if (deathtype == DEATH_SLIME)
443                                 bprint ("^1",s, "^1 was slimed\n");
444                         else if (deathtype == DEATH_LAVA)
445                                 if(sv_gentle)
446                                         bprint ("^1",s, "^1 found a hot place\n");
447                                 else
448                                         bprint ("^1",s, "^1 turned into hot slag\n");
449                         else if (deathtype == DEATH_FALL)
450                                 if(sv_gentle)
451                                         bprint ("^1",s, "^1 tested gravity (and it worked)\n");
452                                 else
453                                         bprint ("^1",s, "^1 hit the ground with a crunch\n");
454                         else if (deathtype == DEATH_SHOOTING_STAR)
455                                 bprint ("^1",s, "^1 became a shooting star\n");
456                         else if (deathtype == DEATH_SWAMP)
457                                 if(sv_gentle)
458                                         bprint ("^1",s, "^1 discovered a swamp\n");
459                                 else
460                                         bprint ("^1",s, "^1 is now conserved for centuries to come\n");
461             else if(deathtype == DEATH_TURRET)
462                     bprint ("^1",s, "^1 was mowed down by a turret \n");
463                         else if(deathtype == DEATH_TOUCHEXPLODE)
464                                 bprint ("^1",s, "^1 died in an accident\n");
465                         else
466                                 if(sv_gentle)
467                                         bprint ("^1",s, "^1 needs a restart\n");
468                                 else
469                                         bprint ("^1",s, "^1 died\n");
470                         GiveFrags(targ, targ, -1);
471                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
472                                 announce(targ, "announcer/male/botlike.wav");
473                         }
474
475                         if (targ.killcount > 2)
476                                 if(sv_gentle)
477                                         bprint ("^1",s,"^1 needs a restart after a ",ftos(targ.killcount)," scoring spree\n");
478                                 else
479                                         bprint ("^1",s,"^1 died with a ",ftos(targ.killcount)," kill spree\n");
480
481                         LogDeath("accident", deathtype, targ, targ);
482                 }
483                 targ.death_origin = targ.origin;
484                 if(targ != attacker)
485                         targ.killer_origin = attacker.origin;
486                 // FIXME: this should go in PutClientInServer
487                 if (targ.killcount)
488                         targ.killcount = 0;
489         }
490 }
491
492 // these are updated by each Damage call for use in button triggering and such
493 entity damage_targ;
494 entity damage_inflictor;
495 entity damage_attacker;
496
497 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
498 {
499         float mirrordamage;
500         float mirrorforce;
501         entity attacker_save;
502         mirrordamage = 0;
503         mirrorforce = 0;
504
505         if (gameover || targ.killcount == -666)
506                 return;
507
508         local entity oldself;
509         oldself = self;
510         self = targ;
511         damage_targ = targ;
512         damage_inflictor = inflictor;
513         damage_attacker = attacker;
514                 attacker_save = attacker;
515         
516         if(targ.classname == "player")
517                 if(targ.hook)
518                         if(targ.hook.aiment)
519                                 if(targ.hook.aiment == attacker)
520                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
521
522         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
523         if(DEATH_ISWEAPON(deathtype, WEP_HOOK))
524         {
525                 if(targ.classname == "player")
526                         if not(IsDifferentTeam(targ, attacker))
527                         {
528                                 self = oldself;
529                                 return;
530                         }
531         }
532
533         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
534         {
535                 // These are ALWAYS lethal
536                 // No damage modification here
537                 // Instead, prepare the victim for his death...
538                 targ.armorvalue = 0;
539                 targ.spawnshieldtime = 0;
540                 targ.health = 0.9; // this is < 1
541                 targ.flags -= targ.flags & FL_GODMODE;
542                 damage = 100000;
543         }
544         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
545         {
546                 // no processing
547         }
548         else
549         {
550                 if (targ.classname == "player")
551                 if (attacker.classname == "player")
552                 if (!targ.isbot)
553                 if (attacker.isbot)
554                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
555
556                 // nullify damage if teamplay is on
557                 if(deathtype != DEATH_TELEFRAG)
558                 if(attacker.classname == "player")
559                 {
560                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
561                         {
562                                 damage = 0;
563                                 force = '0 0 0';
564                         }
565                         else if(attacker.team == targ.team)
566                         {
567                                 if(teamplay == 1)
568                                         damage = 0;
569                                 else if(attacker != targ)
570                                 {
571                                         if(teamplay == 3)
572                                                 damage = 0;
573                                         else if(teamplay == 4)
574                                         {
575                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
576                                                 {
577                                                         mirrordamage = cvar("g_mirrordamage") * damage;
578                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
579                                                         if(g_minstagib)
580                                                         {
581                                                                 if(cvar("g_friendlyfire") == 0)
582                                                                         damage = 0;
583                                                         }
584                                                         else
585                                                                 damage = cvar("g_friendlyfire") * damage;
586                                                         // mirrordamage will be used LATER
587                                                 }
588                                                 else
589                                                         damage = 0;
590                                         }
591                                 }
592                         }
593                 }
594
595                 if(targ.classname == "player")
596                 if(attacker.classname == "player")
597                 if(attacker != targ)
598                 {
599                         targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
600                         attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
601                 }
602
603                 if (g_minstagib)
604                 {
605                         if ((deathtype == DEATH_FALL)  ||
606                                 (deathtype == DEATH_DROWN) ||
607                                 (deathtype == DEATH_SLIME) ||
608                                 (deathtype == DEATH_LAVA))
609                         {
610                                 self = oldself;
611                                 return;
612                         }
613                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
614                         {
615                                 targ.armorvalue -= 1;
616                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue),"\n"));
617                                 damage = 0;
618                                 targ.hitsound += 1;
619                         }
620                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
621                         {
622                                 damage = 0;
623                                 if (targ != attacker)
624                                 {
625                                         if (targ.classname == "player")
626                                                 centerprint(attacker, "Secondary fire inflicts no damage!\n");
627                                         damage = 0;
628                                         mirrordamage = 0;
629                                         force = '0 0 0';
630                                         // keep mirrorforce
631                                         attacker = targ;
632                                 }
633                         }
634                 }
635
636                 // apply strength multiplier
637                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
638                 {
639                         if(targ == attacker)
640                         {
641                                 damage = damage * cvar("g_balance_powerup_strength_selfdamage");
642                                 force = force * cvar("g_balance_powerup_strength_selfforce");
643                         }
644                         else
645                         {
646                                 damage = damage * cvar("g_balance_powerup_strength_damage");
647                                 force = force * cvar("g_balance_powerup_strength_force");
648                         }
649                 }
650
651                 // apply invincibility multiplier
652                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
653                         damage = damage * cvar("g_balance_powerup_invincible_takedamage");
654
655                 if (targ == attacker)
656                         damage = damage * cvar("g_balance_selfdamagepercent");  // Partial damage if the attacker hits himself
657
658                 // CTF: reduce damage/force
659                 if(g_ctf)
660                 if(targ == attacker)
661                 if(targ.flagcarried)
662                 {
663                         damage = damage * cvar("g_ctf_flagcarrier_selfdamage");
664                         force = force * cvar("g_ctf_flagcarrier_selfforce");
665                 }
666
667                 if(g_runematch)
668                 {
669                         // apply strength rune
670                         if (attacker.runes & RUNE_STRENGTH)
671                         {
672                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
673                                 {
674                                         damage = damage * cvar("g_balance_rune_strength_combo_damage");
675                                         force = force * cvar("g_balance_rune_strength_combo_force");
676                                 }
677                                 else
678                                 {
679                                         damage = damage * cvar("g_balance_rune_strength_damage");
680                                         force = force * cvar("g_balance_rune_strength_force");
681                                 }
682                         }
683                         else if (attacker.runes & CURSE_WEAK)
684                         {
685                                 damage = damage * cvar("g_balance_curse_weak_damage");
686                                 force = force * cvar("g_balance_curse_weak_force");
687                         }
688
689                         // apply defense rune
690                         if (targ.runes & RUNE_DEFENSE)
691                         {
692                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
693                                         damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
694                                 else
695                                         damage = damage * cvar("g_balance_rune_defense_takedamage");
696                         }
697                         else if (targ.runes & CURSE_VULNER)
698                                 damage = damage * cvar("g_balance_curse_vulner_takedamage");
699                 }
700
701                 // count the damage
702                 if(attacker)
703                 if(!targ.deadflag)
704                 if(targ.takedamage == DAMAGE_AIM)
705                 if(targ != attacker)
706                 if(targ.classname == "player")
707                 {
708                         if(IsDifferentTeam(targ, attacker))
709                         {
710                                 if(damage > 0)
711                                 {
712                                         if(targ.BUTTON_CHAT)
713                                                 attacker.typehitsound += 1;
714                                         else
715                                                 attacker.hitsound += 1;
716
717                                         damage_goodhits += 1;
718                                         damage_gooddamage += damage;
719
720                                         if(!g_minstagib)
721                                         if(IsFlying(targ))
722                                                 yoda = 1;
723
724                                         if(g_minstagib)
725                                         if(targ.items & IT_STRENGTH)
726                                                 yoda = 1;
727
728                                         // HEAD SHOT:
729                                         // find height of hit on player axis
730                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
731                                         vector headmins, headmaxs, org;
732                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
733                                         headmins = org + '0.5 0 0' * targ.mins_x + '0 0.5 0' * targ.mins_y + '0 0 1' * targ.view_ofs_z;
734                                         headmaxs = org + '0.5 0 0' * targ.maxs_x + '0 0.5 0' * targ.maxs_y + '0 0 1' * targ.maxs_z;
735                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
736                                                 headshot = 1;
737                                 }
738                         }
739                         else
740                         {
741                                 attacker.typehitsound += 1; // TODO possibly trigger teamkill complain sound!
742                                 if(time > attacker.teamkill_complain)
743                                 {
744                                         attacker.teamkill_complain = time + 5;
745                                         attacker.teamkill_soundtime = time + 0.4;
746                                         attacker.teamkill_soundsource = targ;
747                                 }
748                         }
749                 }
750         }
751
752         // apply push
753         if (self.damageforcescale)
754         if (vlen(force))
755         {
756                 self.velocity = self.velocity + self.damageforcescale * force;
757                 self.flags = self.flags - (self.flags & FL_ONGROUND);
758         }
759         // apply damage
760         if (damage != 0)
761         if (self.event_damage)
762                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
763         self = oldself;
764
765         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
766         {
767                 // Savage: vampire mode
768                 if (g_vampire)
769                 if (!g_minstagib)
770                 if (time > self.spawnshieldtime)
771                 {
772                         attacker.health += damage;
773                 }
774                 if(g_runematch)
775                 {
776                         if (attacker.runes & RUNE_VAMPIRE)
777                         {
778                         // apply vampire rune
779                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
780                                 {
781                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
782                                         attacker.health = bound(
783                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
784                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
785                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
786                                 }
787                                 else
788                                 {
789                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
790                                         attacker.health = bound(
791                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
792                                                                                         // empathy won't let you gain health in the same way...
793                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
794                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
795                                         }
796                         }
797                         // apply empathy curse
798                         else if (attacker.runes & CURSE_EMPATHY)
799                         {
800                                 attacker.health = bound(
801                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
802                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
803                                         attacker.health);
804                         }
805                 }
806         }
807
808         // apply mirror damage if any
809         if(mirrordamage > 0 || mirrorforce > 0)
810         {
811                 attacker = attacker_save;
812                 if(g_minstagib)
813                         if(mirrordamage > 0)
814                         {
815                                 // just lose extra LIVES, don't kill the player for mirror damage
816                                 if(attacker.armorvalue > 0)
817                                 {
818                                         attacker.armorvalue = attacker.armorvalue - 1;
819                                         centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue),"\n"));
820                                         attacker.hitsound += 1;
821                                 }
822                                 mirrordamage = 0;
823                         }
824                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
825                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
826         }
827 }
828
829 vector NearestPointOnBox(entity box, vector org)
830 {
831         vector m1, m2, nearest;
832
833         m1 = box.mins + box.origin;
834         m2 = box.maxs + box.origin;
835
836         nearest_x = bound(m1_x, org_x, m2_x);
837         nearest_y = bound(m1_y, org_y, m2_y);
838         nearest_z = bound(m1_z, org_z, m2_z);
839
840         return nearest;
841 }
842
843 float RadiusDamage_running;
844 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
845 // Returns total damage applies to creatures
846 {
847         entity  targ;
848         float   finaldmg;
849         float   power;
850         vector  blastorigin;
851         vector  force;
852         vector  diff;
853         vector  center;
854         vector  nearest;
855         float   total_damage_to_creatures;
856         entity  next;
857
858         if(RadiusDamage_running)
859         {
860                 string save;
861                 print("RadiusDamage called recursively!\n");
862                 print("Expect stuff to go HORRIBLY wrong.\n");
863                 print("Causing a stack trace...\n");
864                 save = cvar_string("prvm_backtraceforwarnings");
865                 cvar_set("prvm_backtraceforwarnings", "1");
866                 fclose(-1); // calls VM_Warning
867                 cvar_set("prvm_backtraceforwarnings", save);
868                 return 0;
869         }
870
871         RadiusDamage_running = 1;
872
873         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
874         total_damage_to_creatures = 0;
875
876         targ = findradius (blastorigin, rad);
877         while (targ)
878         {
879                 next = targ.chain;
880                 if (targ != inflictor)
881                         if (ignore != targ)
882                         {
883                                 // LordHavoc: measure distance to nearest point on target (not origin)
884                                 // (this guarentees 100% damage on a touch impact)
885                                 nearest = NearestPointOnBox(targ, blastorigin);
886                                 diff = nearest - blastorigin;
887                                 // round up a little on the damage to ensure full damage on impacts
888                                 // and turn the distance into a fraction of the radius
889                                 power = 1 - ((vlen (diff) - 2) / rad);
890                                 //bprint(" ");
891                                 //bprint(ftos(power));
892                                 if (power > 0)
893                                 {
894                                         if (power > 1)
895                                                 power = 1;
896                                         finaldmg = coredamage * power + edgedamage * (1 - power);
897                                         if (finaldmg > 0)
898                                         {
899                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
900                                                 // if it's a player, use the view origin as reference
901                                                 if (targ.classname == "player")
902                                                         center = targ.origin + targ.view_ofs;
903                                                 force = normalize(center - blastorigin) * (finaldmg / coredamage) * forceintensity;
904                                                 // test line of sight to multiple positions on box,
905                                                 // and do damage if any of them hit
906                                                 local float c;
907                                                 c = ceil(finaldmg / 10);
908                                                 if (c > 20)
909                                                         c = 20;
910                                                 while (c > 0)
911                                                 {
912                                                         c = c - 1;
913                                                         traceline(blastorigin, nearest, TRUE, inflictor);
914                                                         if (trace_fraction == 1 || trace_ent == targ
915                                                             || cvar("g_throughfloor"))
916                                                         {
917                                                                 if(targ.iscreature)
918                                                                         total_damage_to_creatures += finaldmg;
919                                                                 if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
920                                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
921                                                                 else
922                                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
923                                                                 break;
924                                                         }
925                                                         nearest_x = targ.mins_x + random() * targ.size_x;
926                                                         nearest_y = targ.mins_y + random() * targ.size_y;
927                                                         nearest_z = targ.mins_z + random() * targ.size_z;
928                                                 }
929                                         }
930                                 }
931                         }
932                 targ = next;
933         }
934
935         RadiusDamage_running = 0;
936
937         return total_damage_to_creatures;
938 }