data/qcsrc/server/cl_player.qc

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.colormap = oldself.colormap;
  28         self.iscreature = oldself.iscreature;
  29         self.angles = oldself.angles;
  30         self.avelocity = oldself.avelocity;
  31         self.classname = "body";
  32         self.damageforcescale = oldself.damageforcescale;
  33         self.effects = oldself.effects;
  34         self.event_damage = oldself.event_damage;
  35         self.frame = oldself.frame;
  36         self.health = oldself.health;
  37         self.armorvalue = oldself.armorvalue;
  38         self.armortype = oldself.armortype;
  39         self.model = oldself.model;
  40         self.modelindex = oldself.modelindex;
  41         self.movetype = oldself.movetype;
  42         self.nextthink = oldself.nextthink;
  43         self.skin = oldself.skin;
  44         self.solid = oldself.solid;
  45         self.takedamage = oldself.takedamage;
  46         self.think = oldself.think;
  47         self.gibrandom = oldself.gibrandom;
  48         self.customizeentityforclient = oldself.customizeentityforclient;
  49         if (keepvelocity == 1)
  50                 self.velocity = oldself.velocity;
  51         self.oldvelocity = self.velocity;
  52         self.fade_time = oldself.fade_time;
  53         self.fade_rate = oldself.fade_rate;
  54         //self.weapon = oldself.weapon;
  55         setorigin(self, oldself.origin);
  56         setsize(self, oldself.mins, oldself.maxs);
  57         self.oldorigin = oldself.origin;
  58         self = oldself;
  59 }
  60
  61 void player_anim (void)
  62 {
  63         if (self.deadflag != DEAD_NO)
  64         {
  65                 if (time > self.dead_time)
  66                 {
  67                         if (self.maxs_z > 5)
  68                         {
  69                                 self.maxs_z = 5;
  70                                 setsize(self, self.mins, self.maxs);
  71                         }
  72                         self.frame = self.dead_frame;
  73                 }
  74                 else
  75                         self.frame = self.die_frame;
  76                 return;
  77         }
  78
  79
  80         if (self.crouch)
  81         {
  82                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  83                         self.frame = $duckwalk;
  84                 else
  85                         self.frame = $duckidle;
  86         }
  87         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  88         {
  89                 if (self.movement_x > 0 && self.movement_y == 0)
  90                         self.frame = $run;
  91                 else if (self.movement_x < 0 && self.movement_y == 0)
  92                         self.frame = $runbackwards;
  93                 else if (self.movement_x == 0 && self.movement_y > 0)
  94                         self.frame = $straferight;
  95                 else if (self.movement_x == 0 && self.movement_y < 0)
  96                         self.frame = $strafeleft;
  97                 else if (self.movement_x > 0 && self.movement_y > 0)
  98                         self.frame = $forwardright;
  99                 else if (self.movement_x > 0 && self.movement_y < 0)
 100                         self.frame = $forwardleft;
 101                 else if (self.movement_x < 0 && self.movement_y > 0)
 102                         self.frame = $backright;
 103                 else if (self.movement_x < 0 && self.movement_y < 0)
 104                         self.frame = $backleft;
 105                 else
 106                         self.frame = $run;
 107         }
 108         else if (self.pain_finished > time)
 109                 self.frame = self.pain_frame;
 110         else if (self.attack_finished > time)
 111                 self.frame = $shoot;
 112         else
 113                 self.frame = $idle;
 114
 115         if (!(self.flags & FL_ONGROUND))
 116         {
 117                 if (self.crouch)
 118                         self.frame = $duckidle;         // if player is crouching while in air, show crouch frame
 119                 else
 120                         self.frame = $jump;
 121         }
 122 }
 123 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 124
 125 void SpawnThrownWeapon (vector org, float w)
 126 {
 127         if (!cvar("g_pickup_items"))
 128         if (!cvar("g_minstagib"))
 129                 return;
 130         if (!w)
 131                 return;
 132         if (w == IT_LASER)
 133                 return;
 134
 135         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 136 }
 137
 138 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 139 {
 140         local float take, save;
 141         te_blood (hitloc, force, damage);
 142         // damage resistance (ignore most of the damage from a bullet or similar)
 143         damage = max(damage - 5, 1);
 144
 145         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 146         take = bound(0, damage - save, damage);
 147
 148         if (save > 10)
 149                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 150         else if (take > 30)
 151                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 152         else if (take > 10)
 153                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 154
 155         if (take > 50)
 156                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 157         if (take > 100)
 158                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 159
 160         if (!(self.flags & FL_GODMODE))
 161         {
 162                 self.armorvalue = self.armorvalue - save;
 163                 self.health = self.health - take;
 164                 // pause regeneration for 5 seconds
 165                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 166         }
 167         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 168         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 169         self.dmg_inflictor = inflictor;
 170
 171         if (self.health <= -50)
 172         {
 173                 // don't use any animations as a gib
 174                 self.frame = 0;
 175                 self.dead_frame = 0;
 176                 self.die_frame = 0;
 177                 // view just above the floor
 178                 self.view_ofs = '0 0 4';
 179
 180                 // make a juicy mess
 181                 local float multiplier;
 182                 multiplier = 1;
 183                 if (cvar("ekg"))
 184                         multiplier = 5;
 185                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 186
 187                 // make a meaty mess
 188                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 189                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 190
 191                 local float c;
 192                 c = 0;
 193                 while (c < multiplier)
 194                 {
 195                         c = c + 1;
 196                         TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 197                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 198                         TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 199                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 200                         TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 201                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 202                         TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 203
 204                         // these destory on impact
 205                         TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 206                         //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 207                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 208                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 209                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 210                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 211                 }
 212
 213                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 214         }
 215 }
 216
 217 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 218 {
 219         local float take, save, waves, sdelay;
 220
 221         te_blood (hitloc, force, damage);
 222         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 223         {
 224                 if (random() > 0.5)
 225                         self.pain_frame = $pain1;
 226                 else
 227                         self.pain_frame = $pain2;
 228                 self.pain_finished = time + 0.5;        //Supajoe
 229
 230                 // throw off bot aim temporarily
 231                 local float shake;
 232                 shake = damage * 5 / (bound(0,skill,100) + 1);
 233                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 234                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 235         }
 236
 237         if(cvar("g_arena"))
 238         if(numspawned < 2)
 239                 return;
 240
 241         if (!cvar("g_minstagib"))
 242         {
 243                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 244                 take = bound(0, damage - save, damage);
 245         }
 246         else
 247         {
 248                 save = 0;
 249                 take = damage;
 250         }
 251
 252         if (save > 10)
 253                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 254         else if (take > 30)
 255                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 256         else if (take > 10)
 257                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 258
 259         if (take > 50)
 260                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 261         if (take > 100)
 262                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 263
 264         if (time > self.spawnshieldtime)
 265         {
 266                 if (!(self.flags & FL_GODMODE))
 267                 {
 268                         self.armorvalue = self.armorvalue - save;
 269                         self.health = self.health - take;
 270                         // pause regeneration for 5 seconds
 271                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 272                 }
 273                 else
 274                         self.max_armorvalue += (save + take);
 275         }
 276         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 277         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 278         self.dmg_inflictor = inflictor;
 279
 280         if(attacker == self)
 281         {
 282                 // don't reset pushltime for self damage as it may be an attempt to
 283                 // escape a lava pit or similar
 284                 //self.pushltime = 0;
 285         }
 286         else if(attacker.classname == "player" || attacker.classname == "gib")
 287         {
 288                 self.pusher = attacker;
 289                 self.pushltime = time + cvar("g_maxpushtime");
 290         }
 291         else if(time < self.pushltime)
 292         {
 293                 attacker = self.pusher;
 294                 self.pushltime = max(self.pushltime, time + 0.6);
 295         }
 296         else
 297                 self.pushltime = 0;
 298
 299         if (self.health < 1)
 300         {
 301                 self.deaths += 1;
 302
 303                 // become fully visible
 304                 self.alpha = 1;
 305                 // clear selected player display
 306                 ClearSelectedPlayer();
 307                 // throw a weapon
 308                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 309                 // print an obituary message
 310                 Obituary (attacker, self, deathtype);
 311                 DropAllRunes(self);
 312                 if(self == attacker)
 313                         kh_Key_DropAll(self, TRUE);
 314                 else if(attacker.classname == "player" || attacker.classname == "gib")
 315                         kh_Key_DropAll(self, FALSE);
 316                 else
 317                         kh_Key_DropAll(self, TRUE);
 318                 if(self.flagcarried)
 319                         DropFlag(self.flagcarried);
 320                 // clear waypoints
 321                 WaypointSprite_PlayerDead();
 322                 // make the corpse upright (not tilted)
 323                 self.angles_x = 0;
 324                 self.angles_z = 0;
 325                 // don't spin
 326                 self.avelocity = '0 0 0';
 327                 // view from the floor
 328                 self.view_ofs = '0 0 -8';
 329                 // toss the corpse
 330                 self.movetype = MOVETYPE_TOSS;
 331                 // shootable corpse
 332                 self.solid = SOLID_CORPSE;
 333                 // don't stick to the floor
 334                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 335                 // dying animation
 336                 self.deadflag = DEAD_DYING;
 337                 // when to allow respawn
 338                 sdelay = 0;
 339                 waves = 0;
 340                 if(cvar("g_respawn_mapsettings"))
 341                 {
 342                         sdelay = cvar("g_respawn_mapsettings_delay");
 343                         waves = cvar("g_respawn_mapsettings_waves");
 344                 }
 345                 if(!sdelay)
 346                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 347                 if(!sdelay)
 348                         sdelay = cvar("g_respawn_delay");
 349                 if(!waves)
 350                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 351                 if(!waves)
 352                         waves = cvar("g_respawn_waves");
 353                 if(waves)
 354                         self.death_time = ceil((time + sdelay) / waves) * waves;
 355                 else
 356                         self.death_time = time + sdelay;
 357                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 358                         self.respawn_countdown = 10; // first number to count down from is 10
 359                 else
 360                         self.respawn_countdown = -1; // do not count down
 361                 // when to switch to the dead_frame
 362                 self.dead_time = time + 2;
 363                 if (random() < 0.5)
 364                 {
 365                         self.die_frame = $die1;
 366                         self.dead_frame = $dead1;
 367                 }
 368                 else
 369                 {
 370                         self.die_frame = $die2;
 371                         self.dead_frame = $dead2;
 372                 }
 373                 // start the animation
 374                 player_anim();
 375                 // set damage function to corpse damage
 376                 self.event_damage = PlayerCorpseDamage;
 377                 // call the corpse damage function just in case it wants to gib
 378                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 379                 // set up to fade out later
 380                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 381
 382                 // remove laserdot
 383                 if(self.weaponentity)
 384                         if(self.weaponentity.lasertarget)
 385                                 remove(self.weaponentity.lasertarget);
 386
 387                 if(clienttype(self) == CLIENTTYPE_REAL)
 388                 {
 389                         self.fixangle = TRUE;
 390                         //msg_entity = self;
 391                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 392                         //WriteAngle (MSG_ONE, self.v_angle_x);
 393                         //WriteAngle (MSG_ONE, self.v_angle_y);
 394                         //WriteAngle (MSG_ONE, 80);
 395                 }
 396
 397                 if(cvar("g_arena"))
 398                         Spawnqueue_Unmark(self);
 399         }
 400 }
 401
 402 float UpdateSelectedPlayer_countvalue(float v)
 403 {
 404         return max(0, (v - 1.0) / 0.5);
 405 }
 406
 407 // returns: -2 if no hit, otherwise cos of the angle
 408 // uses the global v_angle
 409 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 410 {
 411         vector so, d;
 412         float c;
 413
 414         if(p == self)
 415                 return -2;
 416
 417         if(p.deadflag)
 418                 return -2;
 419
 420         so = self.origin + self.view_ofs;
 421         d = p.origin - so;
 422
 423         // misaimed?
 424         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 425                 return -2;
 426
 427         // now find the cos of the angle...
 428         c = normalize(d) * v_forward;
 429
 430         if(c <= mincosangle)
 431                 return -2;
 432
 433         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 434         if(trace_fraction < 1)
 435                 return -2;
 436
 437         return c;
 438 }
 439
 440 void ClearSelectedPlayer()
 441 {
 442         if(self.selected_player)
 443         {
 444                 centerprint_expire(self, CENTERPRIO_POINT);
 445                 self.selected_player = world;
 446                 self.selected_player_display_needs_update = FALSE;
 447         }
 448 }
 449
 450 void UpdateSelectedPlayer()
 451 {
 452         entity selected;
 453         float selected_score;
 454         selected = world;
 455         selected_score = 0.95; // 18 degrees
 456
 457         if(!cvar("sv_allow_shownames"))
 458                 return;
 459
 460         if(clienttype(self) != CLIENTTYPE_REAL)
 461                 return;
 462
 463         if(self.cvar_cl_shownames == 0)
 464                 return;
 465
 466         if(self.cvar_cl_shownames == 1 && !teams_matter)
 467                 return;
 468
 469         makevectors(self.v_angle); // sets v_forward
 470
 471         // 1. cursor trace is always right
 472         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 473         {
 474                 selected = self.cursor_trace_ent;
 475         }
 476         else
 477         {
 478                 // 2. if we don't have a cursor trace, find the player which is least
 479                 //    mis-aimed at
 480                 entity p;
 481                 FOR_EACH_PLAYER(p)
 482                 {
 483                         float c;
 484                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 485                         if(c >= -1)
 486                         {
 487                                 selected = p;
 488                                 selected_score = c;
 489                         }
 490                 }
 491         }
 492
 493         if(selected)
 494         {
 495                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 496         }
 497         else
 498         {
 499                 if(time < self.selected_player_display_timeout)
 500                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 501                                 selected = self.selected_player;
 502         }
 503
 504         if(selected)
 505         {
 506                 if(selected == self.selected_player)
 507                 {
 508                         float save;
 509                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 510                         self.selected_player_count = self.selected_player_count + frametime;
 511                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 512                         {
 513                                 string namestr, healthstr;
 514                                 namestr = playername(selected);
 515                                 if(teams_matter)
 516                                 {
 517                                         healthstr = ftos(floor(selected.health));
 518                                         if(self.team == selected.team)
 519                                         {
 520                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 521                                                 self.selected_player_display_needs_update = TRUE;
 522                                         }
 523                                 }
 524                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 525                         }
 526                 }
 527                 else
 528                 {
 529                         ClearSelectedPlayer();
 530                         self.selected_player = selected;
 531                         self.selected_player_time = time;
 532                         self.selected_player_count = 0;
 533                         self.selected_player_display_needs_update = FALSE;
 534                 }
 535         }
 536         else
 537         {
 538                 ClearSelectedPlayer();
 539         }
 540
 541         if(self.selected_player)
 542                 self.last_selected_player = self.selected_player;
 543 }