data/qcsrc/server/cl_weapons.qc

   1 // switch between weapons
   2 void W_SwitchWeapon(float imp)
   3 {
   4         if (self.weapon != imp)
   5         if (client_hasweapon(self, imp, TRUE, TRUE))
   6                 W_SwitchWeapon_Force(self, imp);
   7 };
   8
   9 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain)
  10 {
  11         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast;
  12         n = tokenize(weaponorder);
  13         switchtonext = switchtolast = 0;
  14         first_valid = prev_valid = 0;
  15
  16         if(dir == 0)
  17                 switchtonext = 1;
  18
  19         for(i = 0; i < n; ++i)
  20         {
  21                 weaponwant = stof(argv(i));
  22
  23                 if(imp >= 0)
  24                         if((get_weaponinfo(weaponwant)).impulse != imp)
  25                                 continue;
  26
  27                 if(client_hasweapon(pl, weaponwant, TRUE, FALSE))
  28                 {
  29                         if(switchtonext)
  30                                 return weaponwant;
  31                         if(!first_valid)
  32                                 first_valid = weaponwant;
  33                         if(weaponwant == pl.switchweapon)
  34                         {
  35                                 if(dir >= 0)
  36                                         switchtonext = 1;
  37                                 else if(prev_valid)
  38                                         return prev_valid;
  39                                 else
  40                                         switchtolast = 1;
  41                         }
  42                         prev_valid = weaponwant;
  43                 }
  44         }
  45         if(first_valid)
  46         {
  47                 if(switchtolast)
  48                         return prev_valid;
  49                 else
  50                         return first_valid;
  51         }
  52         // complain
  53         if(complain)
  54         {
  55                 for(i = 0; i < n; ++i)
  56                 {
  57                         weaponwant = stof(argv(i));
  58                         if(imp >= 0)
  59                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  60                                         continue;
  61                         client_hasweapon(pl, weaponwant, TRUE, TRUE);
  62                 }
  63         }
  64         return 0;
  65 }
  66
  67 void W_CycleWeapon(string weaponorder, float dir)
  68 {
  69         float w;
  70         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1);
  71         if(w > 0)
  72                 W_SwitchWeapon(w);
  73 }
  74
  75 void W_NextWeaponOnImpulse(float imp)
  76 {
  77         float w;
  78         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1);
  79         if(w > 0)
  80                 W_SwitchWeapon(w);
  81 }
  82
  83 // next weapon
  84 void W_NextWeapon(float list)
  85 {
  86         if(list == 0)
  87                 W_CycleWeapon(weaponpriority_hudselector_0, -1);
  88         else if(list == 1)
  89                 W_CycleWeapon(weaponpriority_hudselector_1, -1);
  90         else if(list == 2)
  91                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
  92 }
  93
  94 // prev weapon
  95 void W_PreviousWeapon(float list)
  96 {
  97         if(list == 0)
  98                 W_CycleWeapon(weaponpriority_hudselector_0, +1);
  99         else if(list == 1)
 100                 W_CycleWeapon(weaponpriority_hudselector_1, +1);
 101         else if(list == 2)
 102                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 103 }
 104
 105 string W_FixWeaponOrder(string order, float complete)
 106 {
 107         return fixPriorityList(order, WEP_FIRST, WEP_LAST, complete);
 108 }
 109
 110 string W_FixWeaponOrder_AllowIncomplete(string order)
 111 {
 112         return W_FixWeaponOrder(order, 0);
 113 }
 114
 115 string W_FixWeaponOrder_ForceComplete(string order)
 116 {
 117         if(order == "")
 118                 order = cvar_string("cl_weaponpriority");
 119         return W_FixWeaponOrder(order, 1);
 120 }
 121
 122 float w_getbestweapon(entity e)
 123 {
 124         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, 0);
 125 };
 126
 127 // generic weapons table
 128 // TODO should they be macros instead?
 129 float weapon_action(float wpn, float wrequest)
 130 {
 131         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 132 };
 133
 134 string W_Name(float weaponid)
 135 {
 136         return (get_weaponinfo(weaponid)).message;
 137 }
 138
 139 float W_WeaponBit(float wpn)
 140 {
 141         return (get_weaponinfo(wpn)).weapons;
 142 }
 143
 144 float W_AmmoItemCode(float wpn)
 145 {
 146         return (get_weaponinfo(wpn)).items;
 147 }
 148
 149 void thrown_wep_think()
 150 {
 151         self.solid = SOLID_TRIGGER;
 152         self.owner = world;
 153         SUB_SetFade(self, time + 20, 1);
 154 }
 155
 156 // returns amount of ammo used, or -1 for failure, or 0 for no ammo count
 157 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 158 {
 159         entity oldself, wep;
 160         float wa, ammo;
 161         var .float ammofield;
 162
 163         wep = spawn();
 164
 165         setorigin(wep, org);
 166         wep.classname = "droppedweapon";
 167         wep.velocity = velo;
 168         wep.owner = wep.enemy = own;
 169         wep.classname = "droppedweapon";
 170         wep.flags = wep.flags | FL_TOSSED;
 171         wep.colormap = own.colormap;
 172
 173         wa = W_AmmoItemCode(wpn);
 174         if(wa == IT_SUPERWEAPON || wa == 0)
 175         {
 176                 oldself = self;
 177                 self = wep;
 178                 weapon_defaultspawnfunc(wpn);
 179                 self = oldself;
 180                 if(startitem_failed)
 181                         return -1;
 182                 wep.think = thrown_wep_think;
 183                 wep.nextthink = time + 0.5;
 184                 return 0;
 185         }
 186         else
 187         {
 188                 ammofield = Item_CounterField(wa);
 189                 oldself = self;
 190                 self = wep;
 191                 weapon_defaultspawnfunc(wpn);
 192                 self = oldself;
 193                 if(startitem_failed)
 194                         return -1;
 195                 if(doreduce)
 196                 {
 197                         ammo = min(own.ammofield, wep.ammofield);
 198                         wep.ammofield = ammo;
 199                         own.ammofield -= ammo;
 200                 }
 201                 wep.think = thrown_wep_think;
 202                 wep.nextthink = time + 0.5;
 203                 return wep.ammofield;
 204         }
 205 }
 206
 207 // toss current weapon
 208 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 209 {
 210         local float w, a, wb;
 211
 212         w = self.weapon;
 213         if (w == 0)
 214                 return; // just in case
 215         if (w == WEP_LASER)
 216                 return; // just in case
 217         if (g_rocketarena)
 218                 return;
 219         if (g_lms)
 220                 return;
 221         if (g_nixnex)
 222                 return;
 223         if (!cvar("g_pickup_items"))
 224                 return;
 225
 226         wb = W_WeaponBit(w);
 227         if(self.weapons & wb != wb)
 228                 return;
 229
 230         self.weapons = self.weapons - wb;
 231         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 232         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 233         if(a < 0)
 234                 return;
 235         if(self.health >= 1)
 236         {
 237                 if(a == 0)
 238                         sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 239                 else
 240                         sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", ftos(a), " ", Item_CounterFieldName(W_AmmoItemCode(w)), "\n"));
 241         }
 242 };
 243
 244 // Bringed back weapon frame
 245 void W_WeaponFrame()
 246 {
 247         if((arena_roundbased && time < warmup) || ((time < restart_countdown) && !cvar("sv_ready_restart_after_countdown")))
 248                 return;
 249
 250         if (!self.weaponentity || self.health < 1)
 251                 return; // Dead player can't use weapons and injure impulse commands
 252
 253         if(!self.switchweapon)
 254         {
 255                 self.weapon = 0;
 256                 self.weaponentity.state = WS_CLEAR;
 257                 return;
 258         }
 259
 260         makevectors(self.v_angle);
 261
 262         // Change weapon
 263         if (self.weapon != self.switchweapon)
 264         {
 265                 if (self.weaponentity.state == WS_CLEAR)
 266                 {
 267                         player_setanim(self.anim_draw, FALSE, TRUE, TRUE);
 268                         self.weaponentity.state = WS_RAISE;
 269                         weapon_action(self.switchweapon, WR_SETUP);
 270                         // VorteX: add player model weapon select frame here
 271                         // setcustomframe(PlayerWeaponRaise);
 272                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 273                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 274                 }
 275                 else if (self.weaponentity.state == WS_READY)
 276                 {
 277 #ifndef INDEPENDENT_ATTACK_FINISHED
 278                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 279                         {
 280 #endif
 281                         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 282                         sound (self, CHAN_WEAPON2, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 283                         self.weaponentity.state = WS_DROP;
 284                         // set up weapon switch think in the future, and start drop anim
 285                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 286                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 287 #ifndef INDEPENDENT_ATTACK_FINISHED
 288                         }
 289 #endif
 290                 }
 291         }
 292
 293         float wb;
 294         wb = W_WeaponBit(self.weapon);
 295
 296         // call the think code which may fire the weapon
 297         // and do so multiple times to resolve framerate dependency issues if the
 298         // server framerate is very low and the weapon fire rate very high
 299         local float c;
 300         c = 0;
 301         while (c < 5)
 302         {
 303                 c = c + 1;
 304                 if(wb && self.weapons & wb == 0)
 305                 {
 306                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 307                         wb = 0;
 308                 }
 309                 if(wb)
 310                         weapon_action(self.weapon, WR_THINK);
 311                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 312                         self.weapon_think();
 313         }
 314
 315         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 316         //if (ATTACK_FINISHED(self) < time)
 317         //      ATTACK_FINISHED(self) = time;
 318
 319         //if (self.weapon_nextthink < time)
 320         //      self.weapon_nextthink = time;
 321
 322         // update currentammo incase it has changed
 323         if (self.items & IT_CELLS)
 324                 self.currentammo = self.ammo_cells;
 325         else if (self.items & IT_ROCKETS)
 326                 self.currentammo = self.ammo_rockets;
 327         else if (self.items & IT_NAILS)
 328                 self.currentammo = self.ammo_nails;
 329         else if (self.items & IT_SHELLS)
 330                 self.currentammo = self.ammo_shells;
 331         else
 332                 self.currentammo = 1;
 333
 334 };
 335
 336 float nixnex_weapon;
 337 float nixnex_nextchange;
 338 float nixnex_nextweapon;
 339 .float nixnex_lastchange_id;
 340 .float nixnex_lastinfotime;
 341 .float nixnex_nextincr;
 342
 343 void Nixnex_ChooseNextWeapon()
 344 {
 345         float numberof, id;
 346         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 347         if(g_nixnex_with_laser)
 348                 numberof = numberof - 1;
 349         id = WEP_FIRST + ceil(random() * numberof) - 1;
 350
 351         if(g_nixnex_with_laser) // skip the laser if needed
 352                 id = id + 1;
 353
 354         if(id >= nixnex_weapon) // skip the current weapon
 355                 id = id + 1;
 356
 357         if(id < WEP_FIRST) // can't happen, but to be sure...
 358         {
 359                 dprint("Won't happen (id < WEP_FIRST)\n");
 360                 id = WEP_FIRST;
 361         }
 362         if(id > WEP_LAST) // either
 363         {
 364                 dprint("Won't happen (id > WEP_LAST)\n");
 365                 id = WEP_LAST;
 366         }
 367
 368         nixnex_nextweapon = id;
 369 }
 370
 371 void Nixnex_GiveCurrentWeapon()
 372 {
 373         float dt;
 374         if(g_nixnex)
 375         {
 376                 if(!nixnex_nextweapon)
 377                         Nixnex_ChooseNextWeapon();
 378
 379                 dt = ceil(nixnex_nextchange - time);
 380
 381                 if(dt <= 0)
 382                 {
 383                         nixnex_weapon = nixnex_nextweapon;
 384                         nixnex_nextweapon = 0;
 385                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 386                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 387                 }
 388
 389                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 390                 {
 391                         self.nixnex_lastchange_id = nixnex_nextchange;
 392                         if (self.items & IT_UNLIMITED_AMMO)
 393                         {
 394                                 self.ammo_shells = cvar("g_pickup_shells_max");
 395                                 self.ammo_nails = cvar("g_pickup_nails_max");
 396                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 397                                 self.ammo_cells = cvar("g_pickup_cells_max");
 398                         }
 399                         else
 400                         {
 401                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 402                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 403                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 404                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 405                         }
 406                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 407                         if(dt >= 1 && dt <= 5)
 408                                 self.nixnex_lastinfotime = -42;
 409                         else
 410                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 411                 }
 412                 if(self.nixnex_lastinfotime != dt)
 413                 {
 414                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 415                         if(dt >= 1 && dt <= 5)
 416                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 417                 }
 418
 419                 if(!(self.items & IT_UNLIMITED_AMMO) && time > self.nixnex_nextincr)
 420                 {
 421                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 422                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 423                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 424                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 425                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 426                 }
 427
 428                 self.weapons = 0;
 429                 if(g_nixnex_with_laser)
 430                         self.weapons = self.weapons | WEPBIT_LASER;
 431                 self.weapons = self.weapons | W_WeaponBit(nixnex_weapon);
 432
 433                 if(self.switchweapon != nixnex_weapon)
 434                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 435                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 436                                         W_SwitchWeapon(nixnex_weapon);
 437         }
 438 }
 439
 440 void RegisterWeapons()
 441 {
 442         // %weaponaddpoint
 443         register_weapon(WEP_LASER,            w_laser,     0,              1, 1,     0, "laser",     "laser",           "Laser");
 444         register_weapon(WEP_SHOTGUN,          w_shotgun,   IT_SHELLS,      2, 1,  2500, "shotgun",   "shotgun",         "Shotgun");
 445         register_weapon(WEP_UZI,              w_uzi,       IT_NAILS,       3, 1,  5000, "uzi",       "uzi",             "Machine Gun");
 446         register_weapon(WEP_GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS,     4, 1,  5000, "gl",        "grenadelauncher", "Mortar");
 447         register_weapon(WEP_ELECTRO,          w_electro,   IT_CELLS,       5, 1,  5000, "electro",   "electro",         "Electro");
 448         register_weapon(WEP_CRYLINK,          w_crylink,   IT_CELLS,       6, 1,  5000, "crylink",   "crylink",         "Crylink");
 449         register_weapon(WEP_NEX,              w_nex,       IT_CELLS,       7, 1, 10000, "nex",       "nex",             "Nex");
 450         register_weapon(WEP_HAGAR,            w_hagar,     IT_ROCKETS,     8, 1,  5000, "hagar",     "hagar",           "Hagar");
 451         register_weapon(WEP_ROCKET_LAUNCHER,  w_rlauncher, IT_ROCKETS,     9, 1, 10000, "rl",        "rocketlauncher",  "Rocket Launcher");
 452         register_weapon(WEP_PORTO,            w_porto,     IT_SUPERWEAPON, 0, 0,     0, "porto" ,    "porto",           "Port-O-Launch");
 453         register_weapon(WEP_MINSTANEX,        w_minstanex, IT_CELLS,       7, 0, 10000, "minstanex", "minstanex",       "MinstaNex");
 454         register_weapons_done();
 455 }