]> icculus.org git repositories - divverent/nexuiz.git/blob - data/qcsrc/server/cl_weaponsystem.qc
added: g_projectiles_newton_style
[divverent/nexuiz.git] / data / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 // VorteX: static frame globals
11 float WFRAME_FIRE1 = 0;
12 float WFRAME_FIRE2 = 1;
13 float WFRAME_IDLE = 2;
14
15 void(float fr, float t, void() func) weapon_thinkf;
16
17 vector w_shotorg;
18 vector w_shotdir;
19
20 // this function calculates w_shotorg and w_shotdir based on the weapon model
21 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
22 // make sure you call makevectors first (FIXME?)
23 void(entity ent, vector vecs, float antilag, float recoil, string snd) W_SetupShot =
24 {
25         local vector trueaimpoint;
26
27         traceline_hitcorpse(self, self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
28         trueaimpoint = trace_endpos;
29
30         // if aiming at a player and the original trace won't hit that player
31         // anymore, try aiming at the player's new position
32         if (antilag)
33         if (!trace_ent.takedamage)                 // shot would miss without antilag
34         if (self.cursor_trace_ent)                 // but it HAD hit on the client
35         if (self.cursor_trace_ent.takedamage)      //   and even something evil
36         // if (trace_ent != self.cursor_trace_ent) // and it is different (redundant check, see takedamage)
37         if (cvar("g_antilag"))
38                 trueaimpoint = self.cursor_trace_ent.origin;
39
40         /*
41         // don't allow the shot to start inside a wall
42         local vector startorg;
43         local vector idealorg;
44         startorg = ent.origin + ent.view_ofs;// - '0 0 8';
45         idealorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
46         traceline_hitcorpse (ent, startorg, idealorg, MOVE_NOMONSTERS, ent);
47         w_shotorg = trace_endpos;
48         */
49         // all positions in the code are now required to be inside the player box
50         w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
51
52         w_shotdir = normalize(trueaimpoint - w_shotorg);
53
54         if (!cvar("g_norecoil"))
55                 self.punchangle_x = recoil * -1;
56
57         if (snd != "")
58                 sound (self, CHAN_WEAPON, snd, 1, ATTN_NORM);
59
60         if (self.items & IT_STRENGTH)
61         if (!cvar("g_minstagib"))
62                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
63 };
64
65 void LaserTarget_Think()
66 {
67         entity e;
68         vector offset;
69         float uselaser;
70         uselaser = 0;
71
72         // list of weapons that will use the laser, and the options that enable it
73         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && cvar("g_laserguided_missile"))
74                 uselaser = 1;
75         // example
76         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
77         //      uselaser = 1;
78
79
80
81         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
82         if(!uselaser)
83         {
84                 // rocket launcher isn't selected, so no laser target.
85                 if(self.lasertarget != world)
86                 {
87                         remove(self.lasertarget);
88                         self.lasertarget = world;
89                 }
90                 return;
91         }
92
93         if(!self.lasertarget)
94         {
95                 // we don't have a lasertarget entity, so spawn one
96                 //bprint("create laser target\n");
97                 e = self.lasertarget = spawn();
98                 e.owner = self.owner;                   // Its owner is my owner
99                 e.classname = "laser_target";
100                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
101                 setmodel(e, "models/laser_dot.mdl");    // what it looks like
102                 e.scale = 1.25;                         // make it larger
103                 e.alpha = 0.25;                         // transparency
104                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
105                 e.effects = EF_FULLBRIGHT;
106                 // make it dynamically glow
107                 // you should avoid over-using this, as it can slow down the player's computer.
108                 e.glow_color = 251; // red color
109                 e.glow_size = 12;
110         }
111         else
112                 e = self.lasertarget;
113
114         // move the laser dot to where the player is looking
115
116         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
117         offset = '0 0 26' + v_right*3;
118         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
119         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
120         if(trace_plane_normal != '0 0 0')
121                 e.angles = vectoangles(trace_plane_normal);
122         else
123                 e.angles = vectoangles(v_forward);
124 }
125
126 .string weaponname;
127 void() CL_Weaponentity_Think =
128 {
129         self.nextthink = time;
130         if (intermission_running)
131                 self.frame = WFRAME_IDLE;
132         if (self.owner.weaponentity != self)
133         {
134                 remove(self);
135                 return;
136         }
137         if (self.owner.deadflag != DEAD_NO)
138         {
139                 self.model = "";
140                 return;
141         }
142         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
143         {
144                 self.cnt = self.owner.weapon;
145                 self.dmg = self.owner.modelindex;
146                 self.deadflag = self.owner.deadflag;
147                 if (self.owner.weaponname != "")
148                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym"));
149                 else
150                         self.model = "";
151         }
152         self.effects = self.owner.effects;
153
154         if (self.flags & FL_FLY)
155                 // owner is currently being teleported, so don't apply EF_NODRAW otherwise the viewmodel would "blink"
156                 self.effects = self.effects - (self.effects & EF_NODRAW);
157
158         if(self.owner.alpha >= 0)
159                 self.alpha = self.owner.alpha;
160         else
161                 self.alpha = 1;
162         self.colormap = self.owner.colormap;
163
164         self.angles = '0 0 0';
165         local float f;
166         f = 0;
167         if (self.state == WS_RAISE)
168                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
169         else if (self.state == WS_DROP)
170                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
171         else if (self.state == WS_CLEAR)
172                 f = 1;
173         self.angles_x = -90 * f * f;
174
175         // create or update the lasertarget entity
176         LaserTarget_Think();
177 };
178
179 void() CL_ExteriorWeaponentity_Think =
180 {
181         self.nextthink = time;
182         if (self.owner.exteriorweaponentity != self)
183         {
184                 remove(self);
185                 return;
186         }
187         if (self.owner.deadflag != DEAD_NO)
188         {
189                 self.model = "";
190                 return;
191         }
192         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
193         {
194                 self.cnt = self.owner.weapon;
195                 self.dmg = self.owner.modelindex;
196                 self.deadflag = self.owner.deadflag;
197                 if (self.owner.weaponname != "")
198                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3"));
199                 else
200                         self.model = "";
201                 setattachment(self, self.owner, "bip01 r hand");
202                 // if that didn't find a tag, hide the exterior weapon model
203                 if (!self.tag_index)
204                         self.model = "";
205         }
206         self.effects = self.owner.effects;
207         if(self.owner.alpha >= 0)
208                 self.alpha = self.owner.alpha;
209         else
210                 self.alpha = 1;
211         self.colormap = self.owner.colormap;
212 };
213
214 // spawning weaponentity for client
215 void() CL_SpawnWeaponentity =
216 {
217         self.weaponentity = spawn();
218         self.weaponentity.solid = SOLID_NOT;
219         self.weaponentity.owner = self;
220         self.weaponentity.weaponentity = self.weaponentity;
221         setmodel(self.weaponentity, "");
222         self.weaponentity.origin = '0 0 0';
223         self.weaponentity.angles = '0 0 0';
224         self.weaponentity.viewmodelforclient = self;
225         self.weaponentity.flags = 0;
226         self.weaponentity.think = CL_Weaponentity_Think;
227         self.weaponentity.nextthink = time;
228         self.weaponentity.scale = 0.61;
229
230         self.exteriorweaponentity = spawn();
231         self.exteriorweaponentity.solid = SOLID_NOT;
232         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
233         self.exteriorweaponentity.owner = self;
234         self.exteriorweaponentity.origin = '0 0 0';
235         self.exteriorweaponentity.angles = '0 0 0';
236         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
237         self.exteriorweaponentity.nextthink = time;
238 };
239
240 float(entity cl, float wpn, float andammo, float complain) client_hasweapon =
241 {
242         local float itemcode, f;
243         local entity oldself;
244
245         if (wpn < WEP_FIRST || wpn > WEP_LAST)
246         {
247                 if (complain)
248                         sprint(self, "Invalid weapon\n");
249                 return FALSE;
250         }
251         itemcode = W_ItemCode(wpn);
252         if (cl.items & itemcode)
253         {
254                 if (andammo)
255                 {
256                         oldself = self;
257                         self = cl;
258                         f = weapon_action(wpn, WR_CHECKAMMO1);
259                         f = f + weapon_action(wpn, WR_CHECKAMMO2);
260                         self = oldself;
261                         if (!f)
262                         {
263                                 if (complain)
264                                         sprint(self, "You don't have any ammo for that weapon\n");
265                                 return FALSE;
266                         }
267                 }
268                 return TRUE;
269         }
270         if (complain)
271                 sprint(self, "You don't own that weapon\n");
272         return FALSE;
273 };
274
275 // Weapon subs
276 void() w_clear =
277 {
278         if (self.weapon != -1)
279                 self.weapon = 0;
280         if (self.weaponentity)
281         {
282                 self.weaponentity.state = WS_CLEAR;
283                 setmodel(self.weaponentity, "");
284                 self.weaponentity.effects = 0;
285         }
286 };
287
288 void() w_ready =
289 {
290         if (self.weaponentity)
291         {
292                 self.weaponentity.state = WS_READY;
293                 weapon_thinkf(WFRAME_IDLE, 0.1, w_ready);
294         }
295 };
296
297 // FIXME: add qw-style client-custom weaponrating (cl_weaponrating)?
298 float(entity e) w_getbestweapon
299 {// add new weapons here
300         if (client_hasweapon(e, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
301                 return WEP_ROCKET_LAUNCHER;
302         else if (client_hasweapon(e, WEP_NEX, TRUE, FALSE))
303                 return WEP_NEX;
304         else if (client_hasweapon(e, WEP_HAGAR, TRUE, FALSE))
305                 return WEP_HAGAR;
306         else if (client_hasweapon(e, WEP_GRENADE_LAUNCHER, TRUE, FALSE))
307                 return WEP_GRENADE_LAUNCHER;
308         else if (client_hasweapon(e, WEP_ELECTRO, TRUE, FALSE))
309                 return WEP_ELECTRO;
310         else if (client_hasweapon(e, WEP_CRYLINK, TRUE, FALSE))
311                 return WEP_CRYLINK;
312         else if (client_hasweapon(e, WEP_UZI, TRUE, FALSE))
313                 return WEP_UZI;
314         else if (client_hasweapon(e, WEP_SHOTGUN, TRUE, FALSE))
315                 return WEP_SHOTGUN;
316         else if (client_hasweapon(e, WEP_LASER, FALSE, FALSE))
317                 return WEP_LASER;
318         else
319                 return 0;
320 };
321
322 // Setup weapon for client (after this raise frame will be launched)
323 void(float windex, string wname, float hudammo) weapon_setup =
324 {
325         self.items = self.items - (self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS));
326         self.items = self.items | hudammo;
327
328         // the two weapon entities will notice this has changed and update their models
329         self.weapon = windex;
330         self.weaponname = wname;
331
332         // might fire faster after switch
333         self.attack_finished = min(max(time, self.attack_finished_old + 1), self.attack_finished);
334 };
335
336 // perform weapon to attack (weaponstate and attack_finished check is here)
337 float(float secondary, float attacktime) weapon_prepareattack =
338 {
339         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
340         {
341                 self.switchweapon = w_getbestweapon(self);
342                 if (self.switchweapon != self.weapon)
343                         self.cnt = self.weapon;
344                 return FALSE;
345         }
346         // don't fire if previous attack is not finished
347         if (self.attack_finished > time)
348                 return FALSE;
349         // don't fire while changing weapon
350         if (self.weaponentity.state != WS_READY)
351                 return FALSE;
352         self.weaponentity.state = WS_INUSE;
353         self.attack_finished_old = self.attack_finished;
354         self.attack_finished = max(time, self.attack_finished + attacktime);
355         return TRUE;
356 };
357
358 void(float fr, float t, void() func) weapon_thinkf =
359 {
360         if (fr >= 0)
361         {
362                 if (self.weaponentity != world)
363                         self.weaponentity.frame = fr;
364         }
365
366         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
367         {
368                 backtrace("Tried to override initial weapon think function - should this really happen?");
369         }
370
371         if(cvar("g_runematch"))
372         {
373                 if(self.runes & RUNE_SPEED)
374                 {
375                         if(self.runes & CURSE_SLOW)
376                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
377                         else
378                                 t = t * cvar("g_balance_rune_speed_atkrate");
379                 }
380                 else if(self.runes & CURSE_SLOW)
381                 {
382                         t = t * cvar("g_balance_curse_slow_atkrate");
383                 }
384         }
385
386         // VorteX: haste can be added here
387         self.weapon_nextthink = max(time, self.weapon_nextthink_lastframe + t);
388         self.weapon_think = func;
389 };
390
391 void(float spd, vector org) weapon_boblayer1 =
392 {
393         // VorteX: haste can be added here
394 };
395
396 void(entity missile) W_SetupProjectileVelocity =
397 {
398         vector pvelocity;
399         vector mdirection;
400         float mspeed;
401         float outspeed;
402         float nstyle;
403         vector mvelocity;
404         vector outvelocity;
405
406         if(missile.owner == world)
407                 error("Unowned missile");
408         pvelocity = missile.owner.velocity;
409         mvelocity = missile.velocity;
410         mdirection = normalize(mvelocity);
411         mspeed = vlen(mvelocity);
412
413         nstyle = cvar("g_projectiles_newton_style");
414         if(nstyle == 0)
415         {
416                 // absolute velocity
417                 outvelocity = mvelocity;
418         }
419         else if(nstyle == 1)
420         {
421                 // true Newtonian projectiles
422                 outvelocity = pvelocity + mvelocity;
423         }
424         else if(nstyle == 2)
425         {
426                 // true Newtonian projectiles with automatic aim adjustment
427                 //
428                 // solve: |outspeed * mdirection - pvelocity| = mspeed
429                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
430                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
431                 // PLUS SIGN!
432                 // not defined?
433                 // then...
434                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
435                 // velocity without mdirection component > mspeed
436                 // fire at smallest possible mspeed that works?
437                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
438
439                 float D;
440                 float p;
441                 float q;
442                 p = mdirection * pvelocity;
443                 q = pvelocity * pvelocity - mspeed * mspeed;
444                 D = p * p - q;
445                 if(D < 0)
446                 {
447                         dprint("impossible shot, adjusting\n");
448                         D = 0;
449                 }
450                 outspeed = p + sqrt(D);
451                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
452                 outvelocity = mdirection * outspeed;
453         }
454         else if(nstyle == 3)
455         {
456                 // pseudo-Newtonian:
457                 outspeed = mspeed + mdirection * pvelocity;
458                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
459                 outvelocity = mdirection * outspeed;
460         }
461         else if(nstyle == 4)
462         {
463                 // tZorkian:
464                 outspeed = mspeed + vlen(pvelocity);
465                 outvelocity = mdirection * outspeed;
466         }
467         else
468                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
469
470         dprint("Adjusted from ", vtos(missile.velocity));
471         missile.velocity = outvelocity;
472         dprint(" to ", vtos(missile.velocity), "\n");
473 }