data/qcsrc/server/ctf.qc

   1
   2 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
   3                                                                 /// I used this, in part, to fix the looping score bug. - avirox
   4
   5 //float FLAGSCORE_PICKUP        =  1;
   6 //float FLAGSCORE_RETURN        =  5; // returned by owner team
   7 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
   8 //float FLAGSCORE_CAPTURE       =  5;
   9 //float FLAGSCORE_CAPTURE_TEAM  = 20;
  10
  11 #define FLAG_CARRY_POS '-15 0 7'
  12
  13 void() FlagThink;
  14 void() FlagTouch;
  15
  16 void() place_flag =
  17 {
  18         if(!self.t_width)
  19                 self.t_width = 0.1; // frame animation rate
  20         if(!self.t_length)
  21                 self.t_length = 119; // maximum frame
  22
  23         setattachment(self, world, "");
  24         self.mdl = self.model;
  25         self.flags = FL_ITEM;
  26         self.solid = SOLID_TRIGGER;
  27         self.movetype = MOVETYPE_TOSS;
  28         self.velocity = '0 0 0';
  29         self.origin_z = self.origin_z + 6;
  30         self.think = FlagThink;
  31         self.touch = FlagTouch;
  32         self.nextthink = time + 0.1;
  33         self.cnt = FLAG_BASE;
  34         self.mangle = self.angles;
  35         //self.effects = self.effects | EF_DIMLIGHT;
  36         if (!droptofloor())
  37         {
  38                 dprint("Flag fell out of level at ", vtos(self.origin), "\n");
  39                 remove(self);
  40                 return;
  41         }
  42         self.oldorigin = self.origin;
  43 };
  44
  45 void LogCTF(string mode, float flagteam, entity actor)
  46 {
  47         string s;
  48         if(!cvar("sv_eventlog"))
  49                 return;
  50         s = strcat(":ctf:", mode);
  51         s = strcat(s, ":", ftos(flagteam));
  52         if(actor != world)
  53                 s = strcat(s, ":", ftos(actor.playerid));
  54         GameLogEcho(s, FALSE);
  55 }
  56
  57 void(entity e) RegenFlag =
  58 {
  59         setattachment(e, world, "");
  60         e.movetype = MOVETYPE_TOSS;
  61         e.solid = SOLID_TRIGGER;
  62         // TODO: play a sound here
  63         setorigin(e, e.oldorigin);
  64         e.angles = e.mangle;
  65         e.cnt = FLAG_BASE;
  66         e.owner = world;
  67         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
  68 };
  69
  70 void(entity e) ReturnFlag =
  71 {
  72         if (e.owner)
  73         if (e.owner.flagcarried == e)
  74         {
  75                 WaypointSprite_DetachCarrier(e.owner);
  76                 e.owner.flagcarried = world;
  77         }
  78         e.owner = world;
  79         RegenFlag(e);
  80 };
  81
  82 void(entity e) DropFlag =
  83 {
  84         local entity p;
  85
  86         if (!e.owner)
  87         {
  88                 dprint("FLAG: drop - no owner?!?!\n");
  89                 return;
  90         }
  91         p = e.owner;
  92         if (p.flagcarried != e)
  93         {
  94                 dprint("FLAG: drop - owner is not carrying this flag??\n");
  95                 return;
  96         }
  97         bprint(p.netname, "^7 lost the ", e.netname, "\n");
  98         WaypointSprite_DetachCarrier(p);
  99         LogCTF("dropped", p.team, p.flagcarried);
 100
 101         setattachment(e, world, "");
 102
 103         if (p.flagcarried == e)
 104                 p.flagcarried = world;
 105         e.owner = world;
 106
 107         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 108         e.solid = SOLID_TRIGGER;
 109         e.movetype = MOVETYPE_TOSS;
 110         // setsize(e, '-16 -16 0', '16 16 74');
 111         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 112         e.cnt = FLAG_DROPPED;
 113         e.velocity = '0 0 300';
 114         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 115
 116         trace_startsolid = FALSE;
 117         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 118         if(trace_startsolid)
 119                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 120 };
 121
 122 void AnimateFlag()
 123 {
 124         if(self.delay > time)
 125                 return;
 126         self.delay = time + self.t_width;
 127         if(self.nextthink > self.delay)
 128                 self.nextthink = self.delay;
 129
 130         self.frame = self.frame + 1;
 131         if(self.frame > self.t_length)
 132                 self.frame = 0;
 133 }
 134
 135 void() FlagThink =
 136 {
 137         local entity e;
 138
 139         self.nextthink = time + 0.1;
 140
 141         AnimateFlag();
 142
 143         if (self.cnt == FLAG_BASE)
 144                 return;
 145
 146         if (self.cnt == FLAG_DROPPED)
 147         {
 148                 // flag fallthrough? FIXME remove this if bug is really fixed now
 149                 if(self.origin_z < -131072)
 150                 {
 151                         dprint("FLAG FALLTHROUGH just happened\n");
 152                         self.pain_finished = 0;
 153                 }
 154                 setattachment(self, world, "");
 155                 if (time > self.pain_finished)
 156                 {
 157                         bprint("The ", self.netname, " has returned to base\n");
 158                         sound (e, CHAN_AUTO, self.noise3, 1, ATTN_NONE);
 159                         LogCTF("returned", self.team, world);
 160                         ReturnFlag(self);
 161                 }
 162                 return;
 163         }
 164
 165         e = self.owner;
 166         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 167         {
 168                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 169                 DropFlag(self);
 170                 return;
 171         }
 172 };
 173
 174 float   flagcaptimerecord;
 175 .float  flagpickuptime;
 176
 177 void() FlagTouch =
 178 {
 179         if(gameover) return;
 180
 181         local float t;
 182         local entity head;
 183         local entity player;
 184         local string s, s0;
 185         if (other.classname != "player")
 186                 return;
 187         if (other.health < 1) // ignore dead players
 188                 return;
 189
 190         if (self.cnt == FLAG_CARRY)
 191                 return;
 192
 193         if (self.cnt == FLAG_BASE)
 194         if (other.team == self.team)
 195         if (other.flagcarried) // he's got a flag
 196         if (other.flagcarried.team != self.team) // capture
 197         {
 198                 if (other.flagcarried == world)
 199                 {
 200                         return;
 201                 }
 202                 t = time - other.flagcarried.flagpickuptime;
 203                 s = ftos_decimals(t, 2);
 204                 s0 = ftos_decimals(flagcaptimerecord, 2);
 205                 if (flagcaptimerecord == 0)
 206                 {
 207                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, " seconds\n");
 208                         flagcaptimerecord = t;
 209                 }
 210                 else if (t < flagcaptimerecord)
 211                 {
 212                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", breaking the previous record of ", s0, " seconds\n");
 213                         flagcaptimerecord = t;
 214                 }
 215                 else
 216                 {
 217                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", failing to break the previous record of ", s0, " seconds\n");
 218                 }
 219
 220                 LogCTF("capture", other.flagcarried.team, other);
 221                 // give credit to the individual player
 222                 UpdateFrags(other, cvar("g_ctf_flagscore_capture"));
 223
 224                 // give credit to all players of the team (rewards large teams)
 225                 // NOTE: this defaults to 0
 226                 FOR_EACH_PLAYER(head)
 227                         if (head.team == self.team)
 228                                 UpdateFrags(head, cvar("g_ctf_flagscore_capture_team"));
 229
 230                 sound (self, CHAN_AUTO, self.noise2, 1, ATTN_NONE);
 231                 WaypointSprite_DetachCarrier(other);
 232                 RegenFlag (other.flagcarried);
 233                 other.flagcarried = world;
 234                 other.next_take_time = time + 1;
 235         }
 236         if (self.cnt == FLAG_BASE)
 237         if (other.team == 5 || other.team == 14) // only red and blue team can steal flags
 238         if (other.team != self.team)
 239         if (!other.flagcarried)
 240         {
 241                 if (other.next_take_time > time)
 242                         return;
 243                 // pick up
 244                 self.flagpickuptime = time; // used for timing runs
 245                 self.solid = SOLID_NOT;
 246                 setorigin(self, self.origin); // relink
 247                 self.owner = other;
 248                 other.flagcarried = self;
 249                 self.cnt = FLAG_CARRY;
 250                 bprint(other.netname, "^7 got the ", self.netname, "\n");
 251                 UpdateFrags(other, cvar("g_ctf_flagscore_pickup"));
 252                 LogCTF("steal", self.team, other);
 253                 sound (self, CHAN_AUTO, self.noise, 1, ATTN_NONE);
 254
 255                 FOR_EACH_PLAYER(player)
 256                         if(player.team == self.team)
 257                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 258
 259                 self.movetype = MOVETYPE_NONE;
 260                 setorigin(self, FLAG_CARRY_POS);
 261                 setattachment(self, other, "");
 262                 WaypointSprite_AttachCarrier("flagcarrier", other);
 263
 264                 return;
 265         }
 266
 267         if (self.cnt == FLAG_DROPPED)
 268         {
 269                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 270                 if (other.team == self.team || (other.team != 5 && other.team != 14))
 271                 {
 272                         // return flag
 273                         bprint(other.netname, "^7 returned the ", self.netname, "\n");
 274                         if (other.team == 5 || other.team == 14)
 275                                 UpdateFrags(other, cvar("g_ctf_flagscore_return"));
 276                         else
 277                                 UpdateFrags(other, cvar("g_ctf_flagscore_return_rogue"));
 278                         LogCTF("return", self.team, other);
 279                         sound (self, CHAN_AUTO, self.noise1, 1, ATTN_NONE);
 280                         ReturnFlag(self);
 281                 }
 282                 else if (!other.flagcarried)
 283                 {
 284                         // pick up
 285                         self.solid = SOLID_NOT;
 286                         setorigin(self, self.origin); // relink
 287                         self.owner = other;
 288                         other.flagcarried = self;
 289                         self.cnt = FLAG_CARRY;
 290                         bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 291                         UpdateFrags(other, cvar("g_ctf_flagscore_pickup"));
 292                         LogCTF("pickup", self.team, other);
 293                         sound (self, CHAN_AUTO, self.noise, 1, ATTN_NONE);
 294
 295                         FOR_EACH_PLAYER(player)
 296                                 if(player.team == self.team)
 297                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 298
 299                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 300                         setorigin(self, FLAG_CARRY_POS);
 301                         setattachment(self, other, "");
 302                         WaypointSprite_AttachCarrier("flagcarrier", other);
 303                 }
 304         }
 305 };
 306
 307 /*QUAKED info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 308 CTF Starting point for a player
 309 in team one (Red).
 310
 311 Keys:
 312 "angle"
 313  viewing angle when spawning
 314 */
 315 void() info_player_team1 =
 316 {
 317         self.classname = "info_player_deathmatch";
 318         self.team = 5; // red
 319         relocate_spawnpoint();
 320 };
 321 //self.team = 4;self.classname = "info_player_start";info_player_start();};
 322
 323 /*QUAKED info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 324 CTF Starting point for a player in
 325 team two (Blue).
 326
 327 Keys:
 328 "angle"
 329  viewing angle when spawning
 330 */
 331 void() info_player_team2 =
 332 {
 333         self.classname = "info_player_deathmatch";
 334         self.team = 14; // blue
 335         relocate_spawnpoint();
 336 };
 337 //self.team = 13;self.classname = "info_player_start";info_player_start();};
 338
 339 /*QUAKED info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 340 CTF Starting point for a player in
 341 team three (Magenta).
 342
 343 Keys:
 344 "angle"
 345  viewing angle when spawning
 346 */
 347 void() info_player_team3 =
 348 {
 349         self.classname = "info_player_deathmatch";
 350         self.team = 10; // purple
 351         relocate_spawnpoint();
 352 };
 353
 354
 355 /*QUAKED info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 356 CTF Starting point for a player in
 357 team four (Yellow).
 358
 359 Keys:
 360 "angle"
 361  viewing angle when spawning
 362 */
 363 void() info_player_team4 =
 364 {
 365         self.classname = "info_player_deathmatch";
 366         self.team = 13; // yellow
 367         relocate_spawnpoint();
 368 };
 369
 370
 371
 372
 373 /*QUAKED item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 374 CTF flag for team one (Red).
 375 Multiple are allowed.
 376
 377 Keys:
 378 "angle"
 379  Angle the flag will point
 380 (minus 90 degrees)
 381 "model"
 382  model to use, note this needs red and blue as skins 0 and 1
 383  (default models/ctf/flag.md3)
 384 "noise"
 385  sound played when flag is picked up
 386  (default ctf/take.wav)
 387 "noise1"
 388  sound played when flag is returned by a teammate
 389  (default ctf/return.wav)
 390 "noise2"
 391  sound played when flag is captured
 392  (default ctf/capture.wav)
 393 "noise3"
 394  sound played when flag is lost in the field and respawns itself
 395  (default ctf/respawn.wav)
 396 */
 397
 398 void() item_flag_team1 =
 399 {
 400         if (!cvar("g_ctf"))
 401                 return;
 402         //if(!cvar("teamplay"))
 403         //      cvar_set("teamplay", "3");
 404
 405         self.classname = "item_flag_team1";
 406         self.team = 5; // color 4 team (red)
 407         self.items = IT_KEY2; // gold key (redish enough)
 408         self.netname = "^1RED^7 flag";
 409         self.target = "###item###";
 410         self.skin = 0;
 411         if (!self.model)
 412                 self.model = "models/ctf/flag_red.md3";
 413         if (!self.noise)
 414                 self.noise = "ctf/take.wav";
 415         if (!self.noise1)
 416                 self.noise1 = "ctf/return.wav";
 417         if (!self.noise2)
 418                 self.noise2 = "ctf/capture.wav";
 419         if (!self.noise3)
 420                 self.noise3 = "ctf/respawn.wav";
 421         precache_model (self.model);
 422         setmodel (self, self.model); // precision set below
 423         precache_sound (self.noise);
 424         precache_sound (self.noise1);
 425         precache_sound (self.noise2);
 426         precache_sound (self.noise3);
 427         setsize(self, '-16 -16 -37', '16 16 37');
 428         setorigin(self, self.origin + '0 0 37');
 429         self.nextthink = time + 0.2; // start after doors etc
 430         self.think = place_flag;
 431
 432         if(!self.scale)
 433                 self.scale = 0.6;
 434         //if(!self.glow_size)
 435         //      self.glow_size = 50;
 436
 437         self.effects = self.effects | EF_FULLBRIGHT | EF_LOWPRECISION;
 438         droptofloor();
 439
 440         WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 37');
 441 };
 442
 443 /*QUAKED item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 444 CTF flag for team two (Blue).
 445 Multiple are allowed.
 446
 447 Keys:
 448 "angle"
 449  Angle the flag will point
 450 (minus 90 degrees)
 451
 452 */
 453
 454 void() item_flag_team2 =
 455 {
 456         if (!cvar("g_ctf"))
 457                 return;
 458         //if(!cvar("teamplay"))
 459         //      cvar_set("teamplay", "3");
 460
 461         self.classname = "item_flag_team2";
 462         self.team = 14; // color 13 team (blue)
 463         self.items = IT_KEY1; // silver key (bluish enough)
 464         self.netname = "^4BLUE^7 flag";
 465         self.target = "###item###";
 466         self.skin = 0;
 467         if (!self.model)
 468                 self.model = "models/ctf/flag_blue.md3";
 469         if (!self.noise)
 470                 self.noise = "ctf/take.wav";
 471         if (!self.noise1)
 472                 self.noise1 = "ctf/return.wav";
 473         if (!self.noise2)
 474                 self.noise2 = "ctf/capture.wav";
 475         if (!self.noise3)
 476                 self.noise3 = "ctf/respawn.wav";
 477         precache_model (self.model);
 478         setmodel (self, self.model); // precision set below
 479         precache_sound (self.noise);
 480         precache_sound (self.noise1);
 481         precache_sound (self.noise2);
 482         precache_sound (self.noise3);
 483         setsize(self, '-16 -16 -37', '16 16 37');
 484         setorigin(self, self.origin + '0 0 37');
 485         self.nextthink = time + 0.2; // start after doors etc
 486         self.think = place_flag;
 487
 488         if(!self.scale)
 489                 self.scale = 0.6;
 490         //if(!self.glow_size)
 491         //      self.glow_size = 50;
 492
 493         self.effects = self.effects | EF_FULLBRIGHT | EF_LOWPRECISION;
 494         droptofloor();
 495
 496         WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 37');
 497 };
 498
 499
 500 // spawnfunctions for q3 flags
 501 void team_CTF_redflag()
 502 {
 503         item_flag_team1();
 504 }
 505
 506 void team_CTF_blueflag()
 507 {
 508         item_flag_team2();
 509 }
 510
 511
 512 /*QUAKED ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 513 Team declaration for CTF gameplay, this allows you to decide what team
 514 names and control point models are used in your map.
 515
 516 Note: If you use ctf_team entities you must define at least 2!  However, unlike
 517 domination, you don't need to make a blank one too.
 518
 519 Keys:
 520 "netname"
 521  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 522 "cnt"
 523  Scoreboard color of the team (for example 4 is red and 13 is blue)
 524
 525 */
 526
 527 void() ctf_team =
 528 {
 529         self.classname = "ctf_team";
 530         self.team = self.cnt + 1;
 531 };
 532
 533 // code from here on is just to support maps that don't have control point and team entities
 534 void ctf_spawnteam (string teamname, float teamcolor)
 535 {
 536         local entity oldself;
 537         oldself = self;
 538         self = spawn();
 539         self.classname = "ctf_team";
 540         self.netname = teamname;
 541         self.cnt = teamcolor;
 542
 543         ctf_team();
 544
 545         self = oldself;
 546 };
 547
 548 // spawn some default teams if the map is not set up for ctf
 549 void() ctf_spawnteams =
 550 {
 551         float numteams;
 552
 553         numteams = 2;//cvar("g_ctf_default_teams");
 554
 555         ctf_spawnteam("Red", 4);
 556         ctf_spawnteam("Blue", 13);
 557 };
 558
 559 void() ctf_delayedinit =
 560 {
 561         self.think = SUB_Remove;
 562         self.nextthink = time;
 563         // if no teams are found, spawn defaults
 564         if (find(world, classname, "ctf_team") == world)
 565                 ctf_spawnteams();
 566 };
 567
 568 void() ctf_init =
 569 {
 570         local entity e;
 571         e = spawn();
 572         e.think = ctf_delayedinit;
 573         e.nextthink = time + 0.1;
 574 };
 575
 576 void(entity flag) ctf_setstatus2 =
 577 {
 578         if (flag) {
 579                 local float shift;
 580                 if (flag.team == 5) shift = IT_RED_FLAG_TAKEN;
 581                 else if (flag.team == 14) shift = IT_BLUE_FLAG_TAKEN;
 582                 else shift = 0;
 583
 584                 local float status;
 585                 if (flag.cnt == FLAG_CARRY)
 586                         if (flag.owner == self) status = 3;
 587                         else status = 1;
 588                 else if (flag.cnt == FLAG_DROPPED) status = 2;
 589                 else status = 0;
 590
 591                 self.items = self.items | (shift * status);
 592         }
 593 };
 594
 595 void() ctf_setstatus =
 596 {
 597         self.items = self.items - (self.items & IT_RED_FLAG_TAKEN);
 598         self.items = self.items - (self.items & IT_RED_FLAG_LOST);
 599         self.items = self.items - (self.items & IT_BLUE_FLAG_TAKEN);
 600         self.items = self.items - (self.items & IT_BLUE_FLAG_LOST);
 601
 602         if (cvar("g_ctf")) {
 603                 local entity flag;
 604                 flag = find(world, classname, "item_flag_team1");
 605                 ctf_setstatus2(flag);
 606                 flag = find(world, classname, "item_flag_team2");
 607                 ctf_setstatus2(flag);
 608         }
 609 };