data/qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags;
   6         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   7
   8         nags = 0;
   9         if(readycount)
  10         {
  11                 nags |= 1;
  12                 if(to.ready == 0)
  13                         nags |= 2;
  14         }
  15         if(votecalled)
  16         {
  17                 nags |= 4;
  18                 if(to.vote_vote == 0)
  19                         nags |= 8;
  20         }
  21
  22         if(sendflags & 128)
  23         {
  24                 WriteByte(MSG_ENTITY, nags | 128);
  25                 if(votecalled)
  26                         WriteString(MSG_ENTITY, votecalledvote_display);
  27                 else
  28                         WriteString(MSG_ENTITY, "");
  29         }
  30         else
  31                 WriteByte(MSG_ENTITY, nags);
  32
  33         return TRUE;
  34 }
  35 void Nagger_Init()
  36 {
  37         nagger = spawn();
  38         Net_LinkEntity(nagger);
  39         nagger.SendFlags = 128;
  40         nagger.SendEntity = Nagger_SendEntity;
  41 }
  42 void Nagger_VoteChanged()
  43 {
  44         if(nagger)
  45                 nagger.SendFlags = 128;
  46 }
  47 void Nagger_VoteCountChanged()
  48 {
  49         if(nagger)
  50                 nagger.SendFlags = 1;
  51 }
  52 void Nagger_ReadyCounted()
  53 {
  54         if(nagger)
  55                 nagger.SendFlags = 1;
  56 }
  57
  58 void ReadyCount();
  59 string MapVote_Suggest(string m);
  60
  61 .float floodcontrol_chat;
  62 .float floodcontrol_team;
  63 void Say(entity source, float teamsay, string msgin)
  64 {
  65         string msgstr, colorstr, cmsgstr, namestr;
  66         float flood;
  67         entity head;
  68
  69         if(Ban_MaybeEnforceBan(source))
  70                 return;
  71
  72         if(!teamsay)
  73                 if(substring(msgin, 0, 1) == " ")
  74                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  75
  76         msgin = formatmessage(msgin);
  77
  78         if(msgin == "")
  79                 return;
  80
  81         if(source.classname != "player")
  82                 colorstr = "^0"; // black for spectators
  83         else if(teams_matter)
  84                 colorstr = Team_ColorCode(source.team);
  85         else
  86                 teamsay = FALSE;
  87
  88         if(intermission_running)
  89                 teamsay = FALSE;
  90
  91         /*
  92          * using bprint solves this... me stupid
  93         // how can we prevent the message from appearing in a listen server?
  94         // for now, just give "say" back and only handle say_team
  95         if(!teamsay)
  96         {
  97                 clientcommand(self, strcat("say ", msgin));
  98                 return;
  99         }
 100         */
 101
 102         if(cvar("g_chat_teamcolors"))
 103                 namestr = playername(source);
 104         else
 105                 namestr = source.netname;
 106         if(teamsay)
 107         {
 108                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
 109                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
 110         }
 111         else
 112                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
 113
 114         // FLOOD CONTROL
 115         flood = 0;
 116         {
 117                 float flood_spl;
 118                 float flood_burst;
 119                 float flood_lmax;
 120                 var .float flood_field;
 121                 float lines;
 122                 if(teamsay)
 123                 {
 124                         flood_spl = cvar("g_chat_flood_spl_team");
 125                         flood_burst = cvar("g_chat_flood_burst_team");
 126                         flood_lmax = cvar("g_chat_flood_lmax_team");
 127                         flood_field = floodcontrol_team;
 128                 }
 129                 else
 130                 {
 131                         flood_spl = cvar("g_chat_flood_spl");
 132                         flood_burst = cvar("g_chat_flood_burst");
 133                         flood_lmax = cvar("g_chat_flood_lmax");
 134                         flood_field = floodcontrol_chat;
 135                 }
 136                 flood_burst = max(0, flood_burst - 1);
 137                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 138                 lines = ceil(strlennocol(msgstr) / 75);
 139                 if(flood_lmax && lines > flood_lmax)
 140                         flood = 2;
 141                 else if(time >= self.flood_field)
 142                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
 143                 else
 144                         flood = 1;
 145         }
 146
 147         if(flood)
 148         {
 149                 if(cvar("g_chat_flood_notify_flooder"))
 150                 {
 151                         if(flood == 1)
 152                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
 153                         else if(flood == 2)
 154                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
 155                 }
 156                 else
 157                         sprint(self, msgstr);
 158                 print("NOTE: ", playername(self), "^7 is flooding.\n");
 159         }
 160         else if(teamsay)
 161         {
 162                 if(source.classname == "player")
 163                 {
 164                         FOR_EACH_REALPLAYER(head)
 165                         {
 166                                 if(head.team == source.team)
 167                                 {
 168                                         sprint(head, msgstr);
 169                                         centerprint(head, cmsgstr);
 170                                 }
 171                         }
 172                 }
 173                 else
 174                 {
 175                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 176                         {
 177                                 sprint(head, msgstr);
 178                                 centerprint(head, cmsgstr);
 179                         }
 180                 }
 181         }
 182         else
 183         {
 184                 // TODO invent a cvar name for allowing global chat by spectators during warmup anyway
 185                 if(cvar("g_chat_nospectators") && source.classname != "player") {
 186                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 187                                 sprint(head, msgstr);
 188                         }
 189                 }
 190                 else
 191                         bprint(msgstr);
 192         }
 193
 194         strunzone(msgstr);
 195 }
 196
 197 entity GetPlayer(string name)
 198 {
 199         float num;
 200         entity e;
 201         string ns;
 202
 203         if(substring(name, 0, 1) == "#") {
 204                 num = stof(substring(name, 1, 999));
 205                 if(num >= 1 && num <= maxclients) {
 206                         for((e = world); num > 0; --num, (e = nextent(e)))
 207                                 ;
 208                         //if(clienttype(e) == CLIENTTYPE_REAL)
 209                         if(e.classname == "player")
 210                                 return e;
 211                 }
 212         } else {
 213                 ns = strdecolorize(name);
 214                 FOR_EACH_REALPLAYER(e) {
 215                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 216                                 return e;
 217                         }
 218                 }
 219         }
 220         return world;
 221 }
 222
 223 //float ctf_clientcommand();
 224 void SV_ParseClientCommand(string s) {
 225         local string cmd;
 226         local float i, j, tokens;
 227
 228         tokens = tokenize_sane(s);
 229
 230         if(GameCommand_Vote(s, self)) {
 231                 return;
 232         } else if(GameCommand_MapVote(argv(0))) {
 233                 return;
 234         } else if(argv(0) == "autoswitch") {
 235                 // be backwards compatible with older clients (enabled)
 236                 self.autoswitch = ("0" != argv(1));
 237                 local string autoswitchmsg;
 238                 if (self.autoswitch) {
 239                         autoswitchmsg = "on";
 240                 } else {
 241                         autoswitchmsg = "off";
 242                 }
 243                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 244         } else if(argv(0) == "clientversion") {
 245                 if not(self.flags & FL_CLIENT)
 246                         return;
 247                 if (argv(1) == "$gameversion") {
 248                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 249                         // either that or someone wants to be funny
 250                         self.version = 1;
 251                 } else {
 252                         self.version = stof(argv(1));
 253                 }
 254                 if(self.version != cvar("gameversion"))
 255                 {
 256                         self.classname = "observer";
 257                         self.version_mismatch = 1;
 258                         PutClientInServer();
 259                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 260                         //JoinBestTeam(self, FALSE, TRUE);
 261                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 262                         self.classname = "observer";
 263                         stuffcmd(self,"menu_showteamselect\n");
 264                 }
 265         } else if(argv(0) == "reportcvar") { // old system
 266                 GetCvars(1);
 267         } else if(argv(0) == "sentcvar") { // new system
 268                 GetCvars(1);
 269         } else if(argv(0) == "spectate") {
 270                 if not(self.flags & FL_CLIENT)
 271                         return;
 272                 if(g_lms || g_arena)
 273                         return; // don't allow spectating in lms, unless player runs out of lives
 274                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 275                         if(self.flagcarried)
 276                                 DropFlag(self.flagcarried, world, world);
 277                         kh_Key_DropAll(self, TRUE);
 278                         WaypointSprite_PlayerDead();
 279                         self.classname = "observer";
 280                         if(blockSpectators)
 281                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 282                         PutClientInServer();
 283                 }
 284         } else if(argv(0) == "join") {
 285                 if not(self.flags & FL_CLIENT)
 286                         return;
 287                 if(!g_arena)
 288                 if (self.classname != "player" && !lockteams)
 289                 {
 290                         if(isJoinAllowed()) {
 291                                 self.classname = "player";
 292                                 PlayerScore_Clear(self);
 293                                 bprint ("^4", self.netname, "^4 is playing now\n");
 294                                 PutClientInServer();
 295                         }
 296                         else {
 297                                 //player may not join because of g_maxplayers is set
 298                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 299                         }
 300                 }
 301         } else if( argv(0) == "selectteam" ) {
 302                 if not(self.flags & FL_CLIENT)
 303                         return;
 304                 if( !cvar("teamplay") ) {
 305                         sprint( self, "selecteam can only be used in teamgames\n");
 306                 } else if(cvar("g_campaign")) {
 307                         //JoinBestTeam(self, 0);
 308                 } else if(lockteams) {
 309                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 310                 } else if( argv(1) == "red" ) {
 311                         DoTeamChange(COLOR_TEAM1);
 312                 } else if( argv(1) == "blue" ) {
 313                         DoTeamChange(COLOR_TEAM2);
 314                 } else if( argv(1) == "yellow" ) {
 315                         DoTeamChange(COLOR_TEAM3);
 316                 } else if( argv(1) == "pink" ) {
 317                         DoTeamChange(COLOR_TEAM4);
 318                 } else if( argv(1) == "auto" ) {
 319                         DoTeamChange(-1);
 320                 } else {
 321                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 322                 }
 323         } else if(argv(0) == "ready") {
 324                 if not(self.flags & FL_CLIENT)
 325                         return;
 326                 if((inWarmupStage && 0 < g_warmup_limit) // with unlimited warmup players have to be able to restart
 327                    || cvar("sv_ready_restart"))
 328                 {
 329                         if(timeoutStatus) {
 330                                 return sprint(self, "^1You cannot reset the game while a timeout is active!\n");
 331                         }
 332
 333                         if(game_starttime == 0 || cvar("sv_ready_restart_repeatable"))
 334                         {
 335                                 self.ready = TRUE;
 336                                 bprint(self.netname, "^2 is ready\n");
 337                                 ReadyCount();
 338                         } else {
 339                                 sprint(self, "^1game has already been restarted\n");
 340                         }
 341                 }
 342         } else if(argv(0) == "maplist") {
 343                 local float n;
 344                 local string col;
 345                 n = tokenize_sane(cvar_string("g_maplist"));
 346                 sprint(self, "^7Maps in list: ");
 347                 for(i = 0, j = 0; i < n; ++i)
 348                 {
 349                         if(MapInfo_CheckMap(argv(i)))
 350                         {
 351                                 if(mod(j, 2))
 352                                         col = "^2";
 353                                 else
 354                                         col = "^3";
 355                                 sprint(self, strcat(col, argv(i), " "));
 356                                 ++j;
 357                         }
 358                 }
 359                 sprint(self, "\n");
 360         } else if(argv(0) == "lsmaps") {
 361                 sprint(self, "^7Maps available: ");
 362                 for(i = 0, j = 0; i < MapInfo_count; ++i)
 363                 {
 364                         if(MapInfo_Get_ByID(i))
 365                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 366                         {
 367                                 if(mod(i, 2))
 368                                         col = "^2";
 369                                 else
 370                                         col = "^3";
 371                                 ++j;
 372                                 sprint(self, strcat(col, MapInfo_Map_bspname, " "));
 373                         }
 374                 }
 375                 sprint(self, "\n");
 376         } else if(argv(0) == "voice") {
 377                 VoiceMessage(argv(1));
 378         } else if(argv(0) == "say") {
 379                 if(tokens >= 2)
 380                         Say(self, FALSE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 381                 //clientcommand(self, formatmessage(s));
 382         } else if(argv(0) == "say_team") {
 383                 if(tokens >= 2)
 384                         Say(self, TRUE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 385                 //clientcommand(self, formatmessage(s));
 386         } else if(argv(0) == "info") {
 387                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 388                 if(cmd == "")
 389                         sprint(self, "ERROR: unsupported info command\n");
 390                 else
 391                         wordwrap_sprint(cmd, 1111);
 392         } else if(argv(0) == "suggestmap") {
 393                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 394         } else if(argv(0) == "calltimeout") {
 395                 if not(self.flags & FL_CLIENT)
 396                         return;
 397                 if(cvar("sv_timeout")) {
 398                         if(self.classname == "player") {
 399                                 if(votecalled)
 400                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 401                                 else
 402                                         evaluateTimeoutCall();
 403                         }
 404                         else
 405                                 sprint(self, "^7Error: only players can call a timeout!\n");
 406                 }
 407         } else if(argv(0) == "resumegame") {
 408                 if not(self.flags & FL_CLIENT)
 409                         return;
 410                 if(cvar("sv_timeout")) {
 411                         evaluateResumeGame();
 412                 }
 413         } else if(argv(0) == "teamstatus") {
 414                 Score_NicePrint(self);
 415         } else if(argv(0) == "cvar_changes") {
 416                 sprint(self, cvar_changes);
 417         } else {
 418                 //if(ctf_clientcommand())
 419                 //      return;
 420                 cmd = argv(0);
 421                 /* checks not needed any more since DP has separated clientcommands and regular commands
 422                 if(cmd != "status")
 423                 if(cmd != "name")
 424                 //if(cmd != "say") // handled above
 425                 //if(cmd != "say_team") // handled above
 426                 if(cmd != "tell")
 427                 if(cmd != "color")
 428                 if(cmd != "kill")
 429                 if(cmd != "pause")
 430                 if(cmd != "kick")
 431                 if(cmd != "ping")
 432                 if(cmd != "pings")
 433                 if(cmd != "ban")
 434                 if(cmd != "pmodel")
 435                 if(cmd != "rate")
 436                 if(cmd != "playermodel")
 437                 if(cmd != "playerskin")
 438                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 439                 {
 440                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 441                         return;
 442                 }
 443                 */
 444                 clientcommand(self,s);
 445         }
 446 }
 447
 448 void ReadyRestart()
 449 {
 450         local entity e;
 451
 452         bprint("^1Server is restarting...\n");
 453
 454         VoteReset();
 455
 456         // no arena, assault support yet...
 457         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 458                 localcmd("restart\n");
 459
 460         // clear overtime
 461         if(checkrules_overtimeend)
 462                 checkrules_overtimeend = 0;
 463
 464         game_starttime = time + RESTART_COUNTDOWN;
 465         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 466
 467         inWarmupStage = 0; //once the game is restarted the game is in match stage
 468
 469         //reset the .ready status of all players (also spectators)
 470         FOR_EACH_CLIENTSLOT(e)
 471                 e.ready = 0;
 472         readycount = 0;
 473         Nagger_ReadyCounted();
 474         FOR_EACH_REALCLIENT(e)
 475         {
 476                 msg_entity = e;
 477                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
 478                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
 479                 WriteByte(MSG_ONE, 0);
 480         }
 481
 482         if(cvar("teamplay_lockonrestart") && teams_matter) {
 483                 lockteams = 1;
 484                 bprint("^1The teams are now locked.\n");
 485         }
 486
 487         //initiate the restart-countdown-announcer entity
 488         restartAnnouncer = spawn();
 489         restartAnnouncer.think = restartAnnouncer_Think;
 490         restartAnnouncer.nextthink = time;
 491         restartAnnouncer.cnt = RESTART_COUNTDOWN;
 492
 493         //after a restart every players number of allowed timeouts gets reset, too
 494         if(cvar("sv_timeout"))
 495         {
 496                 FOR_EACH_REALPLAYER(e)
 497                         e.allowedTimeouts = cvar("sv_timeout_number");
 498         }
 499
 500         //play the prepareforbattle sound to everyone
 501         play2all("announcer/robotic/prepareforbattle.wav");
 502
 503         //reset map immediately if this cvar is not set
 504         if (!cvar("sv_ready_restart_after_countdown"))
 505                 reset_map();
 506
 507         // reset ALL scores
 508         Score_ClearAll();
 509
 510         if(cvar("sv_eventlog"))
 511                 GameLogEcho(":restart");
 512 }
 513
 514 /**
 515  * Counts how many players are ready. If not enough players are ready, the function
 516  * does nothing. If all players are ready, the timelimit will be extended and the
 517  * restart_countdown variable is set to allow other functions like PlayerPostThink
 518  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 519  * is not set the map will be resetted.
 520  *
 521  * Function is called after the server receives a 'ready' sign from a player.
 522  */
 523 void ReadyCount()
 524 {
 525         local entity e;
 526         local float r, p;
 527
 528         r = p = 0;
 529
 530         FOR_EACH_REALPLAYER(e)
 531         {
 532                 p += 1;
 533                 if(e.ready)
 534                         r += 1;
 535         }
 536
 537         readycount = r;
 538
 539         if(r) // at least one is ready
 540         if(r == p) // and, everyone is ready
 541                 ReadyRestart();
 542
 543         Nagger_ReadyCounted();
 544 }
 545
 546 /**
 547  * Shows the restart countdown for all players.
 548  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 549  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 550  * is set to 1).
 551  */
 552 void restartAnnouncer_Think() {
 553         local entity plr;
 554         local string s;
 555         if(self.cnt <= 0) { //show the "Begin" message and
 556                 if (cvar("sv_ready_restart_after_countdown")) {
 557                         restart_mapalreadyrestarted = 1;
 558                         reset_map();
 559                 }
 560
 561                 FOR_EACH_REALCLIENT(plr) {
 562                         if(plr.classname == "player") {
 563                                 s = strcat(NEWLINES, "^1Begin!");
 564                                 centerprint(plr, s);
 565                         }
 566                 }
 567                 play2all("announcer/robotic/begin.wav");
 568
 569                 remove(self);
 570                 return;
 571         }
 572         else {
 573                 FOR_EACH_REALCLIENT(plr) {
 574                         if(plr.classname == "player") {
 575                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(self.cnt), " seconds");
 576                                 centerprint(plr, s);
 577                         }
 578                 }
 579
 580                 if(self.cnt <= 3) {
 581                         play2all(strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 582                 }
 583                 self.nextthink = time + 1;
 584                 self.cnt -= 1;
 585         }
 586 }
 587
 588 /**
 589  * Checks whether the player who calls the timeout is allowed to do so.
 590  * If so, it initializes the timeout countdown. It also checks whether another
 591  * timeout was already running at this time and reacts correspondingly.
 592  *
 593  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 594  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 595  *
 596  * This function is called when a player issues the calltimeout command.
 597  */
 598 void evaluateTimeoutCall() {
 599         if (inWarmupStage && !g_warmup_allow_timeout)
 600                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 601         if (time < game_starttime )
 602                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 603         if (timeoutStatus != 2) {
 604                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 605                 if (cvar("timelimit")) {
 606                         //a timelimit was used
 607                         local float myTl;
 608                         myTl = cvar("timelimit");
 609
 610                         local float lastPossibleTimeout;
 611                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 612
 613                         if (lastPossibleTimeout < time - game_starttime)
 614                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 615                 }
 616         }
 617         //player may not call a timeout if he has no calls left
 618         if (self.allowedTimeouts < 1)
 619                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 620         //now all required checks are passed
 621         self.allowedTimeouts -= 1;
 622         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 623         remainingTimeoutTime = cvar("sv_timeout_length");
 624         remainingLeadTime = cvar("sv_timeout_leadtime");
 625         timeoutInitiator = self;
 626         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 627                 timeoutStatus = 1;
 628                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 629                 timeoutHandler = spawn();
 630                 timeoutHandler.think = timeoutHandler_Think;
 631         }
 632         timeoutHandler.nextthink = time; //always let the entity think asap
 633
 634         //inform all connected clients about the timeout call
 635         play2all("announcer/robotic/timeoutcalled.wav");
 636 }
 637
 638 /**
 639  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 640  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 641  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 642  * value of the cvar sv_timeout_resumetime.
 643  *
 644  * This function is called when a player issues the resumegame command.
 645  */
 646 void evaluateResumeGame() {
 647         if (!timeoutStatus)
 648                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 649         if (self != timeoutInitiator)
 650                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 651         if (timeoutStatus == 1) {
 652                 remainingTimeoutTime = timeoutStatus = 0;
 653                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 654                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 655         }
 656         else if (timeoutStatus == 2) {
 657                 //only shorten the remainingTimeoutTime if it makes sense
 658                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 659                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 660                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 661                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 662                 }
 663                 else
 664                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 665
 666         }
 667 }