data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 // VorteX: static frame globals
  11 float WFRAME_FIRE1 = 0;
  12 float WFRAME_FIRE2 = 1;
  13 float WFRAME_IDLE = 2;
  14
  15 void(float fr, float t, void() func) weapon_thinkf;
  16
  17 vector w_shotorg;
  18 vector w_shotdir;
  19
  20 // this function calculates w_shotorg and w_shotdir based on the weapon model
  21 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  22 // make sure you call makevectors first (FIXME?)
  23 void(entity ent, vector vecs, float antilag, float recoil, string snd) W_SetupShot =
  24 {
  25         local vector trueaimpoint;
  26         traceline_hitcorpse(self, self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  27         trueaimpoint = trace_endpos;
  28
  29         if (cvar("g_shootfromeye"))
  30                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x;
  31         else if (cvar("g_shootfromcenter"))
  32                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + '0 0 1' * vecs_z;
  33         else
  34                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
  35         w_shotdir = normalize(trueaimpoint - w_shotorg);
  36
  37         // explanation of g_antilag:
  38         // if client reports it was aiming at a player, and the serverside trace
  39         // says it would miss, change the aim point to the player's new origin,
  40         // but only if the shot at the player's new origin would hit of course
  41         //
  42         // FIXME: a much better method for bullet weapons would be to leave a
  43         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  44         // ghost corresponding to this player's ping time, and if so it would do
  45         // damage to the real player
  46         if (antilag)
  47         if (self.cursor_trace_ent)                 // client was aiming at someone
  48         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  49         if (cvar("g_antilag"))
  50         {
  51                 // verify that the shot would miss without antilag
  52                 // (avoids an issue where guns would always shoot at their origin)
  53                 traceline_hitcorpse(self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  54                 if (!trace_ent.takedamage)
  55                 {
  56                         // verify that the shot would hit if altered
  57                         traceline_hitcorpse(self, w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  58                         if (trace_ent == self.cursor_trace_ent)
  59                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
  60                 }
  61         }
  62
  63         if (!g_norecoil)
  64                 self.punchangle_x = recoil * -1;
  65
  66         if (snd != "")
  67                 sound (self, CHAN_WEAPON, snd, 1, ATTN_NORM);
  68
  69         if (self.items & IT_STRENGTH)
  70         if (!g_minstagib)
  71                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", 1, ATTN_NORM);
  72 };
  73
  74 void LaserTarget_Think()
  75 {
  76         entity e;
  77         vector offset;
  78         float uselaser;
  79         uselaser = 0;
  80
  81         // list of weapons that will use the laser, and the options that enable it
  82         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
  83                 uselaser = 1;
  84         // example
  85         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
  86         //      uselaser = 1;
  87
  88
  89
  90         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
  91         if(!uselaser)
  92         {
  93                 // rocket launcher isn't selected, so no laser target.
  94                 if(self.lasertarget != world)
  95                 {
  96                         remove(self.lasertarget);
  97                         self.lasertarget = world;
  98                 }
  99                 return;
 100         }
 101
 102         if(!self.lasertarget)
 103         {
 104                 // we don't have a lasertarget entity, so spawn one
 105                 //bprint("create laser target\n");
 106                 e = self.lasertarget = spawn();
 107                 e.owner = self.owner;                   // Its owner is my owner
 108                 e.classname = "laser_target";
 109                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 110                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 111                 e.scale = 1.25;                         // make it larger
 112                 e.alpha = 0.25;                         // transparency
 113                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 114                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 115                 // make it dynamically glow
 116                 // you should avoid over-using this, as it can slow down the player's computer.
 117                 e.glow_color = 251; // red color
 118                 e.glow_size = 12;
 119         }
 120         else
 121                 e = self.lasertarget;
 122
 123         // move the laser dot to where the player is looking
 124
 125         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 126         offset = '0 0 26' + v_right*3;
 127         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 128         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 129         if(trace_plane_normal != '0 0 0')
 130                 e.angles = vectoangles(trace_plane_normal);
 131         else
 132                 e.angles = vectoangles(v_forward);
 133 }
 134
 135 float CL_Weaponentity_CustomizeEntityForClient()
 136 {
 137         self.viewmodelforclient = self.owner;
 138         if(other.classname == "spectator")
 139                 if(other.enemy == self.owner)
 140                         self.viewmodelforclient = other;
 141         return TRUE;
 142 }
 143
 144 .string weaponname;
 145 void() CL_Weaponentity_Think =
 146 {
 147         self.nextthink = time;
 148         if (intermission_running)
 149                 self.frame = WFRAME_IDLE;
 150         if (self.owner.weaponentity != self)
 151         {
 152                 remove(self);
 153                 return;
 154         }
 155         if (self.owner.deadflag != DEAD_NO)
 156         {
 157                 self.model = "";
 158                 return;
 159         }
 160         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 161         {
 162                 self.cnt = self.owner.weapon;
 163                 self.dmg = self.owner.modelindex;
 164                 self.deadflag = self.owner.deadflag;
 165                 if (self.owner.weaponname != "")
 166                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 167                 else
 168                         self.model = "";
 169         }
 170         self.effects = self.owner.effects | EF_LOWPRECISION;
 171         self.effects = self.effects - (self.effects & (EF_FULLBRIGHT)); // can mask team color, so get rid of it
 172
 173         if (self.flags & FL_FLY)
 174                 // owner is currently being teleported, so don't apply EF_NODRAW otherwise the viewmodel would "blink"
 175                 self.effects = self.effects - (self.effects & EF_NODRAW);
 176
 177         if(self.owner.alpha >= 0)
 178                 self.alpha = self.owner.alpha;
 179         else
 180                 self.alpha = 1;
 181         self.colormap = self.owner.colormap;
 182
 183         self.angles = '0 0 0';
 184         local float f;
 185         f = 0;
 186         if (self.state == WS_RAISE)
 187                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 188         else if (self.state == WS_DROP)
 189                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 190         else if (self.state == WS_CLEAR)
 191                 f = 1;
 192         self.angles_x = -90 * f * f;
 193
 194         // create or update the lasertarget entity
 195         LaserTarget_Think();
 196 };
 197
 198 void() CL_ExteriorWeaponentity_Think =
 199 {
 200         float tag_found;
 201         self.nextthink = time;
 202         if (self.owner.exteriorweaponentity != self)
 203         {
 204                 remove(self);
 205                 return;
 206         }
 207         if (self.owner.deadflag != DEAD_NO)
 208         {
 209                 self.model = "";
 210                 return;
 211         }
 212         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 213         {
 214                 self.cnt = self.owner.weapon;
 215                 self.dmg = self.owner.modelindex;
 216                 self.deadflag = self.owner.deadflag;
 217                 if (self.owner.weaponname != "")
 218                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 219                 else
 220                         self.model = "";
 221
 222                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 223                 {
 224                         self.tag_index = tag_found;
 225                         self.tag_entity = self.owner;
 226                 }
 227                 else
 228                         setattachment(self, self.owner, "bip01 r hand");
 229
 230                 // if that didn't find a tag, hide the exterior weapon model
 231                 if (!self.tag_index)
 232                         self.model = "";
 233         }
 234         self.effects = self.owner.effects | EF_LOWPRECISION;
 235         self.effects = self.effects - (self.effects & (EF_BLUE | EF_RED)); // eat performance
 236         if(self.owner.alpha >= 0)
 237                 self.alpha = self.owner.alpha;
 238         else
 239                 self.alpha = 1;
 240         self.colormap = self.owner.colormap;
 241 };
 242
 243 // spawning weaponentity for client
 244 void() CL_SpawnWeaponentity =
 245 {
 246         self.weaponentity = spawn();
 247         self.weaponentity.solid = SOLID_NOT;
 248         self.weaponentity.owner = self;
 249         self.weaponentity.weaponentity = self.weaponentity;
 250         setmodel(self.weaponentity, ""); // precision set when changed
 251         self.weaponentity.origin = '0 0 0';
 252         self.weaponentity.angles = '0 0 0';
 253         self.weaponentity.viewmodelforclient = self;
 254         self.weaponentity.flags = 0;
 255         self.weaponentity.think = CL_Weaponentity_Think;
 256         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 257         self.weaponentity.nextthink = time;
 258         self.weaponentity.scale = 0.61;
 259
 260         self.exteriorweaponentity = spawn();
 261         self.exteriorweaponentity.solid = SOLID_NOT;
 262         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 263         self.exteriorweaponentity.owner = self;
 264         self.exteriorweaponentity.origin = '0 0 0';
 265         self.exteriorweaponentity.angles = '0 0 0';
 266         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 267         self.exteriorweaponentity.nextthink = time;
 268 };
 269
 270 float(entity cl, float wpn, float andammo, float complain) client_hasweapon =
 271 {
 272         local float itemcode, f;
 273         local entity oldself;
 274
 275         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 276         {
 277                 if (complain)
 278                         sprint(self, "Invalid weapon\n");
 279                 return FALSE;
 280         }
 281         itemcode = W_ItemCode(wpn);
 282         if (cl.items & itemcode)
 283         {
 284                 if (andammo)
 285                 {
 286                         oldself = self;
 287                         self = cl;
 288                         f = weapon_action(wpn, WR_CHECKAMMO1);
 289                         f = f + weapon_action(wpn, WR_CHECKAMMO2);
 290                         self = oldself;
 291                         if (!f)
 292                         {
 293                                 if (complain)
 294                                         sprint(self, "You don't have any ammo for that weapon\n");
 295                                 return FALSE;
 296                         }
 297                 }
 298                 return TRUE;
 299         }
 300         if (complain)
 301         {
 302                 // DRESK - 3/16/07
 303                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 304                 if(itemsInMap & itemcode)
 305                         sprint(self, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 306                 else
 307                         sprint(self, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 308         }
 309         return FALSE;
 310 };
 311
 312 // Weapon subs
 313 void() w_clear =
 314 {
 315         if (self.weapon != -1)
 316                 self.weapon = 0;
 317         if (self.weaponentity)
 318         {
 319                 self.weaponentity.state = WS_CLEAR;
 320                 // self.weaponname = ""; // next frame will setmodel it to "" when needed anyway
 321                 self.weaponentity.effects = 0;
 322         }
 323 };
 324
 325 void() w_ready =
 326 {
 327         if (self.weaponentity)
 328         {
 329                 self.weaponentity.state = WS_READY;
 330                 weapon_thinkf(WFRAME_IDLE, 0.1, w_ready);
 331         }
 332 };
 333
 334 // FIXME: add qw-style client-custom weaponrating (cl_weaponrating)?
 335 float(entity e) w_getbestweapon
 336 {// add new weapons here
 337         if (client_hasweapon(e, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 338                 return WEP_ROCKET_LAUNCHER;
 339         else if (client_hasweapon(e, WEP_NEX, TRUE, FALSE))
 340                 return WEP_NEX;
 341         else if (client_hasweapon(e, WEP_HAGAR, TRUE, FALSE))
 342                 return WEP_HAGAR;
 343         else if (client_hasweapon(e, WEP_GRENADE_LAUNCHER, TRUE, FALSE))
 344                 return WEP_GRENADE_LAUNCHER;
 345         else if (client_hasweapon(e, WEP_ELECTRO, TRUE, FALSE))
 346                 return WEP_ELECTRO;
 347         else if (client_hasweapon(e, WEP_CRYLINK, TRUE, FALSE))
 348                 return WEP_CRYLINK;
 349         else if (client_hasweapon(e, WEP_UZI, TRUE, FALSE))
 350                 return WEP_UZI;
 351         else if (client_hasweapon(e, WEP_SHOTGUN, TRUE, FALSE))
 352                 return WEP_SHOTGUN;
 353         else if (client_hasweapon(e, WEP_LASER, FALSE, FALSE))
 354                 return WEP_LASER;
 355         else
 356                 return 0;
 357 };
 358
 359 // Setup weapon for client (after this raise frame will be launched)
 360 void(float windex, string wname, float hudammo) weapon_setup =
 361 {
 362         self.items = self.items - (self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS));
 363         self.items = self.items | hudammo;
 364
 365         // the two weapon entities will notice this has changed and update their models
 366         self.weapon = windex;
 367         self.weaponname = wname;
 368 };
 369
 370 // perform weapon to attack (weaponstate and attack_finished check is here)
 371 float(float secondary, float attacktime) weapon_prepareattack =
 372 {
 373         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 374         {
 375                 self.switchweapon = w_getbestweapon(self);
 376                 if (self.switchweapon != self.weapon)
 377                         self.cnt = self.weapon;
 378                 return FALSE;
 379         }
 380         // don't fire if previous attack is not finished
 381         if (ATTACK_FINISHED(self) > time)
 382                 return FALSE;
 383         // don't fire while changing weapon
 384         if (self.weaponentity.state != WS_READY)
 385                 return FALSE;
 386         self.weaponentity.state = WS_INUSE;
 387         ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self) + attacktime);
 388         return TRUE;
 389 };
 390
 391 void(float fr, float t, void() func) weapon_thinkf =
 392 {
 393         if (fr >= 0)
 394         {
 395                 if (self.weaponentity != world)
 396                         self.weaponentity.frame = fr;
 397         }
 398
 399         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 400         {
 401                 backtrace("Tried to override initial weapon think function - should this really happen?");
 402         }
 403
 404         if(g_runematch)
 405         {
 406                 if(self.runes & RUNE_SPEED)
 407                 {
 408                         if(self.runes & CURSE_SLOW)
 409                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 410                         else
 411                                 t = t * cvar("g_balance_rune_speed_atkrate");
 412                 }
 413                 else if(self.runes & CURSE_SLOW)
 414                 {
 415                         t = t * cvar("g_balance_curse_slow_atkrate");
 416                 }
 417         }
 418
 419         // VorteX: haste can be added here
 420         self.weapon_nextthink = max(time, self.weapon_nextthink_lastframe + t);
 421         self.weapon_think = func;
 422
 423         if (fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2)
 424         if (t)
 425         {
 426                 local vector anim;
 427                 anim = self.anim_shoot;
 428                 anim_z = anim_y / t;
 429                 player_setanim(anim, FALSE, TRUE, TRUE);
 430         }
 431 };
 432
 433 void(float spd, vector org) weapon_boblayer1 =
 434 {
 435         // VorteX: haste can be added here
 436 };
 437
 438 vector(vector pvelocity, vector mvelocity) W_CalculateProjectileVelocity =
 439 {
 440         vector mdirection;
 441         float mspeed;
 442         float outspeed;
 443         float nstyle;
 444         vector outvelocity;
 445
 446         mdirection = normalize(mvelocity);
 447         mspeed = vlen(mvelocity);
 448
 449         nstyle = cvar("g_projectiles_newton_style");
 450         if(nstyle == 0)
 451         {
 452                 // absolute velocity
 453                 outvelocity = mvelocity;
 454         }
 455         else if(nstyle == 1)
 456         {
 457                 // true Newtonian projectiles
 458                 outvelocity = pvelocity + mvelocity;
 459         }
 460         else if(nstyle == 2)
 461         {
 462                 // true Newtonian projectiles with automatic aim adjustment
 463                 //
 464                 // solve: |outspeed * mdirection - pvelocity| = mspeed
 465                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
 466                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
 467                 // PLUS SIGN!
 468                 // not defined?
 469                 // then...
 470                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
 471                 // velocity without mdirection component > mspeed
 472                 // fire at smallest possible mspeed that works?
 473                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
 474
 475                 float D;
 476                 float p;
 477                 float q;
 478                 p = mdirection * pvelocity;
 479                 q = pvelocity * pvelocity - mspeed * mspeed;
 480                 D = p * p - q;
 481                 if(D < 0)
 482                 {
 483                         //dprint("impossible shot, adjusting\n");
 484                         D = 0;
 485                 }
 486                 outspeed = p + sqrt(D);
 487                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 488                 outvelocity = mdirection * outspeed;
 489         }
 490         else if(nstyle == 3)
 491         {
 492                 // pseudo-Newtonian:
 493                 outspeed = mspeed + mdirection * pvelocity;
 494                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 495                 outvelocity = mdirection * outspeed;
 496         }
 497         else if(nstyle == 4)
 498         {
 499                 // tZorkian:
 500                 outspeed = mspeed + vlen(pvelocity);
 501                 outvelocity = mdirection * outspeed;
 502         }
 503         else
 504                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
 505
 506         return outvelocity;
 507 }
 508
 509 void(entity missile) W_SetupProjectileVelocity =
 510 {
 511         if(missile.owner == world)
 512                 error("Unowned missile");
 513
 514         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
 515 }
 516
 517 void(float wepcode, float minammo) weapon_register =
 518 {
 519         string s;
 520         float itemcode;
 521         s = strcat("register_bestweapon ", ftos(wepcode), " "); // char for bestweapon
 522         s = strcat(s, ftos(wepcode), " "); // impulse
 523         s = strcat(s, ftos(W_ItemCode(wepcode)), " "); // item code
 524         s = strcat(s, ftos(wepcode), " "); // self.weapon code
 525
 526         // ammo stat
 527         itemcode = W_AmmoItemCode(wepcode);
 528         if(itemcode == IT_SHELLS)
 529                 s = strcat(s, "6 ");
 530         else if(itemcode == IT_NAILS)
 531                 s = strcat(s, "7 ");
 532         else if(itemcode == IT_ROCKETS)
 533                 s = strcat(s, "8 ");
 534         else // if(itemcode == IT_CELLS)
 535                 s = strcat(s, "9 ");
 536
 537         s = strcat(s, ftos(minammo), "\n");
 538         //dprint(s);
 539         stuffcmd(self, s);
 540 }