data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39 }
  40
  41 .float antilag_debug;
  42
  43 // VorteX: static frame globals
  44 float WFRAME_DONTCHANGE = -1;
  45 float WFRAME_FIRE1 = 0;
  46 float WFRAME_FIRE2 = 1;
  47 float WFRAME_IDLE = 2;
  48 float WFRAME_RELOAD = 3;
  49 .float wframe;
  50
  51 void(float fr, float t, void() func) weapon_thinkf;
  52
  53 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  54 {
  55         vector ret;
  56         ret_x = screenright * v;
  57         ret_y = screenup * v;
  58         ret_z = screenforward * v;
  59         return ret;
  60 }
  61
  62 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  63 {
  64         float i, j, k;
  65         vector mi, ma, thisv, myv, ret;
  66
  67         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  68
  69         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  70
  71         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  72         {
  73                 thisv = targ.origin;
  74                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  75                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  76                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  77                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  78                 if(i || j || k)
  79                 {
  80                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  81                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  82                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  83                 }
  84                 else
  85                 {
  86                         // first run
  87                         mi = ma = thisv;
  88                 }
  89         }
  90
  91         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  92         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  93         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  94         ret_z = thisv_z - myv_z;
  95         return ret;
  96 }
  97
  98 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  99 {
 100         vector hitplot;
 101         vector org;
 102         float lag;
 103
 104         if(player.hitplotfh >= 0)
 105         {
 106                 lag = ANTILAG_LATENCY(player);
 107                 if(lag < 0.001)
 108                         lag = 0;
 109                 if(clienttype(player) != CLIENTTYPE_REAL)
 110                         lag = 0; // only antilag for clients
 111
 112                 org = player.origin + player.view_ofs;
 113                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 114                 if(trace_ent.flags & FL_CLIENT)
 115                 {
 116                         antilag_takeback(trace_ent, time - lag);
 117                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 118                         antilag_restore(trace_ent);
 119                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 120                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 121                 }
 122         }
 123 }
 124
 125 vector w_shotorg;
 126 vector w_shotdir;
 127
 128 // this function calculates w_shotorg and w_shotdir based on the weapon model
 129 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 130 // make sure you call makevectors first (FIXME?)
 131 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
 132 {
 133         float nudge = 1; // added to traceline target and subtracted from result
 134         local vector trueaimpoint;
 135         local float oldsolid;
 136         vector vecs, dv;
 137         oldsolid = ent.dphitcontentsmask;
 138         if(ent.weapon == WEP_CAMPINGRIFLE)
 139                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 140         else
 141                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 142         if(antilag)
 143                 traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 144                 // passing world, because we do NOT want it to touch dphitcontentsmask
 145         else
 146                 traceline(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
 147         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 148         trueaimpoint = trace_endpos;
 149
 150         // track max damage
 151         if not(inWarmupStage) {
 152                 entity w;
 153                 w = get_weaponinfo(ent.weapon);
 154                 if(w.weapon_type == WEP_TYPE_SPLASH) {  // splash damage
 155                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 156                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 157                 }
 158         }
 159
 160         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 161
 162         if(ent.weaponentity.movedir_x > 0)
 163         {
 164                 vecs = ent.weaponentity.movedir;
 165                 vecs_y = -vecs_y;
 166         }
 167         else
 168                 vecs = '0 0 0';
 169
 170         if(debug_shotorg != '0 0 0')
 171                 vecs = debug_shotorg;
 172
 173         dv = v_right * vecs_y + v_up * vecs_z;
 174         w_shotorg = ent.origin + ent.view_ofs + dv;
 175
 176         // now move the shotorg forward as much as requested if possible
 177         if(antilag)
 178         {
 179                 if(ent.antilag_debug)
 180                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 181                 else
 182                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 183         }
 184         else
 185                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 186         w_shotorg = trace_endpos - v_forward * nudge;
 187         // calculate the shotdir from the chosen shotorg
 188         w_shotdir = normalize(trueaimpoint - w_shotorg);
 189
 190         if (antilag)
 191         if (!ent.cvar_cl_noantilag)
 192         {
 193                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 194                 {
 195                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 196                         if (!trace_ent.takedamage)
 197                         {
 198                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 199                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 200                                 {
 201                                         entity e;
 202                                         e = trace_ent;
 203                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 204                                         if(trace_ent == e)
 205                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 206                                 }
 207                         }
 208                 }
 209                 else if(cvar("g_antilag") == 3) // client side hitscan
 210                 {
 211                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 212                         if (ent.cursor_trace_ent != ent)         // just to make sure
 213                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 214                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 215                         {
 216                                 // verify that the shot would miss without antilag
 217                                 // (avoids an issue where guns would always shoot at their origin)
 218                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 219                                 if (!trace_ent.takedamage)
 220                                 {
 221                                         // verify that the shot would hit if altered
 222                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 223                                         if (trace_ent == ent.cursor_trace_ent)
 224                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 225                                         else
 226                                                 print("antilag fail\n");
 227                                 }
 228                         }
 229                 }
 230         }
 231
 232         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 233
 234         if (!g_norecoil)
 235                 ent.punchangle_x = recoil * -1;
 236
 237         if (snd != "")
 238         {
 239                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 240         }
 241
 242         if (ent.items & IT_STRENGTH)
 243         if (!g_minstagib)
 244                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 245 };
 246
 247 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 248 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 249 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 250
 251 void LaserTarget_Think()
 252 {
 253         entity e;
 254         vector offset;
 255         float uselaser;
 256         uselaser = 0;
 257
 258         // list of weapons that will use the laser, and the options that enable it
 259         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 260                 uselaser = 1;
 261         // example
 262         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 263         //      uselaser = 1;
 264
 265
 266
 267         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 268         if(!uselaser)
 269         {
 270                 // rocket launcher isn't selected, so no laser target.
 271                 if(self.lasertarget != world)
 272                 {
 273                         remove(self.lasertarget);
 274                         self.lasertarget = world;
 275                 }
 276                 return;
 277         }
 278
 279         if(!self.lasertarget)
 280         {
 281                 // we don't have a lasertarget entity, so spawn one
 282                 //bprint("create laser target\n");
 283                 e = self.lasertarget = spawn();
 284                 e.owner = self.owner;                   // Its owner is my owner
 285                 e.classname = "laser_target";
 286                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 287                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 288                 e.scale = 1.25;                         // make it larger
 289                 e.alpha = 0.25;                         // transparency
 290                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 291                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 292                 // make it dynamically glow
 293                 // you should avoid over-using this, as it can slow down the player's computer.
 294                 e.glow_color = 251; // red color
 295                 e.glow_size = 12;
 296         }
 297         else
 298                 e = self.lasertarget;
 299
 300         // move the laser dot to where the player is looking
 301
 302         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 303         offset = '0 0 26' + v_right*3;
 304         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 305         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 306         if(trace_plane_normal != '0 0 0')
 307                 e.angles = vectoangles(trace_plane_normal);
 308         else
 309                 e.angles = vectoangles(v_forward);
 310 }
 311
 312 float CL_Weaponentity_CustomizeEntityForClient()
 313 {
 314         self.viewmodelforclient = self.owner;
 315         if(other.classname == "spectator")
 316                 if(other.enemy == self.owner)
 317                         self.viewmodelforclient = other;
 318         return TRUE;
 319 }
 320
 321 float qcweaponanimation;
 322 vector weapon_offset = '0 -10 0';
 323 vector weapon_adjust = '10 0 -15';
 324 .vector weapon_morph0origin;
 325 .vector weapon_morph0angles;
 326 .float  weapon_morph0time;
 327 .vector weapon_morph1origin;
 328 .vector weapon_morph1angles;
 329 .float  weapon_morph1time;
 330 .vector weapon_morph2origin;
 331 .vector weapon_morph2angles;
 332 .float  weapon_morph2time;
 333 .vector weapon_morph3origin;
 334 .vector weapon_morph3angles;
 335 .float  weapon_morph3time;
 336 .vector weapon_morph4origin;
 337 .vector weapon_morph4angles;
 338 .float  weapon_morph4time;
 339 .string weaponname;
 340 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 341
 342 /*
 343  * supported formats:
 344  *
 345  * 1. simple animated model, muzzlr flash handling on h_ model:
 346  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 347  *      tags:
 348  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 349  *        shell = casings ejection point (must be on the right hand side of the gun)
 350  *        weapon = attachment for v_tuba.md3
 351  *    v_tuba.md3 - first and third person model
 352  *    g_tuba.md3 - pickup model
 353  *
 354  * 2. fully animated model, muzzle flash handling on h_ model:
 355  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 360  *    v_tuba.md3 - third person model
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 3. fully animated model, muzzle flash handling on v_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 365  *      tags:
 366  *        shot = muzzle end (shot origin)
 367  *        shell = casings ejection point (must be on the right hand side of the gun)
 368  *    v_tuba.md3 - third person model
 369  *      tags:
 370  *        shot = muzzle end (for muzzle flashes)
 371  *    g_tuba.md3 - pickup model
 372  */
 373
 374 void CL_Weaponentity_Think()
 375 {
 376         float tb, v_shot_idx;
 377         self.nextthink = time;
 378         if (intermission_running)
 379                 self.frame = self.anim_idle_x;
 380         if (self.owner.weaponentity != self)
 381         {
 382                 if (self.weaponentity)
 383                         remove(self.weaponentity);
 384                 remove(self);
 385                 return;
 386         }
 387         if (self.owner.deadflag != DEAD_NO)
 388         {
 389                 self.model = "";
 390                 if (self.weaponentity)
 391                         self.weaponentity.model = "";
 392                 return;
 393         }
 394         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 395         {
 396                 self.cnt = self.owner.weapon;
 397                 self.dmg = self.owner.modelindex;
 398                 self.deadflag = self.owner.deadflag;
 399
 400                 string animfilename;
 401                 float animfile;
 402                 if (self.owner.weaponname != "")
 403                 {
 404                         // if there is a child entity, hide it until we're sure we use it
 405                         if (self.weaponentity)
 406                                 self.weaponentity.model = "";
 407                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 408                         v_shot_idx = gettagindex(self, "shot"); // used later
 409
 410                         if(qcweaponanimation)
 411                         {
 412                                 self.angles = '0 0 0';
 413                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 414                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 415                                 self.movedir_x += 32;
 416                                 self.spawnorigin = self.movedir;
 417                                 // oldorigin - not calculated here
 418                         }
 419                         else
 420                         {
 421                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 422                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 423                                 animfile = fopen(animfilename, FILE_READ);
 424                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 425                                 self.anim_fire1  = '0 1 0.01';
 426                                 self.anim_fire2  = '1 1 0.01';
 427                                 self.anim_idle   = '2 1 0.01';
 428                                 self.anim_reload = '3 1 0.01';
 429                                 if (animfile >= 0)
 430                                 {
 431                                         animparseerror = FALSE;
 432                                         self.anim_fire1  = animparseline(animfile);
 433                                         self.anim_fire2  = animparseline(animfile);
 434                                         self.anim_idle   = animparseline(animfile);
 435                                         self.anim_reload = animparseline(animfile);
 436                                         fclose(animfile);
 437                                         if (animparseerror)
 438                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 439                                 }
 440
 441                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 442                                 // if we don't, this is a "real" animated model
 443                                 if(gettagindex(self, "weapon"))
 444                                 {
 445                                         if (!self.weaponentity)
 446                                                 self.weaponentity = spawn();
 447                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 448                                         setattachment(self.weaponentity, self, "weapon");
 449                                 }
 450                                 else
 451                                 {
 452                                         if(self.weaponentity)
 453                                                 remove(self.weaponentity);
 454                                         self.weaponentity = world;
 455                                 }
 456
 457                                 setorigin(self,'0 0 0');
 458                                 self.angles = '0 0 0';
 459                                 self.frame = 0;
 460                                 self.viewmodelforclient = world;
 461
 462                                 float idx;
 463                                 idx = gettagindex(self, "shot");
 464                                 if(idx)
 465                                 {
 466                                         self.movedir = gettaginfo(self, idx);
 467                                 }
 468                                 else
 469                                 {
 470                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 471                                         self.movedir = '0 0 0';
 472                                 }
 473
 474                                 idx = gettagindex(self, "shell");
 475                                 if(idx)
 476                                 {
 477                                         self.spawnorigin = gettaginfo(self, idx);
 478                                 }
 479                                 else
 480                                 {
 481                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 482                                         self.spawnorigin = self.movedir;
 483                                 }
 484
 485                                 if(v_shot_idx)
 486                                 {
 487                                         self.oldorigin = '0 0 0';
 488                                 }
 489                                 else
 490                                 {
 491                                         if(self.weaponentity)
 492                                                 idx = gettagindex(self, "weapon");
 493                                         else
 494                                                 idx = gettagindex(self, "handle");
 495                                         if(idx)
 496                                         {
 497                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 498                                         }
 499                                         else
 500                                         {
 501                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 502                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 503                                         }
 504                                 }
 505
 506                                 self.viewmodelforclient = self.owner;
 507                         }
 508                 }
 509                 else
 510                 {
 511                         self.model = "";
 512                         if(self.weaponentity)
 513                                 remove(self.weaponentity);
 514                         self.weaponentity = world;
 515                         self.movedir = '0 0 0';
 516                         self.spawnorigin = '0 0 0';
 517                         self.oldorigin = '0 0 0';
 518                         self.anim_fire1  = '0 1 0.01';
 519                         self.anim_fire2  = '0 1 0.01';
 520                         self.anim_idle   = '0 1 0.01';
 521                         self.anim_reload = '0 1 0.01';
 522                 }
 523
 524                 self.view_ofs = '0 0 0';
 525
 526                 if(self.movedir_x >= 0)
 527                 {
 528                         vector v0;
 529                         v0 = self.movedir;
 530                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 531                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 532                 }
 533                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 534                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 535
 536                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 537
 538                 // check if an instant weapon switch occurred
 539                 if (qcweaponanimation)
 540                 {
 541                         if (self.state == WS_READY)
 542                         {
 543                                 self.angles = '0 0 0';
 544                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 545                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 546                         }
 547                 }
 548                 else
 549                         setorigin(self, self.view_ofs);
 550                 // reset animstate now
 551                 self.wframe = WFRAME_IDLE;
 552                 self.weapon_morph0time = 0;
 553                 self.weapon_morph1time = 0;
 554                 self.weapon_morph2time = 0;
 555                 self.weapon_morph3time = 0;
 556                 self.weapon_morph4time = 0;
 557                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 558         }
 559
 560         tb = (self.effects & EF_TELEPORT_BIT);
 561         self.effects = self.owner.effects & EFMASK_CHEAP;
 562         self.effects &~= EF_LOWPRECISION;
 563         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 564         self.effects &~= EF_TELEPORT_BIT;
 565         self.effects |= tb;
 566
 567         if(self.owner.alpha == default_player_alpha)
 568                 self.alpha = default_weapon_alpha;
 569         else if(self.owner.alpha != 0)
 570                 self.alpha = self.owner.alpha;
 571         else
 572                 self.alpha = 1;
 573
 574         self.colormap = self.owner.colormap;
 575         if (self.weaponentity)
 576         {
 577                 self.weaponentity.effects = self.effects;
 578                 self.weaponentity.alpha = self.alpha;
 579                 self.weaponentity.colormap = self.colormap;
 580         }
 581
 582         self.angles = '0 0 0';
 583         local float f;
 584         f = 0;
 585         if (self.state == WS_RAISE && !intermission_running)
 586         {
 587                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 588                 self.angles_x = -90 * f * f;
 589                 if (qcweaponanimation)
 590                 {
 591                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 592                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 593                 }
 594         }
 595         else if (self.state == WS_DROP && !intermission_running)
 596         {
 597                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 598                 self.angles_x = -90 * f * f;
 599                 if (qcweaponanimation)
 600                 {
 601                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 602                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 603                 }
 604         }
 605         else if (self.state == WS_CLEAR)
 606         {
 607                 f = 1;
 608                 self.angles_x = -90 * f * f;
 609                 if (qcweaponanimation)
 610                 {
 611                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 612                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 613                 }
 614         }
 615         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 616         {
 617                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 618                 f = 1 - pow(1 - f, 3);
 619                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 620                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 621         }
 622         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 623         {
 624                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 625                 f = 1 - pow(1 - f, 3);
 626                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 627                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 628         }
 629         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 630         {
 631                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 632                 f = 1 - pow(1 - f, 3);
 633                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 634                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 635         }
 636         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 637         {
 638                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 639                 f = 1 - pow(1 - f, 3);
 640                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 641                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 642         }
 643         else if (qcweaponanimation)
 644         {
 645                 // begin a new idle morph
 646                 self.owner.weapon_morph0time   = time;
 647                 self.owner.weapon_morph0angles = self.angles;
 648                 self.owner.weapon_morph0origin = self.origin;
 649
 650                 float r;
 651                 float t;
 652
 653                 r = random();
 654                 if (r < 0.1)
 655                 {
 656                         // turn gun to the left to look at it
 657                         t = 2;
 658                         self.owner.weapon_morph1time   = time + t * 0.2;
 659                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 660                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 661                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 662
 663                         self.owner.weapon_morph2time   = time + t * 0.6;
 664                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 665                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 666                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 667
 668                         self.owner.weapon_morph3time   = time + t;
 669                         self.owner.weapon_morph3angles = '0 0 0';
 670                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 671                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 672                 }
 673                 else if (r < 0.2)
 674                 {
 675                         // raise the gun a bit
 676                         t = 2;
 677                         self.owner.weapon_morph1time   = time + t * 0.2;
 678                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 679                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 680                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 681
 682                         self.owner.weapon_morph2time   = time + t * 0.5;
 683                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 684                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 685                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 686
 687                         self.owner.weapon_morph3time   = time + t;
 688                         self.owner.weapon_morph3angles = '0 0 0';
 689                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 690                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 691                 }
 692                 else if (r < 0.3)
 693                 {
 694                         // tweak it a bit
 695                         t = 5;
 696                         self.owner.weapon_morph1time   = time + t * 0.3;
 697                         self.owner.weapon_morph1angles = randomvec() * 6;
 698                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 699                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 700
 701                         self.owner.weapon_morph2time   = time + t * 0.7;
 702                         self.owner.weapon_morph2angles = randomvec() * 6;
 703                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 704                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 705
 706                         self.owner.weapon_morph3time   = time + t;
 707                         self.owner.weapon_morph3angles = '0 0 0';
 708                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 709                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 710                 }
 711                 else
 712                 {
 713                         // hold it mostly steady
 714                         t = random() * 6 + 4;
 715                         self.owner.weapon_morph1time   = time + t * 0.2;
 716                         self.owner.weapon_morph1angles = randomvec() * 1;
 717                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 718                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 719
 720                         self.owner.weapon_morph2time   = time + t * 0.5;
 721                         self.owner.weapon_morph2angles = randomvec() * 1;
 722                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 723                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 724
 725                         self.owner.weapon_morph3time   = time + t * 0.7;
 726                         self.owner.weapon_morph3angles = randomvec() * 1;
 727                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 728                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 729                 }
 730
 731                 self.owner.weapon_morph4time   = time + t;
 732                 self.owner.weapon_morph4angles = '0 0 0';
 733                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 734                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 735
 736         }
 737
 738         // create or update the lasertarget entity
 739         LaserTarget_Think();
 740 };
 741
 742 void CL_ExteriorWeaponentity_Think()
 743 {
 744         float tag_found;
 745         vector ang;
 746         self.nextthink = time;
 747         if (self.owner.exteriorweaponentity != self)
 748         {
 749                 remove(self);
 750                 return;
 751         }
 752         if (self.owner.deadflag != DEAD_NO)
 753         {
 754                 self.model = "";
 755                 return;
 756         }
 757         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 758         {
 759                 self.cnt = self.owner.weapon;
 760                 self.dmg = self.owner.modelindex;
 761                 self.deadflag = self.owner.deadflag;
 762                 if (self.owner.weaponname != "")
 763                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 764                 else
 765                         self.model = "";
 766
 767                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 768                 {
 769                         self.tag_index = tag_found;
 770                         self.tag_entity = self.owner;
 771                 }
 772                 else
 773                         setattachment(self, self.owner, "bip01 r hand");
 774
 775                 // if that didn't find a tag, hide the exterior weapon model
 776                 if (!self.tag_index)
 777                         self.model = "";
 778         }
 779         self.effects = self.owner.effects | EF_LOWPRECISION;
 780         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 781         if(self.owner.alpha == default_player_alpha)
 782                 self.alpha = default_weapon_alpha;
 783         else if(self.owner.alpha != 0)
 784                 self.alpha = self.owner.alpha;
 785         else
 786                 self.alpha = 1;
 787
 788         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 789         ang_y = 0;
 790         ang_z = 0;
 791
 792         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 793         {
 794                 ang_y = self.owner.v_angle_y;
 795                 makevectors(ang);
 796                 var vector v = v_forward;
 797                 var float t = self.frame1time;
 798                 self.frame1time = time;
 799                 gettaginfo(self.tag_entity, self.tag_index);
 800                 self.frame1time = t;
 801                 // untransform v according to this coordinate space
 802                 vector w;
 803                 w_x = v_forward * v;
 804                 w_y = -v_right * v;
 805                 w_z = v_up * v;
 806                 self.angles = vectoangles(w);
 807         }
 808         else
 809         {
 810                 ang_x = -/* don't ask */ang_x;
 811                 self.angles = ang;
 812         }
 813
 814         self.colormap = self.owner.colormap;
 815 };
 816
 817 // spawning weaponentity for client
 818 void CL_SpawnWeaponentity()
 819 {
 820         self.weaponentity = spawn();
 821         self.weaponentity.classname = "weaponentity";
 822         self.weaponentity.solid = SOLID_NOT;
 823         self.weaponentity.owner = self;
 824         setmodel(self.weaponentity, ""); // precision set when changed
 825         setorigin(self.weaponentity, '0 0 0');
 826         self.weaponentity.angles = '0 0 0';
 827         self.weaponentity.viewmodelforclient = self;
 828         self.weaponentity.flags = 0;
 829         self.weaponentity.think = CL_Weaponentity_Think;
 830         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 831         self.weaponentity.nextthink = time;
 832
 833         self.exteriorweaponentity = spawn();
 834         self.exteriorweaponentity.classname = "exteriorweaponentity";
 835         self.exteriorweaponentity.solid = SOLID_NOT;
 836         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 837         self.exteriorweaponentity.owner = self;
 838         setorigin(self.exteriorweaponentity, '0 0 0');
 839         self.exteriorweaponentity.angles = '0 0 0';
 840         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 841         self.exteriorweaponentity.nextthink = time;
 842 };
 843
 844 .float hasweapon_complain_spam;
 845
 846 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 847 {
 848         local float weaponbit, f;
 849         local entity oldself;
 850
 851         if(time < self.hasweapon_complain_spam)
 852                 complain = 0;
 853         if(complain)
 854                 self.hasweapon_complain_spam = time + 0.2;
 855
 856         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 857         {
 858                 if (complain)
 859                         sprint(self, "Invalid weapon\n");
 860                 return FALSE;
 861         }
 862         weaponbit = W_WeaponBit(wpn);
 863         if (cl.weapons & weaponbit)
 864         {
 865                 if (andammo)
 866                 {
 867                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 868                         {
 869                                 f = 1;
 870                         }
 871                         else
 872                         {
 873                                 oldself = self;
 874                                 self = cl;
 875                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 876                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 877                                 self = oldself;
 878                         }
 879                         if (!f)
 880                         {
 881                                 if (complain)
 882                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 883                                 {
 884                                         play2(cl, "weapons/unavailable.wav");
 885                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 886                                 }
 887                                 return FALSE;
 888                         }
 889                 }
 890                 return TRUE;
 891         }
 892         if (complain)
 893         {
 894                 // DRESK - 3/16/07
 895                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 896                 if(weaponsInMap & weaponbit)
 897                 {
 898                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 899
 900                         if(cvar("g_showweaponspawns"))
 901                         {
 902                                 entity e;
 903                                 string s;
 904
 905                                 e = get_weaponinfo(wpn);
 906                                 s = e.model2;
 907
 908                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 909                                 {
 910                                         if(e.classname == "droppedweapon")
 911                                                 continue;
 912                                         if not(e.flags & FL_ITEM)
 913                                                 continue;
 914                                         WaypointSprite_Spawn(
 915                                                 s,
 916                                                 1, 0,
 917                                                 world, e.origin,
 918                                                 self, 0,
 919                                                 world, enemy,
 920                                                 0
 921                                         );
 922                                 }
 923                         }
 924                 }
 925                 else
 926                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 927
 928                 play2(cl, "weapons/unavailable.wav");
 929         }
 930         return FALSE;
 931 };
 932
 933 // Weapon subs
 934 void w_clear()
 935 {
 936         if (self.weapon != -1)
 937                 self.weapon = 0;
 938         if (self.weaponentity)
 939         {
 940                 self.weaponentity.state = WS_CLEAR;
 941                 self.weaponentity.effects = 0;
 942         }
 943 };
 944
 945 void w_ready()
 946 {
 947         if (self.weaponentity)
 948                 self.weaponentity.state = WS_READY;
 949         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 950 };
 951
 952 // Setup weapon for client (after this raise frame will be launched)
 953 void weapon_setup(float windex)
 954 {
 955         entity e;
 956         qcweaponanimation = cvar("sv_qcweaponanimation");
 957         e = get_weaponinfo(windex);
 958         self.items &~= IT_AMMO;
 959         self.items = self.items | e.items;
 960
 961         // the two weapon entities will notice this has changed and update their models
 962         self.weapon = windex;
 963         self.weaponname = e.mdl;
 964         self.bulletcounter = 0;
 965 };
 966
 967 // perform weapon to attack (weaponstate and attack_finished check is here)
 968 .float race_penalty;
 969 float weapon_prepareattack(float secondary, float attacktime)
 970 {
 971         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 972         //if all players readied up and the countdown is running
 973         if(time < game_starttime || time < self.race_penalty) {
 974                 return FALSE;
 975         }
 976
 977         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 978         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 979         {
 980                 // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 981                 float w, ww;
 982                 w = W_WeaponBit(self.weapon);
 983                 self.weapons &~= w;
 984                 ww = w_getbestweapon(self);
 985                 self.weapons |= w;
 986                 if(ww)
 987                         W_SwitchWeapon_Force(self, ww);
 988                 return FALSE;
 989         }
 990
 991         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 992                 return FALSE;
 993
 994         // do not even think about shooting if switching
 995         if(self.switchweapon != self.weapon)
 996                 return FALSE;
 997
 998         if(attacktime >= 0)
 999         {
1000                 // don't fire if previous attack is not finished
1001                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1002                         return FALSE;
1003                 // don't fire while changing weapon
1004                 if (self.weaponentity.state != WS_READY)
1005                         return FALSE;
1006         }
1007         self.weaponentity.state = WS_INUSE;
1008
1009         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1010
1011         // if the weapon hasn't been firing continuously, reset the timer
1012         if(attacktime >= 0)
1013         {
1014                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1015                 {
1016                         ATTACK_FINISHED(self) = time;
1017                         //dprint("resetting attack finished to ", ftos(time), "\n");
1018                 }
1019                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1020         }
1021         self.bulletcounter += 1;
1022         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1023         return TRUE;
1024 };
1025
1026 void weapon_thinkf(float fr, float t, void() func)
1027 {
1028         vector a;
1029         vector of, or, ou;
1030         float restartanim;
1031
1032         if(fr == WFRAME_DONTCHANGE)
1033         {
1034                 fr = self.weaponentity.wframe;
1035                 restartanim = FALSE;
1036         }
1037         else if (fr == WFRAME_IDLE)
1038                 restartanim = FALSE;
1039         else
1040                 restartanim = TRUE;
1041
1042         of = v_forward;
1043         or = v_right;
1044         ou = v_up;
1045
1046         if (self.weaponentity)
1047         {
1048                 self.weaponentity.wframe = fr;
1049                 if (qcweaponanimation)
1050                 {
1051                         if (fr != WFRAME_IDLE)
1052                         {
1053                                 self.weapon_morph0time = time;
1054                                 self.weapon_morph0angles = self.weaponentity.angles;
1055                                 self.weapon_morph0origin = self.weaponentity.origin;
1056
1057                                 self.weapon_morph1angles = '0 0 0';
1058                                 self.weapon_morph1time = time + t;
1059                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1060                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1061
1062                                 self.weapon_morph2angles = '0 0 0';
1063                                 self.weapon_morph2time = time + t;
1064                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1065                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1066
1067                                 self.weapon_morph3angles = '0 0 0';
1068                                 self.weapon_morph3time = time + t;
1069                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1070                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1071
1072                                 self.weapon_morph4angles = '0 0 0';
1073                                 self.weapon_morph4time = time + t;
1074                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1075                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1076
1077                                 if (fr == WFRAME_FIRE1)
1078                                 {
1079                                         self.weapon_morph1angles = '5 0 0';
1080                                         self.weapon_morph1time = time + t * 0.1;
1081                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1082                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1083                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1084                                 }
1085                                 else if (fr == WFRAME_FIRE2)
1086                                 {
1087                                         self.weapon_morph1angles = '10 0 0';
1088                                         self.weapon_morph1time = time + t * 0.1;
1089                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1090                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1091                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1092                                 }
1093                                 else if (fr == WFRAME_RELOAD)
1094                                 {
1095                                         self.weapon_morph1time = time + t * 0.05;
1096                                         self.weapon_morph1angles = '-10 40 0';
1097                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1098                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1099
1100                                         self.weapon_morph2time = time + t * 0.15;
1101                                         self.weapon_morph2angles = '-10 40 5';
1102                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1103                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1104
1105                                         self.weapon_morph3time = time + t * 0.25;
1106                                         self.weapon_morph3angles = '-10 40 0';
1107                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1108                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1109                                 }
1110                         }
1111                 }
1112                 else
1113                 {
1114                         if (fr == WFRAME_IDLE)
1115                                 a = self.weaponentity.anim_idle;
1116                         else if (fr == WFRAME_FIRE1)
1117                                 a = self.weaponentity.anim_fire1;
1118                         else if (fr == WFRAME_FIRE2)
1119                                 a = self.weaponentity.anim_fire2;
1120                         else if (fr == WFRAME_RELOAD)
1121                                 a = self.weaponentity.anim_reload;
1122                         a_z *= g_weaponratefactor;
1123                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1124                 }
1125         }
1126
1127         v_forward = of;
1128         v_right = or;
1129         v_up = ou;
1130
1131         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1132         {
1133                 backtrace("Tried to override initial weapon think function - should this really happen?");
1134         }
1135
1136         t *= W_WeaponRateFactor();
1137
1138         // VorteX: haste can be added here
1139         if (self.weapon_think == w_ready)
1140         {
1141                 self.weapon_nextthink = time;
1142                 //dprint("started firing at ", ftos(time), "\n");
1143         }
1144         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1145         {
1146                 self.weapon_nextthink = time;
1147                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1148         }
1149         self.weapon_nextthink = self.weapon_nextthink + t;
1150         self.weapon_think = func;
1151         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1152
1153         if (restartanim)
1154         if (t)
1155         if (!self.crouch) // shoot anim stands up, this looks bad
1156         {
1157                 local vector anim;
1158                 anim = self.anim_shoot;
1159                 anim_z = anim_y / t;
1160                 setanim(self, anim, FALSE, TRUE, TRUE);
1161         }
1162 };
1163
1164 void weapon_boblayer1(float spd, vector org)
1165 {
1166         // VorteX: haste can be added here
1167 };
1168
1169 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1170 {
1171         vector mdirection;
1172         float mspeed;
1173         float outspeed;
1174         float nstyle;
1175         vector outvelocity;
1176
1177         mvelocity = mvelocity * g_weaponspeedfactor;
1178
1179         mdirection = normalize(mvelocity);
1180         mspeed = vlen(mvelocity);
1181
1182         nstyle = cvar("g_projectiles_newton_style");
1183         if(nstyle == 0)
1184         {
1185                 // absolute velocity
1186                 outvelocity = mvelocity;
1187         }
1188         else if(nstyle == 1)
1189         {
1190                 // true Newtonian projectiles
1191                 outvelocity = pvelocity + mvelocity;
1192         }
1193         else if(nstyle == 2)
1194         {
1195                 // true Newtonian projectiles with automatic aim adjustment
1196                 //
1197                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1198                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1199                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1200                 // PLUS SIGN!
1201                 // not defined?
1202                 // then...
1203                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1204                 // velocity without mdirection component > mspeed
1205                 // fire at smallest possible mspeed that works?
1206                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1207
1208                 vector solution;
1209                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1210                 if(solution_z)
1211                         outspeed = solution_y; // the larger one
1212                 else
1213                 {
1214                         //outspeed = 0; // slowest possible shot
1215                         outspeed = solution_x; // the real part (that is, the average!)
1216                         //dprint("impossible shot, adjusting\n");
1217                 }
1218
1219                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1220                 outvelocity = mdirection * outspeed;
1221         }
1222         else if(nstyle == 3)
1223         {
1224                 // pseudo-Newtonian:
1225                 outspeed = mspeed + mdirection * pvelocity;
1226                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1227                 outvelocity = mdirection * outspeed;
1228         }
1229         else if(nstyle == 4)
1230         {
1231                 // tZorkian:
1232                 outspeed = mspeed + vlen(pvelocity);
1233                 outvelocity = mdirection * outspeed;
1234         }
1235         else
1236                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1237
1238         return outvelocity;
1239 }
1240
1241 void W_AttachToShotorg(entity flash, vector offset)
1242 {
1243         entity xflash;
1244         flash.owner = self;
1245         flash.angles_z = random() * 360;
1246         if(qcweaponanimation)
1247         {
1248                 setorigin(flash, w_shotorg + w_shotdir * 50);
1249                 flash.angles = vectoangles(w_shotdir);
1250                 flash.angles_z = random() * 360;
1251         }
1252         else
1253         {
1254                 setattachment(flash, self.weaponentity, "shot");
1255                 setorigin(flash, offset);
1256
1257                 xflash = spawn();
1258                 copyentity(flash, xflash);
1259
1260                 flash.viewmodelforclient = self;
1261
1262                 if(self.weaponentity.oldorigin_x > 0)
1263                 {
1264                         setattachment(xflash, self.exteriorweaponentity, "");
1265                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1266                 }
1267                 else
1268                 {
1269                         setattachment(xflash, self.exteriorweaponentity, "shot");
1270                 }
1271         }
1272 }
1273
1274 vector cliptoplane(vector v, vector p)
1275 {
1276         return v - (v * p) * p;
1277 }
1278
1279 vector solve_cubic_pq(float p, float q)
1280 {
1281         float D, u, v, a;
1282         D = q*q/4.0 + p*p*p/27.0;
1283         if(D < 0)
1284         {
1285                 // irreducibilis
1286                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1287                 u = sqrt(-4.0/3.0 * p);
1288                 // a in range 0..pi/3
1289                 // cos(a)
1290                 // cos(a + 2pi/3)
1291                 // cos(a + 4pi/3)
1292                 return
1293                         u *
1294                         (
1295                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1296                                 +
1297                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1298                                 +
1299                                 '0 0 1' * cos(a)
1300                         );
1301         }
1302         else if(D == 0)
1303         {
1304                 // simple
1305                 if(p == 0)
1306                         return '0 0 0';
1307                 u = 3*q/p;
1308                 v = -u/2;
1309                 if(u >= v)
1310                         return '1 1 0' * v + '0 0 1' * u;
1311                 else
1312                         return '0 1 1' * v + '1 0 0' * u;
1313         }
1314         else
1315         {
1316                 // cardano
1317                 u = cbrt(-q/2.0 + sqrt(D));
1318                 v = cbrt(-q/2.0 - sqrt(D));
1319                 return '1 1 1' * (u + v);
1320         }
1321 }
1322 vector solve_cubic_abcd(float a, float b, float c, float d)
1323 {
1324         // y = 3*a*x + b
1325         // x = (y - b) / 3a
1326         float p, q;
1327         vector v;
1328         p = (9*a*c - 3*b*b);
1329         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1330         v = solve_cubic_pq(p, q);
1331         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1332         if(a < 0)
1333                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1334         return v;
1335 }
1336
1337 vector findperpendicular(vector v)
1338 {
1339         vector p;
1340         p_x = v_z;
1341         p_y = -v_x;
1342         p_z = v_y;
1343         return normalize(cliptoplane(p, v));
1344 }
1345
1346 vector W_CalculateProjectileSpread(vector forward, float spread)
1347 {
1348         float sigma;
1349         vector v1, v2;
1350         float dx, dy, r;
1351         float sstyle;
1352         if(spread <= 0)
1353                 return forward;
1354         sstyle = cvar("g_projectiles_spread_style");
1355
1356         if(sstyle == 0)
1357         {
1358                 // this is the baseline for the spread value!
1359                 // standard deviation: sqrt(2/5)
1360                 // density function: sqrt(1-r^2)
1361                 return forward + randomvec() * spread;
1362         }
1363         else if(sstyle == 1)
1364         {
1365                 // same thing, basically
1366                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1367         }
1368         else if(sstyle == 2)
1369         {
1370                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1371                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1372                 v1 = findperpendicular(forward);
1373                 v2 = cross(forward, v1);
1374                 // random point on unit circle
1375                 dx = random() * 2 * M_PI;
1376                 dy = sin(dx);
1377                 dx = cos(dx);
1378                 // radius in our dist function
1379                 r = random();
1380                 r = sqrt(r);
1381                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1382         }
1383         else if(sstyle == 3) // gauss 3d
1384         {
1385                 sigma = spread * 0.44721359549996; // match baseline stddev
1386                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1387                 v1 = forward;
1388                 v1_x += gsl_ran_gaussian(sigma);
1389                 v1_y += gsl_ran_gaussian(sigma);
1390                 v1_z += gsl_ran_gaussian(sigma);
1391                 return v1;
1392         }
1393         else if(sstyle == 4) // gauss 2d
1394         {
1395                 sigma = spread * 0.44721359549996; // match baseline stddev
1396                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1397                 v1_x = gsl_ran_gaussian(sigma);
1398                 v1_y = gsl_ran_gaussian(sigma);
1399                 v1_z = gsl_ran_gaussian(sigma);
1400                 return normalize(forward + cliptoplane(v1, forward));
1401         }
1402         else if(sstyle == 5) // 1-r
1403         {
1404                 sigma = spread * 1.154700538379252; // match baseline stddev
1405                 v1 = findperpendicular(forward);
1406                 v2 = cross(forward, v1);
1407                 // random point on unit circle
1408                 dx = random() * 2 * M_PI;
1409                 dy = sin(dx);
1410                 dx = cos(dx);
1411                 // radius in our dist function
1412                 r = random();
1413                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1414                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1415         }
1416         else if(sstyle == 6) // 1-r^2
1417         {
1418                 sigma = spread * 1.095445115010332; // match baseline stddev
1419                 v1 = findperpendicular(forward);
1420                 v2 = cross(forward, v1);
1421                 // random point on unit circle
1422                 dx = random() * 2 * M_PI;
1423                 dy = sin(dx);
1424                 dx = cos(dx);
1425                 // radius in our dist function
1426                 r = random();
1427                 r = sqrt(1 - r);
1428                 r = sqrt(1 - r);
1429                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1430         }
1431         else if(sstyle == 7) // (1-r) (2-r)
1432         {
1433                 sigma = spread * 1.224744871391589; // match baseline stddev
1434                 v1 = findperpendicular(forward);
1435                 v2 = cross(forward, v1);
1436                 // random point on unit circle
1437                 dx = random() * 2 * M_PI;
1438                 dy = sin(dx);
1439                 dx = cos(dx);
1440                 // radius in our dist function
1441                 r = random();
1442                 r = 1 - sqrt(r);
1443                 r = 1 - sqrt(r);
1444                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1445         }
1446         else
1447                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1448         return '0 0 0';
1449         /*
1450          * how to derive falloff functions:
1451          * rho(r) := (2-r) * (1-r);
1452          * a : 0;
1453          * b : 1;
1454          * rhor(r) := r * rho(r);
1455          * cr(t) := integrate(rhor(r), r, a, t);
1456          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1457          * variance : scr(b) / cr(b);
1458          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1459          * sqrt(0.4 / variance), numer;
1460          */
1461 }
1462
1463 #if 0
1464 float mspercallsum;
1465 float mspercallsstyle;
1466 float mspercallcount;
1467 #endif
1468 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float spread)
1469 {
1470         if(missile.owner == world)
1471                 error("Unowned missile");
1472
1473         dir = dir + upDir * (pUpSpeed / pSpeed);
1474         pSpeed *= vlen(dir);
1475         dir = normalize(dir);
1476
1477 #if 0
1478         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1479         {
1480                 mspercallsum = mspercallcount = 0;
1481                 mspercallsstyle = cvar("g_projectiles_spread_style");
1482         }
1483         mspercallsum -= gettime(GETTIME_HIRES);
1484 #endif
1485         dir = W_CalculateProjectileSpread(dir, spread);
1486 #if 0
1487         mspercallsum += gettime(GETTIME_HIRES);
1488         mspercallcount += 1;
1489         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1490 #endif
1491
1492         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1493 }
1494
1495 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1496 {
1497         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, spread);
1498 }
1499
1500 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_spread"))
1501 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, cvar(#s "_spread"))