data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.weapon ? e.weapon : e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_FIRE1 = 0;
  20 float WFRAME_FIRE2 = 1;
  21 float WFRAME_IDLE = 2;
  22
  23 void(float fr, float t, void() func) weapon_thinkf;
  24
  25 vector w_shotorg;
  26 vector w_shotdir;
  27
  28 // this function calculates w_shotorg and w_shotdir based on the weapon model
  29 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  30 // make sure you call makevectors first (FIXME?)
  31 void W_SetupShot(entity ent, vector vecs, float antilag, float recoil, string snd)
  32 {
  33         float nudge = 1; // added to traceline target and subtracted from result
  34         local vector trueaimpoint;
  35         local float oldsolid;
  36         oldsolid = self.solid;
  37         self.solid = SOLID_BBOX; // make all shot test traces bypass playerclip
  38         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  39         trueaimpoint = trace_endpos;
  40
  41         if (cvar("g_shootfromeye"))
  42                 w_shotorg = ent.origin + ent.view_ofs;
  43         else if (cvar("g_shootfromcenter"))
  44                 w_shotorg = ent.origin + ent.view_ofs + '0 0 1' * vecs_z;
  45         else
  46                 w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  47         // now move the shotorg forward as much as requested if possible
  48         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  49         w_shotorg = trace_endpos - v_forward * nudge;
  50         // calculate the shotdir from the chosen shotorg
  51         w_shotdir = normalize(trueaimpoint - w_shotorg);
  52
  53         // explanation of g_antilag:
  54         // if client reports it was aiming at a player, and the serverside trace
  55         // says it would miss, change the aim point to the player's new origin,
  56         // but only if the shot at the player's new origin would hit of course
  57         //
  58         // FIXME: a much better method for bullet weapons would be to leave a
  59         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  60         // ghost corresponding to this player's ping time, and if so it would do
  61         // damage to the real player
  62         if (antilag)
  63         if (self.cursor_trace_ent)                 // client was aiming at someone
  64         if (self.cursor_trace_ent != self)         // just to make sure
  65         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  66         if (self.cursor_trace_ent.classname == "player") // and actually a player
  67         if (cvar("g_antilag") == 1)
  68         {
  69                 // verify that the shot would miss without antilag
  70                 // (avoids an issue where guns would always shoot at their origin)
  71                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  72                 if (!trace_ent.takedamage)
  73                 {
  74                         // verify that the shot would hit if altered
  75                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  76                         if (trace_ent == self.cursor_trace_ent)
  77                         {
  78                                 // verify that the shot would hit in the past
  79                                 if(self.antilag_debug)
  80                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  81                                 else
  82                                         antilag_takeback(self.cursor_trace_ent, time - self.ping * 0.001);
  83
  84                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  85                                 antilag_restore(self.cursor_trace_ent);
  86
  87                                 if(trace_ent == self.cursor_trace_ent)
  88                                 {
  89                                         // HIT!
  90                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
  91                                         dprint("ANTILAG HIT for ", self.netname, "\n");
  92                                 }
  93                                 else
  94                                 {
  95                                         // prydon cursor aimbot or odd network conditions
  96                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
  97                                 }
  98
  99                                 if(cvar("developer") >= 2)
 100                                 {
 101                                         vector v, vplus, vel;
 102                                         float X;
 103                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (self.ping * 0.001       ));
 104                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (self.ping * 0.001 + 0.01));
 105                                         vel = (vplus - v) * (1 / 0.01);
 106                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 107                                         v     -= (self.origin + self.view_ofs);
 108                                         // solve: v + X * vel = closest to v_forward axis
 109                                         // project into 2D by subtracting v_forward components:
 110                                         v   -= (v   * v_forward) * v_forward;
 111                                         vel -= (vel * v_forward) * v_forward;
 112                                         // solve: v + X * vel = closest to origin
 113                                         // (v + X * vel)^2 closest to 0
 114                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 115                                         X = -(v * vel) / (vel * vel);
 116                                         dprint("dead center needs adjustment of ", ftos(X * 1000), " (that is, ", ftos(self.ping + X * 1000), " instead of ", ftos(self.ping), "\n");
 117                                 }
 118                         }
 119                 }
 120         }
 121
 122         self.solid = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 123
 124         if (!g_norecoil)
 125                 self.punchangle_x = recoil * -1;
 126
 127         if (snd != "")
 128         {
 129                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 130         }
 131
 132         if (self.items & IT_STRENGTH)
 133         if (!g_minstagib)
 134                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 135 };
 136
 137 void LaserTarget_Think()
 138 {
 139         entity e;
 140         vector offset;
 141         float uselaser;
 142         uselaser = 0;
 143
 144         // list of weapons that will use the laser, and the options that enable it
 145         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 146                 uselaser = 1;
 147         // example
 148         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 149         //      uselaser = 1;
 150
 151
 152
 153         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 154         if(!uselaser)
 155         {
 156                 // rocket launcher isn't selected, so no laser target.
 157                 if(self.lasertarget != world)
 158                 {
 159                         remove(self.lasertarget);
 160                         self.lasertarget = world;
 161                 }
 162                 return;
 163         }
 164
 165         if(!self.lasertarget)
 166         {
 167                 // we don't have a lasertarget entity, so spawn one
 168                 //bprint("create laser target\n");
 169                 e = self.lasertarget = spawn();
 170                 e.owner = self.owner;                   // Its owner is my owner
 171                 e.classname = "laser_target";
 172                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 173                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 174                 e.scale = 1.25;                         // make it larger
 175                 e.alpha = 0.25;                         // transparency
 176                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 177                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 178                 // make it dynamically glow
 179                 // you should avoid over-using this, as it can slow down the player's computer.
 180                 e.glow_color = 251; // red color
 181                 e.glow_size = 12;
 182         }
 183         else
 184                 e = self.lasertarget;
 185
 186         // move the laser dot to where the player is looking
 187
 188         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 189         offset = '0 0 26' + v_right*3;
 190         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 191         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 192         if(trace_plane_normal != '0 0 0')
 193                 e.angles = vectoangles(trace_plane_normal);
 194         else
 195                 e.angles = vectoangles(v_forward);
 196 }
 197
 198 float CL_Weaponentity_CustomizeEntityForClient()
 199 {
 200         self.viewmodelforclient = self.owner;
 201         if(other.classname == "spectator")
 202                 if(other.enemy == self.owner)
 203                         self.viewmodelforclient = other;
 204         return TRUE;
 205 }
 206
 207 .string weaponname;
 208 void CL_Weaponentity_Think()
 209 {
 210         self.nextthink = time;
 211         if (intermission_running)
 212                 self.frame = WFRAME_IDLE;
 213         if (self.owner.weaponentity != self)
 214         {
 215                 remove(self);
 216                 return;
 217         }
 218         if (self.owner.deadflag != DEAD_NO)
 219         {
 220                 self.model = "";
 221                 return;
 222         }
 223         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 224         {
 225                 self.cnt = self.owner.weapon;
 226                 self.dmg = self.owner.modelindex;
 227                 self.deadflag = self.owner.deadflag;
 228                 if (self.owner.weaponname != "")
 229                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 230                 else
 231                         self.model = "";
 232         }
 233         self.effects = self.owner.effects | EF_LOWPRECISION;
 234         self.effects = self.effects - (self.effects & (EF_FULLBRIGHT)); // can mask team color, so get rid of it
 235
 236         if (self.flags & FL_FLY)
 237                 // owner is currently being teleported, so don't apply EF_NODRAW otherwise the viewmodel would "blink"
 238                 self.effects = self.effects - (self.effects & EF_NODRAW);
 239
 240         if(self.owner.alpha >= 0)
 241                 self.alpha = self.owner.alpha;
 242         else
 243                 self.alpha = 1;
 244         self.colormap = self.owner.colormap;
 245
 246         self.angles = '0 0 0';
 247         local float f;
 248         f = 0;
 249         if (self.state == WS_RAISE)
 250                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 251         else if (self.state == WS_DROP)
 252                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 253         else if (self.state == WS_CLEAR)
 254                 f = 1;
 255         self.angles_x = -90 * f * f;
 256
 257         // create or update the lasertarget entity
 258         LaserTarget_Think();
 259 };
 260
 261 void CL_ExteriorWeaponentity_Think()
 262 {
 263         float tag_found;
 264         self.nextthink = time;
 265         if (self.owner.exteriorweaponentity != self)
 266         {
 267                 remove(self);
 268                 return;
 269         }
 270         if (self.owner.deadflag != DEAD_NO)
 271         {
 272                 self.model = "";
 273                 return;
 274         }
 275         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 276         {
 277                 self.cnt = self.owner.weapon;
 278                 self.dmg = self.owner.modelindex;
 279                 self.deadflag = self.owner.deadflag;
 280                 if (self.owner.weaponname != "")
 281                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 282                 else
 283                         self.model = "";
 284
 285                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 286                 {
 287                         self.tag_index = tag_found;
 288                         self.tag_entity = self.owner;
 289                 }
 290                 else
 291                         setattachment(self, self.owner, "bip01 r hand");
 292
 293                 // if that didn't find a tag, hide the exterior weapon model
 294                 if (!self.tag_index)
 295                         self.model = "";
 296         }
 297         self.effects = self.owner.effects | EF_LOWPRECISION;
 298         self.effects = self.effects - (self.effects & (EF_BLUE | EF_RED)); // eat performance
 299         if(self.owner.alpha >= 0)
 300                 self.alpha = self.owner.alpha;
 301         else
 302                 self.alpha = 1;
 303         self.colormap = self.owner.colormap;
 304 };
 305
 306 // spawning weaponentity for client
 307 void CL_SpawnWeaponentity()
 308 {
 309         self.weaponentity = spawn();
 310         self.weaponentity.solid = SOLID_NOT;
 311         self.weaponentity.owner = self;
 312         self.weaponentity.weaponentity = self.weaponentity;
 313         setmodel(self.weaponentity, ""); // precision set when changed
 314         self.weaponentity.origin = '0 0 0';
 315         self.weaponentity.angles = '0 0 0';
 316         self.weaponentity.viewmodelforclient = self;
 317         self.weaponentity.flags = 0;
 318         self.weaponentity.think = CL_Weaponentity_Think;
 319         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 320         self.weaponentity.nextthink = time;
 321         self.weaponentity.scale = 0.61;
 322
 323         self.exteriorweaponentity = spawn();
 324         self.exteriorweaponentity.solid = SOLID_NOT;
 325         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 326         self.exteriorweaponentity.owner = self;
 327         self.exteriorweaponentity.origin = '0 0 0';
 328         self.exteriorweaponentity.angles = '0 0 0';
 329         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 330         self.exteriorweaponentity.nextthink = time;
 331 };
 332
 333 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 334 {
 335         local float weaponbit, f;
 336         local entity oldself;
 337
 338         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 339         {
 340                 if (complain)
 341                         sprint(self, "Invalid weapon\n");
 342                 return FALSE;
 343         }
 344         weaponbit = W_WeaponBit(wpn);
 345         if (cl.weapons & weaponbit)
 346         {
 347                 if (andammo)
 348                 {
 349                         oldself = self;
 350                         self = cl;
 351                         f = weapon_action(wpn, WR_CHECKAMMO1);
 352                         f = f + weapon_action(wpn, WR_CHECKAMMO2);
 353                         self = oldself;
 354                         if (!f)
 355                         {
 356                                 if (complain)
 357                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 358                                 return FALSE;
 359                         }
 360                 }
 361                 return TRUE;
 362         }
 363         if (complain)
 364         {
 365                 // DRESK - 3/16/07
 366                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 367                 if(weaponsInMap & weaponbit)
 368                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 369                 else
 370                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 371         }
 372         return FALSE;
 373 };
 374
 375 // Weapon subs
 376 void w_clear()
 377 {
 378         if (self.weapon != -1)
 379                 self.weapon = 0;
 380         if (self.weaponentity)
 381         {
 382                 self.weaponentity.state = WS_CLEAR;
 383                 // self.weaponname = ""; // next frame will setmodel it to "" when needed anyway
 384                 self.weaponentity.effects = 0;
 385         }
 386 };
 387
 388 void w_ready()
 389 {
 390         if (self.weaponentity)
 391                 self.weaponentity.state = WS_READY;
 392         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 393 };
 394
 395 // Setup weapon for client (after this raise frame will be launched)
 396 void weapon_setup(float windex)
 397 {
 398         entity e;
 399         e = get_weaponinfo(windex);
 400         self.items = self.items - (self.items & IT_AMMO);
 401         self.items = self.items | e.items;
 402
 403         // the two weapon entities will notice this has changed and update their models
 404         self.weapon = windex;
 405         self.weaponname = e.mdl;
 406 };
 407
 408 // perform weapon to attack (weaponstate and attack_finished check is here)
 409 .float race_penalty;
 410 float weapon_prepareattack(float secondary, float attacktime)
 411 {
 412         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 413         //if all players readied up and the countdown is running
 414         if (cvar("sv_ready_restart_after_countdown"))
 415                 if(time < game_starttime || time < self.race_penalty) {
 416                         return FALSE;
 417                 }
 418
 419         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 420         {
 421                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 422                 return FALSE;
 423         }
 424
 425         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 426                 return FALSE;
 427
 428         // do not even think about shooting if switching
 429         if(self.switchweapon != self.weapon)
 430                 return FALSE;
 431
 432         // don't fire if previous attack is not finished
 433         if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 434                 return FALSE;
 435         // don't fire while changing weapon
 436         if (self.weaponentity.state != WS_READY)
 437                 return FALSE;
 438         self.weaponentity.state = WS_INUSE;
 439         // if the weapon hasn't been firing continuously, reset the timer
 440         if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 441         {
 442                 ATTACK_FINISHED(self) = time;
 443                 //dprint("resetting attack finished to ", ftos(time), "\n");
 444         }
 445         ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 446         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 447         return TRUE;
 448 };
 449
 450 void weapon_thinkf(float fr, float t, void() func)
 451 {
 452         if (fr >= 0)
 453         {
 454                 if (self.weaponentity != world)
 455                         self.weaponentity.frame = fr;
 456         }
 457
 458         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 459         {
 460                 backtrace("Tried to override initial weapon think function - should this really happen?");
 461         }
 462
 463         if(g_runematch)
 464         {
 465                 if(self.runes & RUNE_SPEED)
 466                 {
 467                         if(self.runes & CURSE_SLOW)
 468                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 469                         else
 470                                 t = t * cvar("g_balance_rune_speed_atkrate");
 471                 }
 472                 else if(self.runes & CURSE_SLOW)
 473                 {
 474                         t = t * cvar("g_balance_curse_slow_atkrate");
 475                 }
 476         }
 477
 478         // VorteX: haste can be added here
 479         if (self.weapon_think == w_ready)
 480         {
 481                 self.weapon_nextthink = time;
 482                 //dprint("started firing at ", ftos(time), "\n");
 483         }
 484         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
 485         {
 486                 self.weapon_nextthink = time;
 487                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 488         }
 489         self.weapon_nextthink = self.weapon_nextthink + t;
 490         self.weapon_think = func;
 491         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 492
 493         if (fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2)
 494         if (t)
 495         if (!self.crouch) // shoot anim stands up, this looks bad
 496         {
 497                 local vector anim;
 498                 anim = self.anim_shoot;
 499                 anim_z = anim_y / t;
 500                 player_setanim(anim, FALSE, TRUE, TRUE);
 501         }
 502 };
 503
 504 void weapon_boblayer1(float spd, vector org)
 505 {
 506         // VorteX: haste can be added here
 507 };
 508
 509 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
 510 {
 511         vector mdirection;
 512         float mspeed;
 513         float outspeed;
 514         float nstyle;
 515         vector outvelocity;
 516
 517         mdirection = normalize(mvelocity);
 518         mspeed = vlen(mvelocity);
 519
 520         nstyle = cvar("g_projectiles_newton_style");
 521         if(nstyle == 0)
 522         {
 523                 // absolute velocity
 524                 outvelocity = mvelocity;
 525         }
 526         else if(nstyle == 1)
 527         {
 528                 // true Newtonian projectiles
 529                 outvelocity = pvelocity + mvelocity;
 530         }
 531         else if(nstyle == 2)
 532         {
 533                 // true Newtonian projectiles with automatic aim adjustment
 534                 //
 535                 // solve: |outspeed * mdirection - pvelocity| = mspeed
 536                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
 537                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
 538                 // PLUS SIGN!
 539                 // not defined?
 540                 // then...
 541                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
 542                 // velocity without mdirection component > mspeed
 543                 // fire at smallest possible mspeed that works?
 544                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
 545
 546                 float D;
 547                 float p;
 548                 float q;
 549                 p = mdirection * pvelocity;
 550                 q = pvelocity * pvelocity - mspeed * mspeed;
 551                 D = p * p - q;
 552                 if(D < 0)
 553                 {
 554                         //dprint("impossible shot, adjusting\n");
 555                         D = 0;
 556                 }
 557                 outspeed = p + sqrt(D);
 558                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 559                 outvelocity = mdirection * outspeed;
 560         }
 561         else if(nstyle == 3)
 562         {
 563                 // pseudo-Newtonian:
 564                 outspeed = mspeed + mdirection * pvelocity;
 565                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 566                 outvelocity = mdirection * outspeed;
 567         }
 568         else if(nstyle == 4)
 569         {
 570                 // tZorkian:
 571                 outspeed = mspeed + vlen(pvelocity);
 572                 outvelocity = mdirection * outspeed;
 573         }
 574         else
 575                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
 576
 577         return outvelocity;
 578 }
 579
 580 void W_SetupProjectileVelocity(entity missile)
 581 {
 582         if(missile.owner == world)
 583                 error("Unowned missile");
 584
 585         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
 586 }
 587
 588
 589 // WEAPON PLUGIN SYSTEM
 590 entity weapon_info[24];
 591 entity dummy_weapon_info;
 592 .float(float) weapon_func;
 593 string weaponpriority_hudselector_0;
 594 string weaponpriority_hudselector_1;
 595
 596 void register_weapon(float id, float(float) func, float ammotype, float i, float normalweapon, float pickupbasevalue, string modelname, string shortname, string name)
 597 {
 598         entity e;
 599         weapon_info[id - 1] = e = spawn();
 600         e.classname = "weapon_info";
 601         e.weapon = id;
 602         e.weapons = power2of(id - 1);
 603         e.netname = shortname;
 604         e.message = name;
 605         e.items = ammotype;
 606         e.weapon_func = func;
 607         e.mdl = modelname;
 608         e.model = strzone(strcat("models/weapons/g_", modelname, ".md3"));
 609         e.spawnflags = normalweapon;
 610         e.impulse = i;
 611         e.bot_pickupbasevalue = pickupbasevalue;
 612 }
 613 float w_null(float dummy)
 614 {
 615         return 0;
 616 }
 617 void register_weapons_done()
 618 {
 619         dummy_weapon_info = spawn();
 620         dummy_weapon_info.classname = "weapon_info";
 621         dummy_weapon_info.weapon = 0;
 622         dummy_weapon_info.weapons = 0;
 623         dummy_weapon_info.netname = "@!#%'n Tuba";
 624         dummy_weapon_info.items = 0;
 625         dummy_weapon_info.weapon_func = w_null;
 626         dummy_weapon_info.mdl = "";
 627         dummy_weapon_info.model = "";
 628         dummy_weapon_info.spawnflags = 0;
 629         dummy_weapon_info.impulse = -1;
 630         dummy_weapon_info.bot_pickupbasevalue = 0;
 631
 632         float i;
 633         weaponpriority_hudselector_0 = "";
 634         for(i = 24; i >= 1; --i)
 635                 if(weapon_info[i-1])
 636                         weaponpriority_hudselector_0 = strcat(weaponpriority_hudselector_0, " ", ftos(i));
 637
 638         float imp;
 639         weaponpriority_hudselector_1 = "";
 640         for(i = 1; i <= 24; ++i)
 641                 if(weapon_info[i-1] && weapon_info[i-1].impulse == 0)
 642                         weaponpriority_hudselector_1 = strcat(weaponpriority_hudselector_1, " ", ftos(i));
 643         for(imp = 9; imp > 0; --imp)
 644                 for(i = 1; i <= 24; ++i)
 645                         if(weapon_info[i-1] && weapon_info[i-1].impulse == imp)
 646                                 weaponpriority_hudselector_1 = strcat(weaponpriority_hudselector_1, " ", ftos(i));
 647
 648         weaponpriority_hudselector_0 = strzone(substring(weaponpriority_hudselector_0, 1, strlen(weaponpriority_hudselector_0) - 1));
 649         weaponpriority_hudselector_1 = strzone(substring(weaponpriority_hudselector_1, 1, strlen(weaponpriority_hudselector_1) - 1));
 650 }
 651 entity get_weaponinfo(float id)
 652 {
 653         entity w;
 654         if(id < WEP_FIRST || id > WEP_LAST)
 655                 return dummy_weapon_info;
 656         w = weapon_info[id - 1];
 657         if(w)
 658                 return w;
 659         return dummy_weapon_info;
 660 }