data/qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 if(votecalled)
  33                         WriteString(MSG_ENTITY, votecalledvote_display);
  34                 else
  35                         WriteString(MSG_ENTITY, "");
  36         }
  37
  38         if(nags & 1)
  39         {
  40                 for(i = 1; i <= maxclients; i += 8)
  41                 {
  42                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  43                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  44                                         f |= b;
  45                         WriteByte(MSG_ENTITY, f);
  46                 }
  47         }
  48
  49         return TRUE;
  50 }
  51 void Nagger_Init()
  52 {
  53         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  54 }
  55 void Nagger_VoteChanged()
  56 {
  57         if(nagger)
  58                 nagger.SendFlags |= 128;
  59 }
  60 void Nagger_VoteCountChanged()
  61 {
  62         if(nagger)
  63                 nagger.SendFlags |= 1;
  64 }
  65 void Nagger_ReadyCounted()
  66 {
  67         if(nagger)
  68                 nagger.SendFlags |= 1;
  69 }
  70
  71 void ReadyCount();
  72 string MapVote_Suggest(string m);
  73
  74 entity GetPlayer(string name)
  75 {
  76         float num;
  77         entity e;
  78         string ns;
  79
  80         if(substring(name, 0, 1) == "#") {
  81                 num = stof(substring(name, 1, 999));
  82                 if(num >= 1 && num <= maxclients) {
  83                         for((e = world); num > 0; --num, (e = nextent(e)))
  84                                 ;
  85                         //if(clienttype(e) == CLIENTTYPE_REAL)
  86                         if(e.classname == "player")
  87                                 return e;
  88                 }
  89         } else {
  90                 ns = strdecolorize(name);
  91                 FOR_EACH_REALPLAYER(e) {
  92                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  93                                 return e;
  94                         }
  95                 }
  96         }
  97         return world;
  98 }
  99
 100 //float ctf_clientcommand();
 101 float readyrestart_happened;
 102 .float lms_spectate_warning;
 103 void SV_ParseClientCommand(string s) {
 104         local string cmd;
 105         local float tokens, f, effectnum;
 106         local vector start, end;
 107
 108         tokens = tokenize_sane(s);
 109
 110         if(GameCommand_Vote(s, self)) {
 111                 return;
 112         } else if(GameCommand_MapVote(argv(0))) {
 113                 return;
 114         } else if(argv(0) == "autoswitch") {
 115                 // be backwards compatible with older clients (enabled)
 116                 self.autoswitch = ("0" != argv(1));
 117                 local string autoswitchmsg;
 118                 if (self.autoswitch) {
 119                         autoswitchmsg = "on";
 120                 } else {
 121                         autoswitchmsg = "off";
 122                 }
 123                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 124         } else if(argv(0) == "clientversion") {
 125                 if not(self.flags & FL_CLIENT)
 126                         return;
 127                 if (argv(1) == "$gameversion") {
 128                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 129                         // either that or someone wants to be funny
 130                         self.version = 1;
 131                 } else {
 132                         self.version = stof(argv(1));
 133                 }
 134                 if(self.version != cvar("gameversion"))
 135                 {
 136                         self.classname = "observer";
 137                         self.version_mismatch = 1;
 138                         PutClientInServer();
 139                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 140                         //JoinBestTeam(self, FALSE, TRUE);
 141                 } else if(teams_matter && !cvar("sv_spectate")) {
 142                         self.classname = "observer";
 143                         stuffcmd(self,"menu_showteamselect\n");
 144                 }
 145         } else if(argv(0) == "reportcvar") { // old system
 146                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 147                 {
 148                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1)), " \"", cvar_defstring(argv(1)), "\"");
 149                         tokens = tokenize_sane(s);
 150                 }
 151                 GetCvars(1);
 152         } else if(argv(0) == "sentcvar") { // new system
 153                 if(tokens == 2) // undefined cvar: use the default value on the server then
 154                 {
 155                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1)), " \"", cvar_defstring(argv(1)), "\"");
 156                         tokens = tokenize_sane(s);
 157                 }
 158                 GetCvars(1);
 159         } else if(argv(0) == "spectate") {
 160                 if not(self.flags & FL_CLIENT)
 161                         return;
 162                 if(g_arena)
 163                         return;
 164                 if(g_lms)
 165                 {
 166                         if(self.lms_spectate_warning)
 167                         {
 168                                 // mark player as spectator
 169                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 170                         }
 171                         else
 172                         {
 173                                 self.lms_spectate_warning = 1;
 174                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 175                                 return;
 176                         }
 177                 }
 178                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 179                         if(self.flagcarried)
 180                                 DropFlag(self.flagcarried, world, world);
 181                         kh_Key_DropAll(self, TRUE);
 182                         WaypointSprite_PlayerDead();
 183                         self.classname = "observer";
 184                         if(blockSpectators)
 185                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 186                         PutClientInServer();
 187                 }
 188         } else if(argv(0) == "join") {
 189                 if not(self.flags & FL_CLIENT)
 190                         return;
 191                 if(!g_arena)
 192                 if (self.classname != "player" && !lockteams)
 193                 {
 194                         if(isJoinAllowed()) {
 195                                 self.classname = "player";
 196                                 PlayerScore_Clear(self);
 197                                 bprint ("^4", self.netname, "^4 is playing now\n");
 198                                 PutClientInServer();
 199                         }
 200                         else {
 201                                 //player may not join because of g_maxplayers is set
 202                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 203                         }
 204                 }
 205         } else if( argv(0) == "selectteam" ) {
 206                 if not(self.flags & FL_CLIENT)
 207                         return;
 208                 if( !teams_matter ) {
 209                         sprint( self, "selecteam can only be used in teamgames\n");
 210                 } else if(cvar("g_campaign")) {
 211                         //JoinBestTeam(self, 0);
 212                 } else if(lockteams) {
 213                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 214                 } else if( argv(1) == "red" ) {
 215                         DoTeamChange(COLOR_TEAM1);
 216                 } else if( argv(1) == "blue" ) {
 217                         DoTeamChange(COLOR_TEAM2);
 218                 } else if( argv(1) == "yellow" ) {
 219                         DoTeamChange(COLOR_TEAM3);
 220                 } else if( argv(1) == "pink" ) {
 221                         DoTeamChange(COLOR_TEAM4);
 222                 } else if( argv(1) == "auto" ) {
 223                         DoTeamChange(-1);
 224                 } else {
 225                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 226                 }
 227         } else if(argv(0) == "ready") {
 228                 if not(self.flags & FL_CLIENT)
 229                         return;
 230
 231                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 232                    || cvar("sv_ready_restart"))
 233                 {
 234                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 235                         {
 236                                 if (self.ready) // toggle
 237                                 {
 238                                         self.ready = FALSE;
 239                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 240                                 }
 241                                 else
 242                                 {
 243                                         self.ready = TRUE;
 244                                         bprint(self.netname, "^2 is ready\n");
 245                                 }
 246
 247                                 // cannot reset the game while a timeout is active!
 248                                 if(!timeoutStatus)
 249                                         ReadyCount();
 250                         } else {
 251                                 sprint(self, "^1Game has already been restarted\n");
 252                         }
 253                 }
 254         } else if(argv(0) == "maplist") {
 255                 sprint(self, maplist_reply);
 256         } else if(argv(0) == "lsmaps") {
 257                 sprint(self, lsmaps_reply);
 258         } else if(argv(0) == "records") {
 259                 sprint(self, records_reply);
 260         } else if(argv(0) == "voice") {
 261                 if(tokens >= 3)
 262                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 263                 else
 264                         VoiceMessage(argv(1), "");
 265         } else if(argv(0) == "say") {
 266                 if(tokens >= 2)
 267                         Say(self, FALSE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 268                 //clientcommand(self, formatmessage(s));
 269         } else if(argv(0) == "say_team") {
 270                 if(tokens >= 2)
 271                         Say(self, TRUE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 272                 //clientcommand(self, formatmessage(s));
 273         } else if(argv(0) == "info") {
 274                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 275                 if(cmd == "")
 276                         sprint(self, "ERROR: unsupported info command\n");
 277                 else
 278                         wordwrap_sprint(cmd, 1111);
 279         } else if(argv(0) == "suggestmap") {
 280                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 281         } else if(argv(0) == "timeout") {
 282                 if not(self.flags & FL_CLIENT)
 283                         return;
 284                 if(cvar("sv_timeout")) {
 285                         if(self.classname == "player") {
 286                                 if(votecalled)
 287                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 288                                 else
 289                                         evaluateTimeout();
 290                         }
 291                         else
 292                                 sprint(self, "^7Error: only players can call a timeout!\n");
 293                 }
 294         } else if(argv(0) == "timein") {
 295                 if not(self.flags & FL_CLIENT)
 296                         return;
 297                 if(cvar("sv_timeout")) {
 298                         evaluateTimein();
 299                 }
 300         } else if(argv(0) == "teamstatus") {
 301                 Score_NicePrint(self);
 302         } else if(argv(0) == "cvar_changes") {
 303                 sprint(self, cvar_changes);
 304         } else if(argv(0) == "pointparticles") {
 305                 if(sv_cheats && tokens == 5)
 306                 {
 307                         // arguments:
 308                         //   effectname
 309                         //   origin (0..1, on crosshair line)
 310                         //   velocity
 311                         //   howmany
 312                         effectnum = particleeffectnum(argv(1));
 313                         f = stof(argv(2));
 314                         start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 315                         end = stov(argv(3));
 316                         f = stof(argv(4));
 317                         pointparticles(effectnum, start, end, f);
 318                 }
 319                 else
 320                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 321         } else if(argv(0) == "trailparticles") {
 322                 if(sv_cheats && tokens == 3)
 323                 {
 324                         // arguments:
 325                         //   effectname
 326                         //   shot origin vector
 327                         effectnum = particleeffectnum(argv(1));
 328                         W_SetupShot(self, stov(argv(2)), FALSE, FALSE, "");
 329                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 330                         trailparticles(self, effectnum, w_shotorg, trace_endpos);
 331                 }
 332                 else
 333                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname shotorigin\n");
 334         } else {
 335                 //if(ctf_clientcommand())
 336                 //      return;
 337                 cmd = argv(0);
 338                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 339                 if(cmd != "status")
 340                 if(cmd != "max")
 341                 if(cmd != "monster")
 342                 if(cmd != "scrag")
 343                 if(cmd != "wraith")
 344                 if(cmd != "gimme")
 345                 if(cmd != "god")
 346                 if(cmd != "notarget")
 347                 if(cmd != "fly")
 348                 if(cmd != "noclip")
 349                 if(cmd != "give")
 350                 //if(cmd != "say") // handled above
 351                 //if(cmd != "say_team") // handled above
 352                 if(cmd != "tell")
 353                 if(cmd != "kill")
 354                 if(cmd != "pause")
 355                 if(cmd != "ping")
 356                 if(cmd != "name")
 357                 if(cmd != "color")
 358                 if(cmd != "rate")
 359                 if(cmd != "pmodel")
 360                 if(cmd != "playermodel")
 361                 if(cmd != "playerskin")
 362                 if(cmd != "prespawn")
 363                 if(cmd != "spawn")
 364                 if(cmd != "begin")
 365                 if(cmd != "pings")
 366                 if(cmd != "sv_startdownload")
 367                 if(cmd != "download")
 368                 {
 369                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 370                         return;
 371                 }
 372                 clientcommand(self,s);
 373         }
 374 }
 375
 376 void ReadyRestartForce()
 377 {
 378         local entity e;
 379
 380         bprint("^1Server is restarting...\n");
 381
 382         VoteReset();
 383
 384         // clear overtime
 385         if (checkrules_overtimesadded > 0) {
 386                 //we have to decrease timelimit to its original value again!!
 387                 float newTL;
 388                 newTL = cvar("timelimit");
 389                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 390                 cvar_set("timelimit", ftos(newTL));
 391         }
 392
 393         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 394
 395
 396         readyrestart_happened = 1;
 397         game_starttime = time + RESTART_COUNTDOWN;
 398         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 399
 400         inWarmupStage = 0; //once the game is restarted the game is in match stage
 401
 402         //reset the .ready status of all players (also spectators)
 403         FOR_EACH_CLIENTSLOT(e)
 404                 e.ready = 0;
 405         readycount = 0;
 406         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 407
 408         if(cvar("teamplay_lockonrestart") && teams_matter) {
 409                 lockteams = 1;
 410                 bprint("^1The teams are now locked.\n");
 411         }
 412
 413         //initiate the restart-countdown-announcer entity
 414         if(cvar("sv_ready_restart_after_countdown"))
 415         {
 416                 restartTimer = spawn();
 417                 restartTimer.think = restartTimer_Think;
 418                 restartTimer.nextthink = game_starttime;
 419         }
 420
 421         //after a restart every players number of allowed timeouts gets reset, too
 422         if(cvar("sv_timeout"))
 423         {
 424                 FOR_EACH_REALPLAYER(e)
 425                         e.allowedTimeouts = cvar("sv_timeout_number");
 426         }
 427
 428         //reset map immediately if this cvar is not set
 429         if (!cvar("sv_ready_restart_after_countdown"))
 430                 reset_map(TRUE);
 431
 432         if(cvar("sv_eventlog"))
 433                 GameLogEcho(":restart");
 434 }
 435
 436 void ReadyRestart()
 437 {
 438         // no arena, assault support yet...
 439         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 440                 localcmd("restart\n");
 441
 442         // reset ALL scores, but only do that at the beginning
 443         //of the countdown if sv_ready_restart_after_countdown is off!
 444         //Otherwise scores could be manipulated during the countdown!
 445         if (!cvar("sv_ready_restart_after_countdown"))
 446                 Score_ClearAll();
 447
 448         ReadyRestartForce();
 449 }
 450
 451 /**
 452  * Counts how many players are ready. If not enough players are ready, the function
 453  * does nothing. If all players are ready, the timelimit will be extended and the
 454  * restart_countdown variable is set to allow other functions like PlayerPostThink
 455  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 456  * is not set the map will be resetted.
 457  *
 458  * Function is called after the server receives a 'ready' sign from a player.
 459  */
 460 void ReadyCount()
 461 {
 462         local entity e;
 463         local float r, p;
 464
 465         r = p = 0;
 466
 467         FOR_EACH_REALPLAYER(e)
 468         {
 469                 p += 1;
 470                 if(e.ready)
 471                         r += 1;
 472         }
 473
 474         readycount = r;
 475
 476         Nagger_ReadyCounted();
 477
 478         if(r) // at least one is ready
 479         if(r == p) // and, everyone is ready
 480                 ReadyRestart();
 481 }
 482
 483 /**
 484  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 485  * is set)
 486  */
 487 void restartTimer_Think() {
 488         restart_mapalreadyrestarted = 1;
 489         Score_ClearAll();
 490         reset_map(TRUE);
 491         remove(self);
 492         return;
 493 }
 494
 495 /**
 496  * Checks whether the player who calls the timeout is allowed to do so.
 497  * If so, it initializes the timeout countdown. It also checks whether another
 498  * timeout was already running at this time and reacts correspondingly.
 499  *
 500  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 501  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 502  *
 503  * This function is called when a player issues the calltimeout command.
 504  */
 505 void evaluateTimeout() {
 506         if (inWarmupStage && !g_warmup_allow_timeout)
 507                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 508         if (time < game_starttime )
 509                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 510         if (timeoutStatus != 2) {
 511                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 512                 if (cvar("timelimit")) {
 513                         //a timelimit was used
 514                         local float myTl;
 515                         myTl = cvar("timelimit");
 516
 517                         local float lastPossibleTimeout;
 518                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 519
 520                         if (lastPossibleTimeout < time - game_starttime)
 521                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 522                 }
 523         }
 524         //player may not call a timeout if he has no calls left
 525         if (self.allowedTimeouts < 1)
 526                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 527         //now all required checks are passed
 528         self.allowedTimeouts -= 1;
 529         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 530         remainingTimeoutTime = cvar("sv_timeout_length");
 531         remainingLeadTime = cvar("sv_timeout_leadtime");
 532         timeoutInitiator = self;
 533         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 534                 timeoutStatus = 1;
 535                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 536                 timeoutHandler = spawn();
 537                 timeoutHandler.think = timeoutHandler_Think;
 538         }
 539         timeoutHandler.nextthink = time; //always let the entity think asap
 540
 541         //inform all connected clients about the timeout call
 542         play2all("announcer/robotic/timeoutcalled.wav");
 543 }
 544
 545 /**
 546  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 547  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 548  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 549  * value of the cvar sv_timeout_resumetime.
 550  *
 551  * This function is called when a player issues the resumegame command.
 552  */
 553 void evaluateTimein() {
 554         if (!timeoutStatus)
 555                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 556         if (self != timeoutInitiator)
 557                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 558         if (timeoutStatus == 1) {
 559                 remainingTimeoutTime = timeoutStatus = 0;
 560                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 561                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 562         }
 563         else if (timeoutStatus == 2) {
 564                 //only shorten the remainingTimeoutTime if it makes sense
 565                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 566                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 567                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 568                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 569                 }
 570                 else
 571                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 572
 573         }
 574 }