data/qcsrc/server/ctf.qc

   1 .entity sprite;
   2 entity ctf_worldflaglist; // CTF flags in the map
   3 .entity ctf_worldflagnext;
   4 .float dropperid;
   5 .float ctf_droptime;
   6
   7 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
   8                                                                 /// I used this, in part, to fix the looping score bug. - avirox
   9 //float FLAGSCORE_PICKUP        =  1;
  10 //float FLAGSCORE_RETURN        =  5; // returned by owner team
  11 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
  12 //float FLAGSCORE_CAPTURE       =  5;
  13
  14 #define FLAG_CARRY_POS '-15 0 7'
  15
  16 .float ctf_captureshielded; // set to 1 if the player is too bad to be allowed to capture
  17
  18 float captureshield_min_negscore; // punish at -20 points
  19 float captureshield_max_ratio; // punish at most 30% of each team
  20 float captureshield_force; // push force of the shield
  21
  22 float ctf_captureshield_shielded(entity p)
  23 {
  24         float s, se;
  25         entity e;
  26         float players_worseeq, players_total;
  27
  28         if(captureshield_max_ratio <= 0)
  29                 return FALSE;
  30
  31         s = PlayerScore_Add(p, SP_SCORE, 0);
  32         if(s >= -captureshield_min_negscore)
  33                 return FALSE;
  34
  35         players_total = players_worseeq = 0;
  36         FOR_EACH_PLAYER(e)
  37         {
  38                 if(e.team != p.team)
  39                         continue;
  40                 se = PlayerScore_Add(e, SP_SCORE, 0);
  41                 if(se <= s)
  42                         ++players_worseeq;
  43                 ++players_total;
  44         }
  45
  46         // player is in the worse half, if >= half the players are better than him, or consequently, if < half of the players are worse
  47         // use this rule here
  48
  49         if(players_worseeq >= players_total * captureshield_max_ratio)
  50                 return FALSE;
  51
  52         return TRUE;
  53 }
  54
  55 void ctf_captureshield_update(entity p, float dir)
  56 {
  57         float should;
  58         if(dir == p.ctf_captureshielded) // 0: shield only, 1: unshield only
  59         {
  60                 should = ctf_captureshield_shielded(p);
  61                 if(should != dir)
  62                 {
  63                         if(should)
  64                         {
  65                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Make some defensive scores before trying again.");
  66                                 // TODO csqc notifier for this
  67                         }
  68                         else
  69                         {
  70                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now free.\n\n^3Feel free to ^1try to capture^3 the flag again\n^3if you think you will succeed.");
  71                                 // TODO csqc notifier for this
  72                         }
  73                         p.ctf_captureshielded = should;
  74                 }
  75         }
  76 }
  77
  78 float ctf_captureshield_customize()
  79 {
  80         if not(other.ctf_captureshielded)
  81                 return FALSE;
  82         if(self.team == other.team)
  83                 return FALSE;
  84         return TRUE;
  85 }
  86
  87 void ctf_captureshield_touch()
  88 {
  89         if not(other.ctf_captureshielded)
  90                 return;
  91         if(self.team == other.team)
  92                 return;
  93         vector mymid;
  94         vector othermid;
  95         mymid = (self.absmin + self.absmax) * 0.5;
  96         othermid = (other.absmin + other.absmax) * 0.5;
  97         Damage(other, self, self, 0, DEATH_HURTTRIGGER, mymid, normalize(othermid - mymid) * captureshield_force);
  98         centerprint_atprio(other, CENTERPRIO_SHIELDING, "^3You are ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Get some defensive scores before trying again.");
  99 }
 100
 101 void ctf_captureshield_spawn()
 102 {
 103         entity e;
 104         e = spawn();
 105         e.enemy = self;
 106         e.team = self.team;
 107         e.touch = ctf_captureshield_touch;
 108         e.customizeentityforclient = ctf_captureshield_customize;
 109         e.classname = "ctf_captureshield";
 110         e.effects = EF_ADDITIVE;
 111         e.movetype = MOVETYPE_NOCLIP;
 112         e.solid = SOLID_TRIGGER;
 113         e.avelocity = '7 0 11';
 114         setorigin(e, self.origin);
 115         setmodel(e, "models/onslaught/generator_shield.md3");
 116         e.scale = 0.5;
 117         setsize(e, e.scale * e.mins, e.scale * e.maxs);
 118         print(etos(e), "\n");
 119 }
 120
 121 float ctf_score_value(string parameter)
 122 {
 123         if(g_ctf_win_mode != 2)
 124                 return cvar(strcat("g_ctf_personal", parameter));
 125         else
 126                 return cvar(strcat("g_ctf_flag", parameter));
 127 }
 128
 129 void FakeTimeLimit(entity e, float t)
 130 {
 131         msg_entity = e;
 132         WriteByte(MSG_ONE, 3); // svc_updatestat
 133         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
 134         if(t < 0)
 135                 WriteCoord(MSG_ONE, cvar("timelimit"));
 136         else
 137                 WriteCoord(MSG_ONE, (t + 1) / 60);
 138 }
 139
 140 float   flagcaptimerecord;
 141 .float  flagpickuptime;
 142 //.float  iscommander;
 143 //.float  ctf_state;
 144
 145 void() FlagThink;
 146 void() FlagTouch;
 147
 148 void place_flag()
 149 {
 150         if(!self.t_width)
 151                 self.t_width = 0.1; // frame animation rate
 152         if(!self.t_length)
 153                 self.t_length = 119; // maximum frame
 154
 155         setattachment(self, world, "");
 156         self.mdl = self.model;
 157         self.flags = FL_ITEM;
 158         self.solid = SOLID_TRIGGER;
 159         self.movetype = MOVETYPE_NONE;
 160         self.velocity = '0 0 0';
 161         self.origin_z = self.origin_z + 6;
 162         self.think = FlagThink;
 163         self.touch = FlagTouch;
 164         self.nextthink = time + 0.1;
 165         self.cnt = FLAG_BASE;
 166         self.mangle = self.angles;
 167         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 168         //self.effects = self.effects | EF_DIMLIGHT;
 169         if(self.noalign)
 170         {
 171                 self.dropped_origin = self.origin;
 172         }
 173         else
 174         {
 175                 droptofloor();
 176                 self.movetype = MOVETYPE_TOSS;
 177         }
 178         InitializeEntity(self, ctf_captureshield_spawn, INITPRIO_SETLOCATION);
 179 };
 180
 181 void LogCTF(string mode, float flagteam, entity actor)
 182 {
 183         string s;
 184         if(!cvar("sv_eventlog"))
 185                 return;
 186         s = strcat(":ctf:", mode);
 187         s = strcat(s, ":", ftos(flagteam));
 188         if(actor != world)
 189                 s = strcat(s, ":", ftos(actor.playerid));
 190         GameLogEcho(s);
 191 }
 192
 193 void RegenFlag(entity e)
 194 {
 195         setattachment(e, world, "");
 196         e.damageforcescale = 0;
 197         e.movetype = MOVETYPE_NONE;
 198         if(!self.noalign)
 199                 e.movetype = MOVETYPE_TOSS;
 200         e.solid = SOLID_TRIGGER;
 201         // TODO: play a sound here
 202         setorigin(e, e.dropped_origin);
 203         e.angles = e.mangle;
 204         e.cnt = FLAG_BASE;
 205         e.owner = world;
 206         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 207 };
 208
 209 void ReturnFlag(entity e)
 210 {
 211         if (e.owner)
 212         if (e.owner.flagcarried == e)
 213         {
 214                 WaypointSprite_DetachCarrier(e.owner);
 215                 e.owner.flagcarried = world;
 216
 217                 if(e.speedrunning)
 218                         FakeTimeLimit(e.owner, -1);
 219         }
 220         e.owner = world;
 221         RegenFlag(e);
 222 };
 223
 224 void DropFlag(entity e, entity penalty_receiver, entity attacker)
 225 {
 226         local entity p;
 227
 228         if(e.speedrunning)
 229         {
 230                 ReturnFlag(e);
 231                 return;
 232         }
 233
 234         if (!e.owner)
 235         {
 236                 dprint("FLAG: drop - no owner?!?!\n");
 237                 return;
 238         }
 239         p = e.owner;
 240         if (p.flagcarried != e)
 241         {
 242                 dprint("FLAG: drop - owner is not carrying this flag??\n");
 243                 return;
 244         }
 245         bprint(p.netname, "^7 lost the ", e.netname, "\n");
 246
 247         if(penalty_receiver)
 248                 UpdateFrags(penalty_receiver, -ctf_score_value("penalty_suicidedrop"));
 249         else
 250                 UpdateFrags(p, -ctf_score_value("penalty_drop"));
 251         PlayerScore_Add(p, SP_CTF_DROPS, +1);
 252         ctf_captureshield_update(p, 0); // shield only
 253         e.playerid = attacker.playerid;
 254         e.ctf_droptime = time;
 255
 256         if(p.waypointsprite_attachedforcarrier)
 257         {
 258                 WaypointSprite_Ping(p.waypointsprite_attachedforcarrier);
 259                 WaypointSprite_DetachCarrier(p);
 260         }
 261         else
 262         {
 263                 bprint("\{1}^1Flag carrier had no flag sprite?!?\n");
 264                 backtrace("Flag carrier had no flag sprite?!?");
 265         }
 266         LogCTF("dropped", p.team, p);
 267
 268         setattachment(e, world, "");
 269         e.damageforcescale = cvar("g_balance_ctf_damageforcescale");
 270
 271         if (p.flagcarried == e)
 272                 p.flagcarried = world;
 273         e.owner = world;
 274
 275         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 276         e.solid = SOLID_TRIGGER;
 277         e.movetype = MOVETYPE_TOSS;
 278         // setsize(e, '-16 -16 0', '16 16 74');
 279         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 280         e.cnt = FLAG_DROPPED;
 281         e.velocity = '0 0 300';
 282         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 283
 284         trace_startsolid = FALSE;
 285         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 286         if(trace_startsolid)
 287                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 288 };
 289
 290 void AnimateFlag()
 291 {
 292         if(self.delay > time)
 293                 return;
 294         self.delay = time + self.t_width;
 295         if(self.nextthink > self.delay)
 296                 self.nextthink = self.delay;
 297
 298         self.frame = self.frame + 1;
 299         if(self.frame > self.t_length)
 300                 self.frame = 0;
 301 }
 302
 303 void FlagThink()
 304 {
 305         local entity e;
 306
 307         self.nextthink = time + 0.1;
 308
 309         if(self == ctf_worldflaglist) // only for the first flag
 310         {
 311                 FOR_EACH_CLIENT(e)
 312                         ctf_captureshield_update(e, 1); // release shield only
 313         }
 314
 315         AnimateFlag();
 316
 317         if(self.speedrunning)
 318         if(self.cnt == FLAG_CARRY)
 319         {
 320                 if(self.owner)
 321                 if(flagcaptimerecord)
 322                 if(time >= self.flagpickuptime + flagcaptimerecord)
 323                 {
 324                         bprint("The ", self.netname, " became impatient after ", ftos_decimals(flagcaptimerecord, 2), " seconds and returned itself\n");
 325
 326                         self.owner.impulse = 77; // returning!
 327                         e = self;
 328                         self = self.owner;
 329                         ReturnFlag(e);
 330                         ImpulseCommands();
 331                         self = e;
 332                         return;
 333                 }
 334         }
 335
 336         if (self.cnt == FLAG_BASE)
 337                 return;
 338
 339         if (self.cnt == FLAG_DROPPED)
 340         {
 341                 // flag fallthrough? FIXME remove this if bug is really fixed now
 342                 if(self.origin_z < -131072)
 343                 {
 344                         dprint("FLAG FALLTHROUGH just happened\n");
 345                         self.pain_finished = 0;
 346                 }
 347                 setattachment(self, world, "");
 348                 if (time > self.pain_finished)
 349                 {
 350                         bprint("The ", self.netname, " has returned to base\n");
 351                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 352                         LogCTF("returned", self.team, world);
 353                         ReturnFlag(self);
 354                 }
 355                 return;
 356         }
 357
 358         e = self.owner;
 359         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 360         {
 361                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 362                 DropFlag(self, world, world);
 363                 return;
 364         }
 365
 366         if(cvar("g_ctf_allow_drop"))
 367         if(e.BUTTON_USE)
 368                 DropFlag(self, e, world);
 369 };
 370
 371 void FlagTouch()
 372 {
 373         if(gameover) return;
 374
 375         local float t;
 376         local entity player;
 377         local string s, s0, h0, h1;
 378         if (other.classname != "player")
 379                 return;
 380         if (other.health < 1) // ignore dead players
 381                 return;
 382
 383         if (self.cnt == FLAG_CARRY)
 384                 return;
 385
 386         if (self.cnt == FLAG_BASE)
 387         if (other.team == self.team)
 388         if (other.flagcarried) // he's got a flag
 389         if (other.flagcarried.team != self.team) // capture
 390         {
 391                 if (other.flagcarried == world)
 392                 {
 393                         return;
 394                 }
 395                 if(player_count - currentbots <= 1) // at most one human
 396                 {
 397                         t = time - other.flagcarried.flagpickuptime;
 398                         s = ftos_decimals(t, 2);
 399                         s0 = ftos_decimals(flagcaptimerecord, 2);
 400                         h0 = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
 401                         h1 = other.netname;
 402                         if(h0 == h1)
 403                                 h0 = "his";
 404                         else
 405                                 h0 = strcat(h0, "^7's"); // h0: display text for previous netname
 406                         if (flagcaptimerecord == 0)
 407                         {
 408                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, " seconds\n");
 409                                 flagcaptimerecord = t;
 410                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 411                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 412                                 GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 413                         }
 414                         else if (t < flagcaptimerecord)
 415                         {
 416                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", breaking ", strcat(h0, " previous record of ", s0, " seconds\n"));
 417                                 flagcaptimerecord = t;
 418                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 419                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 420                                 GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 421                         }
 422                         else
 423                         {
 424                                 bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", failing to break ", strcat(h0, " record of ", s0, " seconds\n"));
 425                         }
 426                 }
 427
 428                 PlayerTeamScore_Add(other, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 429                 LogCTF("capture", other.flagcarried.team, other);
 430                 // give credit to the individual player
 431                 UpdateFrags(other, ctf_score_value("score_capture"));
 432
 433                 sound (other, CHAN_AUTO, self.noise2, VOL_BASE, ATTN_NONE);
 434                 WaypointSprite_DetachCarrier(other);
 435                 if(self.speedrunning)
 436                         FakeTimeLimit(other, -1);
 437                 RegenFlag (other.flagcarried);
 438                 other.flagcarried = world;
 439                 other.next_take_time = time + 1;
 440         }
 441         if (self.cnt == FLAG_BASE)
 442         if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2) // only red and blue team can steal flags
 443         if (other.team != self.team)
 444         if (!other.flagcarried)
 445         if (!other.ctf_captureshielded)
 446         {
 447                 if (other.next_take_time > time)
 448                         return;
 449                 // pick up
 450                 self.flagpickuptime = time; // used for timing runs
 451                 self.speedrunning = other.speedrunning; // if speedrunning, flag will self-return and teleport the owner back after the record
 452                 if(other.speedrunning)
 453                 if(flagcaptimerecord)
 454                         FakeTimeLimit(other, time + flagcaptimerecord);
 455                 self.solid = SOLID_NOT;
 456                 setorigin(self, self.origin); // relink
 457                 self.owner = other;
 458                 other.flagcarried = self;
 459                 self.cnt = FLAG_CARRY;
 460                 self.angles = '0 0 0';
 461                 bprint(other.netname, "^7 got the ", self.netname, "\n");
 462                 UpdateFrags(other, ctf_score_value("score_pickup_base"));
 463                 self.dropperid = other.playerid;
 464                 PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 465                 LogCTF("steal", self.team, other);
 466                 sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 467
 468                 FOR_EACH_PLAYER(player)
 469                         if(player.team == self.team)
 470                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 471
 472                 self.movetype = MOVETYPE_NONE;
 473                 setorigin(self, FLAG_CARRY_POS);
 474                 setattachment(self, other, "");
 475                 WaypointSprite_AttachCarrier("flagcarrier", other);
 476                 WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 477                 WaypointSprite_Ping(self.sprite);
 478
 479                 return;
 480         }
 481
 482         if (self.cnt == FLAG_DROPPED)
 483         {
 484                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 485                 if (other.team == self.team || (other.team != COLOR_TEAM1 && other.team != COLOR_TEAM2))
 486                 {
 487                         // return flag
 488                         bprint(other.netname, "^7 returned the ", self.netname, "\n");
 489
 490                         // punish the player who last had it
 491                         FOR_EACH_PLAYER(player)
 492                                 if(player.playerid == self.dropperid)
 493                                 {
 494                                         PlayerScore_Add(player, SP_SCORE, -ctf_score_value("penalty_returned"));
 495                                         ctf_captureshield_update(player, 0); // shield only
 496                                 }
 497
 498                         // punish the team who was last carrying it
 499                         if(self.team == COLOR_TEAM1)
 500                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, -ctf_score_value("penalty_returned"));
 501                         else
 502                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, -ctf_score_value("penalty_returned"));
 503
 504                         // reward the player who returned it
 505                         if(other.playerid == self.playerid) // is this the guy who killed the FC last?
 506                         {
 507                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 508                                         UpdateFrags(other, ctf_score_value("score_return_by_killer"));
 509                                 else
 510                                         UpdateFrags(other, ctf_score_value("score_return_rogue_by_killer"));
 511                         }
 512                         else
 513                         {
 514                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 515                                         UpdateFrags(other, ctf_score_value("score_return"));
 516                                 else
 517                                         UpdateFrags(other, ctf_score_value("score_return_rogue"));
 518                         }
 519                         PlayerScore_Add(other, SP_CTF_RETURNS, 1);
 520                         LogCTF("return", self.team, other);
 521                         sound (other, CHAN_AUTO, self.noise1, VOL_BASE, ATTN_NONE);
 522                         ReturnFlag(self);
 523                 }
 524                 else if (!other.flagcarried && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_balance_ctf_delay_collect")))
 525                 {
 526                         // pick up
 527                         self.solid = SOLID_NOT;
 528                         setorigin(self, self.origin); // relink
 529                         self.owner = other;
 530                         other.flagcarried = self;
 531                         self.cnt = FLAG_CARRY;
 532                         bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 533
 534                         float f;
 535                         f = bound(0, (self.pain_finished - time) / cvar("g_ctf_flag_returntime"), 1);
 536                         //print("factor is ", ftos(f), "\n");
 537                         f = ctf_score_value("score_pickup_dropped_late") * (1-f)
 538                           + ctf_score_value("score_pickup_dropped_early") * f;
 539                         f = floor(f + 0.5);
 540                         self.dropperid = other.playerid;
 541                         //print("score is ", ftos(f), "\n");
 542
 543                         UpdateFrags(other, f);
 544                         PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 545                         LogCTF("pickup", self.team, other);
 546                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 547
 548                         FOR_EACH_PLAYER(player)
 549                                 if(player.team == self.team)
 550                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 551
 552                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 553                         setorigin(self, FLAG_CARRY_POS);
 554                         setattachment(self, other, "");
 555                         self.damageforcescale = 0;
 556                         WaypointSprite_AttachCarrier("flagcarrier", other);
 557                         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 558                 }
 559         }
 560 };
 561
 562 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 563 CTF Starting point for a player
 564 in team one (Red).
 565
 566 Keys:
 567 "angle"
 568  viewing angle when spawning
 569 */
 570 void spawnfunc_info_player_team1()
 571 {
 572         if(g_assault)
 573         {
 574                 remove(self);
 575                 return;
 576         }
 577         self.team = COLOR_TEAM1; // red
 578         spawnfunc_info_player_deathmatch();
 579 };
 580 //self.team = 4;self.classname = "info_player_start";spawnfunc_info_player_start();};
 581
 582 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 583 CTF Starting point for a player in
 584 team two (Blue).
 585
 586 Keys:
 587 "angle"
 588  viewing angle when spawning
 589 */
 590 void spawnfunc_info_player_team2()
 591 {
 592         if(g_assault)
 593         {
 594                 remove(self);
 595                 return;
 596         }
 597         self.team = COLOR_TEAM2; // blue
 598         spawnfunc_info_player_deathmatch();
 599 };
 600 //self.team = 13;self.classname = "info_player_start";spawnfunc_info_player_start();};
 601
 602 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 603 CTF Starting point for a player in
 604 team three (Magenta).
 605
 606 Keys:
 607 "angle"
 608  viewing angle when spawning
 609 */
 610 void spawnfunc_info_player_team3()
 611 {
 612         if(g_assault)
 613         {
 614                 remove(self);
 615                 return;
 616         }
 617         self.team = COLOR_TEAM3; // purple
 618         spawnfunc_info_player_deathmatch();
 619 };
 620
 621
 622 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 623 CTF Starting point for a player in
 624 team four (Yellow).
 625
 626 Keys:
 627 "angle"
 628  viewing angle when spawning
 629 */
 630 void spawnfunc_info_player_team4()
 631 {
 632         if(g_assault)
 633         {
 634                 remove(self);
 635                 return;
 636         }
 637         self.team = COLOR_TEAM4; // yellow
 638         spawnfunc_info_player_deathmatch();
 639 };
 640
 641
 642
 643
 644 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 645 CTF flag for team one (Red).
 646 Multiple are allowed.
 647
 648 Keys:
 649 "angle"
 650  Angle the flag will point
 651 (minus 90 degrees)
 652 "model"
 653  model to use, note this needs red and blue as skins 0 and 1
 654  (default models/ctf/flag.md3)
 655 "noise"
 656  sound played when flag is picked up
 657  (default ctf/take.wav)
 658 "noise1"
 659  sound played when flag is returned by a teammate
 660  (default ctf/return.wav)
 661 "noise2"
 662  sound played when flag is captured
 663  (default ctf/redcapture.wav)
 664 "noise3"
 665  sound played when flag is lost in the field and respawns itself
 666  (default ctf/respawn.wav)
 667 */
 668
 669 void spawnfunc_item_flag_team1()
 670 {
 671         if (!g_ctf)
 672         {
 673                 remove(self);
 674                 return;
 675         }
 676
 677         //if(!cvar("teamplay"))
 678         //      cvar_set("teamplay", "3");
 679
 680         // link flag into ctf_worldflaglist
 681         self.ctf_worldflagnext = ctf_worldflaglist;
 682         ctf_worldflaglist = self;
 683
 684         self.classname = "item_flag_team";
 685         if(g_ctf_reverse)
 686         {
 687                 self.team = COLOR_TEAM2; // color 13 team (blue)
 688                 self.items = IT_KEY1; // silver key (bluish enough)
 689         }
 690         else
 691         {
 692                 self.team = COLOR_TEAM1; // color 4 team (red)
 693                 self.items = IT_KEY2; // gold key (redish enough)
 694         }
 695         self.netname = "^1RED^7 flag";
 696         self.target = "###item###";
 697         self.skin = 0;
 698         if(self.spawnflags & 1)
 699                 self.noalign = 1;
 700         if (!self.model)
 701                 self.model = "models/ctf/flag_red.md3";
 702         if (!self.noise)
 703                 self.noise = "ctf/take.wav";
 704         if (!self.noise1)
 705                 self.noise1 = "ctf/return.wav";
 706         if (!self.noise2)
 707                 self.noise2 = "ctf/redcapture.wav"; // blue team scores by capturing the red flag
 708         if (!self.noise3)
 709                 self.noise3 = "ctf/respawn.wav";
 710         precache_model (self.model);
 711         setmodel (self, self.model); // precision set below
 712         precache_sound (self.noise);
 713         precache_sound (self.noise1);
 714         precache_sound (self.noise2);
 715         precache_sound (self.noise3);
 716         //setsize(self, '-16 -16 -37', '16 16 37');
 717         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 718         setorigin(self, self.origin + '0 0 37');
 719         self.nextthink = time + 0.2; // start after doors etc
 720         self.think = place_flag;
 721
 722         if(!self.scale)
 723                 self.scale = 0.6;
 724         //if(!self.glow_size)
 725         //      self.glow_size = 50;
 726
 727         self.effects = self.effects | EF_LOWPRECISION;
 728         if(cvar("g_ctf_fullbrightflags"))
 729                 self.effects |= EF_FULLBRIGHT;
 730
 731         waypoint_spawnforitem(self);
 732
 733         WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 37', self, sprite);
 734         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '1 0 0');
 735
 736         precache_model("models/onslaught/generator_shield.md3");
 737 };
 738
 739 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 740 CTF flag for team two (Blue).
 741 Multiple are allowed.
 742
 743 Keys:
 744 "angle"
 745  Angle the flag will point
 746 (minus 90 degrees)
 747 "model"
 748  model to use, note this needs red and blue as skins 0 and 1
 749  (default models/ctf/flag.md3)
 750 "noise"
 751  sound played when flag is picked up
 752  (default ctf/take.wav)
 753 "noise1"
 754  sound played when flag is returned by a teammate
 755  (default ctf/return.wav)
 756 "noise2"
 757  sound played when flag is captured
 758  (default ctf/bluecapture.wav)
 759 "noise3"
 760  sound played when flag is lost in the field and respawns itself
 761  (default ctf/respawn.wav)
 762 */
 763
 764 void spawnfunc_item_flag_team2()
 765 {
 766         if (!g_ctf)
 767         {
 768                 remove(self);
 769                 return;
 770         }
 771         //if(!cvar("teamplay"))
 772         //      cvar_set("teamplay", "3");
 773
 774         // link flag into ctf_worldflaglist
 775         self.ctf_worldflagnext = ctf_worldflaglist;
 776         ctf_worldflaglist = self;
 777
 778         self.classname = "item_flag_team";
 779         if(g_ctf_reverse)
 780         {
 781                 self.team = COLOR_TEAM1; // color 4 team (red)
 782                 self.items = IT_KEY2; // gold key (redish enough)
 783         }
 784         else
 785         {
 786                 self.team = COLOR_TEAM2; // color 13 team (blue)
 787                 self.items = IT_KEY1; // silver key (bluish enough)
 788         }
 789         self.netname = "^4BLUE^7 flag";
 790         self.target = "###item###";
 791         self.skin = 0;
 792         if(self.spawnflags & 1)
 793                 self.noalign = 1;
 794         if (!self.model)
 795                 self.model = "models/ctf/flag_blue.md3";
 796         if (!self.noise)
 797                 self.noise = "ctf/take.wav";
 798         if (!self.noise1)
 799                 self.noise1 = "ctf/return.wav";
 800         if (!self.noise2)
 801                 self.noise2 = "ctf/bluecapture.wav"; // red team scores by capturing the blue flag
 802         if (!self.noise3)
 803                 self.noise3 = "ctf/respawn.wav";
 804         precache_model (self.model);
 805         setmodel (self, self.model); // precision set below
 806         precache_sound (self.noise);
 807         precache_sound (self.noise1);
 808         precache_sound (self.noise2);
 809         precache_sound (self.noise3);
 810         //setsize(self, '-16 -16 -37', '16 16 37');
 811         setsize(self, PL_MIN + '0 0 -13', PL_MAX + '0 0 -13');
 812         setorigin(self, self.origin + '0 0 37');
 813         self.nextthink = time + 0.2; // start after doors etc
 814         self.think = place_flag;
 815
 816         if(!self.scale)
 817                 self.scale = 0.6;
 818         //if(!self.glow_size)
 819         //      self.glow_size = 50;
 820
 821         self.effects = self.effects | EF_LOWPRECISION;
 822         if(cvar("g_ctf_fullbrightflags"))
 823                 self.effects |= EF_FULLBRIGHT;
 824
 825         waypoint_spawnforitem(self);
 826
 827         WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 37', self, sprite);
 828         WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, '0 0 1');
 829
 830         precache_model("models/onslaught/generator_shield.md3");
 831 };
 832
 833
 834 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 835 Team declaration for CTF gameplay, this allows you to decide what team
 836 names and control point models are used in your map.
 837
 838 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike
 839 domination, you don't need to make a blank one too.
 840
 841 Keys:
 842 "netname"
 843  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 844 "cnt"
 845  Scoreboard color of the team (for example 4 is red and 13 is blue)
 846
 847 */
 848
 849 void spawnfunc_ctf_team()
 850 {
 851         if (!g_ctf)
 852         {
 853                 remove(self);
 854                 return;
 855         }
 856         self.classname = "ctf_team";
 857         self.team = self.cnt + 1;
 858 };
 859
 860 // code from here on is just to support maps that don't have control point and team entities
 861 void ctf_spawnteam (string teamname, float teamcolor)
 862 {
 863         local entity oldself;
 864         oldself = self;
 865         self = spawn();
 866         self.classname = "ctf_team";
 867         self.netname = teamname;
 868         self.cnt = teamcolor;
 869
 870         spawnfunc_ctf_team();
 871
 872         self = oldself;
 873 };
 874
 875 // spawn some default teams if the map is not set up for ctf
 876 void ctf_spawnteams()
 877 {
 878         float numteams;
 879
 880         numteams = 2;//cvar("g_ctf_default_teams");
 881
 882         ctf_spawnteam("Red", COLOR_TEAM1 - 1);
 883         ctf_spawnteam("Blue", COLOR_TEAM2 - 1);
 884 };
 885
 886 void ctf_delayedinit()
 887 {
 888         // if no teams are found, spawn defaults
 889         if (find(world, classname, "ctf_team") == world)
 890                 ctf_spawnteams();
 891
 892         ScoreRules_ctf();
 893 };
 894
 895 void ctf_init()
 896 {
 897         InitializeEntity(world, ctf_delayedinit, INITPRIO_GAMETYPE);
 898         flagcaptimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
 899
 900         captureshield_min_negscore = cvar("g_ctf_shield_min_negscore");
 901         captureshield_max_ratio = cvar("g_ctf_shield_max_ratio");
 902         captureshield_force = cvar("g_ctf_shield_force");
 903 };
 904
 905 void ctf_setstatus2(entity flag, float shift)
 906 {
 907         if (flag.cnt == FLAG_CARRY)
 908                 if (flag.owner == self)
 909                         self.items |= shift * 3;
 910                 else
 911                         self.items |= shift * 1;
 912         else if (flag.cnt == FLAG_DROPPED)
 913                 self.items |= shift * 2;
 914         else
 915         {
 916                 // no status bits
 917         }
 918 };
 919
 920 void ctf_setstatus()
 921 {
 922         self.items (-) IT_RED_FLAG_TAKEN;
 923         self.items (-) IT_RED_FLAG_LOST;
 924         self.items (-) IT_BLUE_FLAG_TAKEN;
 925         self.items (-) IT_BLUE_FLAG_LOST;
 926         self.items (-) IT_CTF_SHIELDED;
 927
 928         if (g_ctf) {
 929                 local entity flag;
 930                 float redflags, blueflags;
 931
 932                 if(self.ctf_captureshielded)
 933                         self.items |= IT_CTF_SHIELDED;
 934
 935                 redflags = 0;
 936                 blueflags = 0;
 937
 938                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 939                 {
 940                         if(flag.items & IT_KEY2) // blue
 941                                 ++redflags;
 942                         else if(flag.items & IT_KEY1) // red
 943                                 ++blueflags;
 944                 }
 945
 946                 // blinking magic: if there is more than one flag, show one of these in a clever way
 947                 if(redflags)
 948                         redflags = mod(floor(time * redflags * 0.75), redflags);
 949                 if(blueflags)
 950                         blueflags = mod(floor(time * blueflags * 0.75), blueflags);
 951
 952                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 953                 {
 954                         if(flag.items & IT_KEY2) // blue
 955                         {
 956                                 if(--redflags == -1) // happens exactly once (redflags is in 0..count-1, and will --'ed count times)
 957                                         ctf_setstatus2(flag, IT_RED_FLAG_TAKEN);
 958                         }
 959                         else if(flag.items & IT_KEY1) // red
 960                         {
 961                                 if(--blueflags == -1) // happens exactly once
 962                                         ctf_setstatus2(flag, IT_BLUE_FLAG_TAKEN);
 963                         }
 964                 }
 965         }
 966 };
 967 /*
 968 entity(float cteam) ctf_team_has_commander =
 969 {
 970         entity pl;
 971         if(cteam != COLOR_TEAM1 || cteam != COLOR_TEAM2)
 972                 return world;
 973
 974         FOR_EACH_REALPLAYER(pl) {
 975                 if(pl.team == cteam && pl.iscommander) {
 976                         return pl;
 977                 }
 978         }
 979         return world;
 980 };
 981
 982 void(entity e, float st) ctf_setstate =
 983 {
 984         e.ctf_state = st;
 985         ++e.version;
 986 };
 987
 988 void(float cteam) ctf_new_commander =
 989 {
 990         entity pl, plmax;
 991
 992         plmax = world;
 993         FOR_EACH_REALPLAYER(pl) {
 994                 if(pl.team == cteam) {
 995                         if(pl.iscommander) { // don't reassign if alreay there
 996                                 return;
 997                         }
 998                         if(plmax == world || plmax.frags < pl.frags) <<<<<<<<<<<<<<<<< BROKEN in new scoring system
 999                                 plmax = pl;
1000                 }
1001         }
1002         if(plmax == world) {
1003                 bprint(strcat(ColoredTeamName(cteam), " Team has no Commander!\n"));
1004                 return;
1005         }
1006
1007         plmax.iscommander = TRUE;
1008         ctf_setstate(plmax, 3);
1009         sprint(plmax, "^3You're the commander now!\n");
1010         centerprint(plmax, "^3You're the commander now!\n");
1011 };
1012
1013 void() ctf_clientconnect =
1014 {
1015         self.iscommander = FALSE;
1016
1017         if(!self.team || self.classname != "player") {
1018                 ctf_setstate(self, -1);
1019         } else
1020                 ctf_setstate(self, 0);
1021
1022         self.team_saved = self.team;
1023
1024         if(self.team != 0 && self.classname == "player" && !ctf_team_has_commander(self.team)) {
1025                 ctf_new_commander(self.team);
1026         }
1027 };
1028
1029 void() ctf_playerchanged =
1030 {
1031         if(!self.team || self.classname != "player") {
1032                 ctf_setstate(self, -1);
1033         } else if(self.ctf_state < 0 && self.classname == "player") {
1034                 ctf_setstate(self, 0);
1035         }
1036
1037         if(self.iscommander &&
1038            (self.classname != "player" || self.team != self.team_saved)
1039                 )
1040         {
1041                 self.iscommander = FALSE;
1042                 if(self.classname == "player")
1043                         ctf_setstate(self, 0);
1044                 else
1045                         ctf_setstate(self, -1);
1046                 ctf_new_commander(self.team_saved);
1047         }
1048
1049         self.team_saved = self.team;
1050
1051         ctf_new_commander(self.team);
1052 };
1053
1054 void() ctf_clientdisconnect =
1055 {
1056         if(self.iscommander)
1057         {
1058                 ctf_new_commander(self.team);
1059         }
1060 };
1061
1062 entity GetPlayer(string);
1063 float() ctf_clientcommand =
1064 {
1065         entity e;
1066         if(argv(0) == "order") {
1067                 if(!g_ctf) {
1068                         sprint(self, "This command is not supported in this gamemode.\n");
1069                         return TRUE;
1070                 }
1071                 if(!self.iscommander) {
1072                         sprint(self, "^1You are not the commander!\n");
1073                         return TRUE;
1074                 }
1075                 if(argv(2) == "") {
1076                         sprint(self, "Usage: order #player status   - (playernumber as in status)\n");
1077                         return TRUE;
1078                 }
1079                 e = GetPlayer(argv(1));
1080                 if(e == world) {
1081                         sprint(self, "Invalid player.\nUsage: order #player status   - (playernumber as in status)\n");
1082                         return TRUE;
1083                 }
1084                 if(e.team != self.team) {
1085                         sprint(self, "^3You can only give orders to your own team!\n");
1086                         return TRUE;
1087                 }
1088                 if(argv(2) == "attack") {
1089                         sprint(self, strcat("Ordering ", e.netname, " to attack!\n"));
1090                         sprint(e, "^1Attack!\n");
1091                         centerprint(e, "^7You've been ordered to^9\n^1Attack!\n");
1092                         ctf_setstate(e, 1);
1093                 } else if(argv(2) == "defend") {
1094                         sprint(self, strcat("Ordering ", e.netname, " to defend!\n"));
1095                         sprint(e, "^Defend!\n");
1096                         centerprint(e, "^7You've been ordered to^9\n^2Defend!\n");
1097                         ctf_setstate(e, 2);
1098                 } else {
1099                         sprint(self, "^7Invalid command, use ^3attack^7, or ^3defend^7.\n");
1100                 }
1101                 return TRUE;
1102         }
1103         return FALSE;
1104 };
1105 */